В уроці розглядаються різні способи отримання віку за датою народження в Excel. Ви дізнаєтеся кілька формул для обчислення віку у вигляді кількості повних років, отримаєте точний вік в роках, місяцях і днях на сьогоднішню дату або на певну дату.

В Excel немає спеціальної функції для обчислення віку, проте існує кілька різних способів перетворення дати народження у вік. У цьому уроці ми пояснимо переваги та недоліки кожного способу, покажемо, як скласти ідеальну формулу для обчислення віку в Excel та налаштувати її для вирішення конкретних завдань.

Як розрахувати вік за датою народження в Excel

У повсякденному житті все частіше постає питання " Скільки тобі років? " зазвичай має на увазі відповідь із зазначенням, скільки років ви прожили. У Microsoft Excel можна скласти формулу для обчислення точного віку в місяцях, днях, годинах і навіть хвилинах. Але давайте будемо традиційними, і спочатку дізнаємося, як порахувати вік за датою народження в роках.

Базова формула Excel для віку в роках

Як ви зазвичай визначаєте вік людини? Просто віднімаючи дату народження від поточної дати. Цю умовну формулу віку можна також використовувати в Excel.

Припускаючи, що дата народження знаходиться в комірці B2, формула для обчислення віку в роках виглядає наступним чином:

=(СЬОГОДНІ()-B2)/365

Перша частина формули (СЬОГОДНІ()-B2) повертає різницю між поточною датою і датою народження в днях, а потім ви ділите це число на 365, щоб отримати кількість років.

Формула очевидна і легко запам'ятовується, проте є невелика проблема. У більшості випадків вона повертає десяткове число, як показано на скріншоті нижче.

Для відображення кількості повних років використовуйте функцію INT для округлення десяткового дробу до найближчого цілого числа:

=INT((TODAY()-B2)/365)

Недоліки: Використання цієї формули віку в Excel дає досить точні результати, але не бездоганні. Ділення на середню кількість днів у році працює добре в більшості випадків, але іноді дає неправильний вік. Наприклад, якщо хтось народився 29 лютого, а сьогодні 28 лютого, формула зробить людину на один день старшою.

Як варіант, можна ділити не на 365, а на 365,25, оскільки кожен четвертий рік має 366 днів. Однак і цей підхід не є ідеальним. Наприклад, якщо ви розраховуєте вік дитини, яка ще не пережила високосний рік, то ділення на 365,25 дасть неправильний результат.

В цілому, віднімання дати народження від поточної дати відмінно працює в звичайному житті, але не є ідеальним підходом в Excel. Далі в цьому уроці ви дізнаєтеся кілька спеціальних функцій, які безпомилково обчислюють вік незалежно від року.

Обчислити вік від дати народження за допомогою функції YEARFRAC

Більш надійним способом перетворення дати народження у вік в Excel є використання функції ФОРМУЛА РОКУ, яка повертає частку року, тобто кількість цілих днів між двома датами.

Синтаксис функції YEARFRAC наступний:

Перші два аргументи очевидні і навряд чи потребують додаткових пояснень. Основа необов'язковий аргумент, який визначає основу підрахунку днів для використання.

Щоб отримати абсолютно вірну формулу віку, передайте у функцію YEARFRAC наступні значення:

• Дата_початку - дата народження.
• Дата закінчення - Функція TODAY() для повернення сьогоднішньої дати.
• Основа - основа використання 1 яка вказує Excel розділити фактичну кількість днів у місяці на фактичну кількість днів у році.

Враховуючи вищевикладене, формула Excel для розрахунку віку від дати народження виглядає наступним чином:

Якщо припустити, що дата народження знаходиться в комірці B2, то формула набуває наступного вигляду:

=YEARFRAC(B2, TODAY(), 1)

Як і в попередньому прикладі, результат функції СРЗНАЧ також є десятковим числом. Щоб виправити це, використовуйте функцію ОПУСК з 0 в останньому аргументі, оскільки вам не потрібні десяткові знаки після коми.

Отже, ось покращена формула YEARFRAC для розрахунку віку в Excel:

=ROUNDDOWN(YEARFRAC(B2, TODAY(), 1), 0)

Розрахувати вік в Excel за допомогою DATEDIF

Ще один спосіб перетворення дати народження у вік в Excel - це використання функції ДАТАДИФ:

Ця функція може повертати різницю між двома датами в різних одиницях часу, таких як роки, місяці і дні, в залежності від значення, яке ви вкажете в полі підрозділ аргумент:

• Y - повертає кількість повних років між датою початку та датою закінчення.
• M - повертає кількість повних місяців між датами.
• D - повертає кількість дні між цими двома датами.
• YM - прибутковість місяці не звертаючи уваги на дні і роки.
• MD - повертає різницю в дні нехтуючи місяцями і роками.
• YD - повертає різницю в дні не звертаючи уваги на роки.

Оскільки ми ставимо за мету розрахувати вік в років ми використовуємо одиницю "у":

У цьому прикладі дата народження знаходиться в комірці B2, і ви посилаєтесь на цю комірку у своїй формулі віку:

=DATEDIF(B2, TODAY(), "y")

Додаткова функція округлення в цьому випадку не потрібна, оскільки формула DATEDIF з одиницею "y" обчислює кількість повних років:

Як отримати вік від дня народження в роках, місяцях і днях

Як ви щойно переконалися, обчислити вік як кількість повних років, прожитих людиною, легко, але цього не завжди достатньо. Якщо ви хочете дізнатися точний вік, тобто скільки років, місяців і днів знаходиться між датою народження людини і поточною датою, напишіть 3 різні функції DATEDIF:

1. Отримати кількість років: =DATEDIF(B2, TODAY(), "Y")
2. Отримати кількість місяців: =DATEDIF(B2, TODAY(), "YM")
3. Отримати кількість днів: =DATEDIF(B2,TODAY(), "MD")

Де B2 - дата народження.

А потім звести вищезгадані функції в одну формулу, ось так:

=DATEDIF(B2,TODAY(), "Y") & DATEDIF(B2,TODAY(), "YM") & DATEDIF(B2,TODAY(), "MD")

Наведена вище формула повертає 3 числа (роки, місяці та дні), об'єднані в один текстовий рядок, як показано на скріншоті нижче:

Не дуже зрозуміло, еге ж? Щоб зробити результати більш осмисленими, відокремте цифри комами і визначте, що означає кожне значення:

=DATEDIF(B2,TODAY(), "Y") & "Роки" & DATEDIF(B2,TODAY(), "YM") & "Місяці" & DATEDIF(B2,TODAY(), "MD") & "Дні"

Зараз результат виглядає набагато краще:

Формула чудово працює, але ви можете її ще більше вдосконалити, приховуючи нульові значення. Для цього додайте 3 оператори IF, які перевіряють наявність 0, по одному на кожен DATEDIF:

=IF(DATEDIF(B2, TODAY(), "y")=0,"",DATEDIF(B2, TODAY(), "y")&" років, ")& IF(DATEDIF(B2, TODAY(), "ym")=0,"",DATEDIF(B2, TODAY(), "ym")&" місяців, ")& IF(DATEDIF(B2, TODAY(), "md")=0,"",DATEDIF(B2, TODAY(), "md")&" днів ")

Наступний скріншот демонструє остаточну формулу віку Excel в дії - вона повертає вік в роках, місяцях і днях, відображаючи тільки ненульовий цінності:

Порада. Якщо ви шукаєте формулу Excel для розрахунку віку в роки та місяці візьмемо вищенаведену формулу і видалимо останній блок IF(DATEDIF()), який обчислює дні.

Конкретні формули для розрахунку віку в Excel

Загальні формули розрахунку віку, розглянуті вище, чудово працюють у більшості випадків. Однак у деяких ситуаціях вам може знадобитися щось дуже специфічне. Звичайно, неможливо охопити всі сценарії, але наведені нижче приклади дадуть вам деякі ідеї щодо того, як ви можете налаштувати формулу віку залежно від вашої конкретної задачі.

Як розрахувати вік на певну дату в Excel

Якщо ви хочете дізнатися вік людини на певну дату, використовуйте формулу віку ДАТАИФ, розглянуту вище, але замініть функцію СЬОГОДНІ() у 2-му аргументі на конкретну дату.

Якщо припустити, що дата народження знаходиться в B1, наступна формула поверне вік станом на 1 січня 2020 року:

=DATEDIF(B1, "1/1/2020", "Y") & "Роки" & DATEDIF(B1, "1/1/2020", "YM") & "Місяці" & DATEDIF(B1, "1/1/2020", "MD") & "Дні"

Щоб зробити формулу віку більш гнучкою, ви можете ввести дату в якусь комірку і посилатися на цю комірку у формулі:

=DATEDIF(B1, B2, "Y") & "Роки" & DATEDIF(B1,B2, "YM") & "Місяці" &DATEDIF(B1,B2, "MD") & "Дні"

Де B1 - дата народження, а B2 - дата, на яку ви хочете розрахувати вік.

Обчислити вік у певному році

Ця формула стане в нагоді в ситуаціях, коли повна дата для розрахунку не визначена, а відомий лише рік.

Припустимо, ви працюєте з медичною базою даних, і ваша мета - з'ясувати вік пацієнтів на момент проходження ними останнього повного медичного огляду.

Якщо припустити, що дати народження знаходяться в колонці В, починаючи з рядка 3, а рік останнього медичного огляду - в колонці С, то формула розрахунку віку виглядає наступним чином:

=DATEDIF(B3,DATE(C3, 1, 1), "y")

Оскільки точна дата проходження медогляду не визначена, використовується функція ДАТА з довільним аргументом числа і місяця, наприклад, ДАТА(С3, 1, 1).

Функція DATE витягує рік з комірки B3, формує повну дату, використовуючи введені вами номери місяця і дня (1-січень у цьому прикладі), і передає цю дату в DATEDIF. В результаті ви отримуєте вік пацієнта станом на 1 січня певного року:

Дізнатися дату досягнення особою N років

Припустимо, ваш друг народився 8 березня 1978 р. Як дізнатися, коли йому виповнюється 50 років? Зазвичай ви просто додаєте 50 років до дати народження людини. В Excel ви робите те ж саме, використовуючи функцію ДАТА:

=DATE(РІК(B2) + 50, МІСЯЦЬ(B2), ДЕНЬ(B2))

Де B2 - дата народження.

Замість того, щоб жорстко кодувати кількість років у формулі, ви можете посилатися на певну комірку, де ваші користувачі можуть ввести будь-яку кількість років (F1 на скріншоті нижче):

Обчислення віку з дня, місяця та року в різних комірках

Якщо дата народження розбита на 3 різні комірки (наприклад, рік у B3, місяць у C3 і день у D3), Ви можете обчислити вік таким чином:

• Отримати дату народження можна за допомогою функцій ДАТА і ДАТАЗНАЧЕННЯ:

  DATE(B3,MONTH(DATEVALUE(C3& "1")),D3)

• Вставте наведену вище формулу в DATEDIF для обчислення віку від дати народження в роках, місяцях і днях: =DATEDIF(DATE(B3, MONTH(DATEVALUE(C3& "1")), D3), TODAY(), "y") & "Роки" & DATEDIF(DATE(B3, MONTH(DATEVALUE(C3& "1")), D3),TODAY(), "ym") & "Місяці" & DATEDIF(DATE(B3, MONTH(DATEVALUE(C3& "1")), D3),TODAY(), "md") & "Дні"

  

Більше прикладів розрахунку кількості днів до/після дати можна знайти в розділі Як розрахувати дні з або до дати в Excel.

Калькулятор віку в Excel

Якщо ви хочете мати власний калькулятор віку в Excel, ви можете зробити його, використовуючи кілька різних формул DATEDIF, описаних нижче. Якщо ви не хочете винаходити велосипед, ви можете скористатися калькулятором віку, створеним нашими професіоналами в Excel.

Як створити калькулятор віку в Excel

Тепер, коли ви знаєте, як створити формулу віку в Excel, ви можете створити власний калькулятор віку, наприклад, цей:

Примітка: Для перегляду вбудованого робочого зошита, будь ласка, дозвольте використання маркетингових файлів cookie.

Те, що ви бачите вище - це вбудований аркуш Excel Online, тому сміливо вводьте дату свого народження у відповідну клітинку, і ви отримаєте свій вік за мить.

Калькулятор використовує наступні формули для обчислення віку на основі дати народження в комірці А3 та сьогоднішньої дати.

• Формула у комірці B5 обчислює вік у роках, місяцях та днях: =DATEDIF(B2,TODAY(), "Y") & "Роки" & DATEDIF(B2,TODAY(), "YM") & "Місяці" & DATEDIF(B2,TODAY(), "MD") & "Дні"
• Формула у комірці B6 обчислює вік у місяцях: =DATEDIF($B$3,TODAY(), "m")
• Формула у комірці B7 обчислює вік у днях: =DATEDIF($B$3,TODAY(), "d")

Якщо ви маєте певний досвід роботи з елементами керування форми Excel, ви можете додати опцію обчислення віку на певну дату, як показано на наступному скріншоті:

Для цього додаємо пару опціональних кнопок ( Вкладка "Розробник > Вставка > Елементи управління формою > Кнопка вибору А потім написати формулу ЕСЛИ/ДАТАЛИФ, щоб отримати вік або на сьогоднішню дату, або на дату, вказану користувачем.

Формула працює за наступною логікою:

• У разі, якщо Сьогоднішня дата встановлюється прапорець, у зв'язаній комірці (I5 у цьому прикладі) з'являється значення 1, і формула віку обчислюється на основі сьогоднішньої дати: IF($I$5=1, DATEDIF($B$3,TODAY(), "Y") & "Роки" & DATEDIF($B$3,TODAY(), "YM") & "Місяці" & DATEDIF($B$3,TODAY(), "MD") & "Дні")
• У разі, якщо Конкретна дата вибирається опція І вводиться дата в комірку В7, вік розраховується на вказану дату: IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7, "Y") & "Роки", & DATEDIF($B$3, $B$7, "YM") & "Місяці", & DATEDIF($B$3, $B$7, "MD") & "Дні", ""))

Нарешті, вкладіть наведені вище функції одна в одну, і ви отримаєте повну формулу розрахунку віку (в B9):

=IF($I$5=1, DATEDIF($B$3, TODAY(), "Y") & "Роки" & DATEDIF($B$3, TODAY(), "YM") & "Місяці" & DATEDIF($B$3, TODAY(), "MD") & "Дні", IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7, "Y") & "Роки" & DATEDIF($B$3, $B$7, "YM") & "Місяці", & DATEDIF($B$3, $B$7, "MD") & "Дні", "")

Формули в B10 і B11 працюють за тією ж логікою. Звичайно, вони набагато простіші, оскільки включають лише одну функцію DATEDIF, яка повертає вік як кількість повних місяців або днів відповідно.

Щоб дізнатися подробиці, запрошую вас завантажити цей калькулятор віку в Excel і дослідити формули в комірках B9:B11.

Завантажити калькулятор віку в Excel

Готовий до використання калькулятор віку для Excel

Користувачам нашого Ultimate Suite не потрібно турбуватися про створення власного вікового калькулятора в Excel - він знаходиться всього в парі кліків:

1. Виділіть комірку, в яку потрібно вставити формулу віку, перейдіть на кнопку Ablebits Tools вкладка> Дата та час і натисніть кнопку Майстер зміни дати та часу кнопку.

   

2. Запуститься Майстер встановлення дати та часу, і ви перейдете безпосередньо до Вік рахунок.
3. Про це йдеться на Вік На вкладці "Вкладка" вам потрібно вказати 3 речі:
   • Дані про народження у вигляді посилання на комірку або дати у форматі мм/дд/рр.
   • Вік на момент сьогоднішня дата або конкретна дата .
   • Виберіть, чи розраховувати вік у днях, місяцях, роках або точний вік.
4. Натисніть на кнопку Вставте формулу кнопку.

Готово!

Формула миттєво вставляється у вибрану комірку, і ви двічі клацаєте маркер заповнення, щоб скопіювати її вниз по стовпчику.

Як ви могли помітити, формула, створена нашим калькулятором віку в Excel, складніша, ніж ті, які ми розглядали раніше, але вона враховує однину і множину таких часових одиниць, як "день" і "дні".

Якщо ви хочете позбутися нульових одиниць, таких як "0 днів", виберіть Не допускається показати нуль одиниць прапорець:

Якщо вам цікаво протестувати цей калькулятор віку, а також відкрити для себе ще 60 надбудов для Excel, які заощаджують час, ви можете завантажити пробну версію нашого Ultimate Suite в кінці цієї публікації.

Як виділити певні вікові категорії (молодше або старше певного віку)

У деяких ситуаціях може знадобитися не тільки розрахувати вік в Excel, але і виділити комірки, які містять вік, менший або більший певного віку.

Якщо ваша формула обчислення віку повертає кількість повних років, то ви можете створити звичайне правило умовного форматування на основі простої формули, подібної до цієї:

• Для виділення віку, що дорівнює або перевищує 18 років: =$C2>=18
• Щоб виділити вік до 18 років: =$C2<18

Де C2 - крайня верхня комірка у стовпчику "Вік" (не включаючи заголовок стовпчика).

Але що робити, якщо ваша формула виводить вік в роках і місяцях, або в роках, місяцях і днях? У цьому випадку вам доведеться створити правило на основі формули ДАТАДИФ, яка обчислює вік від дати народження в роках.

Припустимо, що дати народження знаходяться в колонці B, починаючи з рядка 2, формули виглядають наступним чином:

• Для виділення віку під 18 (жовтий): =DATEDIF($B2, TODAY(), "Y")<18
• Для виділення віку між 18 та 65 (зелений): =AND(DATEDIF($B2, TODAY(), "Y")>=18, DATEDIF($B2, TODAY(), "Y")<=65)
• Для виділення віку закінчився 65 (синій): =DATEDIF($B2, TODAY(), "Y")>65

Для створення правил на основі наведених вище формул виділіть комірки або цілі рядки, які потрібно виділити, перейдіть на вкладку Головна сторінка вкладка> Стилі групу і натисніть Умовне форматування > Нове правило... > Використовуйте формулу, щоб визначити, які клітинки форматувати .

Детально з кроками можна ознайомитися тут: Як створити правило умовного форматування на основі формули.

Ось так можна розрахувати вік в Excel. Сподіваюся, формули були для вас легкими для засвоєння і ви спробуєте їх у своїх робочих таблицях. Дякую за прочитання і сподіваюся побачити вас на нашому блозі наступного тижня!

Доступні для завантаження

Приклади розрахунку віку в Excel (файл .xlsx)

Ultimate Suite 14-денна повнофункціональна версія (файл .exe)