To je zadnji del serije o edinstvenih vrednostih v Excelu, ki prikazuje, kako s formulo pridobiti seznam različnih/enakih vrednosti v stolpcu in kako to formulo prilagoditi za različne nabore podatkov. Naučili se boste tudi, kako hitro pridobiti seznam različnih vrednosti z uporabo Excelovega naprednega filtra in kako izločiti edinstvene vrstice z orodjem za odstranjevanje dvojnikov.

V nekaj nedavnih člankih smo obravnavali različne metode za štetje in iskanje edinstvenih vrednosti v Excelu. Če ste imeli priložnost prebrati ta navodila, že veste, kako z identifikacijo, filtriranjem in kopiranjem pridobiti edinstven ali razločen seznam. Toda to je nekoliko dolgotrajen in še zdaleč ne edini način za pridobivanje edinstvenih vrednosti v Excelu. To lahko storite veliko hitreje z uporabo posebne formule in v trenutkuPredstavil vam bom to in še nekaj drugih tehnik.

Nasvet. Če želite hitro pridobiti edinstvene vrednosti v najnovejši različici programa Excel 365, ki podpira dinamične nize, uporabite funkcijo UNIQUE, kot je razloženo v zgoraj povezanem učbeniku.

Kako pridobiti edinstvene vrednosti v Excelu

Da bi se izognili zmedi, se najprej dogovorimo, čemu v Excelu pravimo edinstvene vrednosti. Edinstvene vrednosti so vrednosti, ki so na seznamu samo enkrat. Na primer:

Če želite v Excelu pridobiti seznam edinstvenih vrednosti, uporabite eno od naslednjih formul.

Polje formulo za edinstvene vrednosti (izpolnite jo s pritiskom kombinacije tipk Ctrl + Shift + Enter ):

=IFERROR(INDEX($A$2:$A$10, MATCH(0, COUNTIF($B$1:B1,$A$2:$A$10) + (COUNTIF($A$2:$A$10, $A$2:$A$10)1), 0)), "")

Redno formulo za edinstvene vrednosti (zaključite s pritiskom na tipko Enter):

=IFERROR(INDEX($A$2:$A$10, MATCH(0,INDEX(COUNTIF($B$1:B1, $A$2:$A$10)+(COUNTIF($A$2:$A$10, $A$2:$A$10)1),0,0), 0)), "")

V zgornjih formulah so uporabljena naslednja sklicevanja:

• A2:A10 - seznam virov.
• B1 - zgornja celica edinstvenega seznama minus 1. V tem primeru začnemo edinstven seznam v celici B2, zato formuli dodamo B1 (B2-1=B1). Če se vaš edinstven seznam začne na primer v celici C3, spremenite $B$1:B1 v $C$2:C2.

Opomba: Ker se formula sklicuje na celico nad prvo celico edinstvenega seznama, ki je običajno glavo stolpca (B1 v tem primeru), se prepričajte, da ima vaša glava edinstveno ime, ki se ne pojavlja nikjer drugje v stolpcu.

V tem primeru iz stolpca A (natančneje iz območja A2:A20) pridobivamo edinstvena imena, naslednja slika zaslona pa prikazuje delovanje formule polja:

Podrobna razlaga logike formule je na voljo v ločenem razdelku, tukaj pa je opisano, kako formulo uporabite za pridobivanje edinstvenih vrednosti v delovnih listih programa Excel:

• Spremenite eno od formul glede na svoj nabor podatkov.
• V prvo celico edinstvenega seznama (B2 v tem primeru) vnesite formulo.
• Če uporabljate formulo z matriko, pritisnite kombinacijo tipk Ctrl + Shift + Enter . Če ste se odločili za običajno formulo, pritisnite tipko Enter kot običajno.
• Kopirajte formulo navzdol, kolikor je potrebno, tako da povlečete ročaj za zapolnitev. Ker sta obe formuli za edinstvene vrednosti zaprti v funkciji IFERROR, lahko formulo kopirate do konca tabele in ne bo obremenjevala podatkov z napakami ne glede na to, kako malo edinstvenih vrednosti je bilo izvlečenih.

Kako dobiti različne vrednosti v Excelu (edinstvene + prve podvojene pojavitve)

Kot ste morda že uganili iz naslova tega poglavja, različne vrednosti v Excelu so vse različne vrednosti na seznamu, tj. edinstvene vrednosti in prvi primeri podvojenih vrednosti. Na primer:

Če želite v Excelu dobiti ločen seznam, uporabite naslednje formule.

Polje različna formula (zahteva pritisk Ctrl + Shift + Enter ):

=IFERROR(INDEX($A$2:$A$10, MATCH(0, COUNTIF($B$1:B1, $A$2:$A$10), 0)), "")

Redno različna formula:

=IFERROR(INDEX($A$2:$A$10, MATCH(0, INDEX(COUNTIF($B$1:B1, $A$2:$A$10), 0, 0), 0)), "")

Kje:

• A2:A10 je seznam virov.
• B1 je celica nad prvo celico ločenega seznama. V tem primeru se ločeni seznam začne v celici B2 (to je prva celica, v katero vnesete formulo), zato se sklicujete na B1.

Izvleček različnih vrednosti v stolpcu brez upoštevanja praznih celic

Če vaš izvorni seznam vsebuje prazne celice, bi izrazita formula, ki smo jo pravkar obravnavali, vrnila ničlo za vsako prazno vrstico, kar bi lahko predstavljalo težavo. Če želite to odpraviti, formulo še nekoliko izboljšajte:

Formula polja za izvleček različne vrednosti brez praznih mest :

=IFERROR(INDEX($A$2:$A$10, MATCH(0, COUNTIF($B$1:B1, $A$2:$A$10&"") + IF($A$2:$A$10="",1,0), 0)), "")

Pridobi seznam različnih vrednosti besedila brez upoštevanja številk in praznih mest

Na podoben način lahko dobite seznam različnih vrednosti brez praznih celic in celic s številkami. :

=IFERROR(INDEX($A$2:$A$10, MATCH(0, COUNTIF($B$1:B1, $A$2:$A$10&"") + IF(ISTEXT($A$2:$A$10)=FALSE,1,0), 0)), "")

V zgornjih formulah so A2:A10 izvorni seznam, B1 pa je celica tik nad prvo celico različnega seznama.

Naslednja zaslonska slika prikazuje rezultat obeh formul:

Kako v Excelu izluščiti različne vrednosti, občutljive na velikost črk

Pri delu s podatki, občutljivimi na velikost črk, kot so gesla, uporabniška imena ali imena datotek, boste morda morali pridobiti seznam različnih vrednosti, občutljivih na velikost črk. V ta namen uporabite naslednjo formulo polja, kjer so A2:A10 izvorni seznam, B1 pa celica nad prvo celico seznama različnih vrednosti:

Formula za polje za pridobitev različnih vrednosti, občutljivih na velike in male črke (zahteva pritisk Ctrl + Shift + Enter )

=IFERROR(INDEX($A$2:$A$10, MATCH(0, FREQUENCY(IF(EXACT($A$2:$A$10,TRANSPOSE($B$1:B1)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), 0)), "")

Delovanje formule edinstvenost/različnost

To poglavje je napisano posebej za tiste radovedne in premišljene uporabnike programa Excel, ki ne želijo le poznati formule, temveč tudi v celoti razumeti njeno bistvo.

Samoumevno je, da formule za pridobivanje edinstvenih in različnih vrednosti v Excelu niso niti trivialne niti preproste. Toda če si jih ogledate podrobneje, lahko opazite, da vse formule temeljijo na istem pristopu - uporabi funkcij INDEX/MATCH v kombinaciji s funkcijami COUNTIF ali COUNTIF + IF.

Za našo poglobljeno analizo uporabimo formulo za polje, ki pridobi seznam različnih vrednosti, saj so vse druge formule, obravnavane v tem učbeniku, izboljšave ali različice te osnovne formule:

=IFERROR(INDEX($A$2:$A$10, MATCH(0, COUNTIF($B$1:B1, $A$2:$A$10), 0)), "")

Za začetek opustimo očitno funkcijo IFERROR, ki se uporablja z enim samim namenom, da odpravi napake #N/A, kadar število celic, v katere ste kopirali formulo, presega število različnih vrednosti v izvornem seznamu.

Zdaj pa razčlenimo osrednji del naše posebne formule:

1. COUNTIF(območje, merila) vrne število celic v območju, ki izpolnjujejo določen pogoj.

   V tem primeru formula COUNTIF($B$1:B1, $A$2:$A$10) vrne polje 1 in 0 glede na to, ali se katera od vrednosti izvornega seznama ($A$2:$A$10) pojavi nekje na razločnem seznamu ($B$1:B1). Če je vrednost najdena, formula vrne 1, sicer 0.

   Poglej tudi: Excelova funkcija LINEST s primeri formul

   Zlasti v celici B2 postane COUNTIF($B$1:B1, $A$2:$A$10):

   COUNTIF("Distinct", {"Ronnie"; "David"; "Sally"; "Jeremy"; "Robert"; "David"; "Robert"; "Tom"; "Sally"})

   in vračila:

   {0;0;0;0;0;0;0;0;0}

   ker nobena od postavk izvornega seznama ( merila ) se pojavi v obseg kjer funkcija išče ujemanje. V tem primeru, obseg ($B$1:B1) je sestavljen iz enega samega elementa - "Distinct".

2. MATCH(lookup_value, lookup_array, [match_type]) vrne relativni položaj vrednosti iskanja v polju.

V tem primeru je vrednost lookup_value 0, zato:

MATCH(0,COUNTIF($B$1:B1, $A$2:$A$10), 0)

se spremeni v:

MATCH(0, { 0 ;0;0;0;0;0;0;0;0},0)

in vrne

saj naša funkcija MATCH dobi prvo vrednost, ki je popolnoma enaka vrednosti iskanja (kot ste se spomnili, je vrednost iskanja 0).

V tem primeru je INDEX($A$2:$A$10, 1)

postane:

INDEX({"Ronnie"; "David"; "Sally"; "Jeremy"; "Robert"; "David"; "Robert"; "Tom"; "Sally"}, 1)

in vrne "Ronnie".

Ko formulo kopiramo navzdol po stolpcu, se razločevalni seznam ($B$1:B1) razširi, ker je referenca druge celice (B1) relativna referenca, ki se spreminja glede na relativni položaj celice, v kateri se premika formula.

Ko se kopira v celico B3, se torej COUNTIF($B$1: B1 , $A$2:$A$10) spremeni v COUNTIF($B$1: B2 , $A$2:$A$10) in postane:

COUNTIF({"Distinct"; "Ronnie"}, {"Ronnie"; "David"; "Sally"; "Jeremy"; "Robert"; "David"; "Robert"; "Tom"; "Sally"})), 0)), "")

in vračila:

{1;0;0;0;0;0;0;0;0}

ker je v območju $B$1:B2 najden en "Ronnie".

In nato MATCH(0,{1; 0 ;0;0;0;0;0;0;0;0;0},0) vrne 2, ker je 2 relativni položaj prve 0 v polju.

In končno, INDEX($A$2:$A$10, 2) vrne vrednost iz 2. vrstice, ki je "David".

Nasvet: Za boljše razumevanje logike formule lahko v vrstici formul izberete različne dele formule in pritisnete F9, da vidite, kakšna je vrednost izbranega dela:

Če imate še vedno težave pri razumevanju formule, si lahko ogledate naslednji priročnik za podrobno razlago delovanja povezave INDEX/MATCH: INDEX & MATCH as a better alternative to Excel VLOOKUP.

Kot smo že omenili, druge formule, obravnavane v tem učbeniku, temeljijo na isti logiki, le z nekaj spremembami:

Formula za edinstvene vrednosti - vsebuje še eno funkcijo COUNTIF, ki iz edinstvenega seznama izključi vse elemente, ki se v izvornem seznamu pojavijo več kot enkrat: COUNTIF($A$2:$A$10, $A$2:$A$10)1 .

Formula za različne vrednosti, ki ne upošteva praznih mest - tukaj dodate funkcijo IF, ki preprečuje dodajanje praznih celic na seznam različnih vrednosti: IF($A$2:$A$13="",1,0) .

Formula za razločevanje besedilnih vrednosti brez upoštevanja številk - s funkcijo ISTEXT preverite, ali je vrednost besedilo, s funkcijo IF pa zavrnete vse druge vrste vrednosti, vključno s praznimi celicami: IF(ISTEXT($A$2:$A$13)=FALSE,1,0) .

Izvleček različnih vrednosti iz stolpca z Excelovim naprednim filtrom

Če ne želite izgubljati časa z odkrivanjem skrivnostnih zapletov formul za različne vrednosti, lahko hitro dobite seznam različnih vrednosti z uporabo naprednega filtra. Podrobni koraki sledijo v nadaljevanju.

1. Izberite stolpec podatkov, iz katerega želite izluščiti različne vrednosti.
2. Preklopite na Podatki zavihek> Razvrsti in filtriraj in kliknite skupino Napredno gumb:

• Preverite Kopiranje na drugo lokacijo radijski gumb.
• V Razpon seznama preverite, ali je območje vira prikazano pravilno.
• V Kopiraj v polje , vnesite najvišjo celico ciljnega območja. Upoštevajte, da lahko filtrirane podatke kopirate samo v aktivni list .
• Izberite Samo edinstveni zapisi

Bodite pozorni na to, da čeprav je možnost naprednega filtra poimenovana " Samo edinstveni zapisi ", izvleče različne vrednosti tj. edinstvene vrednosti in prve pojavitve podvojenih vrednosti.

Izvleček edinstvenih in različnih vrstic z odstranjevalcem dvojnikov

V zadnjem delu tega priročnika vam pokažem našo lastno rešitev za iskanje in izločanje izrazitih in edinstvenih vrednosti v Excelovih listih. Ta rešitev združuje vsestranskost Excelovih formul in preprostost naprednega filtra. Poleg tega zagotavlja nekaj edinstvenih funkcij, kot so:

• Poiščite in izločite edinstvene/različne vrstice na podlagi vrednosti v enem ali več stolpcih.
• Poišči , poudariti in kopiranje edinstvene vrednosti na katero koli drugo mesto v istem ali drugem delovnem zvezku.

Zdaj si oglejmo orodje za odstranjevanje dvojnikov v akciji.

Recimo, da imate zbirno tabelo, ustvarjeno z združitvijo podatkov iz več drugih tabel. Ta zbirna tabela očitno vsebuje veliko podvojenih vrstic in vaša naloga je izločiti edinstvene vrstice, ki so v tabeli samo enkrat, ali različne vrstice, vključno z edinstvenimi in prvimi podvojenimi pojavi. V vsakem primeru je z dodatkom Odstranjevalec dvojnikov delo opravljeno v 5 hitrih korakih.

1. Izberite katero koli celico v izvorni tabeli in kliknite Odstranjevalec dvojnikov gumb na Podatkovni zapisi o napravah Ablebits v zavihku Dedupe skupina.

Čarovnik za odstranjevanje dvojnikov se bo zagnal in izbral celotno tabelo. Naslednji za nadaljevanje naslednjega koraka.

• Edinstvene
• Edinstvene +1. pojavitve (različne)

V tem primeru želimo izluščiti edinstvene vrstice ki se v izvorni tabeli pojavijo samo enkrat, zato izberemo Edinstvene možnost:

Nasvet. Kot lahko vidite na zgornji sliki zaslona, sta na voljo tudi 2 možnosti za podvojene vrednosti , ga imejte v mislih, če boste morali odšteti kakšen drug delovni list.

Všeč vam je ta hiter in preprost način za pridobitev seznama edinstvenih vrednosti ali vrstic v Excelu? Če je tako, vas spodbujam, da prenesete spodnjo ocenjevalno različico in jo preizkusite. Odstranjevalec dvojnikov in vsa druga orodja za prihranek časa, ki jih imamo, so vključena v Ultimate Suite za Excel.

Razpoložljivi prenosi

Iskanje edinstvenih vrednosti v Excelu - vzorčni delovni zvezek (.xlsx datoteka)

Ultimate Suite - preizkusna različica (.exe datoteka)