Opplæringen viser hvordan du bruker TEXTJOIN-funksjonen til å slå sammen tekst i Excel med praktiske eksempler.

Inntil nylig var det to utbredte metoder for å slå sammen celleinnhold i Excel: sammenkoblingen operator og CONCATENATE-funksjon. Med introduksjonen av TEXTJOIN ser det ut til at det har dukket opp et kraftigere alternativ, som lar deg slå sammen tekst på en mer fleksibel måte, inkludert eventuelle avgrensninger i mellom. Men i sannhet er det mye mer i det!

Excel TEXTJOIN-funksjonen

TEXTJOIN i Excel slår sammen tekststrenger fra flere celler eller områder og skiller de kombinerte verdiene med et hvilket som helst skilletegn som du spesifiserer. Den kan enten ignorere eller inkludere tomme celler i resultatet.

Funksjonen er tilgjengelig i Excel for Office 365, Excel 2021 og Excel 2019.

Syntaksen til TEXTJOIN-funksjonen er som følger :

Hvor:

• Delimiter (påkrevd) - er en skilletegn mellom hver tekstverdi som du kombinerer. Vanligvis leveres den som en tekststreng omsluttet av doble anførselstegn eller en referanse til en celle som inneholder en tekststreng. Et tall oppgitt som skilletegn behandles som tekst.
• Ignorer_tom (obligatorisk) - Bestemmer om tomme celler skal ignoreres eller ikke:
  • TRUE - ignorer eventuelle tomme celler.
  • USANN - inkluder tomme celler i den resulterende strengen.
• Tekst1 (obligatorisk) - første verdi for å bli med. Kan leveres som en tekststreng, en referanse til en celle som inneholder en streng, eller en rekke strenger, for eksempel et celleområde.
• Tekst2 , … (valgfritt) - tilleggstekstverdier å slås sammen. Maksimalt 252 tekstargumenter er tillatt, inkludert tekst1 .

La oss som et eksempel kombinere adressedeler fra cellene B2, C2 og D2 sammen til én celle, og separere verdiene med komma og mellomrom:

Med CONCATENATE-funksjonen må du spesifisere hver celle individuelt og sette et skilletegn (", ") etter hver referanse, noe som kan være plagsomt når du slår sammen innholdet i mange celler:

=CONCATENATE(A2, ", ", B2, ", ", C2)

Med Excel TEXTJOIN spesifiserer du skilletegnet bare én gang i det første argumentet, og oppgir et celleområde for det tredje argumentet:

=TEXTJOIN(", ", TRUE, A2:C2)

TEXTJOIN i Excel - 6 ting å huske

For effektivt å bruke TEXTJOIN i regnearkene dine, er det noen viktige punkter å være oppmerksom på:

1. TEXTJOIN er en ny funksjon, som kun er tilgjengelig i Excel 2019 - Excel 365. I tidligere Excel-versjoner, vennligst bruk CONCATENATE-funksjonen eller "&" operator i stedet.
2. I nye versjoner av Excel, kan du også bruke CONCAT-funksjonen til å sette sammen verdier fra separate celler og områder, men uten alternativer for skilletegn eller tomme celler.
3. Hvilket som helst tall oppgitt. til TEXTJOIN for skilletegn eller tekst argumenter konverteres til tekst.
4. Hvis skilletegn ikke er spesifisert eller er en tom streng (""), sammenkobles tekstverdier uten noen skilletegn.
5. Funksjonen kan håndtere opptil 252 tekstargumenter.
6. Den resulterende strengen kan inneholde maksimalt 32 767 tegn, som er cellegrensen i Excel. Hvis denne grensen overskrides, returnerer en TEXTJOIN-formel #VERDI! feil.

Hvordan slå sammen tekst i Excel - formeleksempler

For bedre å forstå alle fordelene med TEXTJOIN, la oss ta en titt på hvordan du bruker funksjonen i virkelige scenarier .

Konverter kolonne til kommadelt liste

Når du ønsker å sette sammen en vertikal liste som skiller verdiene med komma, semikolon eller et annet skilletegn, er TEXTJOIN den rette funksjonen å bruke.

For dette eksemplet setter vi sammen seire og tap for hvert lag fra tabellen nedenfor. Dette kan gjøres med følgende formler, som bare er forskjellige i celleområdet som er sammenføyd.

For Team 1:

=TEXTJOIN(",", FALSE, B2:B6)

For Team 2:

=TEXTJOIN(",", FALSE, C2:C6)

Og så videre.

I alle formlene brukes følgende argumenter:

• Delimiter - a komma (",").
• Ignore_empty er satt til FALSE for å inkludere tomme celler fordi vi må vise hvilke spill som ikke ble spilt.

Som Resultatet vil du få fire kommadelte lister som representerer seire og tap for hvert lag i en kompakt form:

Sett sammen celler med forskjellige skilletegn

I en situasjon hvor du trenger å skille de kombinerte verdiene med forskjellige skilletegn, kan du enten angi flere skilletegn som en matrisekonstant eller legge inn hvert skilletegn i en separat celle og bruk en områdereferanse for skilletegn -argumentet.

Forutsatt at du vil slå sammen celler som inneholder forskjellige navnedeler og få resultatet i dette formatet: Etternavn , Fornavn Mellomnavn .

Som du kan se, er etternavnet og fornavnet atskilt med et komma og et mellomrom (", "), mens fornavnet og mellomnavnet med et mellomrom (" ") bare. Så vi inkluderer disse to skilletegnene i en matrisekonstant {", "," "} og får følgende formel:

=TEXTJOIN({", "," "}, TRUE, A2:C2)

Hvor A2:C2 er navnedelene som skal kombineres.

Alternativt kan du skrive inn skilletegn uten anførselstegn i noen tomme celler (for eksempel et komma og et mellomrom i F3 og et mellomrom i G3) og bruke området $F$3:$G$3 (vær oppmerksom på de absolutte cellereferansene) for skilletegn -argumentet:

=TEXTJOIN($F$3:$G$3, TRUE, A2:C2)

Ved å bruke denne generelle tilnærmingen kan du slå sammen celleinnhold i ulike former.

For eksempel, hvis du vil ha resultatet i formatet Fornavn Mellomstart Etternavn , bruk VENSTRE-funksjonen til å trekke ut det første tegnet (initialboken) fra celle C2. Når det gjelder skilletegnene, setter vi et mellomrom (" ") mellom fornavnet og den midtre initialen; enpunktum og et mellomrom (". ") mellom initialen og etternavnet:

=TEXTJOIN({" ",". "}, TRUE, B2, LEFT(C2,1), A2)

Sett sammen tekst og datoer i Excel

I et spesifikt tilfelle når du slår sammen tekst og datoer, det vil ikke fungere å levere datoer direkte til en TEXTJOIN-formel. Som du kanskje husker, lagrer Excel datoer som serienumre, så formelen din vil returnere et tall som representerer datoen som vist på skjermbildet nedenfor:

=TEXTJOIN(" ", TRUE, A2:B2)

For å fikse dette, må du konvertere datoen inn i en tekststreng før du kobler den sammen. Og her kommer TEKST-funksjonen med ønsket formatkode ("mm/dd/åååå" i vårt tilfelle) godt med:

=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyy"))

Slå sammen tekst med linjeskift

Hvis du ønsker å slå sammen tekst i Excel slik at hver verdi starter på en ny linje, bruker du CHAR(10) som skilletegn (der 10 er et linjematingstegn).

For eksempel, for å kombinere tekst fra cellene A2 og B2 som skiller verdiene med et linjeskift, dette er formelen som skal brukes:

=TEXTJOIN(CHAR(10), TRUE, A2:B2)

Tips. For at resultatet skal vises i flere linjer som vist i skjermbildet ovenfor, sørg for at funksjonen Bryt tekst er slått på.

TEXTJOIN IF for å slå sammen tekst med betingelser

På grunn av muligheten til Excel TEXTJOIN til å håndtere arrays av strenger, kan den også brukes til å betinget slå sammen innholdet i to eller flere celler. For å få det gjort, bruk HVIS-funksjonen til å evaluere et celleområde og returnere en rekke verdier som oppfyller betingelsen til tekst1 -argumentet tilTEXTJOIN.

Fra tabellen vist i skjermbildet nedenfor, anta at du ønsker å hente en liste over Team 1 -medlemmer. For å oppnå dette, nest følgende IF-setning inn i tekst1 -argumentet:

IF($B$2:$B$9=1, $A$2:$A$9, "")

På vanlig engelsk sier formelen ovenfor: Hvis kolonne B er lik 1, returner en verdi fra kolonne A i samme rad; ellers returnerer en tom streng.

Den komplette formelen for Team 1 har denne formen:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))

På lignende måte kan du få en kommadelt liste over medlemmene i Team 2:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, ""))

Merk. På grunn av funksjonen Dynamic Arrays som er tilgjengelig i Excel 365 og 2021, fungerer dette som en vanlig formel, vist i skjermbildet ovenfor. I Excel 2019 må du angi den som en tradisjonell matriseformel ved å trykke på Ctrl + Shift + Enter-snarveien.

Slå opp og returner flere treff i kommadelt liste

Som du sikkert vet, Excel VLOOKUP-funksjonen kan bare returnere det første funnet. Men hva om du trenger å få alle treff for en bestemt ID, SKU eller noe annet?

For å skrive ut resultatene i separate celler, bruk en av formlene som er beskrevet i Slik VLOOKUP flere verdier i Excel.

For å slå opp og returnere alle samsvarende verdier i en enkelt celle som en kommadelt liste, bruk TEXTJOIN IF-formelen.

For å se hvordan det fungerer i praksis, la oss hente en liste over produkter kjøpt av en gitt selger fra prøvetabellenunder. Dette kan enkelt gjøres med følgende formel:

=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))

Hvor A2:A12 er selgernavn, B2:B12 er produkter og D2 er selgeren av interesse.

Formelen ovenfor går til E2 og bringer alle kampene for målselgeren i D2 (Adam). På grunn av den smarte bruken av relative (for målselgeren) og absolutte (for selgernavnene og produktene) cellereferanser, kopierer formelen riktig til cellene nedenfor og fungerer bra for de to andre selgerne også:

Merk. Som med forrige eksempel fungerer dette som en vanlig formel i Excel 365 og 2021, og som en CSE-formel (Ctrl + Shift + Enter ) i Excel 2019.

Formelens logikk er nøyaktig den samme som i forrige eksempel:

IF-setningen sammenligner hvert navn i A2:A12 med målnavnet i D2 (Adam i vårt tilfelle):

IF($A$2:$A$12=D2, $B$2:$B$12, "")

Hvis den logiske testen evaluerer til TRUE (dvs. navnet i D2 samsvarer med navnet i kolonne A), returnerer formelen et produkt fra kolonne B; ellers returneres en tom streng (""). Resultatet av IF er følgende matrise:

{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}

Arrayen går til TEXTJOIN-funksjonen som tekst1 -argumentet. Og fordi TEXTJOIN er konfigurert til å skille verdiene med et komma og et mellomrom (", "), får vi denne strengen som sluttresultat:

Bananas, Apples, Appels, Sitrons

Excel TEXTJOIN fungerer ikke

Når TEXTJOIN-formelen din resulterer i en feil, er det mest sannsynligå være en av følgende:

• #NAME? feil oppstår når TEXTJOIN brukes i en eldre versjon av Excel der denne funksjonen ikke støttes (før 2019) eller når funksjonens navn er feilstavet.
• #VERDI! feil oppstår hvis den resulterende strengen overskrider 32 767 tegn.
• #VALUE! feil kan også oppstå hvis Excel ikke gjenkjenner skilletegnet som tekst, for eksempel hvis du oppgir et ikke-utskrivbart tegn som CHAR(0).

Det er hvordan du bruker TEXTJOIN-funksjonen i Excel. Jeg takker for at du leser og håper å se deg på bloggen vår neste uke!

Tilgjengelige nedlastinger

Excel TEXTJOIN-formeleksempler