म एक्सेलमा पाठ भएका कक्षहरू कसरी गणना गर्छु? त्यहाँ कुनै पनि पाठ, विशिष्ट वर्ण वा केवल फिल्टर कक्षहरू समावेश कक्षहरू गणना गर्न केही फरक सूत्रहरू छन्। सबै सूत्रहरू Excel 365, 2021, 2019, 2016, 2013 र 2010 मा काम गर्छन्।

सुरुमा, Excel स्प्रेडसिटहरू नम्बरहरूसँग काम गर्न डिजाइन गरिएको थियो। तर आजकल हामी प्रायः तिनीहरूलाई पाठ भण्डारण गर्न र हेरफेर गर्न प्रयोग गर्छौं। तपाईको कार्यपत्रमा पाठ सहित कतिवटा कक्षहरू छन् भनेर जान्न चाहनुहुन्छ? माइक्रोसफ्ट एक्सेलमा यसका लागि धेरै प्रकार्यहरू छन्। तपाईंले कुन प्रयोग गर्नुपर्छ? खैर, यो स्थिति मा निर्भर गर्दछ। यस ट्युटोरियलमा, तपाईंले विभिन्न सूत्रहरू फेला पार्नुहुनेछ र जब प्रत्येक सूत्र प्रयोग गर्न उत्तम हुन्छ।

एक्सेलमा पाठ भएका कक्षहरूको संख्या कसरी गणना गर्ने

त्यहाँ दिइएको दायरामा कुनै पाठ स्ट्रिङ वा क्यारेक्टरहरू समावेश छन् भनेर पत्ता लगाउनका लागि दुई आधारभूत सूत्रहरू छन्।

पाठसहितका सबै कक्षहरू गणना गर्न COUNTIF सूत्र

जब तपाईं कक्षहरूको सङ्ख्या फेला पार्न चाहनुहुन्छ एक्सेलमा पाठ, मापदण्ड तर्कमा तारा चिन्हको साथ COUNTIF प्रकार्य उत्तम र सजिलो समाधान हो:

किनभने तारा चिन्ह (*) एक वाइल्डकार्ड हो जुन वर्णहरूको कुनै पनि अनुक्रमसँग मेल खान्छ, सूत्रले कुनै पनि पाठ समावेश गर्ने सबै कक्षहरूलाई गणना गर्दछ।

कुनै पाठसँग कक्षहरू गणना गर्न SUMPRODUCT सूत्र

को संख्या प्राप्त गर्ने अर्को तरिका पाठ समावेश कक्षहरू SUMPRODUCT र ISTEXT प्रकार्यहरू संयोजन गर्न हो:

वा

ISTEXT प्रकार्यले तोकिएको प्रत्येक कक्षमा छ कि छैन भनेर जाँच गर्दछ। दायराले कुनै पनि पाठ क्यारेक्टरहरू समावेश गर्दछ र TRUE (पाठ भएका कक्षहरू) र FALSE (अन्य कक्षहरू) मानहरूको एर्रे फर्काउँछ। डबल युनरी (--) वा गुणन अपरेशनले TRUE र FALSE लाई क्रमशः १ र ० मा जोड्छ, एक र शून्यको एरे उत्पादन गर्छ। SUMPRODUCT प्रकार्यले एरेका सबै तत्वहरूलाई जोड्छ र 1 को संख्या फर्काउँछ, जुन पाठ समावेश गर्ने कक्षहरूको संख्या हो।

यी सूत्रहरूले कसरी काम गर्छ भन्ने बारे थप बुझ्नको लागि, कृपया कुन मानहरू गणना गरिन्छ हेर्नुहोस् र हेर्नुहोस्। जुन होइनन्:

उदाहरणका लागि, संख्याहरू, मितिहरू, तार्किक मानहरू, त्रुटिहरू बाहेक A2:A10 दायरामा पाठ भएका कक्षहरू गणना गर्न र खाली कक्षहरू, यी मध्ये एउटा सूत्र प्रयोग गर्नुहोस्:

=COUNTIF(A2:A10, "*")

=SUMPRODUCT(--ISTEXT(A2:A10))

=SUMPRODUCT(ISTEXT(A2:A10)*1)

तलको स्क्रिनसटले परिणाम देखाउँछ:

स्पेस र खाली स्ट्रिङहरू बाहेक पाठका साथ कक्षहरू गणना गर्नुहोस्

माथि छलफल गरिएका सूत्रहरू गणनासबै कक्षहरू जसमा कुनै पाठ वर्णहरू छन्। केहि परिस्थितिहरूमा, तथापि, यो भ्रमित हुन सक्छ किनभने केहि कोशिकाहरू मात्र खाली देखिन सक्छन् तर, वास्तवमा, खाली स्ट्रिङहरू, अपोस्ट्रोफहरू, खाली ठाउँहरू, रेखा विच्छेदहरू, आदि जस्ता मानव आँखामा अदृश्य वर्णहरू समावेश छन्। सेललाई सूत्रद्वारा गणना गरिन्छ जसले गर्दा प्रयोगकर्ताले आफ्नो कपाल बाहिर निकाल्ने कारण पत्ता लगाउन प्रयास गर्छ :)

गणनाबाट "झूटा सकारात्मक" खाली कक्षहरू बहिष्कार गर्न, "बहिष्कृत" क्यारेक्टरको साथ COUNTIFS प्रकार्य प्रयोग गर्नुहोस्। दोस्रो मापदण्ड।

उदाहरणका लागि, दायरा A2:A7 मा पाठ भएका कक्षहरू गणना गर्न स्पेस क्यारेक्टर समावेश गर्नेहरूलाई बेवास्ता गर्दै, यो सूत्र प्रयोग गर्नुहोस्:

=COUNTIFS(A2:A7,"*", A2:A7, " ")

यदि तपाइँको लक्षित दायरामा कुनै पनि सूत्र-संचालित डाटा समावेश छ भने, केहि सूत्रहरूले खाली स्ट्रिङ ("") परिणाम दिन सक्छ। खाली स्ट्रिङहरू भएका कक्षहरूलाई पनि बेवास्ता गर्न, मापदण्ड1 तर्कमा "*" लाई "*?*" ले बदल्नुहोस्:

=COUNTIFS(A2:A9,"*?*", A2:A9, " ")

एउटा प्रश्न तारा चिन्हले घेरिएको चिन्हले कक्षमा कम्तिमा एउटा पाठ क्यारेक्टर हुनुपर्छ भनेर संकेत गर्छ। खाली स्ट्रिङमा कुनै क्यारेक्टरहरू नभएकोले, यसले मापदण्ड पूरा गर्दैन र गणना गरिँदैन। Apostrophe (') बाट सुरु हुने खाली कक्षहरूलाई पनि गणना गरिँदैन।

तलको स्क्रिनसटमा, A7 मा स्पेस, A8 मा apostrophe र A9 मा खाली स्ट्रिङ (="") छ। हाम्रो सूत्रले ती सबै कक्षहरू छोड्छ र पाठ-सेलहरूको गणना फर्काउँछ3:

कसरी एक्सेलमा निश्चित पाठ भएका कक्षहरू गणना गर्ने

निश्चित पाठ वा क्यारेक्टर भएका कक्षहरूको सङ्ख्या प्राप्त गर्न, तपाईंले केवल त्यो पाठ आपूर्ति गर्नुहोस् COUNTIF प्रकार्यको मापदण्ड तर्कमा। तलका उदाहरणहरूले सूक्ष्मताहरू व्याख्या गर्छन्।

नमूना पाठसँग मिलाउन ठीक रूपमा , उद्धरण चिन्हहरूमा संलग्न पूर्ण पाठ प्रविष्ट गर्नुहोस्:

आंशिक मिल्ने भएका कक्षहरू गणना गर्न, पाठलाई दुई ताराहरू बीचमा राख्नुहोस्, जसले पाठको अगाडि र पछाडि कुनै पनि अक्षरहरू प्रतिनिधित्व गर्दछ:

उदाहरणका लागि, दायरा A2:A7 मा "केरा" शब्द ठ्याक्कै समावेश भएका कतिवटा कक्षहरू पत्ता लगाउन, प्रयोग गर्नुहोस्। यो सूत्र:

=COUNTIF(A2:A7, "bananas")

कुनै पनि स्थानमा तिनीहरूको सामग्रीको अंशको रूपमा "केरा" समावेश गर्ने सबै कक्षहरू गणना गर्न, यो प्रयोग गर्नुहोस्:

=COUNTIF(A2:A7, "*bananas*")

सूत्रलाई थप प्रयोगकर्ता-अनुकूल बनाउनको लागि, तपाईंले मापदण्डलाई पूर्वनिर्धारित कक्षमा राख्न सक्नुहुन्छ, D2 भन्नुहोस्, र दोस्रो तर्कमा सेल सन्दर्भ राख्न सक्नुहुन्छ:

=COUNTIF(A2:A7, D2)

इनपुटमा निर्भर गर्दै D2 मा, सूत्रले नमूना पाठलाई पूर्ण वा आंशिक रूपमा मिलाउन सक्छ:

• पूर्ण मिलानको लागि, स्रोत तालिकामा देखा पर्ने सम्पूर्ण शब्द वा वाक्यांश टाइप गर्नुहोस्, उदाहरणका लागि। केरा ।
• आंशिक मिलानको लागि, वाइल्डकार्ड वर्णहरूले घेरिएको नमूना पाठ टाइप गर्नुहोस्, जस्तै *केला* ।

को रूपमा सूत्र हो केस-असंवेदनशील , तपाईंले अक्षर केसको बारेमा चिन्ता नगर्न सक्नुहुन्छ,यसको मतलब *केला* ले पनि गर्नेछ।

वैकल्पिक रूपमा, आंशिक मिलान भएका कक्षहरू गणना गर्न, सेल सन्दर्भलाई जोड्नुहोस्। र वाइल्डकार्ड वर्णहरू जस्तै:

=COUNTIF(A2:A7, "*"&D2&"*")

थप जानकारीको लागि, कृपया एक्सेलमा विशिष्ट पाठ भएका कक्षहरू कसरी गणना गर्ने हेर्नुहोस्।

कसरी एक्सेलमा पाठसँग फिल्टर गरिएका कक्षहरू गणना गर्न

एउटा क्षणमा सान्दर्भिक डेटा मात्र प्रदर्शन गर्न एक्सेल फिल्टर प्रयोग गर्दा, तपाईंले कहिलेकाहीँ पाठसँग दृश्य कक्षहरू गणना गर्न आवश्यक पर्दछ । अफसोसको कुरा, यस कार्यको लागि त्यहाँ कुनै एक-क्लिक समाधान छैन, तर तलको उदाहरणले तपाईंलाई सहज रूपमा चरणहरू मार्फत हिंड्नेछ।

मान्नुहोस्, तपाईंसँग तलको छविमा देखाइएको जस्तो तालिका छ। केही प्रविष्टिहरू सूत्रहरू प्रयोग गरेर ठूलो डाटाबेसबाट तानिएका थिए, र बाटोमा विभिन्न त्रुटिहरू देखा पर्‍यो। तपाईं स्तम्भ A मा वस्तुहरूको कुल संख्या फेला पार्न खोज्दै हुनुहुन्छ। सबै पङ्क्तिहरू देखिने गरी, COUNTIF सूत्र जुन हामीले पाठको साथ कक्षहरू गणना गर्न प्रयोग गरेका छौं:

=COUNTIF(A2:A10, "*")

र अब, तपाईंले सूचीलाई केही मापदण्डहरूद्वारा संकुचित गर्नुहुन्छ, भन्नुहोस् 10 भन्दा बढी मात्रामा वस्तुहरूलाई फिल्टर गर्नुहोस्। प्रश्न यो हो- कति वस्तुहरू बाँकी छन्?

गणना गर्न पाठसँग फिल्टर गरिएका कक्षहरू , तपाईंले यो गर्न आवश्यक छ:

1. तपाईंको स्रोत तालिकामा, सबै पङ्क्तिहरू दृश्यात्मक बनाउनुहोस्। यसका लागि, सबै फिल्टरहरू खाली गर्नुहोस् र लुकेका पङ्क्तिहरू अनहाइड गर्नुहोस्।
2. सबTOTAL सूत्रको साथ एउटा सहायक स्तम्भ थप्नुहोस् जसले पङ्क्ति छ कि छैन भनेर संकेत गर्दछ।फिल्टर गरिएको वा छैन।

   फिल्टर गरिएका कक्षहरू ह्यान्डल गर्न, function_num तर्कको लागि 3 प्रयोग गर्नुहोस्:

   =SUBTOTAL(3, A2)

   सबै पहिचान गर्न लुकेका कक्षहरू , फिल्टर आउट र म्यानुअल रूपमा लुकाइएको, function_num मा 103 राख्नुहोस्:

   =SUBTOTAL(103, A2)

   यस उदाहरणमा, हामी केवल दृश्य कक्षहरू गणना गर्न चाहन्छौं। पाठको साथ अन्य कक्षहरू कसरी लुकेका थिए, त्यसकारण हामी A2 मा दोस्रो सूत्र प्रविष्ट गर्छौं र यसलाई A10 मा प्रतिलिपि गर्छौं।

   दृश्य कक्षहरूको लागि, सूत्रले 1 फर्काउँछ। तपाईंले फिल्टर गर्ने बित्तिकै वा म्यानुअल रूपमा केही पङ्क्तिहरू लुकाउनुहोस्, सूत्रले तिनीहरूका लागि ० फर्काउनेछ। (तपाईले ती शून्यहरू देख्नुहुने छैन किनभने तिनीहरू लुकेका पङ्क्तिहरूका लागि फर्काइएका छन्। यसले यस तरिकाले काम गर्छ भनेर सुनिश्चित गर्न, लुकेको कक्षको सामग्रीलाई सबटोटल सूत्रको साथमा कुनै पनि देखिने भन्नुहोस्, भन्नुहोस् =D2, पङ्क्ति 2 लुकेको छ भनी मान्नुहोस्। .)

   

3. पाठसँग देखिने कक्षहरू गणना गर्न दुई फरक criteria_range / मापदण्ड जोडीहरूसँग COUNTIFS प्रकार्य प्रयोग गर्नुहोस्:
   • Criteria1 - दायरा A2:A10 मा कुनै पनि पाठ ("*") भएका कक्षहरूको लागि खोजी गर्दछ।
   • Criteria2 - दृश्य कक्षहरू पत्ता लगाउन D2:D10 दायरामा 1 को लागि खोजी गर्दछ।<17

   =COUNTIFS(A2:A10, "*", D2:D10, 1)

अब, तपाईले चाहानु भएको डेटा फिल्टर गर्न सक्नुहुन्छ, र सूत्रले तपाईलाई स्तम्भ A मा कतिवटा फिल्टर गरिएका कक्षहरू पाठ समावेश गर्दछ भनेर बताउनेछ। हाम्रो केस):

यदि तपाइँ तपाइँको कार्यपत्रमा अतिरिक्त स्तम्भ सम्मिलित गर्न चाहनुहुन्न भने, तपाइँलाई कार्य पूरा गर्न लामो सूत्र चाहिन्छ। केवल तपाईं एक छान्नुहोस्राम्रो जस्तै:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISTEXT(A2:A10)))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), -- (ISTEXT(A2:A10)))

गुण अपरेटरले पनि काम गर्नेछ:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))) * (ISTEXT(A2:A10)))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10)-MIN(ROW(A2:A10)),,1)) * (ISTEXT(A2:A10)))

कुन सूत्र प्रयोग गर्ने तपाईंको व्यक्तिगत प्राथमिकताको कुरा हो - परिणाम कुनै पनि अवस्थामा समान हुनेछ:

यी सूत्रहरूले कसरी काम गर्दछ

पहिलो सूत्रले निर्दिष्ट दायरामा SUBTOTAL मा सबै कक्षहरूको व्यक्तिगत सन्दर्भहरूलाई "फिड" गर्न INDIRECT प्रकार्य प्रयोग गर्दछ। दोस्रो सूत्रले एउटै उद्देश्यका लागि OFFSET, ROW र MIN प्रकार्यहरूको संयोजन प्रयोग गर्दछ।

SUBTOTAL प्रकार्यले 1's र 0's को एर्रे फर्काउँछ जहाँ देखिने कक्षहरू र शून्यहरू लुकेका कक्षहरू (जस्तै हेल्पर स्तम्भ) सँग मेल खान्छ। माथि)।

ISTEXT प्रकार्यले A2:A10 मा प्रत्येक सेल जाँच गर्छ र यदि सेलमा पाठ समावेश छ भने TRUE फर्काउँछ, अन्यथा FALSE। डबल युनरी अपरेटर (--) ले TRUE र FALSE मानहरूलाई 1's र 0's मा जबरजस्ती गर्छ। यस बिन्दुमा, सूत्र निम्नानुसार देखिन्छ:

=SUMPRODUCT({0;1;1;1;0;1;1;0;0}, {1;1;1;0;1;1;0;1;1})

SUMPRODUCT प्रकार्यले पहिले एउटै स्थितिमा दुवै एरेका तत्वहरूलाई गुणन गर्छ र त्यसपछि परिणामित एरेको योग गर्दछ।

शून्यले गुणन गर्दा शून्य प्राप्त हुन्छ, दुवै एरेमा 1 द्वारा प्रतिनिधित्व गरिएका कक्षहरू मात्र अन्तिम एरेमा 1 हुन्छन्।

=SUMPRODUCT({0;1;1;0;0;1;0;0;0})

र माथिको एरेमा 1 को संख्या देखिने संख्या हो। पाठ समावेश गर्ने कक्षहरू।

यस्तै Excel मा पाठ भएका कक्षहरू कसरी गणना गर्ने। पढ्नुभएकोमा म तपाईंलाई धन्यवाद दिन्छु र अर्को हप्ता हाम्रो ब्लगमा तपाईंलाई भेट्ने आशा गर्छु!

उपलब्धडाउनलोडहरू

पाठसँग कक्षहरू गणना गर्न एक्सेल सूत्रहरू