Daftar Isi
Apakah Anda tahu cara menjumlahkan angka di kolom tertentu ketika nilai di kolom lain memenuhi salah satu kondisi yang ditentukan? Pada artikel ini, Anda akan mempelajari 3 cara berbeda untuk melakukan SUMIF menggunakan beberapa kriteria dan logika OR.
Microsoft Excel memiliki fungsi khusus untuk menjumlahkan sel dengan beberapa kondisi - fungsi SUMIFS. Fungsi ini dirancang untuk bekerja dengan logika AND - sel ditambahkan hanya ketika semua kriteria yang ditentukan BENAR untuk sel itu. Namun, dalam beberapa situasi, Anda mungkin perlu menjumlahkan dengan beberapa kriteria OR, yaitu menambahkan sel ketika salah satu kondisinya BENAR. Dan inilah saatnya fungsi SUMIFsangat berguna.
SUMIF + SUMIF untuk menjumlahkan sel yang sama dengan ini atau itu
Ketika Anda ingin menjumlahkan angka-angka dalam satu kolom ketika kolom lain sama dengan A atau B, solusi yang paling jelas adalah menangani setiap kondisi satu per satu, dan kemudian menjumlahkan hasilnya bersama-sama:
SUMIF(range, kriteria1 , sum_range) + SUMIF(range, kriteria2 , sum_range)Dalam tabel di bawah ini, misalkan Anda ingin menjumlahkan penjualan untuk dua produk yang berbeda, katakanlah Apel dan Lemon Untuk ini, Anda bisa menyediakan item-item yang diminati secara langsung di dalam kriteria argumen dari 2 fungsi SUMIF yang berbeda:
=SUMIF(A2:A10, "apel", B2:B10) + SUMIF(A2:A10, "lemon", B2:B10)
Atau, Anda bisa memasukkan kriteria dalam sel terpisah, dan merujuk ke sel tersebut:
=SUMIF(A2:A10, E1, B2:B10) + SUMIF(A2:A10, E2, B2:B10)
Di mana A2:A10 adalah daftar item ( rentang ), B2:B10 adalah angka-angka untuk dijumlahkan ( sum_rage ), E1 dan E2 adalah item target ( kriteria ):
Bagaimana formula ini bekerja:
Fungsi SUMIF pertama menjumlahkan Apel penjualan, SUMIF kedua menjumlahkan Lemon Operasi penjumlahan menjumlahkan sub-total bersama-sama dan menghasilkan total.
SUMIF dengan konstanta array - rumus ringkas dengan beberapa kriteria
Pendekatan SUMIF + SUMIF bekerja dengan baik untuk 2 kondisi. Jika Anda perlu menjumlahkan dengan 3 kriteria atau lebih, rumusnya akan menjadi terlalu besar dan sulit dibaca. Untuk mencapai hasil yang sama dengan rumus yang lebih ringkas, berikan kriteria Anda dalam konstanta array:
SUM(SUMIF(range, { crireria1 , crireria2 , crireria3 , ...}, sum_range))Harap diingat bahwa rumus ini bekerja berdasarkan logika OR - sel dijumlahkan ketika satu kondisi terpenuhi.
Dalam kasus kita, untuk menjumlahkan penjualan untuk 3 item yang berbeda, rumusnya adalah:
=SUM(SUMIF(A2:A10, {"Apel", "Lemon", "Jeruk"}, B2:B10))
Pada screenshot di atas, kondisinya dikodekan dalam array, yang berarti kamu harus memperbarui rumusnya dengan setiap perubahan dalam kriterianya. Untuk menghindari hal ini, kamu bisa memasukkan kriterianya ke dalam cell yang sudah ditentukan sebelumnya dan memasoknya ke rumus sebagai referensi range (E1:E3 dalam contoh ini).
=SUM(SUMIF(A2:A10, E1:E3, B2:B10))
Di Excel 365 yang mendukung array dinamis, ini berfungsi sebagai rumus biasa yang dilengkapi dengan tombol Enter. Di versi Excel 2019 pra-dinamis, Excel 2016, Excel 2013, dan sebelumnya, ini harus dimasukkan sebagai rumus array dengan pintasan Ctrl + Shift + Enter:
Bagaimana formula ini bekerja:
Konstanta larik yang dimasukkan ke dalam kriteria SUMIF memaksanya untuk mengembalikan beberapa hasil dalam bentuk larik. Dalam kasus kita, ini adalah 3 jumlah yang berbeda: untuk Apel , Lemon dan Jeruk :
{425;425;565}
Untuk mendapatkan totalnya, kita menggunakan fungsi SUM dan membungkusnya di sekitar rumus SUMIF.
SUMPRODUCT dan SUMIF untuk menjumlahkan sel dengan beberapa kondisi OR
Tidak suka array dan mencari rumus normal yang memungkinkan Anda menjumlahkan dengan beberapa kriteria dalam sel yang berbeda? Tidak masalah. Alih-alih SUM, gunakan fungsi SUMPRODUCT yang menangani array secara native:
SUMPRODUCT(SUMIF(range, crireria_range , sum_range))
Dengan asumsi kondisi berada di sel E1, E2 dan E3, rumusnya berbentuk seperti ini:
=SUMPRODUCT(SUMIF(A2:A10, E1:E3, B2:B10))
Bagaimana formula ini bekerja:
Seperti pada contoh sebelumnya, fungsi SUMIF mengembalikan larik angka, yang mewakili jumlah untuk setiap kondisi individu. SUMPRODUCT menambahkan angka-angka ini bersama-sama dan menghasilkan total akhir. Tidak seperti fungsi SUM, SUMPRODUCT dirancang untuk memproses larik, sehingga berfungsi sebagai rumus biasa tanpa Anda harus menekan Ctrl + Shift + Enter .
SUMIF menggunakan beberapa kriteria dengan wildcard
Karena fungsi SUMIF Excel mendukung wildcard, Anda dapat memasukkannya dalam beberapa kriteria jika diperlukan.
Misalnya, untuk menjumlahkan penjualan untuk semua jenis Apel dan Pisang , rumusnya adalah:
=SUM(SUMIF(A2:A10, {"*Apples", "*Bananas"}, B2:B10))
Jika kondisimu seharusnya dimasukkan ke dalam cell individual, kamu bisa mengetikkan wildcard secara langsung di cell-cell tersebut dan memberikan referensi range sebagai kriteria untuk rumus SUMPRODUCT SUMIFnya:
Dalam contoh ini, kita menaruh karakter wildcard (*) sebelum nama item untuk mencocokkan urutan karakter sebelumnya, seperti Apel hijau dan Pisang Goldfinger Untuk mendapatkan total item yang mengandung teks tertentu di mana saja di dalam sel, tempatkan tanda bintang di kedua sisinya, misalnya "*apple*".
Itulah cara menggunakan SUMIF di Excel dengan beberapa kondisi. Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!
Buku kerja latihan untuk diunduh
SUMIF beberapa kriteria (file .xlsx)
