Ha rendszeres látogatója vagy ennek a blognak, valószínűleg észrevettél már néhány cikket, amelyek az Excel feltételes formázás különböző aspektusait tárgyalják. Most pedig kihasználjuk ezt a tudást, és olyan táblázatokat fogunk létrehozni, amelyek megkülönböztetik a hétköznapokat és a hétvégéket, kiemelik az ünnepnapokat és megjelenítik a közelgő határidőt vagy késést. Más szóval, Excel feltételes formázást fogunk alkalmazni a dátumokra.

Ha van némi alapismerete az Excel képletekről, akkor valószínűleg ismeri a dátum- és időfüggvényeket, mint például a NOW, TODAY, DATE, WEEKDAY stb. Ebben a bemutatóban egy lépéssel továbbvisszük ezt a funkciót, hogy Excel dátumok feltételes formázása a kívánt módon.

Excel feltételes formázás dátumokhoz (beépített szabályok)

A Microsoft Excel 10 lehetőséget biztosít a kiválasztott celláknak az aktuális dátum alapján történő formázására.

1. A formázás alkalmazásához egyszerűen menjen a Home tab> Feltételes formázás> Kiemelje a cellák szabályait és válassza a Egy dátum bekövetkezése .

   

2. Válasszon egyet a dátum opciók az ablak bal oldalán található legördülő listából, a múlt hónaptól a következő hónapig.
3. Végül válasszon az előre definiált formátumok közül, vagy állítsa be az egyéni formátumot a különböző opciók kiválasztásával a Betűtípus , Határ és Töltse ki a címet. Ha az Excel szabványos palettája nem elégséges, akkor bármikor rákattinthat a További színek... gomb.

   

4. Kattintson a címre. OK és élvezd az eredményt! : )

   

Ennek a gyors és egyszerű módszernek azonban két jelentős korlátja van: 1) csak a kijelölt cellákra működik, és 2) a feltételes formátum mindig az aktuális dátum alapján kerül alkalmazásra.

Excel feltételes formázási képletek dátumokhoz

Ha cellákat vagy egész sorokat szeretne kiemelni egy másik cellában lévő dátum alapján , vagy hozzon létre szabályokat a nagyobb időintervallumok (azaz több mint egy hónappal az aktuális dátumtól számítva), akkor egy képleten alapuló saját feltételes formázási szabályt kell létrehoznia. Az alábbiakban néhány példát talál a kedvenc Excel feltételes formázásaimra a dátumokhoz.

Hogyan lehet kiemelni a hétvégéket az Excelben

Sajnálatos módon a Microsoft Excel nem rendelkezik az Outlookhoz hasonló beépített naptárral. Nos, lássuk, hogyan hozhatja létre saját automatizált naptárát meglehetősen kis erőfeszítéssel.

Az Excel-naptár tervezésekor a hét napjainak megjelenítéséhez használhatja a =DATE(év,hónap,dátum) függvényt. Egyszerűen csak írja be az év és a hónap számát valahová a táblázatkezelőben, és hivatkozzon ezekre a cellákra a képletben. Természetesen a számokat közvetlenül a képletbe is beírhatja, de ez nem túl hatékony megközelítés, mert minden hónaphoz ki kellene igazítania a képletet.

Az alábbi képernyőkép a DATE függvényt mutatja be működés közben. A következő képletet használtam =DATE($B$2,$B$1,B$4) amelyet az 5. sorba másolunk.

Tipp: Ha csak a hét napjait szeretné megjeleníteni, mint a fenti képen, jelölje ki a képletet tartalmazó cellákat (esetünkben az 5. sort), kattintson a jobb gombbal, és válassza a következő parancsot Cellák formázása.> Szám> Egyéni A legördülő listából a Típus , válassza a következőket dddd vagy ddd a teljes vagy a rövidített napi nevek megjelenítéséhez.

Az Excel-naptárad már majdnem kész, már csak a hétvégék színét kell megváltoztatnod. Természetesen nem fogod kézzel kiszínezni a cellákat. Az Excel segítségével automatikusan formázzuk a hétvégéket, egy feltételes formázási szabály létrehozásával, amely a következőkön alapul HÉTFŐNAP formula.

1. Azzal kezdjük, hogy kiválasztjuk az Excel naptárunkat, ahol a hétvégéket árnyalni szeretnénk. Esetünkben ez a $B$4:$AE$10 tartomány. Ügyeljen arra, hogy a kijelölést a 1. dátum oszlop - Ebben a példában a B oszlop.
2. A Home fülre, kattintson a Feltételes formázás menü> Új szabály .
3. Hozzon létre egy új feltételes formázási szabályt egy képlet alapján, ahogyan azt a fent hivatkozott útmutatóban elmagyarázzuk.
4. A " Formázza az értékeket, ahol ez a képlet igaz" mezőbe írja be a következő WEEKDAY képletet, amely meghatározza, hogy mely cellák szombati és vasárnapi napok: =WEEKDAY(B$5,2)>5
5. Kattintson a Formátum... gombot, és állítsa be az egyéni formátumot a következő lehetőségek között váltva Betűtípus , Határ és Töltse ki a címet. fülekkel és a különböző formázási beállításokkal játszva. Ha kész, kattintson a OK gomb megnyomásával megtekintheti a szabályt.

Hadd magyarázzam el röviden a WEEKDAY(serial_number,[return_type]) képletet, hogy gyorsan beállíthassa azt saját táblázatkezeléseihez.

• A serial_number paraméter jelöli a keresett dátumot. Megadjuk a dátumot tartalmazó első cellára való hivatkozást, esetünkben a B$5-öt.
• A [return_type] paraméter határozza meg a hét típusát (a szögletes zárójelek azt jelentik, hogy opcionális). A hétfőtől (1) vasárnapig (7) tartó hét visszatérési típusaként a 2-t adja meg. Az elérhető visszatérési típusok teljes listáját itt találja.
• Végül írja be az>5-et, hogy csak a szombatokat (6) és a vasárnapokat (7) emelje ki.

Az alábbi képernyőkép az Excel 2013-ban mutatja az eredményt - a hétvégék pirosas színnel vannak kiemelve.

Tippek:

• Ha a vállalatnál nem szabványos hétvégék vannak, pl. péntek és szombat, akkor a képletet úgy kell módosítani, hogy a számlálás vasárnaptól (1) kezdődjön, és a 6. (péntek) és a 7. (szombat) napot kell kiemelni -. WEEKDAY(B$5,1)>5 .
• Ha vízszintes (fekvő) naptárat készítünk, használjunk relatív oszlopot ($ nélkül) és abszolút sort ($-val) a cellahivatkozásban, mert a sor hivatkozását kell rögzítenünk - a fenti példában ez az 5. sor, tehát B$5-t írtunk be. Ha azonban függőleges tájolású naptárat tervezünk, akkor ennek ellenkezőjét kell tennünk, azaz abszolút oszlopot és relatív sort használnunk, pl. $B5, ahogyan azt az alábbiakban láthatjukaz alábbi képernyőkép:

Hogyan lehet kiemelni az ünnepeket az Excelben

Az Excel-naptár további javítása érdekében árnyalhatja az ünnepnapokat is. Ehhez ugyanabban vagy egy másik táblázatban kell felsorolnia a kiemelni kívánt ünnepnapokat.

Például az A oszlopba a következő ünnepnapokat tettem be ($A$14:$A$17). Természetesen nem mindegyik valódi ünnepnap, de bemutató célokra megteszi : )

Ismét kinyitja Feltételes formázás > Új szabály Ünnepek esetén vagy a következő módot használja MATCH vagy COUNTIF funkció:

• =COUNTIF($A$14:$A$17,B$5)>0
• =MATCH(B$5,$A$14:$A$17,0)

Megjegyzés: Ha más színt választott az ünnepnapokhoz, akkor a munkaszüneti napra vonatkozó szabályt a szabályok listájának elejére kell helyeznie az alábbi módon. Feltételes formázás> Szabályok kezelése...

A következő kép az Excel 2013-ban mutatja az eredményt:

Egy cella feltételes formázása, ha egy értéket dátumra módosítanak

Nem jelent nagy problémát egy cella feltételes formázása, ha egy dátumot adunk hozzá az adott cellához vagy ugyanazon sor bármely más cellájához, amíg más értéktípus nem megengedett. Ebben az esetben egyszerűen használhatunk egy képletet a nem üres cellák kiemelésére, ahogyan azt az Excel feltételes képletek üres és nem üres cellákhoz című fejezetben leírtuk. De mi van akkor, ha ezekben a cellákban már van valamilyen érték, pl. szöveg, és meg akarjuk változtatni a(z)háttérszín, amikor a szöveg dátumra változik?

A feladat kissé bonyolultnak tűnhet, de a megoldás nagyon egyszerű.

1. Először is meg kell határoznia a dátum formátumkódját. Íme néhány példa:
   • D1: dd-mmm-yy vagy d-mmm-yy
   • D2: dd-mmm vagy d-mmm
   • D3: mmm-yy
   • D4: mm/dd/yy vagy m/d/yy vagy m/d/yy h:mm

   A dátumkódok teljes listáját ebben a cikkben találja.

2. Válassza ki azt az oszlopot, ahol meg akarja változtatni a cellák színét, vagy az egész táblázatot, ha a sorokat szeretné kiemelni.
3. Most pedig hozzon létre egy feltételes formázási szabályt egy ehhez hasonló képlet segítségével: =CELL("format",$A2)="D1" A képletben az A a dátumokat tartalmazó oszlop, a D1 pedig a dátumformátum.

   Ha a táblázat 2 vagy több formátumú dátumokat tartalmaz, akkor használja a VAGY operátort, pl. =OR(cell("format", $A2)="D1", cell("format",$A2)="D2", cell("format", $A2)="D3")

   Az alábbi képernyőkép a dátumok ilyen feltételes formázási szabályának eredményét mutatja.

   

Hogyan lehet kiemelni a sorokat egy bizonyos dátum alapján egy bizonyos oszlopban

Tegyük fel, hogy van egy nagy Excel-táblázata, amely két dátumoszlopot tartalmaz (B és C). Minden olyan sort ki szeretne emelni, amely a C oszlopban egy bizonyos dátumot, mondjuk május 14., 13., tartalmaz.

Az Excel feltételes formázás alkalmazásához egy bizonyos dátumra, meg kell találnia annak számérték Először is, mint azt bizonyára tudja, a Microsoft Excel a dátumokat sorszámként tárolja, 1900. január 1-től kezdődően. 1900. január 1. tehát 1-Jan-1900 1, 1900. január 2. 2... és 14. május 13. 41772 számként tárolódik.

A dátum számának megkereséséhez kattintson a jobb gombbal a cellára, válassza a Cellák formázása> Szám és válassza a Általános formátum. Írja le a látott számot, és kattintson a Törölje mert nem igazán akarja megváltoztatni a dátum formátumát.

Tulajdonképpen ez volt a munka nagy része, és most már csak egy feltételes formázási szabályt kell létrehoznia az egész táblázatra ezzel a nagyon egyszerű képlettel: =$C2=41772 A képlet azt feltételezi, hogy a táblázatnak vannak fejlécei, és a 2. sor az első adatsor.

Egy másik lehetőség a DATEVALUE képlet, amely a dátumot a tárolt számformátumba konvertálja, pl. =$C2=DATEVALUE("5/13/2014")

Bármelyik formulát is használja, ugyanaz lesz a hatása:

Dátumok feltételes formázása az Excelben az aktuális dátum alapján

Mint azt valószínűleg tudja, a Microsoft Excel biztosítja a TODAY() függvények különböző számításokhoz az aktuális dátum alapján. Íme néhány példa arra, hogyan használhatja a dátum feltételes formázására az Excelben.

Példa 1. A mai nappal megegyező, annál nagyobb vagy annál kisebb dátumok kiemelése

A cellák vagy egész sorok feltételes formázásához a mai dátum alapján a TODAY függvényt használja a következőképpen:

Egyenlő a mával: =$B2=TODAY()

Nagyobb, mint ma: =$B2>TODAY()

Kevesebb, mint ma: =$B2

Az alábbi képernyőfotó a fenti szabályokat mutatja be működés közben. Kérjük, vegye figyelembe, hogy a cikk írásakor a MÁJUS 2014. június 12-én volt.

Példa 2. Dátumok feltételes formázása Excelben több feltétel alapján

Hasonló módon használhatja a TODAY függvényt más Excel-funkciókkal kombinálva, hogy bonyolultabb forgatókönyveket kezeljen. Például, lehet, hogy az Excel feltételes formázási dátumformulájának színezésére a Számla oszlop, amikor a Szállítási dátum egyenlő vagy nagyobb, mint a mai nap, DE azt szeretné, ha a formázás eltűnne a számlaszám megadásakor.

Ehhez a feladathoz szükség van egy további oszlopra a következő képlettel (ahol az E az Ön Szállítás oszlop és F az Számla oszlop):

=IF(E2>=TODAY(),IF(F2="", 1, 0), 0)

Ha a szállítási dátum nagyobb vagy egyenlő az aktuális dátummal, és a Számla oszlopban nincs szám, a képlet 1, egyébként 0 értéket ad vissza.

Ezután létrehoz egy egyszerű feltételes formázási szabályt a Számla oszlop a következő képlettel =$G2=1 ahol G a kiegészítő oszlop. Természetesen ezt az oszlopot később el tudja majd rejteni.

Példa 3. A közelgő időpontok és késések kiemelése

Tegyük fel, hogy van egy projekt ütemterve Excelben, amely felsorolja a feladatokat, azok kezdő dátumát és időtartamát. Azt szeretné, ha minden feladathoz automatikusan kiszámítanánk a befejező dátumot. További kihívás, hogy a képletnek figyelembe kell vennie a hétvégéket is. Például, ha a kezdő dátum 2014. június 13. és a munkanapok száma (Időtartam) 2, akkor a befejező dátumnak 2014. június 17-nek kell lennie,mivel június 14. és június 15. szombat és vasárnap.

Ehhez a WORKDAY.INTL(start_date,days,[weekend],[holidays]) funkció, pontosabban =WORKDAY.INTL(B2,C2,1) .

A képletben a 3. paraméterként 1-et adunk meg, mivel ez a szombatot és a vasárnapot jelöli ki ünnepnapként. Használhat más értéket is, ha a hétvégéi eltérőek, mondjuk péntek és szombat. A hétvégi értékek teljes listája itt érhető el. Opcionálisan használhatja a 4. paramétert [ünnepnapok] is, amely olyan dátumok (cellatartomány) halmaza, amelyeket ki kell zárni a munkanaptárból.

Végül pedig a sorokat aszerint is kiemelheti, hogy milyen messze van a határidő. Például a következő 2 képleten alapuló feltételes formázási szabályok kiemelik a közelgő, illetve a közelmúltbeli végdátumokat:

• =AND($D2-TODAY()>=0,$D2-TODAY()<=7) - minden olyan sor kiemelése, ahol a Végdátum (D oszlop) a következő 7 nap Ez a képlet nagyon hasznos, amikor a közelgő lejárati dátumokat vagy kifizetéseket kell nyomon követni.
• =AND(TODAY()-$D2>=0,TODAY()-$D2<=7) - minden olyan sor kiemelése, ahol a Végdátum (D oszlop) a az elmúlt 7 napban Ezzel a képlettel nyomon követheti a legutóbbi késedelmes fizetéseket és egyéb késedelmeket.

Íme néhány további képletpélda, amely a fenti táblázatra alkalmazható:

=$D2 - kiemeli az összes lejárt dátumot (azaz az aktuális dátumnál rövidebb dátumokat). Használható lejárt előfizetések, késedelmes fizetések stb. formázására.

=$D2>TODAY() - kiemeli az összes jövőbeli dátumot (azaz az aktuális dátumnál nagyobb dátumokat). Használhatja a közelgő események kiemelésére.

Természetesen a fenti képleteknek végtelen számú változata létezik, az adott feladattól függően. Például:

=$D2-TODAY()>=6 - kiemeli azokat a dátumokat, amelyek 6 vagy több nap múlva esedékesek.

=$D2=TODAY()-14 - kiemeli a pontosan 2 héttel ezelőtti dátumokat.

Dátumok kiemelése egy dátumtartományon belül

Ha a munkalapon a dátumok hosszú listája található, akkor azokat a cellákat vagy sorokat is ki akarja emelni, amelyek egy bizonyos dátumtartományba esnek, azaz minden olyan dátumot ki kell emelni, amely két adott dátum között van.

Ezt a feladatot ismét a TODAY() függvénnyel tudja teljesíteni, csak egy kicsit bonyolultabb képleteket kell összeállítania, ahogyan azt az alábbi példák mutatják.

Képletek a múltbeli dátumok kiemelésére

• Több mint 30 nappal ezelőtt: =TODAY()-$A2>30
• 30 és 15 nappal ezelőtt, beleértve: =AND(TODAY()-$A2>=15, TODAY()-$A2<=30)
• Kevesebb mint 15 nappal ezelőtt: =AND(TODAY()-$A2>=1, TODAY()-$A2<15)

Az aktuális dátum és a jövőbeli dátumok nem színezettek.

Képletek a jövőbeli dátumok kiemelésére

• Több mint 30 nap múlva fog bekövetkezni: =$A2-TODAY()>30
• 30 és 15 nap között: =AND($A2-TODAY()>=15, $A2-TODAY()<=30)
• Kevesebb mint 15 nap alatt: =AND($A2-TODAY()>=1, $A2-TODAY()<15)

Az aktuális dátum és a múltbeli dátumok nincsenek színezve.

Hogyan árnyékoljuk a hézagokat és az időintervallumokat?

Ebben az utolsó példában egy másik Excel dátumfüggvényt fogunk használni - DATEDIF(start_date, end_date, intervallum) Ez a függvény két dátum közötti különbséget számol ki a megadott intervallum alapján. Abban különbözik az összes többi, ebben a tananyagban tárgyalt függvénytől, hogy lehetővé teszi a hónapok vagy évek figyelmen kívül hagyását, és csak a napok vagy hónapok közötti különbséget számítja ki, attól függően, hogy melyiket választja.

Nem érti, hogyan működhet ez az Ön számára? Gondoljon másképp... Tegyük fel, hogy van egy listája a családtagjai és barátai születésnapjairól. Szeretné tudni, hány nap van hátra a következő születésnapjukig? Sőt, hány nap van hátra pontosan az esküvői évfordulóig és más eseményekig, amelyeket nem szeretne kihagyni? Könnyen!

A következő képletre van szükséged (ahol A a te Dátum oszlop):

=DATEDIF(TODAY(), DATE((YEAR(TODAY())+1), MONTH($A2), DAY($A2)), "yd")

A képlet végén található "yd" intervallumtípus az évek figyelmen kívül hagyására és csak a napok közötti különbség kiszámítására szolgál. A rendelkezésre álló intervallumtípusok teljes listáját itt találja.

Tipp: Ha véletlenül elfelejtené vagy elkeveredne az összetett képlet, használhatja helyette ezt az egyszerűt: =365-DATEDIF($A2,TODAY(), "yd") Pontosan ugyanezt az eredményt adja, csak ne feledje, hogy szökőévekben a 365 helyett 366-ot kell használni : )

És most hozzunk létre egy Excel feltételes formázási szabályt, hogy a különböző réseket különböző színekkel árnyaljuk. Ebben az esetben célszerűbb az Excel színskáláit használni, mint külön szabályt létrehozni minden egyes periódushoz.

Az alábbi képernyőkép az Excelben mutatja az eredményt - egy gradiens 3 színű skála, a zöldtől a piroson át a sárgáig terjedő árnyalatokkal.

"Napok a következő születésnapig" Excel webes alkalmazás

Létrehoztuk ezt az Excel webes alkalmazást, hogy megmutassuk a fenti képletet működés közben. Csak adja meg az eseményeket az 1. oszlopban, és változtassa meg a megfelelő dátumokat a 2. oszlopban, hogy kísérletezzen az eredménnyel.

Megjegyzés: A beágyazott munkafüzet megtekintéséhez kérjük, engedélyezze a marketing sütiket.

Ha kíváncsi arra, hogyan hozhat létre ilyen interaktív Excel-táblázatokat, olvassa el ezt a cikket arról, hogyan készíthet webalapú Excel-táblázatokat.

Reméljük, hogy a cikkben tárgyalt Excel feltételes dátumformátumok közül legalább egy hasznosnak bizonyult az Ön számára. Ha valamilyen más feladatra keres megoldást, akkor szívesen látjuk, ha hozzászólást ír. Köszönjük, hogy elolvasta!