Microsoft Excel pakub mitmeid funktsioone, mille eesmärk on loendada erinevaid lahtreid, näiteks tühikuid või mitte tühikuid, numbri-, kuupäeva- või tekstiväärtusi, mis sisaldavad konkreetseid sõnu või märke jne.

Selles artiklis keskendume Exceli funktsioonile COUNTIF, mis on mõeldud lahtrite loendamiseks teie poolt määratud tingimusega. Kõigepealt käsitleme lühidalt süntaksit ja üldist kasutamist, seejärel annan mitmeid näiteid ja hoiatan võimalike veidruste eest, kui kasutate seda funktsiooni mitme kriteeriumi ja konkreetset tüüpi lahtritega.

Põhimõtteliselt on COUNTIFi valemid kõigis Exceli versioonides identsed, nii et saate kasutada selle õpetuse näiteid Excel 365, 2021, 2019, 2016, 2013, 2010 ja 2007 versioonides.

Funktsioon COUNTIF Excelis - süntaks ja kasutamine

Exceli COUNTIF-funktsiooni kasutatakse selleks, et loendada määratud vahemikus olevaid lahtreid, mis vastavad teatavale kriteeriumile või tingimusele.

Näiteks saate kirjutada COUNTIF-valemi, et välja selgitada, mitu lahtrit teie töölehel sisaldavad arvu, mis on suurem või väiksem kui teie määratud arv. Teine tüüpiline COUNTIFi kasutamine Excelis on konkreetse sõnaga või konkreetse(te) tähe(te)ga algavate lahtrite loendamine.

Funktsiooni COUNTIF süntaks on väga lihtne:

Nagu näete, on ainult 2 argumenti, mis mõlemad on vajalikud:

• vahemik - määratleb ühe või mitu lahtrit, mida loendada. Te panete vahemiku valemisse nagu tavaliselt Excelis, nt A1:A20.
• kriteeriumid - määratleb tingimuse, mis ütleb funktsioonile, milliseid rakke loendada. See võib olla number , tekstistring , viide lahtrisse või väljendus Näiteks võite kasutada selliseid kriteeriume: "10", A2, ">=10", "mingi tekst".

Ja siin on kõige lihtsam näide Exceli COUNTIF-funktsioonist. Allpool oleval pildil näete viimase 14 aasta parimate tennisistide nimekirja. Valemiga =COUNTIF(C2:C15, "Roger Federer") loeb, mitu korda on Roger Federeri nimi nimekirjas:

Märkus. Kriteerium ei sõltu suur- ja väiketähendusest, mis tähendab, et kui sisestate ülaltoodud valemis kriteeriumiks "roger federer", annab see sama tulemuse.

Exceli COUNTIF-funktsiooni näited

Nagu te just nägite, on COUNTIF-funktsiooni süntaks väga lihtne. Siiski võimaldab see kriteeriumide palju võimalikke variatsioone, sealhulgas jokkerite, teiste lahtrite väärtuste ja isegi teiste Exceli funktsioonide kasutamist. See mitmekesisus muudab COUNTIF-funktsiooni tõesti võimsaks ja sobivaks paljude ülesannete täitmiseks, nagu te järgnevates näidetes näete.

COUNTIF valem teksti ja numbrite jaoks (täpne vaste)

Tegelikult arutasime funktsiooni COUNTIF, mis loeb tekstiväärtused mis vastab täpselt kindlaksmääratud kriteeriumile. Tuletan teile meelde, et valemiga lahtrite jaoks, mis sisaldavad täpset tekstijada: =COUNTIF(C2:C15, "Roger Federer") Nii et te sisenete:

• Vahemik kui esimene parameeter;
• Koma kui piiritleja;
• Sõna või mitu sõna, mis on jutumärkidesse pandud kui kriteeriumid.

Teksti sisestamise asemel võite kasutada teksti viide mis tahes lahtrisse mis sisaldavad seda sõna või sõnu ja saavad täiesti samad tulemused, nt. =COUNTIF(C1:C9,C7) .

Sarnaselt töötavad COUNTIFi valemid järgmiste valemite puhul numbrid Nagu on näidatud alloleval ekraanipildil, loeb allolev valem suurepäraselt lahtrid, mille kogus on 5 veerus D:

=COUNTIF(D2:D9, 5)

Selles artiklis leiate veel mõned valemid, et lugeda lahtreid, mis sisaldavad mis tahes teksti, konkreetseid sümboleid või ainult filtreeritud lahtreid.

COUNTIF-valemid koos jokerkaardimärkidega (osaline kokkulangevus)

Kui teie Exceli andmed sisaldavad mitmeid võtmesõna(de) variante, mida soovite loendada, siis saate kasutada jokker-märki, et loendada kõiki lahtreid, mis sisaldavad teatud sõna, fraasi või tähte, nagu osa lahtri sisust .

Oletame, et teil on nimekiri erinevatele isikutele määratud ülesannetest ja te soovite teada Danny Brownile määratud ülesannete arvu. Kuna Danny nimi on kirjutatud mitmel erineval viisil, siis sisestame otsingukriteeriumiks "*Brown*". =COUNTIF(D2:D10, "*Brown*") .

An asterisk (*) kasutatakse lahtrite leidmiseks, mis sisaldavad mis tahes järjestikku ees- ja tagantjärgnevaid märke, nagu on näidatud ülaltoodud näites. Kui teil on vaja leida ükskõik millist üksikut märki, sisestage sümbol küsimärk (?), nagu allpool näidatud.

Vihje. Samuti on võimalik kasutage lahtriviidete puhul metsikuid sümboleid liitmisoperaatori (&) abil. Näiteks selle asemel, et sisestada "*Brown*" otse valemisse, võite sisestada selle mõnda lahtrisse, näiteks F1, ja kasutada järgmist valemit "Brown" sisaldavate lahtrite loendamiseks: =COUNTIF(D2:D10, "*"&F1& "*")

Loeb lahtrid, mis algavad või lõpevad teatud tähemärkidega

Võite kasutada kas jokkerit, tärni (*) või küsimärki (?), kusjuures kriteerium sõltub sellest, millist tulemust täpselt soovite saavutada.

Kui soovite teada rakkude arvu, mis on algab või lõpeb teatud tekstiga olenemata sellest, kui palju muid märke lahter sisaldab, kasutage neid valemeid:

=COUNTIF(C2:C10,"Mr*") - loendage lahtrid, mis algavad sõnaga " Härra" .

=COUNTIF(C2:C10,"*ed") - loendage lahtrid, mis lõpevad tähtedega " ed".

Järgneval pildil on näidatud teise valemi toimimist:

Kui otsite nende lahtrite arvu, mis algavad või lõpevad teatud tähtedega ja sisaldavad tähte täpne tähemärkide arv , kasutate Exceli funktsiooni COUNTIF, mille kriteeriumides on küsimärgi märk (?):

=COUNTIF(D2:D9,"??own") - loeb lahtrite D2 kuni D9 tähtedega "oma" lõppevate ja täpselt 5 tähemärki sisaldavate lahtrite arvu, kaasa arvatud tühikud.

=COUNTIF(D2:D9, "Mr??????") - loeb lahtrite D2 kuni D9 tähtedega "härra" algavate lahtrite arvu, mis sisaldavad täpselt 8 tähemärki, kaasa arvatud tühikud.

Vihje. Et leida lahtrite arv, mis sisaldavad tegelik küsimärk või asterisk , sisestage valemis enne märki ? või * tilde (~). Näiteks, =COUNTIF(D2:D9,"*~?*") loeb kõik lahtrid, mis sisaldavad küsimärki vahemikus D2:D9.

Exceli COUNTIF tühjade ja mitte tühjade lahtrite jaoks

Need valemite näited näitavad, kuidas saate kasutada Exceli funktsiooni COUNTIF, et lugeda tühjade või mittetühjade lahtrite arvu kindlaksmääratud vahemikus.

COUNTIF ei ole tühi

Mõnes Exceli COUNTIF-õpetuses ja muudes veebiressurssides võite kohata Excelis tühjade lahtrite loendamise valemeid, mis sarnanevad sellele:

=COUNTIF(A1:A10, "*")

Kuid fakt on see, et ülaltoodud valem loeb ainult rakke, mis sisaldavad mis tahes tekstiväärtused sealhulgas tühjad stringid, mis tähendab, et kuupäevi ja numbreid sisaldavaid lahtreid käsitletakse tühjade lahtritena ja neid ei võeta arvesse!

Kui teil on vaja universaalset COUNTIF valem kõigi mitte tühjade lahtrite loendamiseks kindlaksmääratud vahemikus, siis siin:

Või

See valem töötab korrektselt kõigi väärtustüüpidega - tekst , kuupäevad ja numbrid - nagu näete alloleval ekraanipildil.

COUNTIF tühi

Kui soovite vastupidist, st lugeda tühje lahtreid teatavas vahemikus, peate järgima sama lähenemisviisi - kasutage valemit, milles on tekstiväärtuste jaoks jokker ja kõigi tühjade lahtrite loendamiseks kasutatakse kriteeriumi "".

Valem, et loendatakse lahtrid, mis ei sisalda teksti :

Kuna tärn (*) vastab mis tahes tekstimärkide järjestusele, loeb valem lahtrid, mis ei ole võrdsed *-ga, st mis ei sisalda ühtegi teksti määratud vahemikus.

Universaalne COUNTIF valem toorikute jaoks (kõik väärtustüübid) :

Ülaltoodud valemiga saab õigesti käsitleda numbreid, kuupäevi ja tekstiväärtusi. Näiteks saab nii välja lugeda tühjade lahtrite arvu vahemikus C2:C11:

=COUNTIF(C2:C11,"")

Pidage meeles, et Microsoft Excelil on tühjade lahtrite loendamiseks veel üks funktsioon COUNTBLANK. Näiteks järgmised valemid annavad täpselt samasuguse tulemuse nagu ülaltoodud ekraanipildil olevad COUNTIF-vormelid:

Lugege tühikuid:

=COUNTBLANK(C2:C11)

Loendage tühikuid:

=ROWS(C2:C11)*COLUMNS(C2:C11)-COUNTBLANK(C2:C11)

Pidage ka meeles, et nii COUNTIF kui ka COUNTBLANK loendavad lahtreid, millel on tühjad stringid mis näevad ainult tühjad välja. Kui te ei soovi selliseid lahtreid tühjadena käsitleda, kasutage "=" jaoks kriteeriumid Näiteks:

=COUNTIF(C2:C11,"=")

Lisateavet tühikute ja mitte tühikute lugemise kohta Excelis vt:

• 3 viisi tühjade lahtrite lugemiseks Excelis
• Kuidas lugeda Excelis mitte-tühje lahtreid

COUNTIF suurem, väiksem või võrdne kui

Väärtustega lahtrite loendamiseks suurem kui , vähem kui või võrdne määratud arvu, siis lisate kriteeriumidele lihtsalt vastava operaatori, nagu on näidatud alljärgnevas tabelis.

Palun pöörake tähelepanu sellele, et COUNTIF-valemites on operaator koos numbriga alati jutumärkides .

Kõiki ülaltoodud valemeid saab kasutada ka selleks, et loendab lahtrid teise lahtri väärtuse alusel , peate lihtsalt asendama kriteeriumis oleva numbri lahtriviitega.

Märkus. Juhul, kui raku viide , tuleb operaator sulgeda jutumärkidesse ja lisada enne lahtriviidet ampersand (&). Näiteks, et lugeda lahtrid vahemikus D2:D9, mille väärtus on suurem kui väärtus lahtris D3, kasutate järgmist valemit =COUNTIF(D2:D9,">"&D3) :

Kui soovite lugeda lahtreid, mis sisaldavad tegelik operaator osana lahtri sisust, st tähemärgid ">", "<" või "=", siis kasutage kriteeriumis täringumärki koos operaatoriga. Selliseid kriteeriume käsitletakse pigem tekstijada kui numbrilist väljendit. Näiteks valemit =COUNTIF(D2:D9,"*>5*") loeb kõik lahtrid vahemikus D2:D9, mille sisu on selline "Delivery>5 days" või ">5 available".

Exceli COUNTIF-funktsiooni kasutamine kuupäevadega

Kui soovite loendada lahtreid, mille kuupäevad on suuremad, väiksemad või võrdsed määratud kuupäevaga või teises lahtris oleva kuupäevaga, siis toimige juba tuttaval viisil, kasutades sarnaseid valemeid, mida me hetk tagasi arutasime. Kõik ülaltoodud valemid töötavad nii kuupäevade kui ka numbrite puhul. Toon vaid mõned näited:

Lisaks nendele tavapärastele kasutusviisidele saate kasutada funktsiooni COUNTIF koos spetsiifiliste Exceli kuupäeva ja aja funktsioonidega, nagu TODAY(), et lugeda lahtreid praeguse kuupäeva alusel.

Siin on näide selliste valemite kasutamisest reaalsete andmete kohta (kirjutamise hetkel oli täna 25-Jun-2014):

Excel COUNTIF mitme kriteeriumiga

Tegelikult ei ole Exceli funktsioon COUNTIF tegelikult mõeldud mitme kriteeriumiga lahtrite loendamiseks. Enamasti kasutate selle mitmuse vaste, funktsiooni COUNTIFS, et loendada lahtreid, mis vastavad kahele või enamale kriteeriumile (AND-loogika). Mõned ülesanded saab aga lahendada kahe või enama COUNTIF-funktsiooni kombineerimisega ühes valemis.

Loeb väärtusi kahe arvu vahel

Üks Exceli COUNTIF-funktsiooni kõige tavalisemaid rakendusi 2 kriteeriumiga on arvude loendamine teatud vahemikus, st väiksem kui X, kuid suurem kui Y. Näiteks võite kasutada järgmist valemit, et lugeda lahtreid vahemikus B2:B9, mille väärtus on suurem kui 5 ja väiksem kui 15.

=COUNTIF(B2:B9,">5")-COUNTIF(B2:B9,">=15")

Kuidas see valem töötab:

Siin kasutame kahte eraldi COUNTIF-funktsiooni - esimene leiab välja, mitu väärtust on suurem kui 5 ja teine saab väärtuste arvu, mis on suuremad või võrdsed 15. Seejärel lahutate viimast esimesest ja saate soovitud tulemuse.

Loendage lahtrid, millel on mitu VÕI-kriteeriumi

Olukordades, kus soovite saada mitu erinevat toodet vahemikus, lisage 2 või enam COUNTIF funktsiooni kokku. Oletame, et teil on ostunimekiri ja soovite teada saada, kui palju karastusjooke sisaldub selles. Selleks kasutage sarnast valemit:

=COUNTIF(B2:B13, "Limonaad")+COUNTIF(B2:B13, "*mahl")

Palun pöörake tähelepanu, et me oleme lisanud teise kriteeriumi jokker-märgi (*), seda kasutatakse igasuguse mahla loendamiseks nimekirjas.

Samamoodi saab kirjutada COUNTIF-valemi mitme tingimusega. Siin on näide COUNTIF-valemist mitme OR-tingimusega, mis loeb limonaadi, mahla ja jäätist:

=COUNTIF(B2:B13, "Limonaad") + COUNTIF(B2:B13, "*mahl") + COUNTIF(B2:B13, "Jäätis")

Muude võimaluste kohta lahtrite loendamiseks OR-loogika abil vt seda õpetust: Excel COUNTIF ja COUNTIFS OR-tingimustega.

Funktsiooni COUNTIF kasutamine duplikaatide ja unikaalsete väärtuste leidmiseks

Teine võimalik kasutusviis COUNTIF-funktsioonile Excelis on duplikaatide leidmine ühes veerus, kahe veeru vahel või reas.

Näide 1. Leia ja loe duplikaadid 1 veerus

Näiteks see lihtne valem =COUNTIF(B2:B10,B2)>1 tuvastab kõik dubleerivad kirjed vahemikus B2:B10, samas kui teine funktsioon =COUNTIF(B2:B10,TRUE) ütleb teile, kui palju dubleerivaid kirjeid seal on:

Näide 2. Kahe veeru vaheliste duplikaatide lugemine

Kui teil on kaks eraldi nimekirja, näiteks nimekirjad veergudes B ja C, ja te soovite teada, mitu nime on mõlemas veerus, võite kasutada Exceli COUNTIF-i koos SUMPRODUCT-funktsiooniga loendamiseks. duplikaadid :

=SUMPRODUCT((COUNTIF(B2:B1000,C2:C1000)>0)*(C2:C1000""))

Me võime isegi astuda sammu edasi ja lugeda, kui palju unikaalsed nimed on veerus C, st nimed, mis EI ole veerus B:

=SUMPRODUCT((COUNTIF(B2:B1000,C2:C1000)=0)*(C2:C1000""))

Vihje. Kui soovite esile tõsta dubleerivaid lahtreid või terveid ridu, mis sisaldavad dubleerivaid kirjeid, saate luua COUNTIF-vormelitel põhinevaid tingimuslikke vormindusreegleid, nagu on näidatud selles õpetuses - Exceli tingimuslikud vormindusvalemid dubleerivate kirjete esiletõstmiseks.

Näide 3. Dublikaatide ja unikaalsete väärtuste lugemine reas

Kui soovite loendada duplikaate või unikaalseid väärtusi teatud reas, mitte veerus, kasutage ühte allpool esitatud valemitest. Need valemid võivad olla kasulikud näiteks loterii loosimise ajaloo analüüsimiseks.

Loendage duplikaate reas:

=SUMPRODUCT((COUNTIF(A2:I2,A2:I2)>1)*(A2:I2""))

Loeb unikaalseid väärtusi reas:

=SUMPRODUCT((COUNTIF(A2:I2,A2:I2)=1)*(A2:I2""))

Excel COUNTIF - korduma kippuvad küsimused ja probleemid

Ma loodan, et need näited aitasid teil Exceli funktsiooni COUNTIF tundma õppida. Kui olete proovinud mõnda ülaltoodud valemit oma andmetega ja ei saanud neid tööle või on teil tekkinud probleem teie loodud valemiga, vaadake palun läbi järgmised 5 kõige levinumat probleemi. On suur tõenäosus, et leiate sealt vastuse või kasuliku näpunäite.

1. COUNTIF mittekohalduva rakkude vahemiku kohta

Küsimus: Kuidas saan kasutada COUNTIFi Excelis mitteühenduvas vahemikus või lahtrite valikul?

Vastus: Exceli COUNTIF ei tööta mittekohalduva vahemiku puhul ega võimalda selle süntaksis määrata esimese parameetrina mitu üksikut lahtrit. Selle asemel saate kasutada mitme COUNTIF-funktsiooni kombinatsiooni:

Vale: =COUNTIF(A2,B3,C4,">0")

Õige: =COUNTIF(A2,">0") + COUNTIF(B3,">0") + COUNTIF(C4,">0")

Alternatiivne viis on kasutada funktsiooni INDIRECT, et luua vahemike massiivi. Näiteks mõlemad allpool esitatud valemid annavad sama tulemuse, mida näete ekraanipildil:

=SUM(COUNTIF(INDIRECT({"B2:B8","D2:C8"}),"=0"))

=COUNTIF($B2:$B8,0) + COUNTIF($C2:$C8,0)

2. Ampersand ja jutumärgid COUNTIF-valemites

Küsimus: Millal on vaja kasutada COUNTIF-valemis ampersandi?

Vastus: See on ilmselt kõige keerulisem osa funktsioonist COUNTIF, mis minu isiklikult on väga segane. Kuigi kui sa natuke mõtled, siis näed, mis on selle taga - ampluaa ja jutumärgid on vajalikud, et konstrueerida teksti string argument. Nii et sa võid neid reegleid järgida:

Kui kasutate numbrit või lahtriviidet lahtris täpne vaste kriteeriumide puhul ei ole vaja ei amperaate ega jutumärke. Näiteks:

=COUNTIF(A1:A10,10)

või

=COUNTIF(A1:A10,C1)

Kui teie kriteeriumid hõlmavad tekst , jokker või loogiline operaator numbriga sulgeda see jutumärkidesse. Näiteks:

=COUNTIF(A2:A10, "sidrunid")

või

=COUNTIF(A2:A10, "*") või =COUNTIF(A2:A10,">5")

Juhul kui teie kriteerium on väljendus koos viide rakule või mõni teine Excel funktsioon , tuleb kasutada jutumärke ("") tekstisõnumi alustamiseks ja amperandit (&) sõnumi ühendamiseks ja lõpetamiseks. Näiteks:

=COUNTIF(A2:A10,">"&D2)

või

=COUNTIF(A2:A10,"<="&TODAY())

Kui te kahtlete, kas ampersand on vajalik või mitte, proovige mõlemat viisi. Enamasti töötab ampersand suurepäraselt, nt mõlemad allpool esitatud valemid toimivad võrdselt hästi.

=COUNTIF(C2:C8,"<=5")

ja

=COUNTIF(C2:C8,"<="&5)

3. COUNTIF vormindatud (värvikoodiga) lahtrite puhul

Küsimus: Kuidas loendada lahtreid mitte väärtuste, vaid täidise või kirjavärvi järgi?

Vastus: Kahjuks ei võimalda Exceli funktsiooni COUNTIF süntaks tingimusena kasutada vorminguid. Ainus võimalik viis lahtrite loendamiseks või summeerimiseks nende värvi alusel on kasutada makrot või täpsemalt Exceli kasutaja määratud funktsiooni. Käsitsi värvitud lahtrite ja ka tingimuslikult vormingute jaoks toimiva koodi leiate sellest artiklist - Kuidas lugeda ja summeerida Exceli lahtreid täitmise ja vormingute järgi.kirjavärv.

4. #NAME? viga valemis COUNTIF

Probleem: Minu COUNTIF-valem viskab #NAME? vea. Kuidas saan seda parandada?

Vastus: Tõenäoliselt olete valesti sisestanud valemi. Palun vaadake punkti 1 eespool.

5. Exceli COUNTIF-valem ei tööta

Probleem: Minu COUNTIFi valem ei tööta! Mida ma olen valesti teinud?

Vastus: Kui olete kirjutanud valemi, mis on näiliselt õige, kuid see ei tööta või annab vale tulemuse, alustage kõige ilmsematest asjadest, nagu näiteks vahemik, tingimused, lahtriviited, amplituudide ja jutumärkide kasutamine.

Olge väga ettevaatlik, kui kasutate ruumid COUNTIF valemis. Ühe selle artikli jaoks koostatud valemi loomisel olin juba juuste väljatõmbamise äärel, sest õige valem (ma teadsin kindlalt, et see on õige!) ei tööta. Nagu selgus, oli probleem kusagil vahepealses tühimikus, argh... Vaadake näiteks seda valemit:

=COUNTIF(B2:B13," Limonaad") .

Esmapilgul ei ole selles midagi viga, välja arvatud täiendav tühik pärast algavat jutumärki. Microsoft Excel neelab valemi lihtsalt alla ilma veateate, hoiatuse või muu märkuseta, eeldades, et te tõesti soovite lugeda lahtreid, mis sisaldavad sõna "Lemonade" ja eesolevat tühikut.

Kui kasutate funktsiooni COUNTIF mitme kriteeriumiga, jagage valem mitmeks osaks ja kontrollige iga funktsiooni eraldi.

Ja see on kõik tänaseks päevaks. Järgmises artiklis uurime mitmeid viise, kuidas Excelis lahtreid mitme tingimusega loendada. Loodan, et näeme teid järgmisel nädalal ja täname lugemise eest!