Το σεμινάριο εξετάζει τον τρόπο χρήσης των συναρτήσεων ISTEXT και ISNONTEXT στο Excel για να ελέγξετε αν ένα κελί περιέχει μια τιμή κειμένου ή όχι.

Κάθε φορά που χρειάζεται να λάβετε πληροφορίες σχετικά με το περιεχόμενο κάποιου κελιού στο Excel, συνήθως χρησιμοποιείτε τις λεγόμενες συναρτήσεις πληροφοριών. Τόσο η ISTEXT όσο και η ISNONTEXT ανήκουν σε αυτή την κατηγορία. Η συνάρτηση ISTEXT ελέγχει αν μια τιμή είναι κείμενο και η ISNONTEXT ελέγχει αν μια τιμή δεν είναι κείμενο. Όσο απλή και αν είναι η έννοια, οι συναρτήσεις είναι εκπληκτικά χρήσιμες για την επίλυση ποικίλων διαφορετικών εργασιών στο Excel.

Λειτουργία Excel ISTEXT

Η συνάρτηση ISTEXT στο Excel ελέγχει αν μια καθορισμένη τιμή είναι κείμενο ή όχι. Αν η τιμή είναι κείμενο, η συνάρτηση επιστρέφει TRUE. Για όλους τους άλλους τύπους δεδομένων (όπως αριθμοί, ημερομηνίες, κενά κελιά, σφάλματα κ.λπ.) επιστρέφει FALSE.

Η σύνταξη έχει ως εξής:

ISTEXT(value)

Πού αξία είναι μια τιμή, μια αναφορά κελιού, μια έκφραση ή μια άλλη συνάρτηση της οποίας το αποτέλεσμα θέλετε να ελέγξετε.

Για παράδειγμα, για να διαπιστώσετε αν μια τιμή στο A2 είναι κείμενο ή όχι, χρησιμοποιήστε τον εξής απλό τύπο:

=ISTEXT(A2)

Λειτουργία ISNONTEXT του Excel

Η συνάρτηση ISNONTEXT επιστρέφει TRUE για οποιαδήποτε τιμή μη κειμένου, συμπεριλαμβανομένων αριθμών, ημερομηνιών και ωρών, κενών και άλλων τύπων που επιστρέφουν αποτελέσματα ή σφάλματα μη κειμένου. Για τιμές κειμένου, επιστρέφει FALSE.

Η σύνταξη είναι η ίδια με εκείνη της συνάρτησης ISTEXT:

ISTEXT(value)

Για παράδειγμα, για να ελέγξετε αν μια τιμή στην Α2 δεν είναι κείμενο, χρησιμοποιήστε αυτόν τον τύπο:

=ISNONTEXT(A2)

Όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης, οι τύποι ISTEXT και ISNONTEXT επιστρέφουν τα αντίθετα αποτελέσματα:

Λειτουργίες ISTEXT και ISNONTEXT στο Excel - σημειώσεις χρήσης

Οι λειτουργίες ISTEXT και ISNONTEXT είναι πολύ απλές και εύχρηστες και είναι απίθανο να αντιμετωπίσετε δυσκολίες με αυτές. Τούτου λεχθέντος, υπάρχουν μερικά βασικά σημεία που πρέπει να προσέξετε:

• Και οι δύο συναρτήσεις ανήκουν στην ομάδα συναρτήσεων IS και επιστρέφουν τις λογικές (Boolean) τιμές TRUE ή FALSE.
• Σε μια συγκεκριμένη περίπτωση όταν οι αριθμοί αποθηκεύονται ως κείμενο , το ISTEXT επιστρέφει TRUE και το ISNONTEXT επιστρέφει FALSE.
• Και οι δύο λειτουργίες είναι διαθέσιμες σε όλες τις εκδόσεις του Excel για το Office 365, το Excel 2019, το Excel 2016, το Excel 2013, το Excel 2010, το Excel 2007, το Excel 2003, το Excel XP και το Excel 2000.

Χρήση των ISTEXT και ISNONTEXT στο Excel - παραδείγματα τύπων

Παρακάτω θα βρείτε παραδείγματα πρακτικών χρήσεων των συναρτήσεων ISTEXT και ISNONTEXT στο Excel που ελπίζουμε ότι θα σας βοηθήσουν να κάνετε τα φύλλα εργασίας σας πιο αποδοτικά.

Έλεγχος αν μια τιμή είναι κείμενο

Μερικές φορές, όταν εργάζεστε με μια δέσμη τιμών, μπορεί να παρατηρήσετε με έκπληξη ότι για ορισμένους αριθμούς οι τύποι σας επιστρέφουν λανθασμένα αποτελέσματα ή ακόμη και σφάλματα. Ο πιο προφανής λόγος είναι ότι οι προβληματικοί αριθμοί είναι αποθηκευμένοι ως κείμενο. Οι παρακάτω τύποι θα σας πουν με βεβαιότητα ποιες τιμές είναι κείμενο από τη σκοπιά του Excel.

Τύπος ISTEXT:

Επιστρέφει TRUE για κάθε τιμή που το Excel θεωρεί κείμενο .

=ISTEXT(B2)

Τύπος ISNONTEXT:

Επιστρέφει TRUE για κάθε τιμή που το Excel θεωρεί μη κείμενο .

=ISNONTEXT(B2)

ISTEXT για επικύρωση δεδομένων: επιτρέψτε μόνο κείμενο

Σε ορισμένες περιπτώσεις, μπορεί να θέλετε να επιτρέψετε στους χρήστες να εισάγουν μόνο τιμές κειμένου σε ορισμένα κελιά. Για να το πετύχετε αυτό, δημιουργήστε έναν κανόνα επικύρωσης δεδομένων που βασίζεται σε έναν τύπο ISTEXT. Ακούστε πώς:

1. Επιλέξτε ένα ή περισσότερα κελιά που θέλετε να επικυρώσετε.
2. Στο Δεδομένα στην καρτέλα Εργαλεία δεδομένων ομάδα, κάντε κλικ στο Επικύρωση δεδομένων κουμπί.
3. Στο Ρυθμίσεις της καρτέλας Επικύρωση δεδομένων παράθυρο διαλόγου, επιλέξτε Προσαρμοσμένο για τα κριτήρια επικύρωσης και εισαγάγετε τον τύπο ISTEXT στο αντίστοιχο πλαίσιο.
4. Κάντε κλικ στο OK για να αποθηκεύσετε τον κανόνα.

Σε αυτό το παράδειγμα, επικυρώνουμε τις απαντήσεις του ερωτηματολογίου στα κελιά B2 έως B4 με τη βοήθεια αυτού του τύπου:

=ISTEXT(B2:B4)

Επιπλέον, μπορείτε να ρυθμίσετε τις δικές σας Ειδοποίηση σφάλματος μήνυμα για να εξηγήσετε στους χρήστες σας τι είδους δεδομένα είναι αποδεκτά:

Ως αποτέλεσμα, όταν ο χρήστης προσπαθήσει να εισάγει έναν αριθμό ή μια ημερομηνία σε οποιοδήποτε από τα επικυρωμένα κελιά, θα εμφανιστεί η ακόλουθη ειδοποίηση:

Για περισσότερες πληροφορίες, ανατρέξτε στην ενότητα Χρήση της επικύρωσης δεδομένων στο Excel.

Τύπος του Excel IF ISTEXT

Στην πράξη, οι ISTEXT και ISNONTEXT χρησιμοποιούνται συχνά μαζί με τη συνάρτηση IF για την εξαγωγή ενός πιο φιλικού προς το χρήστη αποτελέσματος από τα τυπικά TRUE και FALSE.

Τύπος 1. Αν είναι κείμενο, τότε

Πηγαίνοντας το πρώτο μας παράδειγμα λίγο παραπέρα, ας υποθέσουμε ότι θέλετε να επιστρέψετε "Ναι" για τιμές κειμένου και "Όχι" για οτιδήποτε άλλο. Για να το έχετε κάνει, απλά φωλιάστε τη συνάρτηση ISTEXT στο λογικό τεστ της IF, και χρησιμοποιήστε "Ναι" και "Όχι" για το value_if_true και value_if_false επιχειρήματα, αντίστοιχα:

=IF(ISTEXT(A2), "Ναι", "Όχι")

Τύπος 2. Ελέγξτε την είσοδο του κελιού

Σε ένα από τα προηγούμενα παραδείγματα, συζητήσαμε πώς να εξασφαλίσουμε έγκυρη εισαγωγή δεδομένων από τον χρήστη με τη χρήση της Επικύρωσης δεδομένων. Αυτό μπορεί επίσης να γίνει σε μια πιο "ήπια" μορφή με τη βοήθεια ενός τύπου του Excel IF ISTEXT.

Στο ερωτηματολόγιο, ας υποθέσουμε ότι θέλετε να προσδιορίσετε ποιες απαντήσεις είναι έγκυρες (κείμενο) και ποιες όχι (μη κείμενο). Για το σκοπό αυτό, χρησιμοποιήστε τις εμφωλευμένες δηλώσεις IF με την ακόλουθη λογική:

• Εάν το εξεταζόμενο κελί είναι κενό, δεν επιστρέφει τίποτα, δηλαδή μια κενή συμβολοσειρά ("").
• Εάν το κελί είναι κείμενο, επιστρέφεται η απάντηση "Έγκυρη απάντηση".
• Εάν δεν ισχύει κανένα από τα παραπάνω, επιστρέψτε "Άκυρη απάντηση - παρακαλώ εισάγετε κείμενο".

Συνδυάζοντας όλα αυτά, προκύπτει ο ακόλουθος τύπος, όπου B2 είναι το κελί που πρέπει να ελεγχθεί:

=IF(B2="", "", IF(ISTEXT(B2), "Valid answer", "Invalid answer - please enter text."))

Ελέγξτε αν μια περιοχή περιέχει κείμενο

Μέχρι στιγμής, ελέγξαμε κάθε κελί ξεχωριστά. Τι γίνεται όμως αν θέλετε να μάθετε αν κάποιο κελί σε μια περιοχή περιέχει κείμενο;

Για να ελέγξετε ολόκληρο το εύρος, συνδυάστε τη συνάρτηση ISTEXT με τη συνάρτηση SUMPRODUCT με αυτόν τον τρόπο:

Για παράδειγμα, ας ελέγξουμε κάθε γραμμή του παρακάτω συνόλου δεδομένων για τιμές κειμένου, κάτι που μπορεί να γίνει με τους ακόλουθους τύπους:

=SUMPRODUCT(ISTEXT(A2:C2)*1)>0

=SUMPRODUCT(--ISTEXT(A2:C2))>0

Ένας από τους παραπάνω τύπους πηγαίνει στο κελί D2 και στη συνέχεια τον σύρετε προς τα κάτω μέσω του κελιού D5.

Έτσι, έχετε πλέον σαφή εικόνα για το ποιες γραμμές περιέχουν μία ή περισσότερες συμβολοσειρές κειμένου (TRUE) και ποιες περιέχουν μόνο αριθμούς (FALSE).

Αν θέλετε να επιστρέψετε διαφορετικά αποτελέσματα, να πείτε "Ναι" ή "Όχι" σε αντίθεση με το TRUE και το FALSE, περικλείστε τον παραπάνω τύπο στη δήλωση IF:

=IF(SUMPRODUCT(--ISTEXT(A2:C2))>0, "Ναι", "Όχι")

Πώς λειτουργεί αυτή η φόρμουλα

Ο τύπος βασίζεται στην ικανότητα του SUMPRODUCT να χειρίζεται πίνακες εγγενώς. Δουλεύοντας από μέσα προς τα έξω, δείτε τι κάνει:

• Η συνάρτηση ISTEXT επιστρέφει έναν πίνακα τιμών TRUE και FALSE. Για A2:C2, λαμβάνουμε αυτόν τον πίνακα:

  {TRUE,TRUE,FALSE}

• Στη συνέχεια, πολλαπλασιάζουμε κάθε στοιχείο του παραπάνω πίνακα με το 1 για να μετατρέψουμε τις λογικές τιμές TRUE και FALSE σε 1 και 0 αντίστοιχα. Ένας διπλός μοναδιαίος τελεστής (--) μπορεί να χρησιμοποιηθεί για τον ίδιο σκοπό. Μετά τον μετασχηματισμό, ο τύπος παίρνει αυτή τη μορφή:

  SUMPRODUCT({1,1,0})>0

• Η συνάρτηση SUMPRODUCT προσθέτει τα 1 και τα 0 και ελέγχετε αν το αποτέλεσμα είναι μεγαλύτερο από το μηδέν. Αν είναι, η περιοχή περιέχει τουλάχιστον μία τιμή κειμένου και ο τύπος επιστρέφει TRUE, αν όχι FALSE.

Έλεγχος αν ένα κελί περιέχει συγκεκριμένο κείμενο

Η συνάρτηση ISTEXT του Excel μπορεί να προσδιορίσει μόνο αν ένα κελί περιέχει κείμενο, δηλαδή απολύτως οποιοδήποτε κείμενο. Για να διαπιστώσετε αν ένα κελί περιέχει μια συγκεκριμένη συμβολοσειρά κειμένου, χρησιμοποιήστε είτε τον τύπο ISNUMBER SEARCH είτε τον τύπο COUNTIF με μπαλαντέρ.

Για παράδειγμα, για να δείτε αν το στοιχείο Item Id στο A2 περιέχει την συμβολοσειρά κειμένου που εισάγεται στο κελί D2, χρησιμοποιήστε τον παρακάτω τύπο (λάβετε υπόψη σας την απόλυτη αναφορά $D$2 που εμποδίζει την αλλαγή της διεύθυνσης του κελιού όταν ο τύπος αντιγράφεται σε άλλα κελιά):

=ISNUMBER(SEARCH($D$2, A2))

Για λόγους ευκολίας, θα το τυλίξουμε στη συνάρτηση IF:

=IF(ISNUMBER(SEARCH($D$2, A2)), "Ναι", "Όχι")

Και λαμβάνετε τα ακόλουθα αποτελέσματα:

Το ίδιο αποτέλεσμα μπορεί να επιτευχθεί με τη COUNTIF:

=IF(COUNTIF(A2, "*"&$D$2& "*")>0, "Ναι", "Όχι")

Για περισσότερα παραδείγματα, ανατρέξτε στην ενότητα Excel Εάν το κελί περιέχει τύπους.

Επισημάνετε τα κελιά που περιέχουν κείμενο

Η συνάρτηση ISTEXT μπορεί επίσης να χρησιμοποιηθεί με την υπό όρους μορφοποίηση του Excel για την επισήμανση κελιών που περιέχουν τιμές κειμένου. Ακολουθεί ο τρόπος:

1. Επιλέξτε όλα τα κελιά που θέλετε να ελέγξετε και επισημάνετε (A2:C5 σε αυτό το παράδειγμα).
2. Στο Αρχική σελίδα στην καρτέλα Στυλ ομάδα, κάντε κλικ στο Νέος κανόνας >, Χρησιμοποιήστε έναν τύπο για να καθορίσετε ποια κελιά θα μορφοποιήσετε .
3. Στο Μορφοποίηση τιμών όπου αυτός ο τύπος είναι αληθής πληκτρολογήστε τον παρακάτω τύπο:

   =ISTEXT(A2)

   Όπου A2 είναι το αριστερότερο κελί της επιλεγμένης περιοχής.

4. Κάντε κλικ στο Μορφή και επιλέξτε την επιθυμητή μορφοποίηση.
5. Κάντε δύο φορές κλικ στο OK για να κλείσετε και τα δύο παράθυρα διαλόγου και να αποθηκεύσετε τον κανόνα.

Για λεπτομερέστερη επεξήγηση κάθε βήματος, ανατρέξτε στην ενότητα: Χρήση τύπων για τη μορφοποίηση υπό όρους του Excel.

Ως αποτέλεσμα, το Excel επισημαίνει όλα τα κελιά με οποιεσδήποτε συμβολοσειρές κειμένου:

Αυτός είναι ο τρόπος χρήσης των συναρτήσεων ISTEXT και ISNONTEXT στο Excel. Σας ευχαριστώ για την ανάγνωση και ελπίζω να σας δω στο blog μας την επόμενη εβδομάδα!

Διαθέσιμες λήψεις

Παραδείγματα τύπων Excel ISTEXT και ISNONTEXT