Падручнік паказвае розныя спосабы вызначэння ўзросту з дня нараджэння ў Excel. Вы даведаецеся некалькі формул для разліку ўзросту як колькасці поўных гадоў, атрымаеце дакладны ўзрост у гадах, месяцах і днях на сённяшнюю ці пэўную дату.

Няма спецыяльнай функцыі для вылічэння узрост у Excel, аднак існуе некалькі розных спосабаў пераўтварэння даты нараджэння ва ўзрост. Гэты падручнік растлумачыць перавагі і недахопы кожнага спосабу, пакажа, як скласці ідэальную формулу разліку ўзросту ў Excel і наладзіць яе для вырашэння некаторых канкрэтных задач.

Як разлічыць узрост па даце нараджэння ў Excel

У паўсядзённым жыцці пытанне « Колькі вам гадоў? » звычайна мае на ўвазе адказ, які паказвае, колькі гадоў вы жывыя. У Microsoft Excel вы можаце зрабіць формулу для вылічэння дакладнага ўзросту ў месяцах, днях, гадзінах і нават хвілінах. Але давайце будзем традыцыйнымі і спачатку даведаемся, як вылічыць узрост ад DOB у гадах.

Асноўная формула Excel для ўзросту ў гадах

Як вы звычайна вызначаеце чыйсьці ўзрост? Проста адняўшы дату нараджэння ад бягучай даты. Гэтую звычайную формулу ўзросту таксама можна выкарыстоўваць у Excel.

Мяркуючы, што дата нараджэння знаходзіцца ў ячэйцы B2, формула для разліку ўзросту ў гадах выглядае наступным чынам:

=(TODAY()-B2)/365

першая частка формулы (СЁННЯ()-B2) вяртае розніцу паміж бягучай датай і датай нараджэння ў днях, а потым вы дзеліце гэтаспасылка на ячэйку або дата ў фармаце мм/дд/гггг.

Гатова!

Формула імгненна ўстаўляецца ў выбраную ячэйку, і вы двойчы пстрыкаеце маркер запаўнення, каб скапіяваць яе ў слупок.

Як вы маглі заўважыць, формула, створаная нашым калькулятарам узросту Excel, больш складаная, чым тыя, якія мы абмяркоўвалі дагэтуль, але яна абслугоўвае адзіночны і множны лік адзінак часу, такіх як «дзень» і «дні».

Калі вы жадаеце пазбавіцца ад нулявых адзінак, такіх як "0 дзён", усталюйце сцяжок Не паказваць нулявыя адзінкі :

Калі вам цікава праверыць гэты калькулятар узросту, а таксама адкрыць для сябе яшчэ 60 надбудоў для Excel, якія дазваляюць зэканоміць час, вы можаце загрузіць пробную версію нашага Ultimate Suite у канцы гэты пост.

Як вылучыць пэўны ўзрост (менш або больш пэўны ўзрост)

У некаторых сітуацыях вам можа спатрэбіцца не толькі вылічыць узрост у Excel, але і вылучыць ячэйкі, якія змяшчаюць узрост меншы або старэйшы за пэўны ўзрост.

Калі ваша формула разліку ўзросту вяртае колькасць поўных гадоў, тады вы можаце стварыць звычайнае правіла ўмоўнага фарматавання на аснове простай формулы, падобнай да гэтых:

• Каб вылучыць узрост, роўны або большы за18: =$C2>=18
• Каб вылучыць узрост да 18 гадоў: =$C2<18

Дзе C2 з'яўляецца самай верхняй ячэйкай у слупку "Узрост" (за выключэннем загаловак слупка).

Але што, калі ваша формула адлюстроўвае ўзрост у гадах і месяцах, або ў гадах, месяцах і днях? У гэтым выпадку вам трэба будзе стварыць правіла на аснове формулы DATEDIF, якое вылічвае ўзрост ад даты нараджэння ў гадах.

Калі выказаць здагадку, што даты нараджэння знаходзяцца ў слупку B, пачынаючы з радка 2, то формулы будуць наступнымі:

• Каб вылучыць узрост да 18 (жоўты): =DATEDIF($B2, TODAY(),"Y")<18
• Каб вылучыць узрост паміж 18 і 65 (зялёны): =AND(DATEDIF($B2, TODAY(),"Y")>=18, DATEDIF($B2, TODAY(),"Y")<=65)
• Каб вылучыць узрост больш 65 (сінім): =DATEDIF($B2, TODAY(),"Y")>65

Каб стварыць правілы на аснове прыведзеных вышэй формул, выберыце ячэйкі або цэлыя радкі, якія вы хочаце вылучыць , перайдзіце на ўкладку Галоўная група > Стылі і націсніце Умоўнае фарматаванне > Новае правіла… > Выкарыстоўваць формула, каб вызначыць, якія ячэйкі фарматаваць .

Падрабязныя крокі можна знайсці тут: Як стварыць правіла ўмоўнага фарматавання на аснове формулы.

Вось як вы разлічваеце ўзрост у Excel. Я спадзяюся, што формулы былі лёгкімі для вас, і вы паспрабуеце іх у сваіх працоўных аркушах. Дзякуй за чытанне і спадзяемся ўбачыць вас у нашым блогу на наступным тыдні!

Даступныя спампоўкі

Прыклады разліку ўзросту ў Excel (файл .xlsx)

Поўны пакет Ultimate Suite на 14 дзён -функцыянальная версія (файл .exe)

Формула відавочная і лёгкая для запамінання, аднак ёсць невялікая праблема. У большасці выпадкаў ён вяртае дзесятковы лік, як паказана на скрыншоце ніжэй.

Каб адлюстраваць колькасць поўных гадоў, выкарыстоўвайце функцыю INT, каб акругліць дзесятковы лік да меншага. бліжэйшы цэлы лік:

=INT((TODAY()-B2)/365)

Недахопы: Выкарыстанне гэтай формулы ўзросту ў Excel дае даволі дакладныя вынікі, але не бездакорныя. Дзяленне на сярэднюю колькасць дзён у годзе часцей за ўсё працуе добра, але часам узрост паказваецца няправільна. Напрыклад, калі хтосьці нарадзіўся 29 лютага, а сёння 28 лютага, формула зробіць чалавека на адзін дзень старэйшым.

У якасці альтэрнатывы вы можаце падзяліць на 365,25 замест 365, бо кожны чацвёрты год мае 366 дзён. Аднак і гэты падыход не ідэальны. Напрыклад, калі вы разлічваеце ўзрост дзіцяці, якое яшчэ не перажыло высакосны год, дзяленне на 365,25 дае няправільны вынік.

У цэлым, адніманне даты нараджэння ад бягучай даты выдатна працуе ў нармальнае жыццё, але гэта не ідэальны падыход у Excel. Далей у гэтым падручніку вы даведаецеся аб некалькіх спецыяльных функцыях, якія беспамылкова вылічваюць узрост незалежна ад года.

Вылічыце ўзрост па даце нараджэння з дапамогай функцыі YEARFRAC

Больш надзейны спосаб пераўтварэння DOB да ўзросту ў Excel выкарыстоўвае функцыю YEARFRAC, якаявяртае долю года, г.зн. колькасць цэлых дзён паміж дзвюма датамі.

Сінтаксіс функцыі YEARFRAC наступны:

першыя два аргументы відавочныя і наўрад ці патрабуюць дадатковых тлумачэнняў. Аснова з'яўляецца неабавязковым аргументам, які вызначае аснову падліку дзён для выкарыстання.

Каб скласці цалкам праўдзівую формулу ўзросту, увядзіце наступныя значэнні ў функцыю YEARFRAC:

• Start_date - дата нараджэння.
• End_date - функцыя TODAY() для вяртання сённяшняй даты.
• Базіс - выкарыстоўвайце аснову 1 , якая загадвае Excel падзяліць фактычную колькасць дзён у месяцы на фактычную колькасць дзён у годзе.

З улікам сказанага вышэй, формула Excel для разліку узрост ад даты нараджэння наступны:

Калі дапусціць, што дата нараджэння знаходзіцца ў ячэйцы B2, формула прымае наступную форму:

=YEARFRAC(B2, TODAY(), 1)

Як і ў папярэднім прыкладзе, вынік функцыі YEARFRAC таксама з'яўляецца дзесятковым лікам. Каб выправіць гэта, выкарыстоўвайце функцыю ROUNDDOWN з 0 у апошнім аргументе, таму што вам не патрэбны знакі пасля коскі.

Такім чынам, вось палепшаная формула YEARFRAC для разліку ўзросту ў Excel:

=ROUNDDOWN(YEARFRAC(B2, TODAY(), 1), 0)

Вылічыце ўзрост у Excel з дапамогай DATEDIF

Яшчэ адзін спосаб пераўтварыць дату нараджэння ва ўзрост у Excel - гэта выкарыстанне функцыі DATEDIF:

Гэта функцыя можа вяртаць розніцу паміж дзвюма датамі ў розных адзінках часу, такіх як гады, месяцы і дні, у залежнасці ад значэння, якое вы падаеце ў аргументе unit :

• Y - вяртае колькасць поўных гадоў паміж пачатковай і канчатковай датамі.
• M - вяртае колькасць поўных месяцаў паміж даты.
• D - вяртае колькасць дзён паміж двума датамі.
• YM - вяртае месяцаў , ігнаруючы дні і гады.
• MD - вяртае розніцу ў днях , не ўлічваючы месяцы і гады.
• YD - вяртае розніцу ў днях , ігнаруючы гады.

Паколькі мы імкнемся вылічыць узрост у гадах , мы выкарыстоўваем адзінку "y":

У гэтым прыкладзе DOB знаходзіцца ў ячэйцы B2, і вы спасылаецеся на гэтую ячэйку ў сваёй формуле ўзросту:

=DATEDIF(B2, TODAY(), "y")

У гэтым выпадку дадатковая функцыя акруглення не патрабуецца, таму што формула DATEDIF з t адзінка "y" вылічае колькасць поўных гадоў:

Як атрымаць узрост ад дня нараджэння ў гадах, месяцах і днях

Як вы толькі што бачылі , падлічыць узрост як колькасць поўных гадоў, пражытых чалавекам, лёгка, але не заўсёды дастаткова. Калі вы хочаце ведаць дакладны ўзрост, г.зн. колькі гадоў, месяцаў і дзён паміж датай нараджэння чалавека і бягучай датай, напішыце 3розныя функцыі DATEDIF:

1. Каб атрымаць колькасць гадоў: =DATEDIF(B2, TODAY(), "Y")
2. Каб атрымаць колькасць месяцаў: =DATEDIF(B2, TODAY(), "YM")
3. Каб атрымаць колькасць дзён: =DATEDIF(B2,TODAY(),"MD")

Дзе B2 — дата нараджэння.

А затым злучыце вышэйпералічаныя функцыі ў адну формулу, напрыклад:

=DATEDIF(B2,TODAY(),"Y") & DATEDIF(B2,TODAY(),"YM") & DATEDIF(B2,TODAY(),"MD")

Прыведзеная вышэй формула вяртае 3 лічбы (гады, месяцы і дні), злучаныя ў адзін тэкставы радок, як паказана на скрыншоце ніжэй:

Не мае асаблівага сэнсу, э-э ? Каб зрабіць вынікі больш значнымі, падзяліце лічбы коскамі і вызначце, што азначае кожнае значэнне:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

Вынік цяпер выглядае значна лепш:

Формула працуе выдатна, але вы можаце яшчэ больш палепшыць яе, схаваўшы нулявыя значэнні. Для гэтага дадайце 3 аператары IF, якія правяраюць 0, па адным на кожны DATEDIF:

=IF(DATEDIF(B2, TODAY(),"y")=0,"",DATEDIF(B2, TODAY(),"y")&" years, ")& IF(DATEDIF(B2, TODAY(),"ym")=0,"",DATEDIF(B2, TODAY(),"ym")&" months, ")& IF(DATEDIF(B2, TODAY(),"md")=0,"",DATEDIF(B2, TODAY(),"md")&" days")

На наступным здымку экрана дэманструецца канчатковая формула ўзросту Excel у дзеянні - яна вяртае ўзрост у гадах, месяцах, і дні, паказваючы толькі ненулявыя значэнні:

Савет. Калі вы шукаеце формулу Excel для разліку ўзросту ў гадах і месяцах , вазьміце прыведзеную вышэй формулу і выдаліце ​​апошні блок IF(DATEDIF()), які вылічвае дні.

Асобныя формулы для вылічыць узрост у Excel

Агульныя формулы разліку ўзросту, разгледжаныя вышэй, выдатна працуюць у большасці выпадкаў. Аднак у некаторых сітуацыях вам можа спатрэбіцца нешта вельмі канкрэтнае. Вядома, немагчыма ахапіць усеі кожны сцэнар, але наступныя прыклады дадуць вам некаторыя ідэі аб тым, як вы можаце наладзіць формулу ўзросту ў залежнасці ад вашай канкрэтнай задачы.

Як вылічыць узрост на пэўную дату ў Excel

Калі вы хочаце ведаць чыйсьці ўзрост на пэўную дату, выкарыстоўвайце формулу ўзросту DATEDIF, разгледжаную вышэй, але заменіце функцыю TODAY() у 2-м аргументе на канкрэтную дату.

Калі дапусціць, што дата нараджэння знаходзіцца ў B1, наступная формула верне ўзрост па стане на 1 студзеня 2020 г.:

=DATEDIF(B1, "1/1/2020","Y") & " Years, " & DATEDIF(B1, "1/1/2020","YM") & " Months, " & DATEDIF(B1, "1/1/2020", "MD") & " Days"

Каб зрабіць вашу формулу ўзросту больш гнуткай, вы можаце ўвесці дату ў нейкую ячэйку і спасылацца на гэтую ячэйку ў сваёй формуле:

=DATEDIF(B1, B2,"Y") & " Years, "& DATEDIF(B1,B2,"YM") & " Months, "&DATEDIF(B1,B2, "MD") & " Days"

Дзе B1 - гэта DOB, а B2 - дата, на якую вы хочаце вылічыць узрост.

Вылічыце ўзрост у пэўны год

Гэта формула карысная ў сітуацыях, калі поўная дата для разліку не вызначана, і вы ведаеце толькі год.

Дапусцім, вы працуеце з медыцынскай базай дадзеных і ваша Мэта - высветліць узрост пацыентаў на той момант, калі яны маладзейшыя прайшоў апошні поўны медыцынскі агляд.

Пры ўмове, што даты нараджэння пазначаны ў слупку B, пачынаючы з радка 3, а год апошняга медыцынскага агляду пазначаны ў слупку C, формула разліку ўзросту выглядае наступным чынам:

=DATEDIF(B3,DATE(C3, 1, 1),"y")

Паколькі дакладная дата медыцынскага агляду не вызначана, вы выкарыстоўваеце функцыю ДАТА з адвольным аргументам даты і месяца, напрыклад. ДАТА(C3, 1, 1).

Функцыя ДАТА здабывае год з ячэйкі B3, робіць поўную дату, выкарыстоўваючы нумары месяца і дня, якія вы паставілі (1-студзень у гэтым прыкладзе), і перадае гэтую дату ў DATEDIF. У выніку вы атрымаеце ўзрост пацыента на 1 студзеня канкрэтнага года:

Высветліце дату, калі чалавеку споўнілася N гадоў

Выкажам здагадку, што ваш сябар нарадзіўся 8 сакавіка 1978 г. Як вы ведаеце, у які дзень яму спаўняецца 50 гадоў? Звычайна вы проста дадаеце 50 гадоў да дня нараджэння чалавека. У Excel вы робіце тое ж самае, выкарыстоўваючы функцыю ДАТА:

=DATE(YEAR(B2) + 50, MONTH(B2), DAY(B2))

Дзе B2 - дата нараджэння.

Замест жорсткага кадавання колькасці гадоў у формула, вы можаце спасылацца на пэўную ячэйку, у якую карыстальнікі могуць уводзіць любую колькасць гадоў (F1 на скрыншоце ніжэй):

Вылічыце ўзрост па днях, месяцах і годах у розных ячэйкі

Калі дата нараджэння падзелена на 3 розныя ячэйкі (напрыклад, год знаходзіцца ў B3, месяц у C3 і дзень у D3), вы можаце вылічыць узрост наступным чынам:

• Атрымаць дату нараджэння з дапамогай функцый DATE і DATEVALUE:

  DATE(B3,MONTH(DATEVALUE(C3&"1")),D3)

• Устаўце прыведзеную вышэй формулу ў DATEDIF, каб вылічыць узрост ад даты нараджэння ў гадах, месяцах і днях: =DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "y") & " Years, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3),TODAY(), "ym") & " Months, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "md") & " Days"

  

Больш прыкладаў вылічэння колькасці дзён да/пасля даты глядзіце ў раздзеле "Як разлічыць дні з або да даты ў Excel".

Узрост калькулятар у Excel

Калі вы хочаце мець свой уласныкалькулятар узросту ў Excel, вы можаце зрабіць яго, выкарыстоўваючы некалькі розных формул DATEDIF, якія тлумачацца ніжэй. Калі вы не хочаце вынаходзіць ровар, вы можаце скарыстацца калькулятарам узросту, створаным нашымі спецыялістамі ў Excel.

Як стварыць калькулятар узросту ў Excel

Цяпер, калі вы ведаеце, як зрабіць формулу ўзросту ў Excel, вы можаце стварыць уласны калькулятар ўзросту, напрыклад, гэты:

Заўвага. Для прагляду ўбудаванай працоўнай кнігі дазвольце маркетынгавыя файлы cookie.

Вышэй вы бачыце ўбудаваны аркуш Excel Online, таму не саромейцеся ўводзіць дату нараджэння ў адпаведную ячэйку, і вы хутка даведаецеся свой узрост.

Калькулятар выкарыстоўвае наступныя формулы для вылічэння ўзросту на падставе даты нараджэння ў ячэйцы A3 і сённяшняй даты.

• Формула ў B5 разлічвае ўзрост у гадах, месяцах і днях: =DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"
• Формула ў B6 разлічвае ўзрост у месяцах: =DATEDIF($B$3,TODAY(),"m")
• Формула ў B7 вылічвае ўзрост у днях: =DATEDIF($B$3,TODAY(),"d")

Калі ў вас ёсць досвед працы з элементамі кіравання формай Excel, вы можаце дадаць опцыю для вылічэння ўзросту на пэўную дату, як паказана на наступным скрыншоце:

Для гэтага дадайце пару кнопак опцый ( укладка "Распрацоўшчык" > Уставіць > Элементы кіравання формай > Кнопка параметраў ), і звязаць іх з нейкай ячэйкай. Затым напішыце формулу IF/DATEDIF, каб атрымаць узрост альбо на сённяшнюю дату, альбо на дату, указаную карыстальнікам.

Формула працуе з наступнымлогіка:

• Калі выбрана поле Сённяшняя дата , значэнне 1 з'яўляецца ў звязанай ячэйцы (I5 у гэтым прыкладзе), і формула ўзросту разлічваецца на аснове сённяшняй даты : IF($I$5=1, DATEDIF($B$3,TODAY(),"Y") & " Years, " & DATEDIF($B$3,TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days")
• Калі выбрана кнопка опцыі Пэўная дата І дата ўведзена ў ячэйку B7, узрост вылічваецца на ўказаную дату: IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

Нарэшце , укладзіце вышэйапісаныя функцыі адна ў адну, і вы атрымаеце поўную формулу разліку ўзросту (у B9):

=IF($I$5=1, DATEDIF($B$3, TODAY(), "Y") & " Years, " & DATEDIF($B$3, TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days", IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

Формулы ў B10 і B11 працуюць з аднолькавай логікай. Вядома, яны нашмат прасцейшыя, таму што ўключаюць толькі адну функцыю DATEDIF для вяртання ўзросту як колькасці поўных месяцаў ці дзён, адпаведна.

Каб даведацца падрабязнасці, я запрашаю вас загрузіць гэты калькулятар узросту Excel і даследаваць формулы ў ячэйках B9:B11.

Спампуйце калькулятар узросту для Excel

Гатовы да выкарыстання калькулятар узросту для Excel

Карыстальнікі нашага Ultimate Suite не маюць патурбавацца аб стварэнні ўласнага калькулятара ўзросту ў Excel - гэта ўсяго ў пару клікаў:

1. Выберыце ячэйку, у якую вы хочаце ўставіць формулу ўзросту, перайдзіце да Інструменты Ablebits укладка > Дата & Група Time і націсніце Date & Кнопка "Майстар часу" .

   

2. Дата & Запусціцца майстар часу, і вы пяройдзеце непасрэдна да ўкладкі Узрост .
3. На ўкладцы Узрост вы можаце ўказаць 3 рэчы:
   • Дадзеныя аб нараджэнні як а