Microsoft Excel, boşluklu veya boşluksuz, sayı, tarih veya metin değerleri içeren, belirli kelimeler veya karakterler içeren vb. farklı hücre türlerini saymak için çeşitli işlevler sağlar.

Bu makalede, belirttiğiniz koşula sahip hücreleri saymak için kullanılan Excel EĞERSAY işlevine odaklanacağız. İlk olarak, sözdizimini ve genel kullanımı kısaca ele alacağız ve daha sonra bu işlevi birden çok ölçütle ve belirli hücre türleriyle kullanırken olası tuhaflıklar hakkında bir dizi örnek sunacağım ve uyaracağım.

Esasen, COUNTIF formülleri tüm Excel sürümlerinde aynıdır, bu nedenle bu eğitimdeki örnekleri Excel 365, 2021, 2019, 2016, 2013, 2010 ve 2007'de kullanabilirsiniz.

Excel'de COUNTIF işlevi - sözdizimi ve kullanım

Excel COUNTIF işlevi, belirli bir aralıktaki belirli bir ölçütü veya koşulu karşılayan hücreleri saymak için kullanılır.

Örneğin, çalışma sayfanızdaki kaç hücrenin belirttiğiniz sayıdan daha büyük veya daha küçük bir sayı içerdiğini bulmak için bir EĞERSAY formülü yazabilirsiniz. Excel'de EĞERSAY'ın bir başka tipik kullanımı da belirli bir sözcük içeren veya belirli harf(ler)le başlayan hücreleri saymaktır.

COUNTIF fonksiyonunun söz dizimi çok basittir:

Gördüğünüz gibi, her ikisi de gerekli olan yalnızca 2 argüman vardır:

• aralık - Sayılacak bir veya birkaç hücreyi tanımlar. Aralığı Excel'de genellikle yaptığınız gibi bir formüle koyarsınız, örneğin A1:A20.
• Kriterler - fonksiyona hangi hücrelerin sayılacağını söyleyen koşulu tanımlar. sayı , metin dizesi , hücre referansı veya ifade Örneğin, aşağıdaki gibi kriterler kullanabilirsiniz: "10", A2, ">=10", "some text".

Ve işte Excel COUNTIF işlevinin en basit örneği. Aşağıdaki resimde gördüğünüz, son 14 yılın en iyi tenis oyuncularının listesidir. Formül =COUNTIF(C2:C15, "Roger Federer") Roger Federer'in adının listede kaç kez yer aldığını sayar:

Not: Bir ölçüt büyük/küçük harfe duyarlı değildir, yani yukarıdaki formülde ölçüt olarak "roger federer" yazarsanız, bu aynı sonucu üretecektir.

Excel COUNTIF işlevi örnekleri

Az önce gördüğünüz gibi, EĞERSAY işlevinin sözdizimi çok basittir. Ancak, joker karakterler, diğer hücrelerin değerleri ve hatta diğer Excel işlevleri dahil olmak üzere ölçütlerin birçok olası varyasyonuna izin verir. Bu çeşitlilik, aşağıdaki örneklerde göreceğiniz gibi EĞERSAY işlevini gerçekten güçlü ve birçok göreve uygun hale getirir.

Metin ve sayılar için COUNTIF formülü (tam eşleşme)

Aslında, sayım yapan COUNTIF fonksiyonunu tartışmıştık metin değerleri tam olarak bir dakika önce belirtilen bir ölçütle eşleşiyor. Tam bir metin dizesi içeren hücreler için formül olduğunu hatırlatalım: =COUNTIF(C2:C15, "Roger Federer") Yani, giriyorsun:

• Bir aralık olarak ilk parametre;
• Virgül olarak sınırlayıcı;
• Tırnak içine alınmış bir kelime veya birkaç kelime Kriterler.

Metin yazmak yerine, bir herhangi bir hücreye referans bu kelimeyi veya kelimeleri içeren ve kesinlikle aynı sonuçları elde eden, ör. =COUNTIF(C1:C9,C7) .

Benzer şekilde, COUNTIF formülleri aşağıdakiler için çalışır sayılar Aşağıdaki ekran görüntüsünde gösterildiği gibi, aşağıdaki formül D Sütununda miktarı 5 olan hücreleri mükemmel şekilde sayar:

=COUNTIF(D2:D9, 5)

Bu makalede, herhangi bir metin, belirli karakterler veya yalnızca filtrelenmiş hücreler içeren hücreleri saymak için birkaç formül daha bulacaksınız.

Joker karakterli COUNTIF formülleri (kısmi eşleşme)

Excel verilerinizin saymak istediğiniz anahtar kelime(ler)in çeşitli varyasyonlarını içermesi durumunda, belirli bir kelime, kelime öbeği veya harf içeren tüm hücreleri saymak için bir joker karakter kullanabilirsiniz hücre içeriğinin bir kısmı .

Diyelim ki elinizde farklı kişilere atanan görevlerin bir listesi var ve Danny Brown'a atanan görevlerin sayısını öğrenmek istiyorsunuz. Danny'nin adı birkaç farklı şekilde yazıldığı için arama kriteri olarak "*Brown*" giriyoruz =COUNTIF(D2:D10, "*Kahverengi*") .

Bir yıldız işareti (*), yukarıdaki örnekte gösterildiği gibi, herhangi bir önde ve sonda karakter dizisine sahip hücreleri bulmak için kullanılır. Herhangi bir tek karakteri eşleştirmeniz gerekiyorsa, bir soru işareti (?) yerine, aşağıda gösterildiği gibi.

İpucu: Aşağıdakileri yapmak da mümkündür hücre referansları ile joker karakterleri kullanma Örneğin, "*Brown*" ifadesini doğrudan formülde vermek yerine, bunu F1 gibi bir hücreye yazabilir ve "Brown" içeren hücreleri saymak için aşağıdaki formülü kullanabilirsiniz: =COUNTIF(D2:D10, "*"&F1& "*")

Belirli karakterlerle başlayan veya biten hücreleri sayma

Tam olarak hangi sonucu elde etmek istediğinize bağlı olarak joker karakter, yıldız işareti (*) veya soru işareti (?) kullanabilirsiniz.

Eğer hücre sayısını bilmek istiyorsanız belirli bir metinle başlar veya biter Bir hücre kaç karakter içeriyor olursa olsun, bu formülleri kullanın:

=COUNTIF(C2:C10,"Mr*") - ile başlayan hücreleri sayar. Bay" .

=COUNTIF(C2:C10,"*ed") - harfleriyle biten hücreleri sayar. ed".

Aşağıdaki resim ikinci formülün nasıl işlediğini göstermektedir:

Belirli harflerle başlayan veya biten ve aşağıdakileri içeren hücrelerin sayısını arıyorsanız tam karakter sayısı Excel COUNTIF işlevini ölçütte soru işareti karakteri (?) ile birlikte kullanırsınız:

=COUNTIF(D2:D9,"??own") - "own" harfleriyle biten ve D2 ile D9 arasındaki hücrelerde boşluklar dahil olmak üzere tam olarak 5 karakter bulunan hücrelerin sayısını sayar.

=COUNTIF(D2:D9, "Mr??????") - "Bay" harfleriyle başlayan ve D2 ile D9 arasındaki hücrelerde boşluklar dahil olmak üzere tam olarak 8 karakter bulunan hücrelerin sayısını sayar.

İpucu. Bir hücreyi içeren hücre sayısını bulmak için gerçek soru işareti veya yıldız işareti formüldeki ? veya * karakterinden önce bir tilde (~) yazın. Örneğin, =COUNTIF(D2:D9,"*~?*") D2:D9 aralığında soru işareti içeren tüm hücreleri sayacaktır.

Boş ve boş olmayan hücreler için Excel COUNTIF

Bu formül örnekleri, belirli bir aralıktaki boş veya boş olmayan hücrelerin sayısını saymak için Excel'de EĞERSAY işlevini nasıl kullanabileceğinizi gösterir.

COUNTIF boş değil

Bazı Excel COUNTIF eğitimlerinde ve diğer çevrimiçi kaynaklarda, Excel'de boş olmayan hücreleri saymak için buna benzer formüllere rastlayabilirsiniz:

=COUNTIF(A1:A10, "*")

Ancak gerçek şu ki, yukarıdaki formül yalnızca herhangi bir metin değerleri boş dizeler de dahil olmak üzere, yani tarih ve sayı içeren hücreler boş hücreler olarak değerlendirilecek ve sayıma dahil edilmeyecektir!

Eğer evrensel bir Boş olmayan tüm hücreleri saymak için COUNTIF formülü belirli bir aralıkta, işte burada:

Ya da

Bu formül tüm değer türleriyle doğru şekilde çalışır - Metin , tarihler ve sayılar - aşağıdaki ekran görüntüsünde görebileceğiniz gibi.

COUNTIF boş

Bunun tersini istiyorsanız, yani belirli bir aralıktaki boş hücreleri saymak istiyorsanız, aynı yaklaşıma bağlı kalmalısınız - metin değerleri için joker karakter içeren ve tüm boş hücreleri saymak için "" ölçütüne sahip bir formül kullanın.

Formül herhangi bir metin içermeyen hücreleri sayar :

Yıldız işareti (*) herhangi bir metin karakteri dizisiyle eşleştiğinden, formül *'a eşit olmayan, yani belirtilen aralıkta herhangi bir metin içermeyen hücreleri sayar.

Boşluklar için evrensel COUNTIF formülü (tüm değer türleri) :

Yukarıdaki formül sayıları, tarihleri ve metin değerlerini doğru bir şekilde işler. Örneğin, C2:C11 aralığındaki boş hücrelerin sayısını şu şekilde alabilirsiniz:

=COUNTIF(C2:C11,"")

Microsoft Excel'in boş hücreleri saymak için başka bir işlevi olduğunu lütfen unutmayın: COUNTBLANK. Örneğin, aşağıdaki formüller yukarıdaki ekran görüntüsünde gördüğünüz COUNTIF formülleriyle tamamen aynı sonuçları üretecektir:

Boşlukları say:

=COUNTBLANK(C2:C11)

Boş olmayanları sayın:

=ROWS(C2:C11)*COLUMNS(C2:C11)-COUNTBLANK(C2:C11)

Ayrıca, hem COUNTIF hem de COUNTBLANK'in şu özelliklere sahip hücreleri saydığını lütfen unutmayın boş dizeler Bu tür hücrelere boşluk muamelesi yapmak istemiyorsanız, boş hücreler için "=" kullanın. Kriterler Örneğin:

=COUNTIF(C2:C11,"=")

Excel'de boşlukları sayma ve boşlukları saymama hakkında daha fazla bilgi için lütfen bkz:

• Excel'de boş hücreleri saymanın 3 yolu
• Excel'de boş olmayan hücreler nasıl sayılır

COUNTIF daha büyük, daha küçük veya eşit

Değerleri olan hücreleri saymak için daha büyük , daha az veya eşittir belirttiğiniz sayı için, aşağıdaki tabloda gösterildiği gibi, ölçütlere karşılık gelen bir işleç eklemeniz yeterlidir.

Lütfen COUNTIF formüllerinde, sayı içeren bir operatörün her zaman tırnak içine alınmış .

Yukarıdaki formüllerin tümünü aşağıdakiler için de kullanabilirsiniz hücreleri başka bir hücre değerine göre sayma kriterindeki sayıyı bir hücre referansı ile değiştirmeniz yeterli olacaktır.

Not: Eğer bir hücre referansı işlecini tırnak içine almanız ve hücre başvurusundan önce bir ve işareti (&) eklemeniz gerekir. Örneğin, D2:D9 aralığında D3 hücresindeki bir değerden daha büyük değerlere sahip hücreleri saymak için şu formülü kullanırsınız =COUNTIF(D2:D9,">"&D3) :

içeren hücreleri saymak istiyorsanız gerçek operatör ">", "<" veya "=" karakterleri gibi hücre içeriğinin bir parçası olarak, ölçütteki işleçle birlikte bir joker karakter kullanın. Bu tür ölçütler, sayısal bir ifade yerine bir metin dizesi olarak ele alınacaktır. Örneğin, formül =COUNTIF(D2:D9,"*>5*") D2:D9 aralığındaki "Delivery>5 days" veya ">5 available" gibi içeriğe sahip tüm hücreleri sayacaktır.

Excel COUNTIF işlevini tarihlerle kullanma

Belirttiğiniz tarihten veya başka bir hücredeki tarihten büyük, küçük veya eşit olan tarihleri içeren hücreleri saymak istiyorsanız, biraz önce tartıştıklarımıza benzer formülleri kullanarak zaten bildiğiniz şekilde ilerlersiniz. Yukarıdaki formüllerin tümü sayılar için olduğu kadar tarihler için de çalışır. Size sadece birkaç örnek vereyim:

Bu yaygın kullanımların yanı sıra, hücreleri geçerli tarihe göre saymak için TODAY() gibi belirli Excel Tarih ve Saat işlevleriyle birlikte COUNTIF işlevini kullanabilirsiniz.

İşte bu tür formüllerin gerçek veriler üzerinde kullanılmasına bir örnek (bugün yazıldığı sırada 25-Haziran-2014 idi):

Birden çok ölçütle Excel COUNTIF

Aslında, Excel EĞERSAY işlevi tam olarak birden çok ölçüt içeren hücreleri saymak için tasarlanmamıştır. Çoğu durumda, iki veya daha fazla ölçütle (VE mantığı) eşleşen hücreleri saymak için çoğul karşılığı olan EĞERSAY işlevini kullanırsınız. Ancak, bazı görevler iki veya daha fazla EĞERSAY işlevini tek bir formülde birleştirerek çözülebilir.

İki sayı arasındaki değerleri sayma

Excel EĞERSAY işlevinin 2 ölçütle en yaygın uygulamalarından biri, belirli bir aralıktaki sayıları saymaktır, yani X'ten küçük ancak Y'den büyük. Örneğin, B2:B9 aralığında bir değerin 5'ten büyük ve 15'ten küçük olduğu hücreleri saymak için aşağıdaki formülü kullanabilirsiniz.

=COUNTIF(B2:B9,">5")-COUNTIF(B2:B9,">=15")

Bu formül nasıl çalışır?

Burada, iki ayrı COUNTIF fonksiyonu kullanıyoruz - ilki 5'ten büyük kaç değer olduğunu buluyor ve diğeri 15'ten büyük veya eşit değerlerin sayısını alıyor. Ardından, ikincisini birincisinden çıkarıyor ve istenen sonucu elde ediyorsunuz.

Birden fazla VEYA ölçütü olan hücreleri sayın

Bir aralıktaki birkaç farklı öğeyi elde etmek istediğiniz durumlarda, 2 veya daha fazla COUNTIF işlevini bir araya getirin. Diyelim ki bir alışveriş listeniz var ve kaç tane meşrubat içerdiğini bulmak istiyorsunuz. Bunu yapmak için şuna benzer bir formül kullanın:

=COUNTIF(B2:B13, "Limonata")+COUNTIF(B2:B13, "*meyve suyu")

Lütfen ikinci kritere joker karakteri (*) eklediğimize dikkat edin, bu karakter listedeki her türlü meyve suyunu saymak için kullanılır.

Aynı şekilde, birden fazla koşul içeren bir EĞERSAY formülü yazabilirsiniz. İşte limonata, meyve suyu ve dondurmayı sayan birden fazla VEYA koşulu içeren EĞERSAY formülüne bir örnek:

=COUNTIF(B2:B13, "Limonata") + COUNTIF(B2:B13, "*meyve suyu") + COUNTIF(B2:B13, "Dondurma")

VEYA mantığıyla hücreleri saymanın diğer yolları için lütfen şu eğitime bakın: VEYA koşullarıyla Excel EĞERSAY ve EĞERSAY.

Yinelenen ve benzersiz değerleri bulmak için COUNTIF işlevini kullanma

Excel'de COUNTIF işlevinin bir başka olası kullanımı, bir sütunda, iki sütun arasında veya bir satırda yinelenenleri bulmak içindir.

Örnek 1. 1 sütundaki kopyaları bulun ve sayın

Örneğin, bu basit formül =COUNTIF(B2:B10,B2)>1 B2:B10 aralığındaki tüm yinelenen girişleri tespit ederken, başka bir işlev =COUNTIF(B2:B10,TRUE) size kaç tane yinelenen olduğunu söyleyecektir:

Örnek 2. İki sütun arasındaki kopyaları sayma

İki ayrı listeniz varsa, örneğin B ve C sütunlarında ad listeleri varsa ve her iki sütunda da kaç ad göründüğünü bilmek istiyorsanız, saymak için SUMPRODUCT işleviyle birlikte Excel COUNTIF'i kullanabilirsiniz kopyalar :

=SUMPRODUCT((COUNTIF(B2:B1000,C2:C1000)>0)*(C2:C1000""))

Hatta bir adım daha ileri gidip kaç tane benzersiz isimler Sütun C'de, yani Sütun B'de görünmeyen isimler vardır:

=SUMPRODUCT((COUNTIF(B2:B1000,C2:C1000)=0)*(C2:C1000""))

İpucu Yinelenen hücreleri veya yinelenen girişler içeren tüm satırları vurgulamak istiyorsanız, bu eğitimde gösterildiği gibi EĞERSAY formüllerine dayalı koşullu biçimlendirme kuralları oluşturabilirsiniz - Yinelenenleri vurgulamak için Excel koşullu biçimlendirme formülleri.

Örnek 3. Bir satırdaki yinelenenleri ve benzersiz değerleri sayma

Bir sütun yerine belirli bir satırdaki yinelenenleri veya benzersiz değerleri saymak istiyorsanız, aşağıdaki formüllerden birini kullanın. Bu formüller, örneğin piyango çekiliş geçmişini analiz etmek için yararlı olabilir.

Bir satırdaki kopyaları sayın:

=SUMPRODUCT((COUNTIF(A2:I2,A2:I2)>1)*(A2:I2""))

Bir satırdaki benzersiz değerleri sayın:

=SUMPRODUCT((COUNTIF(A2:I2,A2:I2)=1)*(A2:I2""))

Excel COUNTIF - sık sorulan sorular ve sorunlar

Umarım bu örnekler Excel COUNTIF işlevi hakkında bir fikir edinmenize yardımcı olmuştur. Yukarıdaki formüllerden herhangi birini verileriniz üzerinde denediyseniz ve çalışmasını sağlayamadıysanız veya oluşturduğunuz formülle ilgili bir sorun yaşıyorsanız, lütfen aşağıdaki en yaygın 5 soruna göz atın. Cevabı veya yararlı bir ipucunu orada bulma şansınız yüksektir.

1. Bitişik olmayan bir hücre aralığında COUNTIF

Soru: Excel'de bitişik olmayan bir aralıkta veya bir hücre seçiminde EĞERSAY'ı nasıl kullanabilirim?

Cevap ver: Excel EĞERSAY bitişik olmayan aralıklarda çalışmaz ve sözdizimi ilk parametre olarak birkaç ayrı hücrenin belirtilmesine izin vermez. Bunun yerine, birkaç EĞERSAY işlevinin bir kombinasyonunu kullanabilirsiniz:

Yanlış: =COUNTIF(A2,B3,C4,">0")

Doğru: =COUNTIF(A2,">0") + COUNTIF(B3,">0") + COUNTIF(C4,">0")

Alternatif bir yol, bir aralık dizisi oluşturmak için INDIRECT işlevini kullanmaktır. Örneğin, aşağıdaki formüllerin her ikisi de ekran görüntüsünde gördüğünüz aynı sonucu üretir:

=SUM(COUNTIF(INDIRECT({"B2:B8","D2:C8"}),"=0"))

=COUNTIF($B2:$B8,0) + COUNTIF($C2:$C8,0)

2. COUNTIF formüllerinde ampersand ve tırnak işaretleri

Soru: Bir EĞERSAY formülünde ne zaman ve işareti kullanmam gerekir?

Cevap ver: Muhtemelen COUNTIF fonksiyonunun en zor kısmıdır ve ben şahsen bunu çok kafa karıştırıcı buluyorum. Yine de biraz düşünürseniz, arkasındaki mantığı göreceksiniz - argüman için bir metin dizesi oluşturmak için bir ve işareti ve tırnak işaretleri gereklidir. Yani, bu kurallara uyabilirsiniz:

içinde bir sayı veya hücre referansı kullanırsanız tam eşleşme kriterlerinde ne ve işaretine ne de tırnak işaretine ihtiyacınız vardır:

=COUNTIF(A1:A10,10)

veya

=COUNTIF(A1:A10,C1)

Kriterleriniz şunları içeriyorsa Metin , joker karakter veya bir sayı ile mantıksal işleç tırnak içine alın. Örneğin:

=COUNTIF(A2:A10, "lemons")

veya

=COUNTIF(A2:A10, "*") veya =COUNTIF(A2:A10,">5")

Ölçütünüzün bir ifade olması durumunda hücre referansı veya başka bir Excel fonksiyon bir metin dizesini başlatmak için tırnak işaretlerini ("") ve dizeyi birleştirmek ve bitirmek için ampersand (&) kullanmanız gerekir. Örneğin:

=COUNTIF(A2:A10,">"&D2)

veya

=COUNTIF(A2:A10,"<="&TODAY())

Bir ve işaretinin gerekli olup olmadığı konusunda şüpheniz varsa, her iki yolu da deneyin. Çoğu durumda bir ve işareti gayet iyi çalışır, örneğin aşağıdaki formüllerin her ikisi de eşit derecede iyi çalışır.

=COUNTIF(C2:C8,"<=5")

ve

=COUNTIF(C2:C8,"<="&5)

3. Biçimlendirilmiş (renk kodlu) hücreler için COUNTIF

Soru: Hücreleri değerler yerine dolgu veya yazı tipi rengine göre nasıl sayabilirim?

Cevap ver: Ne yazık ki, Excel EĞERSAY işlevinin sözdizimi, biçimlerin koşul olarak kullanılmasına izin vermez. Hücreleri renklerine göre saymanın veya toplamanın tek olası yolu bir makro veya daha doğrusu bir Excel Kullanıcı Tanımlı işlevi kullanmaktır. Manuel olarak renklendirilmiş hücreler ve koşullu olarak biçimlendirilmiş hücreler için çalışan kodu bu makalede bulabilirsiniz - Excel hücrelerini dolgu veyazı tipi rengi.

4. COUNTIF formülünde #NAME? hatası

Sorun: COUNTIF formülüm #NAME? hatası veriyor. Nasıl düzeltebilirim?

Cevap ver: Büyük olasılıkla formüle yanlış bir aralık girmişsinizdir. Lütfen yukarıdaki 1. maddeyi kontrol edin.

5. Excel COUNTIF formülü çalışmıyor

Sorun: COUNTIF formülüm çalışmıyor! Neyi yanlış yaptım?

Cevap ver: Görünüşte doğru olan ancak çalışmayan veya yanlış sonuç üreten bir formül yazdıysanız, aralık, koşullar, hücre referansları, ve işareti kullanımı ve tırnak işaretleri gibi en belirgin şeyleri kontrol ederek başlayın.

Kullanırken çok dikkatli olun boşluklar Bu makale için formüllerden birini oluştururken saçımı başımı yolmanın eşiğindeydim çünkü doğru formül (doğru olduğunu kesin olarak biliyordum!) çalışmıyordu. Anlaşıldığı üzere, sorun arada bir yerde küçücük bir boşluktaydı, argh... Örneğin, şu formüle bakın:

=COUNTIF(B2:B13," Limonata") .

İlk bakışta, açılış tırnak işaretinden sonra fazladan bir boşluk dışında yanlış bir şey yoktur. Microsoft Excel, gerçekten 'Limonata' kelimesini ve baştaki boşluğu içeren hücreleri saymak istediğinizi varsayarak, bir hata mesajı, uyarı veya başka bir gösterge olmadan formülü sorunsuz bir şekilde yutacaktır.

COUNTIF işlevini birden fazla ölçütle kullanıyorsanız, formülü birkaç parçaya bölün ve her işlevi ayrı ayrı doğrulayın.

Bugünlük bu kadar. Bir sonraki makalede, Excel'de birden çok koşulla hücre saymanın çeşitli yollarını keşfedeceğiz. Gelecek hafta görüşmek dileğiyle ve okuduğunuz için teşekkürler!