Bu makalede, CONCATENATE işlevini ve "&" operatörünü kullanarak Excel'de metin dizelerini, sayıları ve tarihleri birleştirmenin çeşitli yollarını öğreneceksiniz. Ayrıca tek tek hücreleri, sütunları ve aralıkları birleştirmek için formülleri de tartışacağız.

Excel çalışma kitaplarınızda veriler her zaman ihtiyaçlarınıza göre yapılandırılmaz. Genellikle bir hücrenin içeriğini ayrı hücrelere bölmek veya tam tersini yapmak isteyebilirsiniz - iki veya daha fazla sütundaki verileri tek bir sütunda birleştirmek. Yaygın örnekler arasında adları ve adres parçalarını birleştirme, metni formüle dayalı bir değerle birleştirme, tarihleri ve saatleri istenen biçimde görüntüleme sayılabilir.

Bu eğitimde, çalışma sayfalarınız için en uygun yöntemi seçebilmeniz için çeşitli Excel dize birleştirme tekniklerini inceleyeceğiz.

Excel'de "concatenate" nedir?

Temelde, Excel elektronik tablolarında verileri birleştirmenin iki yolu vardır:

• Hücreleri birleştirme
• Hücre değerlerini birleştirme

Sen ne zaman birleştirme hücrelerinde, iki veya daha fazla hücreyi "fiziksel olarak" tek bir hücrede birleştirirsiniz. Sonuç olarak, birden fazla satır ve/veya sütunda görüntülenen daha büyük bir hücreye sahip olursunuz.

Sen ne zaman concatenate hücrelerini birleştirirseniz, yalnızca İçindekiler Başka bir deyişle, Excel'de birleştirme, iki veya daha fazla değeri bir araya getirme işlemidir. Bu yöntem genellikle farklı hücrelerde bulunan birkaç metin parçasını birleştirmek için kullanılır (teknik olarak bunlara metin dizeleri ya da basitçe dizeler ) veya bir metnin ortasına formülle hesaplanmış bir değer ekleyin.

Aşağıdaki ekran görüntüsü bu iki yöntem arasındaki farkı göstermektedir:

Excel'de hücreleri birleştirmek ayrı bir makalenin konusudur ve bu eğitimde, Excel'de dizeleri birleştirmenin iki ana yolunu tartışacağız - CONCATENATE işlevini ve birleştirme operatörünü (&) kullanarak.

Excel CONCATENATE işlevi

Excel'deki CONCATENATE işlevi, farklı metin parçalarını bir araya getirmek veya birkaç hücredeki değerleri tek bir hücrede birleştirmek için kullanılır.

Excel CONCATENATE'in sözdizimi aşağıdaki gibidir:

Nerede Metin bir metin dizesi, hücre başvurusu veya formüle dayalı değerdir.

CONCATENATE işlevi Excel 365 - 2007'nin tüm sürümlerinde desteklenir.

Örneğin, B6 ve C6 değerlerini virgülle birleştirmek için formül şöyledir:

=CONCATENATE(B6, ",", C6)

Aşağıdaki resimde daha fazla örnek gösterilmektedir:

Not: Excel 365 - Excel 2019'da, CONCATENATE işlevinin tamamen aynı sözdizimine sahip modern bir halefi olan CONCAT işlevi de mevcuttur. CONCATENATE işlevi geriye dönük uyumluluk için saklansa da Microsoft, Excel'in gelecekteki sürümlerinde destekleneceğine dair herhangi bir söz vermemektedir.

Excel'de CONCATENATE kullanma - hatırlanması gerekenler

CONCATENATE formüllerinizin her zaman doğru sonuçları verdiğinden emin olmak için aşağıdaki basit kuralları unutmayın:

• Excel CONCATENATE işlevinin çalışması için en az bir "metin" bağımsız değişkeni gerekir.
• Tek bir formülde, toplam 8.192 karakterden oluşan 255 adede kadar dizeyi birleştirebilirsiniz.
• CONCATENATE işlevinin sonucu, kaynak değerlerin tümü sayı olsa bile her zaman bir metin dizesidir.
• CONCAT işlevinin aksine, Excel CONCATENATE dizileri tanımaz. Her hücre başvurusu ayrı ayrı listelenmelidir. Örneğin, CONCATENATE(A1:A3) yerine CONCATENATE(A1, A2, A3) kullanmalısınız.
• Bağımsız değişkenlerden herhangi biri geçersizse, CONCATENATE işlevi bir #VALUE! hatası döndürür.

Excel'de dizeleri birleştirmek için "&" işleci

Microsoft Excel'de, ve işareti (&) hücreleri birleştirmenin başka bir yoludur. Bu yöntem birçok senaryoda çok kullanışlıdır çünkü ve işareti yazmak "birleştir" kelimesini yazmaktan çok daha hızlıdır :)

Örneğin, iki hücre değerini aralarında bir boşluk bırakarak birleştirmek için formül şöyledir:

=A2&" "&B2

Excel'de birleştirme nasıl yapılır - formül örnekleri

Aşağıda, Excel'de CONCATENATE işlevinin kullanımına ilişkin birkaç örnek bulacaksınız.

İki veya daha fazla hücreyi ayırıcı olmadan birleştirme

Değerlerini birleştirmek için iki hücre bir araya getirmek için, en basit haliyle birleştirme formülünü kullanırsınız:

=CONCATENATE(A2, B2)

Ya da

=A2&B2

Lütfen değerlerin aşağıdaki ekran görüntüsünde olduğu gibi herhangi bir sınırlayıcı olmadan bir araya getirileceğini unutmayın.

Birleştirmek için çoklu hücreler 'de, bitişik hücreleri birleştiriyor olsanız bile her hücre referansını ayrı ayrı sağlamanız gerekir. Örneğin:

=CONCATENATE(A2, B2, C2)

Ya da

=A2&B2&C2

Formüller hem metin hem de sayılar için çalışır. Sayılar söz konusu olduğunda, lütfen sonucun bir metin dizesi olduğunu unutmayın. Sayıya dönüştürmek için CONCATENATE'in çıktısını 1 ile çarpın veya ona 0 ekleyin:

=CONCATENATE(A2, B2)*1

İpucu: Excel 2019 ve sonraki sürümlerde, bir veya daha fazla aralık başvurusu kullanarak birden çok hücreyi hızlı bir şekilde birleştirmek için CONCAT işlevini kullanabilirsiniz.

Hücreleri boşluk, virgül veya başka bir sınırlayıcı ile birleştirin

Çalışma sayfalarınızda, değerleri virgül, boşluk, çeşitli noktalama işaretleri veya kısa çizgi veya eğik çizgi gibi diğer karakterleri içerecek şekilde birleştirmeniz gerekebilir. Bunu yapmak için, istediğiniz karakteri birleştirme formülünüze koymanız yeterlidir. Aşağıdaki örneklerde gösterildiği gibi, bu karakteri tırnak işaretleri içine almayı unutmayın.

ile iki hücreyi birleştirme uzay :

=CONCATENATE(A2, " ", B2)

veya

=A2 & " " & B2

ile iki hücreyi birleştirme virgül :

=CONCATENATE(A2, ", ", B2)

veya

=A2 & ", " & B2

ile iki hücreyi birleştirme kısa çizgi :

=CONCATENATE(A2, "-", B2)

veya

=A2 & "-" & B2

Aşağıdaki ekran görüntüsü sonuçların nasıl görünebileceğini göstermektedir:

İpucu: Excel 2019 ve sonraki sürümlerde, birden çok hücredeki dizeleri belirttiğiniz herhangi bir sınırlayıcıyla birleştirmek için METİN BİRLEŞTİR işlevini kullanabilirsiniz.

Metin dizesi ve hücre değerini birleştirme

Excel BİRLEŞTİR işlevinin yalnızca hücrelerin değerlerini birleştirmekle sınırlı olması için bir neden yoktur. Sonucu daha anlamlı hale getirmek için metin dizelerini birleştirmek için de kullanabilirsiniz. Örneğin:

=CONCATENATE(A2, " ", B2, "tamamlandı")

Yukarıdaki formül, aşağıdaki ekran görüntüsünde satır 2'de olduğu gibi, kullanıcıyı belirli bir projenin tamamlandığı konusunda bilgilendirir. Birleştirilmiş metin dizelerini ayırmak için "tamamlandı" kelimesinden önce bir boşluk eklediğimize lütfen dikkat edin. Birleştirilmiş değerler arasına da bir boşluk (" ") eklenir, böylece sonuç "Proje1" yerine "Proje 1" olarak görüntülenir.

Birleştirme operatörü ile formül bu şekilde yazılabilir:

=A2 & " " & B2 & " tamamlandı"

Aynı şekilde, birleştirme formülünüzün başına veya ortasına bir metin dizesi ekleyebilirsiniz. Örneğin:

=CONCATENATE("Bkz ", A2, " ", B2)

="Bakınız " & A2 & " " & B2

Metin dizesini ve başka bir formülü birleştirme

Bazı formüller tarafından döndürülen sonucu kullanıcılarınız için daha anlaşılır hale getirmek için, değerin gerçekte ne olduğunu açıklayan bir metin dizesiyle birleştirebilirsiniz.

Örneğin, geçerli tarihi istediğiniz biçimde döndürmek için aşağıdaki formülü kullanabilir ve bunun ne tür bir tarih olduğunu belirtebilirsiniz:

=CONCATENATE("Bugün ",TEXT(TODAY(), "mmmm d, yyyy"))

="Bugün " & TEXT(TODAY(), "dd-mmm-yy")

İpucu: Ortaya çıkan metin dizelerini etkilemeden kaynak verileri silmek isterseniz, formülleri değerlerine dönüştürmek için "Özel yapıştır - yalnızca değerler" seçeneğini kullanın.

Metin dizelerini satır sonlarıyla birleştirme

Çoğu zaman, ortaya çıkan metin dizelerini önceki örnekte gösterildiği gibi noktalama işaretleri ve boşluklarla ayırırsınız. Ancak bazı durumlarda, değerleri satır sonu veya satır başı ile ayırmanız gerekebilir. Yaygın bir örnek, ayrı sütunlardaki verilerden posta adreslerini birleştirmektir.

Bir sorun, formüle normal bir karakter gibi satır sonu yazamamanızdır. Bunun yerine, birleştirme formülüne karşılık gelen ASCII kodunu sağlamak için CHAR işlevini kullanırsınız:

• Windows'ta CHAR(10) kullanın; burada 10, aşağıdakiler için karakter kodudur Satır besleme .
• Mac'te CHAR(13) kullanın; burada 13, aşağıdakiler için karakter kodudur Şaryo dönüşü .

Bu örnekte, A'dan F'ye kadar olan sütunlarda adres parçalarına sahibiz ve bunları G sütununda "&" birleştirme operatörünü kullanarak bir araya getiriyoruz. Birleştirilen değerler virgül (", "), boşluk (" ") ve satır sonu CHAR(10) ile ayrılır:

=A2 & " " & B2 & CHAR(10) & C2 & CHAR(10) & D2 & ", " & E2 & " " & F2

CONCATENATE işlevi bu şekli alacaktır:

=CONCATENATE(A2, " ", B2, CHAR(10), C2, CHAR(10), D2, ", ", E2, " ", F2)

Her iki durumda da sonuç 3 satırlık bir metin dizesidir: Not: Birleştirilmiş değerleri ayırmak için satır sonlarını kullanırken, sonucun doğru görüntülenmesi için Metni kaydır özelliğini etkinleştirmeniz gerekir. Bunu yapmak için Ctrl + 1 tuşlarına basarak Hücreleri Biçimlendir iletişim kutusundan Hizalama sekmesine gidin ve Metin kaydırma Kutu.

Aynı şekilde, son dizeleri aşağıdaki gibi diğer karakterlerle ayırabilirsiniz:

• Çift tırnak (") - CHAR(34)
• İleri eğik çizgi (/) - CHAR(47)
• Yıldız işareti (*) - CHAR (42)
• Tam liste ASCII kodları buradan ulaşabilirsiniz.

Excel'de sütunlar nasıl birleştirilir

İki veya daha fazla sütunu birleştirmek için, birleştirme formülünüzü ilk hücreye girin ve ardından doldurma tutamacını (seçili hücrenin sağ alt köşesinde görünen küçük kare) sürükleyerek diğer hücrelere kopyalayın.

Örneğin, değerleri bir boşlukla sınırlayan iki sütunu (A ve B sütunu) birleştirmek için C2'deki formül aşağı kopyalanır:

=CONCATENATE(A2, " ", B2)

Ya da

= A2 & " " & B2 İpucu: Formülü sütundan aşağı kopyalamanın hızlı bir yolu, formülün bulunduğu hücreyi seçmek ve doldurma tutamacına çift tıklamaktır.

Daha fazla bilgi için lütfen Excel'de veri kaybetmeden iki sütunu birleştirme bölümüne bakın.

Biçimlendirmeyi koruyarak metin ve sayıları birleştirme

Bir metin dizesini bir sayı, yüzde veya tarihle birleştirirken, sayısal bir değerin orijinal biçimlendirmesini korumak veya farklı bir şekilde görüntülemek isteyebilirsiniz. Bu, bir birleştirme formülüne yerleştirdiğiniz TEXT işlevi içinde biçim kodunu sağlayarak yapılabilir.

Bu eğitimin başında, metin ve tarihi birleştiren bir formülden bahsetmiştik.

Ve işte birleştiren birkaç formül örneği daha metin ve sayı :

2 ondalık basamaklı ve $ işaretli sayı:

=A2 & " " & TEXT(B2, "$#,#0.00")

Önemsiz sıfırlar ve $ işareti içermeyen sayı:

=A2 & " " & TEXT(B2, "0.#")

Kesirli sayı:

=A2 & " " & TEXT(B2, "# ?/???")

Birleştirmek için metin ve yüzde formüller şunlardır:

İki ondalık basamaklı yüzde:

=A12 & " " & TEXT(B12, "0.00%")

Yuvarlanmış tam yüzde:

=A12 & " " & TEXT(B12, "0%")

Excel'de bir hücre aralığı nasıl birleştirilir

Excel CONCATENATE işlevi dizileri kabul etmediği için birden fazla hücredeki değerleri birleştirmek biraz çaba gerektirebilir.

Birkaç hücreyi (örneğin A1'den A4'e) birleştirmek için aşağıdaki formüllerden birini kullanmanız gerekir:

=CONCATENATE(A1, A2, A3, A4)

veya

=A1 & A2 & A3 & A4

Oldukça küçük bir hücre grubunu birleştirirken, tüm referansları yazmak önemli değildir. Büyük bir aralığı sağlamak, her bir referansı manuel olarak yazmak sıkıcı olacaktır. Aşağıda Excel'de hızlı aralık birleştirme için 3 yöntem bulacaksınız.

Yöntem 1. Birden fazla hücre seçmek için CTRL tuşuna basın

Birkaç hücreyi hızlı bir şekilde seçmek için, formüle dahil etmek istediğiniz her hücreye tıklarken Ctrl tuşunu basılı tutabilirsiniz. İşte ayrıntılı adımlar:

1. Formülü girmek istediğiniz hücreyi seçin.
2. O hücreye veya formül çubuğuna =CONCATENATE( yazın.
3. Ctrl tuşunu basılı tutun ve birleştirmek istediğiniz her hücreye tıklayın.
4. Ctrl düğmesini bırakın, kapanış parantezini yazın ve Enter tuşuna basın.

Yöntem 2. Tüm hücre değerlerini almak için TRANSPOSE işlevini kullanın

Bir aralık onlarca veya yüzlerce hücreden oluşuyorsa, önceki yöntem her hücreye tıklamayı gerektirdiğinden yeterince hızlı olmayabilir. Bu durumda, bir dizi değer döndürmek için TRANSPOSE işlevini kullanabilir ve ardından bunları tek bir hamlede birleştirebilirsiniz.

1. Sonucun görünmesini istediğiniz hücreye, örneğin TRANSPOSE formülünü girin:

   =TRANSPOSE(A1:A10)

2. Formül çubuğunda, formülü hesaplanan değerlerle değiştirmek için F9 tuşuna basın. Sonuç olarak, birleştirilecek bir değerler dizisine sahip olacaksınız.
3. Diziyi çevreleyen küme parantezlerini silin.
4. İlk değerden önce =CONCATENATE( yazın, ardından son değerden sonra kapanış parantezini yazın ve Enter tuşuna basın.

Not: Bu formülün sonucu şöyledir statik Çünkü hücre referanslarını değil, değerleri birleştirir. Kaynak veriler değişirse, işlemi tekrarlamanız gerekecektir.

Yöntem 3. CONCAT işlevini kullanın

Excel 365 ve Excel 2021'de bu basit formül, bir hücre aralığını göz açıp kapayıncaya kadar birleştirir:

=CONCAT(A1:A10)

Yöntem 4. Hücreleri Birleştir eklentisini kullanın

Excel'de herhangi bir aralığı birleştirmenin hızlı ve formülsüz bir yolu, Hücreleri Birleştir eklentisini " Seçimdeki tüm alanları birleştirin " seçeneği, Birkaç hücrenin değerlerini tek bir hücrede birleştirme bölümünde gösterildiği gibi kapalıdır.

Excel "&" operatörü vs. CONCATENATE işlevi

Birçok kullanıcı Excel'de dizeleri birleştirmek için hangisinin daha etkili bir yol olduğunu merak eder - CONCATENATE işlevi veya "&" operatörü.

Tek gerçek fark, CONCATENATE işlevinin 255 dize sınırı olması ve ampersand kullanıldığında böyle bir sınırlama olmamasıdır. Bunun dışında, bu iki yöntem arasında hiçbir fark olmadığı gibi CONCATENATE ve "&" formülleri arasında herhangi bir hız farkı da yoktur.

Ve 255 gerçekten büyük bir sayı olduğundan ve gerçek işlerde bu kadar çok dizgiyi birleştirmeniz neredeyse hiç gerekmeyeceğinden, fark rahatlık ve kullanım kolaylığına dayanır. Bazı kullanıcılar CONCATENATE formüllerini okumayı daha kolay buluyor, ben şahsen "&" yöntemini kullanmayı tercih ediyorum. Bu nedenle, kendinizi daha rahat hissettiğiniz tekniğe bağlı kalın.

Excel'de CONCATENATE'in tersi (hücreleri bölme)

Excel'de birleştirmenin tersi, bir hücrenin içeriğini birden çok hücreye bölmektir. Bu birkaç farklı şekilde yapılabilir:

• Metinden Sütunlara özelliği
• Excel 2013 ve daha yüksek sürümlerde Flash Dolgu seçeneği
• Excel 365'te TEXTSPLIT işlevi
• Hücreleri bölmek için özel formüller (ORTA, SAĞ, SOL, vb.)

Bu makalede de yararlı bilgiler bulabilirsiniz: Excel'de hücreleri birleştirme.

Hücreleri Birleştir eklentisi ile Excel'de birleştirme

Ultimate Suite for Excel'de bulunan Merge Cells eklentisi ile her ikisini de verimli bir şekilde yapabilirsiniz:

• Birleştirme veri kaybı olmadan birkaç hücreyi tek bir hücreye dönüştürür.
• Birleştir birkaç hücrenin değerlerini tek bir hücrede toplayın ve bunları seçtiğiniz herhangi bir sınırlayıcı ile ayırın.

Hücreleri Birleştir aracı 2016'dan 365'e kadar tüm Excel sürümleriyle çalışır ve metin dizeleri, sayılar, tarihler ve özel semboller dahil tüm veri türlerini birleştirebilir. En önemli iki avantajı basitlik ve hızdır - herhangi bir birleştirme birkaç tıklamayla yapılır.

Birkaç hücrenin değerlerini tek bir hücrede birleştirin

Birkaç hücrenin içeriğini birleştirmek için, birleştirilecek aralığı seçer ve aşağıdaki ayarları yapılandırırsınız:

• Altında Ne birleştirilmeli , seçiniz Hücreler bir arada .
• Altında ile birleştirin yazınız. sınırlayıcı (bizim durumumuzda bir virgül ve bir boşluk).
• Sonucu nereye yerleştirmek istediğinizi seçin.
• En önemlisi, işaretini kaldırın Seçimdeki tüm alanları birleştirin Hücrelerin birleştirilip birleştirilmeyeceğini veya değerlerinin birleştirilip birleştirilmeyeceğini kontrol eden bu seçenektir.

Sütunları satır satır birleştirme

İki veya daha fazla sütunu birleştirmek için Hücreleri Birleştir ayarlarını benzer şekilde yapılandırırsınız, ancak birleştirmeyi seçersiniz sütunları tek bir ve sonuçları sol sütuna yerleştirin.

Satırları sütun sütun birleştirin

Her bir satırdaki verileri sütun sütun birleştirmek için seçim yaparsınız:

• Birleştirme satırları tek bir .
• Kullanım satır sonu sınırlayıcı için.
• Sonuçları şuraya yerleştirin üst sıra .

Sonuç buna benzer görünebilir:

Merge Cells eklentisinin veri setlerinizle nasıl başa çıkacağını kontrol etmek için, aşağıdaki Excel için Ultimate Suite'imizin tam işlevsel deneme sürümünü indirebilirsiniz.

Excel'de birleştirme işlemi bu şekilde yapılır. Okuduğunuz için teşekkür ediyor ve gelecek hafta blogumuzda görüşmeyi umuyorum!

Mevcut indirmeler

Birleştirme formülü örnekleri (.xlsx dosyası)

Ultimate Suite 14 günlük deneme sürümü (.exe dosyası)