Ipinapakita ng tutorial kung paano gamitin ang function na VLOOKUP para kumopya ng data mula sa isa pang worksheet o workbook, Vlookup sa maraming sheet, at dynamic na maghanap para ibalik ang mga value mula sa iba't ibang sheet sa iba't ibang mga cell.

Kapag naghahanap ng ilang impormasyon sa Excel, ito ay isang bihirang kaso kapag ang lahat ng data ay nasa parehong sheet. Mas madalas, kakailanganin mong maghanap sa maraming sheet o kahit na iba't ibang workbook. Ang magandang balita ay ang Microsoft Excel ay nagbibigay ng higit sa isang paraan upang gawin ito, at ang masamang balita ay ang lahat ng mga paraan ay medyo mas kumplikado kaysa sa isang karaniwang formula ng VLOOKUP. Ngunit sa kaunting pasensya lang, malalaman natin ang mga ito :)

Paano mag-VLOOKUP sa pagitan ng dalawang sheet

Para sa panimula, siyasatin natin ang isang pinakasimpleng kaso - gamit ang VLOOKUP upang kopyahin ang data mula sa isa pang worksheet. Ito ay halos kapareho sa isang regular na formula ng VLOOKUP na naghahanap sa parehong worksheet. Ang pagkakaiba ay isinama mo ang pangalan ng sheet sa argument na table_array upang sabihin sa iyong formula kung saan matatagpuan ang hanay ng paghahanap sa worksheet.

Ang generic na formula sa VLOOKUP mula sa isa pang sheet ay ang mga sumusunod:

VLOOKUP(lookup_value, Sheet!range, col_index_num, [range_lookup])

Bilang halimbawa, hilahin natin ang mga numero ng benta mula Ene na ulat sa Buod sheet. Para dito, tinukoy namin ang mga sumusunod na argumento:

• Lookup_values ay nasa column A sa Summary sheet, at kamiVLOOKUP:

  VLOOKUP($A2, 'West'!$A$2:$C$6 , 2, FALSE)

  Sa wakas, ang pinakakaraniwang VLOOKUP formula na ito ay naghahanap ng A2 value sa unang column ng hanay na A2:C6 sa West sheet at nagbabalik ng isang tugma mula sa 2nd column. Iyon lang!

  Dynamic na VLOOKUP upang ibalik ang data mula sa maraming sheet sa iba't ibang mga cell

  Una, tukuyin natin kung ano ang eksaktong ibig sabihin ng salitang "dynamic" sa kontekstong ito at kung paano magiging ang formula na ito iba sa mga nauna.

  Kung sakaling mayroon kang malalaking chunks ng data sa parehong format na nahahati sa maraming spreadsheet, maaaring gusto mong kunin ang impormasyon mula sa iba't ibang mga sheet papunta sa iba't ibang mga cell. Ang larawan sa ibaba ay naglalarawan ng konsepto:

  

  Hindi tulad ng mga nakaraang formula na nakakuha ng value mula sa isang partikular na sheet batay sa isang natatanging identifier, sa pagkakataong ito ay naghahanap kami ng mga value mula sa ilang mga sheet sa isang oras.

  May dalawang magkaibang solusyon para sa gawaing ito. Sa parehong mga kaso, kailangan mong gumawa ng kaunting gawaing paghahanda at lumikha ng mga pinangalanang hanay para sa mga cell ng data sa bawat lookup sheet. Para sa halimbawang ito, tinukoy namin ang mga sumusunod na hanay:

  • East_Sales - A2:B6 sa East sheet
  • North_Sales - A2: B6 sa North sheet
  • South_Sales - A2:B6 sa South sheet
  • West_Sales - A2:B6 sa West sheet

  VLOOKUP at nested IFs

  Kung mayroon kang makatwirang bilang ng mga sheet na hahanapin, maaari mong gamitin ang mga nested IF functionupang piliin ang sheet batay sa mga keyword sa mga paunang natukoy na mga cell (mga cell B1 hanggang D1 sa aming kaso).

  Gamit ang lookup value sa A2, ang formula ay sumusunod:

  =VLOOKUP($A2, IF(B$1="east", East_Sales, IF(B$1="north", North_Sales, IF(B$1="south", South_Sales, IF(B$1="west", West_Sales)))), 2, FALSE)

  Isinalin sa English, ang bahaging IF ay nagbabasa ng:

  Kung ang B1 ay Silangan , tingnan ang hanay na pinangalanang East_Sales ; kung ang B1 ay North , tingnan ang hanay na pinangalanang North_Sales ; kung ang B1 ay South , tingnan ang hanay na pinangalanang South_Sales ; at kung ang B1 ay Kanluran , tingnan ang hanay na pinangalanang West_Sales .

  Ang hanay na ibinalik ng IF ay mapupunta sa table_array ng VLOOKUP, na kumukuha isang katugmang halaga mula sa ika-2 column sa kaukulang sheet.

  Ang matalinong paggamit ng mga pinaghalong reference para sa lookup value ($A2 - absolute column at relative row) at ang logical test ng IF (B$1 - relative column at absolute row) ay nagbibigay-daan sa pagkopya ng formula sa ibang mga cell nang walang anumang pagbabago - Awtomatikong inaayos ng Excel ang mga sanggunian batay sa relatibong posisyon ng isang row at column.

  Kaya, ipinasok namin ang formula sa B2, kopyahin ito nang tama at hanggang sa pinakamaraming column at row kung kinakailangan, at makuha ang sumusunod na resulta:

  

  INDIRECT VLOOKUP

  Kapag nagtatrabaho sa maraming sheet, maraming nested level ay maaaring gumawa din ng formula mahaba at mahirap basahin. Ang isang mas mahusay na paraan ay ang gumawa ng dynamic na hanay ng vlookup sa tulong ng INDIRECT:

  =VLOOKUP($A2, INDIRECT(B$1&"_Sales"), 2, FALSE)

  Dito, pinagsasama namin ang reference sa cell na naglalaman ngnatatanging bahagi ng pinangalanang hanay (B1) at ang karaniwang bahagi (_Sales). Gumagawa ito ng text string tulad ng "East_Sales", na INDIRECT ay nagko-convert sa pangalan ng hanay na mauunawaan ng Excel.

  Bilang resulta, makakakuha ka ng compact formula na gumagana nang maganda sa anumang bilang ng mga sheet:

  

  Ganyan ang Vlookup sa pagitan ng mga sheet at file sa Excel. Salamat sa pagbabasa at umaasa akong makita ka sa aming blog sa susunod na linggo!

  Magsanay ng workbook para sa pag-download

  Vlookup maramihang mga halimbawa ng sheet (.xlsx file)

  sumangguni sa unang data cell, na A2.
• Table_array ay ang range na A2:B6 sa Jan sheet. Upang sumangguni dito, lagyan ng prefix ang reference ng range na may pangalan ng sheet na sinusundan ng tandang padamdam: Ene!$A$2:$B$6.

  Mangyaring bigyang-pansin na ni-lock namin ang hanay na may ganap na mga sanggunian sa cell upang maiwasan itong magbago kapag kinokopya ang formula sa ibang mga cell.

  Col_index_num ay 2 dahil gusto naming kopyahin ang isang halaga mula sa column B, na siyang ika-2 column sa array ng talahanayan.

• Range_lookup ay nakatakda sa FALSE upang maghanap ng eksaktong tugma.

Pagsasama-sama ng mga argumento, makukuha natin ang formula na ito:

=VLOOKUP(A2, Jan!$A$2:$B$6, 2, FALSE)

I-drag ang formula pababa sa column at makukuha mo ang resultang ito:

Sa isang katulad na paraan, maaari kang mag-Vlookup ng data mula sa Peb at Mar na mga sheet:

=VLOOKUP(A2, Feb!$A$2:$B$6, 2, FALSE)

=VLOOKUP(A2, Mar!$A$2:$B$6, 2, FALSE)

Mga tip at paalala:

• Kung ang pangalan ng sheet ay naglalaman ng mga puwang o mga hindi alpabetikong character , dapat itong nakapaloob sa mga solong panipi, tulad ng 'Jan Sales'!$A$2:$B$6 . Para sa higit pang impormasyon, pakitingnan ang Paano mag-refer ng isa pang sheet sa Excel.
• Sa halip na direktang mag-type ng pangalan ng sheet sa isang formula, maaari kang lumipat sa lookup worksheet at piliin ang hanay doon. Awtomatikong maglalagay ang Excel ng reference na may tamang syntax, na hindi ka magkakaroon ng problema sa pagsuri sa pangalan at pag-troubleshoot.

Vlookup mula sa ibang workbook

Sa VLOOKUP sa pagitan ng dalawaworkbook, isama ang pangalan ng file sa mga square bracket, na sinusundan ng pangalan ng sheet at tandang padamdam.

Halimbawa, upang maghanap ng halaga ng A2 sa hanay na A2:B6 sa Ene sheet sa ang workbook na Sales_reports.xlsx , gamitin ang formula na ito:

=VLOOKUP(A2, [Sales_reports.xlsx]Jan!$A$2:$B$6, 2, FALSE)

Para sa buong detalye, pakitingnan ang VLOOKUP mula sa isa pang workbook sa Excel.

Vlookup sa kabuuan maraming sheet na may IFERROR

Kapag kailangan mong maghanap sa pagitan ng higit sa dalawang sheet, ang pinakamadaling solusyon ay ang paggamit ng VLOOKUP kasama ng IFERROR. Ang ideya ay mag-nest ng ilang function ng IFERROR upang suriin ang maramihang worksheet nang paisa-isa: kung ang unang VLOOKUP ay hindi makahanap ng tugma sa unang sheet, maghanap sa susunod na sheet, at iba pa.

IFERROR(VLOOKUP(…), IFERROR(VLOOKUP(…), …, " Not found "))

Upang makita kung paano gumagana ang diskarteng ito sa totoong buhay na data, isaalang-alang natin ang sumusunod na halimbawa. Nasa ibaba ang talahanayang Buod na gusto naming punan ng mga pangalan at halaga ng item sa pamamagitan ng paghahanap sa numero ng order sa Kanluran at Silangan na mga sheet:

Una, hihilahin natin ang mga item. Para dito, itinuturo namin ang VLOOKUP formula na hanapin ang order number sa A2 sa East sheet at ibalik ang value mula sa column B (2nd column sa table_array A2:C6). Kung walang mahanap na eksaktong tugma, pagkatapos ay maghanap sa West sheet. Kung nabigo ang parehong Vlookup, ibalik ang "Not found".

=IFERROR(VLOOKUP(A2, East!$A$2:$C$6, 2, FALSE), IFERROR(VLOOKUP(A2, West!$A$2:$C$6, 2, FALSE), "Not found"))

Upang ibalik ang halaga,baguhin lang ang column index number sa 3:

=IFERROR(VLOOKUP(A2, East!$A$2:$C$6, 3, FALSE), IFERROR(VLOOKUP(A2, West!$A$2:$C$6, 3, FALSE), "Not found"))

Tip. Kung kinakailangan, maaari mong tukuyin ang iba't ibang mga array ng talahanayan para sa iba't ibang mga function ng VLOOKUP. Sa halimbawang ito, ang parehong lookup sheet ay may parehong bilang ng mga row (A2:C6), ngunit maaaring magkaiba ang laki ng iyong mga worksheet.

Vlookup sa maraming workbook

Upang Vlookup sa pagitan ng dalawa o higit pang workbook, ilakip ang pangalan ng workbook sa mga square bracket at ilagay ito bago ang pangalan ng sheet. Halimbawa, narito kung paano mo magagawa ang Vlookup sa dalawang magkaibang file ( Book1 at Book2 ) na may iisang formula:

=IFERROR(VLOOKUP(A2, [Book1.xlsx]East!$A$2:$C$6, 2, FALSE), IFERROR(VLOOKUP(A2, [Book2.xlsx]West!$A$2:$C$6, 2, FALSE),"Not found"))

Gawing dynamic ang column index number sa Vlookup na maraming column

Sa sitwasyon kung kailan kailangan mong ibalik ang data mula sa ilang column, ang paggawa ng col_index_num dynamic ay maaaring makatipid sa iyo ng ilang oras. Mayroong ilang mga pagsasaayos na gagawin:

• Para sa argumentong col_index_num , gamitin ang COLUMNS function na nagbabalik ng bilang ng mga column sa isang tinukoy na array: COLUMNS($A$1 :B$1). (Hindi talaga mahalaga ang row coordinate, maaari itong maging anumang row.)
• Sa lookup_value argument, i-lock ang column reference gamit ang $ sign ($A2), para manatili ito naayos kapag kinopya ang formula sa iba pang column.

Bilang resulta, makakakuha ka ng isang uri ng dynamic na formula na kumukuha ng mga tumutugmang value mula sa iba't ibang column, depende sa kung saang column ang formula ay kinopya sa:

=IFERROR(VLOOKUP($A2, East!$A$2:$C$6, COLUMNS($A$1:B$1), FALSE), IFERROR(VLOOKUP($A2, West!$A$2:$C$6, COLUMNS($A$1:B$1), FALSE), "Not found"))

Kapag ipinasok sa column B, COLUMNS ($A$1:B$1)nagsusuri sa 2 na nagsasabi sa VLOOKUP na magbalik ng value mula sa ika-2 column sa array ng talahanayan.

Kapag nakopya sa column C (ibig sabihin, na-drag mo ang formula mula B2 hanggang C2), ang B$1 ay nagbabago sa C$1 dahil kamag-anak ang sanggunian sa hanay. Dahil dito, nagsusuri ang COLUMNS($A$1:C$1) sa 3 na pinipilit ang VLOOKUP na magbalik ng value mula sa ika-3 column.

Mahusay na gumagana ang formula na ito para sa 2 - 3 lookup sheet. Kung mayroon kang higit pa, ang mga paulit-ulit na IFERROR ay nagiging masyadong masalimuot. Ang susunod na halimbawa ay nagpapakita ng medyo mas kumplikado ngunit mas eleganteng diskarte.

Vlookup maramihang mga sheet na may INDIRECT

Isa pang paraan upang Vlookup sa pagitan ng maraming mga sheet sa Excel ay ang paggamit ng kumbinasyon ng VLOOKUP at INDIRECT functions. Ang pamamaraang ito ay nangangailangan ng kaunting paghahanda, ngunit sa huli, magkakaroon ka ng mas compact na formula sa Vlookup sa anumang bilang ng mga spreadsheet.

Ang isang generic na formula sa Vlookup sa mga sheet ay ang sumusunod:

VLOOKUP( lookup_value , INDIRECT("'"&INDEX( Lookup_sheets , MATCH(1, --(COUNTIF(INDIRECT("'" & Lookup_sheets & " '! lookup_range "), lookup_value )>0), 0)) & "'! table_array "), col_index_num , FALSE)

Saan:

• Lookup_sheets - isang pinangalanang hanay na binubuo ng mga pangalan ng lookup sheet.
• Lookup_value - ang value na hahanapin.
• Lookup_range - ang hanay ng column sa mga lookup sheet kung saan hahanapin ang lookupvalue.
• Table_array - ang hanay ng data sa mga lookup sheet.
• Col_index_num - ang numero ng column sa hanay ng talahanayan kung saan pupunta magbalik ng value.

Para gumana nang tama ang formula, pakitandaan ang mga sumusunod na caveat:

• Ito ay isang array formula, na dapat kumpletuhin sa pamamagitan ng pagpindot sa Ctrl + Magkasama ang Shift + Enter key.
• Ang lahat ng sheet ay dapat magkaroon ng parehong pagkakasunud-sunod ng mga column .
• Habang gumagamit kami ng isang table array para sa lahat ng lookup sheet, tukuyin ang pinakamalaking hanay kung ang iyong mga sheet ay may iba't ibang bilang ng mga row.

Paano gamitin ang formula sa Vlookup sa mga sheet

Upang Vlookup ng maramihang mga sheet sa isang pagkakataon, isagawa ang mga ito hakbang:

1. Isulat ang lahat ng pangalan ng lookup sheet sa isang lugar sa iyong workbook at pangalanan ang hanay na iyon ( Lookup_sheets sa aming kaso).

Isaayos ang generic na formula para sa iyong data. Sa halimbawang ito, tayo ay:

• maghahanap ng A2 value ( lookup_value )
• sa range A2:A6 ( lookup_range ) sa apat na worksheet ( Silangan , Hilaga , Timog at Kanluran ), at
• hilahin ang mga katumbas na halaga mula sa column B, na column 2 ( col_index_num ) sa hanay ng data A2:C6 ( table_array ).

Gamit ang mga argumento sa itaas, ang formula ay ganito ang hugis:

=VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'"& Lookup_sheets&"'!$A$2:$A$6"), $A2)>0), 0)) &"'!$A$2:$C$6"), 2, FALSE)

Pakipansin na ni-lock namin ang parehong mga saklaw ($A$2:$A$6 at $A$2:$C$6) na may ganap na mga sanggunian sa cell.

Ipasok ang pormulasa pinakatuktok na cell (B2 sa halimbawang ito) at pindutin ang Ctrl + Shift + Enter upang kumpletuhin ito.

I-double click o i-drag ang fill handle upang kopyahin ang formula pababa sa column.

Bilang ang resulta, mayroon kaming formula upang hanapin ang numero ng order sa 4 na sheet at makuha ang kaukulang item. Kung ang isang partikular na numero ng order ay hindi nakita, ang isang #N/A error ay ipinapakita tulad ng sa row 14:

Upang ibalik ang halaga, palitan lang ang 2 ng 3 sa col_index_num argument bilang ang mga halaga ay nasa ika-3 column ng array ng talahanayan:

=VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'" & Lookup_sheets & "'!$A$2:$A$6"), $A2)>0), 0)) & "'!$A$2:$C$6"), 3, FALSE)

Kung gusto mong palitan ang karaniwang #N/A error notation ng sarili mong text, balutin ang formula sa IFNA function:

=IFNA(VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'" & Lookup_sheets & "'!$A$2:$A$6"), $A2)>0), 0)) & "'!$A$2:$C$6"), 3, FALSE), "Not found")

Vlookup maramihang sheet sa pagitan ng mga workbook

Maaari ding gamitin ang generic na formula na ito (o ang anumang variation nito) sa Vlookup ng maraming sheet sa isang ibang workbook . Para dito, pagsamahin ang pangalan ng workbook sa loob ng INDIRECT tulad ng ipinapakita sa formula sa ibaba:

=IFNA(VLOOKUP($A2, INDIRECT("'[Book1.xlsx]" & INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'[Book1.xlsx]" & Lookup_sheets & "'!$A$2:$A$6"), $A2)>0), 0)) & "'!$A$2:$C$6"), 2, FALSE), "Not found")

Vlookup sa pagitan ng mga sheet at magbalik ng maraming column

Kung gusto mong kumuha ng data mula sa ilang columns, magagawa iyon ng multi-cell array formula nang sabay-sabay. Upang lumikha ng ganoong formula, magbigay ng array constant para sa col_index_num argument.

Sa halimbawang ito, nais naming ibalik ang mga pangalan ng item (column B) at mga halaga (column C), na ay ang ika-2 at ika-3 column sa hanay ng talahanayan, ayon sa pagkakabanggit. Kaya, ang kinakailangang array ay{2,3}.

=VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'"& Lookup_sheets &"'!$A$2:$C$6"), $A2)>0), 0)) &"'!$A$2:$C$6"), {2,3}, FALSE)

Upang maipasok nang tama ang formula sa maraming cell, ito ang kailangan mong gawin:

• Sa unang hilera, piliin ang lahat ng mga cell na mapo-populate (B2:C2 sa aming halimbawa).
• I-type ang formula at pindutin ang Ctrl + Shift + Enter . Ilalagay nito ang parehong formula sa mga napiling cell, na magbabalik ng ibang value sa bawat column.
• I-drag pababa ang formula sa natitirang mga row.

Paano gumagana ang formula na ito

Upang mas maunawaan ang logic, hatiin natin ang pangunahing formula na ito sa mga indibidwal na function:

=VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'"& Lookup_sheets&"'!$A$2:$A$6"), $A2)>0), 0)) &"'!$A$2:$C$6"), 2, FALSE)

Gumagawa mula sa loob palabas, narito kung ano ang ginagawa ng formula:

COUNTIF at INDIRECT

Sa madaling sabi, INDIRECT ang bumubuo ng mga reference para sa lahat ng lookup sheet, at binibilang ng COUNTIF ang mga paglitaw ng lookup value (A2) sa bawat sheet:

--(COUNTIF( INDIRECT("'"&Lookup_sheets&"'!$A$2:$A$6"), $A2)>0)

Sa higit pang detalye:

Una, pagsasama-samahin mo ang pangalan ng range (Lookup_sheets) at ang reference ng range ($A$2: $A$6), pagdaragdag ng mga kudlit at tandang padamdam sa mga tamang lugar para gumawa ng panlabas na sanggunian, at i-feed ang resultang text string sa INDIRECT na function upang dynamic na sumangguni sa mga lookup sheet:

INDIRECT({"'East'!$A$2:$A$6"; "'South'!$A$2:$A$6"; "'North'!$A$2:$A$6"; "'West'!$A$2:$A$6"})

Sinusuri ng COUNTIF ang bawat cell sa hanay na A2:A6 sa bawat lookup sheet laban sa halaga sa A2 sa pangunahing sheet at ibinabalik ang bilang ng mga tugma para sa bawat sheet. Sa aming dataset, ang order number sa A2 (101) ay makikita sa West sheet, na ika-4 sapinangalanang range, kaya ibinabalik ng COUNTIF ang array na ito:

{0;0;0;1}

Susunod, ihahambing mo ang bawat elemento ng array sa itaas na may 0:

--({0; 0; 0; 1}>0)

Ito ay magbubunga isang array ng TRUE (higit sa 0) at FALSE (katumbas ng 0) na mga halaga, na pinipilit mo sa 1 at 0 sa pamamagitan ng paggamit ng double unary (--), at makuha ang sumusunod na array bilang resulta:

{0; 0; 0; 1}

Ang operasyong ito ay isang karagdagang pag-iingat upang mahawakan ang isang sitwasyon kapag ang isang lookup sheet ay naglalaman ng ilang mga paglitaw ng halaga ng paghahanap, kung saan ang COUNTIF ay magbabalik ng isang bilang na higit sa 1, habang ang gusto lang namin ay 1 at 0 sa huling array (sa isang sandali, mauunawaan mo kung bakit).

Pagkatapos ng lahat ng mga pagbabagong ito, ang aming formula ay ganito ang hitsura:

VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, {0;0;0;1} , 0)) &"'!$A$2:$C$6"), 2, FALSE)

INDEX at MATCH

Sa puntong ito, ang isang klasikong kumbinasyon ng INDEX MATCH ay hakbang sa:

INDEX(Lookup_sheets, MATCH(1, {0;0;0;1}, 0))

Ang MATCH function na na-configure para sa eksaktong tugma (0 sa huling argumento) ay naghahanap ng value 1 sa array { 0;0;0;1} at ibinabalik ang posisyon nito, na 4:

INDEX(Lookup_sheets, 4)

Ginagamit ng INDEX function ang numerong ibinalik sa pamamagitan ng MATCH bilang argumento ng row number (row_num), at ibinabalik ang ika-4 na value sa pinangalanang hanay na Lookup_sheets , na West .

Kaya, ang formula ay lalong bumababa sa:

VLOOKUP($A2, INDIRECT("'"&" West "&"'!$A$2:$C$6"), 2, FALSE)

VLOOKUP at INDIRECT

Pinoproseso ng INDIRECT function ang text string sa loob nito:

INDIRECT("'"&"West"&"'!$A$2:$C$6")

At kino-convert ito sa isang reference na napupunta sa table_array argument ng