Sa tutorial na ito, titingnan natin kung paano gamitin ang mga function ng IFERROR at VLOOKUP nang magkasama upang ma-trap at mahawakan ang iba't ibang error. Bilang karagdagan, matututuhan mo kung paano gumawa ng mga sunud-sunod na vlookup sa Excel sa pamamagitan ng paglalagay ng maraming function ng IFERROR sa isa't isa.

Excel VLOOKUP at IFERROR - ang dalawang function na ito ay maaaring medyo mahirap unawain nang magkahiwalay, lalo na kapag pinagsama ang mga ito. Sa artikulong ito, makakahanap ka ng ilang madaling sundan na mga halimbawa na tumutugon sa mga karaniwang gamit at malinaw na naglalarawan ng lohika ng mga formula.

Kung wala kang gaanong karanasan sa mga function ng IFERROR at VLOOKUP, maaaring ito ay magandang ideya na baguhin muna ang kanilang mga pangunahing kaalaman sa pamamagitan ng pagsunod sa mga link sa itaas.

IFERROR VLOOKUP na formula upang mahawakan ang #N/A at iba pang mga error

Kapag nabigo ang Excel Vlookup na mahanap isang lookup value, naglalabas ito ng #N/A error, tulad nito:

Depende sa iyong mga pangangailangan sa negosyo, maaaring gusto mong itago ang error gamit ang sarili mong text, zero , o isang blangkong cell.

Halimbawa 1. IFERROR na may VLOOKUP formula para palitan ang mga error ng sarili mong text

Kung gusto mong palitan ang karaniwang error notation ng iyong custom na text, balutin ang iyong VLOOKUP formula sa IFERROR, at i-type ang anumang text na gusto mo sa 2nd argument ( value_if_error ), halimbawa "Not found":

Gamit ang lookup value sa B2 sa Main table at ang lookup range A2:B4 sa Lookuptalahanayan, ang formula ay may sumusunod na hugis:

=IFERROR(VLOOKUP(B2,'Lookup table'!$A$2:$B$5, 2, FALSE), "Not found")

Ipinapakita ng screenshot sa ibaba ang aming Excel IFERROR VLOOKUP formula na gumagana:

Ang ang resulta ay mukhang mas naiintindihan at hindi gaanong nakakatakot, hindi ba?

Sa katulad na paraan, maaari mong gamitin ang INDEX MATCH kasama ng IFERROR:

=IFERROR(INDEX('Lookup table'!$B$2:$B$5,MATCH(B2,'Lookup table'!$A$2:$A$5,0)), "Not found")

Ang IFERROR Ang formula ng INDEX MATCH ay lalong kapaki-pakinabang kapag gusto mong kumuha ng mga value mula sa isang column na nasa kaliwa ng lookup column (kaliwang lookup), at ibalik ang iyong sariling text kapag walang nakita.

Halimbawa 2. IFERROR na may Ang VLOOKUP upang ibalik ang blangko o 0 kung walang makita

Kung ayaw mong magpakita ng anuman kapag hindi nahanap ang halaga ng paghahanap, hayaang magpakita ang IFERROR ng walang laman na string (""):

Sa aming halimbawa, ang formula ay ganito:

=IFERROR(VLOOKUP(B2,'Lookup table'!$A$2:$B$5, 2, FALSE), "")

Gaya ng nakikita mo, wala itong ibinabalik kapag ang halaga ng paghahanap ay wala sa listahan ng paghahanap.

Kung gusto mong palitan ang error ng zero value , ilagay 0 sa huling a rgument:

=IFERROR(VLOOKUP(B2,'Lookup table'!$A$2:$B$5, 2, FALSE), 0)

Salita ng pag-iingat! Ang Excel IFERROR function ay nakakakuha ng lahat ng uri ng mga error, hindi lamang #N/A. Ito ba ay mabuti o masama? Ang lahat ay nakasalalay sa iyong layunin. Kung nais mong i-mask ang lahat ng posibleng mga error, IFERROR Vlookup ay ang paraan upang pumunta. Ngunit maaaring ito ay isang hindi matalinong pamamaraan sa maraming sitwasyon.

Halimbawa, kung nakagawa ka ng pinangalanang hanay para sa iyong data ng talahanayan, at mali ang spelling ng pangalang iyon sa iyongVlookup formula, si IFERROR ay kukuha ng #NAME? error at palitan ito ng "Not found" o anumang iba pang text na ibibigay mo. Bilang resulta, maaaring hindi mo alam na ang iyong formula ay naghahatid ng mga maling resulta maliban kung ikaw mismo ang makakita ng typo. Sa ganoong kaso, ang isang mas makatwirang diskarte ay ang pag-trap lamang ng mga #N/A na error. Para dito, gamitin ang IFNA Vlookup formula sa Excel 2013 at mas mataas, IF ISNA VLOOKUP sa lahat ng Excel versions.

Ang bottom line ay: maging maingat kapag pumipili ng kasama para sa iyong VLOOKUP formula :)

Nest IFERROR sa loob ng VLOOKUP para laging makahanap ng isang bagay

Isipin ang sumusunod na sitwasyon: naghahanap ka ng isang partikular na value sa isang listahan at hindi mo ito nakita. Anong mga pagpipilian ang mayroon ka? Maaaring makakuha ng N/A error o ipakita ang iyong sariling mensahe. Sa totoo lang, may pangatlong opsyon - kung ang iyong pangunahing vlookup ay natitisod, pagkatapos ay maghanap ng ibang bagay na tiyak na naroroon!

Sa higit pang halimbawa, gumawa tayo ng ilang uri ng dashboard para sa aming mga user na magpapakita sa kanila ng extension bilang ng isang tiyak na opisina. Isang bagay na ganito:

Kaya, paano mo kukunin ang extension mula sa column B batay sa numero ng opisina sa D2? Gamit ang regular na formula ng Vlookup na ito:

=VLOOKUP($D$2,$A$2:$B$7,2,FALSE)

At gagana ito nang maayos hangga't nagpasok ang iyong mga user ng wastong numero sa D2. Ngunit paano kung ang isang gumagamit ay nag-input ng ilang numero na hindi umiiral? Sa kasong ito, hayaan silang tumawag sa sentral na tanggapan! Para dito, i-embed mo ang formula sa itaas sa value argument ng IFERROR, at maglagay ng isa pang Vlookup sa value_if_error argument.

Medyo mahaba ang kumpletong formula, ngunit gumagana ito nang perpekto:

=IFERROR(VLOOKUP("office "&$D$2,$A$2:$B$7,2,FALSE),VLOOKUP("central office",$A$2:$B$7,2,FALSE))

Kung mahanap ang numero ng opisina, makukuha ng user ang kaukulang numero ng extension:

Kung hindi mahanap ang numero ng opisina, ang extension ng sentral na opisina ay ipinapakita:

Upang gawing mas compact ang formula, maaari kang gumamit ng ibang diskarte:

Una, tingnan kung naroroon ang numero sa D2 sa hanay ng paghahanap (pakipansin na itinakda namin ang col_index_num sa 1 para sa formula upang maghanap at magbalik ng halaga mula sa hanay A): VLOOKUP(D2,$A$2:$B$7,1,FALSE)

Kung hindi mahanap ang tinukoy na numero ng opisina, hahanapin namin ang string na "central office", na tiyak na nasa listahan ng paghahanap. Para dito, ibalot mo ang unang VLOOKUP sa IFERROR at ilalagay ang buong kumbinasyong ito sa loob ng isa pang function ng VLOOKUP:

=VLOOKUP(IFERROR(VLOOKUP(D2,$A$2:$B$7,1,FALSE),"central office"),$A$2:$B$7,2)

Well, isang bahagyang naiibang formula, ang parehong resulta:

Ngunit ano ang dahilan upang maghanap ng "central office", maaari mong itanong sa akin. Bakit hindi direktang ibigay ang extension number sa IFERROR? Dahil maaaring magbago ang extension sa isang punto sa hinaharap. Kung mangyari ito, kailangan mong i-update ang iyong data nang isang beses lang sa source table, nang hindi nababahala tungkol sa pag-update ng bawat isa sa iyong mga VLOOKUP formula.

Paano gumawa ng mga sunud-sunod na VLOOKUP sa Excel

Sa mga sitwasyon kung kailan kailangan monggawin ang tinatawag na sequential o chained Vlookups sa Excel depende sa kung nagtagumpay o nabigo ang isang naunang lookup, mag-nest ng dalawa o higit pang mga function ng IFERROR upang patakbuhin ang iyong Vlookups nang isa-isa:

Ang Gumagana ang formula sa sumusunod na lohika:

Kung ang unang VLOOKUP ay walang mahanap, ang unang IFERROR ay na-trap ng isang error at nagpapatakbo ng isa pang VLOOKUP. Kung ang pangalawang VLOOKUP ay nabigo, ang pangalawang IFERROR ay nakakakuha ng isang error at pinapatakbo ang ikatlong VLOOKUP, at iba pa. Kung natitisod ang lahat ng Vlookup, ibabalik ng huling IFERROR ang iyong mensahe.

Lalong kapaki-pakinabang ang nested IFERROR formula na ito kapag kailangan mong mag-Vlookup sa maraming sheet gaya ng ipinapakita sa halimbawa sa ibaba.

Sabihin natin, mayroon kang tatlong listahan ng homogenous na data sa tatlong magkakaibang worksheet (mga numero ng opisina sa halimbawang ito), at gusto mong makakuha ng extension para sa isang partikular na numero.

Ipagpalagay na ang lookup value ay nasa cell A2 sa kasalukuyang sheet, at ang hanay ng paghahanap ay A2:B5 sa 3 magkakaibang worksheet (North, South at West), gumagana ang sumusunod na formula:

=IFERROR(VLOOKUP(A2,North!$A$2:$B$5,2,FALSE), IFERROR(VLOOKUP(A2,South!$A$2:$B$5,2,FALSE), IFERROR(VLOOKUP(A2,West!$A$2:$B$5,2,FALSE),"Not found")))

Kaya, ang aming "chained Ang Vlookups" na formula ay naghahanap sa tatlong magkakaibang mga sheet sa pagkakasunud-sunod na ginawa namin ang mga ito sa formula, at dinadala ang unang tugma na nahanap nito:

Ganito mo ginagamit ang IFERROR sa VLOOKUP sa Excel. Salamat sa pagbabasa at sana makita kitasa aming blog sa susunod na linggo!

Mga available na download

Mga halimbawa ng formula ng Excel IFERROR VLOOKUP