Ingawa idadi ya maneno na herufi katika Majedwali ya Google hutumiwa mara chache sana, bado ni utendaji ambao baadhi yetu tunatarajia kuuona kwenye menyu. Lakini tofauti na Hati za Google, kwa Majedwali ya Google, ni kipengele cha LEN kinachofanya hivyo.

Ingawa kuna njia nyingi tofauti za kuhesabu herufi katika lahajedwali, chapisho la leo la blogu litashughulikia utendaji wa LEN kama wake. Kusudi kuu katika majedwali ni - vizuri, kuhesabu :) Hata hivyo, ni vigumu sana kutumika peke yake. Hapa chini utajifunza jinsi ya kutumia LEN ya Majedwali ya Google kwa usahihi na kupata fomula zinazohitajika zaidi kukokotoa herufi katika lahajedwali.

Kitendaji cha LEN cha Majedwali ya Google - matumizi na sintaksia

The kuu na madhumuni pekee ya chaguo za kukokotoa za LEN katika Majedwali ya Google ni kupata urefu wa kamba. Ni rahisi sana hata inahitaji hoja 1 pekee:

• inaweza kuchukua maandishi yenyewe katika nukuu mbili:

  =LEN("Yggdrasil")

• au rejeleo la kisanduku chenye maandishi ya kuvutia:

  =LEN(A2)

Hebu tuone kama kuna mambo maalum katika kutumia chaguo la kukokotoa katika lahajedwali.

Tabia.

Tabia. count katika Majedwali ya Google

Nitaanza na operesheni rahisi zaidi: hesabu herufi katika Majedwali ya Google kwa njia ya kawaida zaidi - kwa kurejelea kisanduku chenye maandishi kwa kutumia chaguo la kukokotoa la LEN.

I. ingiza fomula kwa B2 na uinakili chini ya safu wima nzima ili kuhesabu herufi katika kila safu:

=LEN(A2)

Kumbuka. Kazi ya LENhukokotoa herufi zote: herufi, nambari, nafasi, alama za uakifi, n.k.

Unaweza kufikiri kwamba kwa njia sawa unaweza kufanya hesabu ya herufi kwa safu nzima ya visanduku, kama hii: LEN(A2:A6) . Lakini, kama jinsi ilivyo ya ajabu, haifanyi kazi kwa njia hii tu.

Ili jumla ya vibambo katika visanduku kadhaa, unafaa kufunika LEN yako katika SUMPRODUCT - chaguo la kukokotoa linalojumlisha nambari kutoka kwa visanduku vilivyoingizwa. Kwa upande wangu, masafa yanarejeshwa na chaguo la kukokotoa la LEN:

=SUMPRODUCT(LEN(A2:A6))

Bila shaka, unaweza kujumuisha chaguo la kukokotoa la SUM badala yake. Lakini SUM katika Majedwali ya Google haichakati safu kutoka kwa vitendaji vingine. Ili kuifanya ifanye kazi, utahitaji kuongeza chaguo jingine la kukokotoa - ArrayFormula:

=ArrayFormula(SUM(LEN(A2:A6)))

Jinsi ya kuhesabu herufi bila nafasi katika Majedwali ya Google

Kama nilivyobainisha hapo juu, Majedwali ya Google. Chaguo za kukokotoa za LEN huhesabu kila herufi inayoona ikijumuisha nafasi.

Lakini vipi ikiwa kuna nafasi za ziada zilizoongezwa kimakosa na hutaki kuzizingatia kwa matokeo?

Kwa kesi kama hii, kuna chaguo la kukokotoa TRIM katika Majedwali ya Google. Hukagua maandishi kwa nafasi zinazoongoza, zinazofuata na zinazorudiwa kati. TRIM inapooanishwa na LEN, ya pili haihesabu nafasi hizo zote zisizo za kawaida.

Huu hapa ni mfano. Niliongeza nafasi katika nafasi tofauti katika safu wima A. Kama unavyoona, ikiwa peke yake, Majedwali ya Google LEN huhesabu yote:

=LEN(A2)

Lakini mara tu unapounganisha TRIM, yote ya ziada nafasi zipoimepuuzwa:

=LEN(TRIM(A2))

Unaweza kwenda mbali zaidi na kufanya fomula yako isizingatie hata hizo nafasi moja kati ya maneno. Chaguo za kukokotoa SUBSTITUTE zitasaidia. Ingawa kusudi lake kuu ni kubadilisha herufi moja na nyingine, kuna mbinu ya kuifanya ipunguze nafasi kabisa:

• text_to_search ndio safu unayofanya kazi nayo: safu wima A, au A2 kuwa sawa.
• search_for inapaswa kuwa herufi ya nafasi katika nukuu mbili: " "
• badilisha_na inapaswa kuwa na nukuu mbili tupu. Iwapo utapuuza nafasi, unahitaji kuzibadilisha bila kitu chochote (kamba tupu): ""
• occurence_number kwa kawaida hutumiwa kubainisha mfano. kuchukua nafasi ya. Lakini kwa kuwa ninaelezea jinsi ya kuhesabu herufi bila nafasi zote, ninapendekeza uache hoja hii kwa kuwa ni ya hiari.

Sasa jaribu na kukusanya hizi zote kwenye Majedwali ya Google LEN na utaona hilo. hakuna nafasi inayozingatiwa:

=LEN(SUBSTITUTE(A2, " ", ""))

Majedwali ya Google: hesabu herufi mahususi

Sambamba sawa na Majedwali ya Google LEN na SUBSTITUTE hutumika wakati wowote unapohitaji kuhesabu herufi mahususi. , herufi, au nambari.

Katika mifano yangu, nitatafuta idadi ya matukio ya herufi 's'. Na wakati huu, nitaanza na formula iliyotengenezwa tayari:

=LEN(A2)-LEN(SUBSTITUTE(A2, "s", ""))

Hebu tuigawanye vipande vipande ili kuelewa jinsi inavyofanya.inafanya kazi:

1. SUBSTITUTE(A2, "s", "") hutafuta herufi 's' katika A2 na kuchukua nafasi ya matukio yote kwa "hakuna chochote", au kamba tupu ( "").
2. LEN(SUBSTITUTE(A2, "s", "") hutatua idadi ya vibambo vyote lakini 's' katika A2.
3. 1>LEN(A2) huhesabu herufi zote katika A2.
4. Mwishowe, unaondoa moja kutoka kwa nyingine.

Tofauti ya matokeo inaonyesha ni 's' ngapi. kwenye seli:

Kumbuka. Unaweza kushangaa kwa nini B1 inasema kuna 's' 1 pekee katika A2 huku unaweza kuona 3?

Jambo ni kwamba, chaguo la kukokotoa SUBSTITUTE ni nyeti kwa hali. Niliiomba ichukue matukio yote ya 's' kwa herufi ndogo na ndivyo ilifanya.

Ili kuifanya ipuuze herufi za maandishi na kuchakata herufi katika herufi ndogo na kubwa, itabidi upige simu nyingine ya chaguo la kukokotoa la Majedwali ya Google. kwa usaidizi: CHINI.

Kidokezo. Angalia njia zingine za kubadilisha muundo wa maandishi katika Majedwali ya Google.

Ni rahisi kama Majedwali ya Google LEN na TRIM kwa sababu inachohitaji ni maandishi tu:

=LOWER(text)

Na inachofanya ni kugeuza mfuatano wote wa maandishi kuwa ndani o herufi ndogo. Ujanja huu ndio hasa unahitaji kufanya Majedwali ya Google kuhesabu herufi mahususi bila kujali muundo wao wa maandishi:

=LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "s", ""))

Kidokezo. Na kama hapo awali, ili kuhesabu jumla ya herufi mahususi katika safu, funga LEN yako katika SUMPRODUCT:

=SUMPRODUCT(LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "s", "")))

Hesabu maneno katika Majedwali ya Google

Ikiwa hapo ni maneno mengi katika seli, kuna uwezekano utahitaji kuwa na nambari yao badala yaurefu wa mfuatano wa Majedwali ya Google.

Na ingawa kuna njia nyingi za kufanya hivyo, leo nitataja jinsi Majedwali ya Google LEN yanavyofanya kazi.

Kumbuka fomula niliyotumia kuhesabu herufi mahususi Majedwali ya Google? Kwa kweli, itakuja kwa manufaa hapa pia. Kwa sababu sitaenda kuhesabu maneno kihalisi. Badala yake, nitahesabu idadi ya nafasi kati ya maneno na kisha kuongeza 1. Angalia:

=LEN(A2)-LEN(SUBSTITUTE((A2), " ", ""))+1

1. LEN(A2) inahesabu idadi ya herufi zote kwenye kisanduku.
2. LEN(SUBSTITUTE((A2)," ","")) huondoa nafasi zote kutoka kwa mfuatano wa maandishi na kuhesabu herufi zilizosalia.
3. Kisha unaondoa moja kutoka kwa nyingine, na tofauti unayopata ni idadi ya nafasi katika seli.
4. Kwa kuwa maneno kila mara huzidi nafasi katika sentensi kwa moja, unaongeza 1 mwishoni.

Majedwali ya Google: hesabu maneno mahususi

Mwishowe, ningependa kushiriki fomula ya Majedwali ya Google ambayo unaweza kutumia kuhesabu maneno mahususi.

Hapa ninayo Wimbo wa The Mock Turtle kutoka kwa Alice's Adventures in Wonderland:

Nataka kujua ni mara ngapi neno 'mapenzi' linatokea katika kila safu mlalo. Ninaamini hutashangaa nikikuambia kuwa fomula ninayohitaji ina utendakazi sawa na hapo awali: Majedwali ya Google LEN, SUBSTITUTE, na LOWER:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "will", "")))/LEN("will")

Fomula inaweza inaonekana inatisha lakini ninaweza kukuhakikishia kuwa ni rahisi kuelewa, kwa hivyo nivumilie :)

1. Kwa kuwa kesi ya maandishi haifanyi kazi.jambo kwangu, mimi hutumia LOWER(A2) kugeuza kila kitu kuwa herufi ndogo.
2. Kisha huenda SUBSTITUTE(LOWER(A2), "will",""))) 2> - huondoa utokeaji wote wa 'will' kwa kuzibadilisha na mifuatano tupu ("").
3. Baada ya hapo, mimi huondoa idadi ya herufi bila neno 'will' kutoka kwa jumla ya urefu wa kamba. . Nambari ninayopata huhesabu herufi zote katika matukio yote ya 'mapenzi' katika kila safu.

   Kwa hivyo, ikiwa 'will' itaonekana mara moja, nambari ni 4 kwani kuna herufi 4 katika neno. Ikiwa inaonekana mara mbili, nambari ni 8, na kadhalika.

4. Mwishowe, ninagawanya nambari hii kwa urefu wa neno moja 'will'.

Kidokezo. Na tena, ikiwa ungependa kupata jumla ya idadi ya mwonekano wote wa neno 'will', ambatisha fomula nzima kwa SUMPRODUCT:

=SUMPRODUCT((LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "will", "")))/LEN("will"))

Kama unavyoona. , matukio haya yote ya hesabu ya herufi hutubiwa kwa ruwaza sawa za utendakazi sawa za Majedwali ya Google: LEN, SUBSTITUTE, LOWER, na SUMPRODUCT.

Ikiwa baadhi ya fomula bado zinakuchanganya, au kama huna uhakika jinsi ya kutumia kila kitu kwa kazi yako mahususi, usiogope na kuomba katika sehemu ya maoni hapa chini!