แม้ว่าคำและจำนวนอักขระใน Google ชีตจะถูกใช้ในบางกรณี แต่ก็ยังคงเป็นฟังก์ชันที่เราคาดว่าจะเห็นในเมนู แต่แตกต่างจาก Google เอกสารตรงที่สำหรับ Google ชีต ฟังก์ชัน LEN ทำหน้าที่ดังกล่าว

แม้ว่าจะมีหลายวิธีในการนับอักขระในสเปรดชีต บล็อกโพสต์ของวันนี้จะครอบคลุมฟังก์ชัน LEN ด้วย จุดประสงค์หลักในตารางคือการ - นับ :) อย่างไรก็ตาม แทบจะไม่ได้ใช้เลย ด้านล่างนี้ คุณจะได้เรียนรู้วิธีใช้ Google ชีต LEN อย่างถูกต้อง และค้นหาสูตรที่ต้องการมากที่สุดในการคำนวณอักขระในสเปรดชีต

ฟังก์ชัน Google ชีต LEN – การใช้งานและไวยากรณ์

หลักและจุดประสงค์เดียวของฟังก์ชัน LEN ใน Google ชีตคือการรับความยาวสตริง ง่ายมากจนต้องการเพียง 1 อาร์กิวเมนต์:

• สามารถใช้ทั้งข้อความในเครื่องหมายคำพูดคู่:

  =LEN("Yggdrasil")

• หรือการอ้างอิงเซลล์ที่มีข้อความที่น่าสนใจ:

  =LEN(A2)

มาดูกันว่าการใช้ฟังก์ชันในสเปรดชีตมีลักษณะเฉพาะหรือไม่

อักขระ นับใน Google ชีต

ฉันจะเริ่มต้นด้วยการดำเนินการที่ง่ายที่สุด: ทำการนับจำนวนอักขระใน Google ชีตด้วยวิธีทั่วไป โดยอ้างอิงเซลล์ด้วยข้อความโดยใช้ฟังก์ชัน LEN

ฉัน ป้อนสูตรไปที่ B2 แล้วคัดลอกลงทั้งคอลัมน์เพื่อนับอักขระในแต่ละแถว:

=LEN(A2)

หมายเหตุ ฟังก์ชัน LENคำนวณอักขระทั้งหมด: ตัวอักษร ตัวเลข ช่องว่าง เครื่องหมายวรรคตอน ฯลฯ

คุณอาจคิดว่าในลักษณะที่คล้ายกัน คุณสามารถนับจำนวนอักขระสำหรับช่วงเซลล์ทั้งหมด เช่น: LEN(A2:A6) แต่เนื่องจาก น่าแปลกที่มันไม่ทำงานด้วยวิธีนี้

ในการรวมอักขระในหลายๆ เซลล์ คุณควรรวม LEN ของคุณไว้ใน SUMPRODUCT ซึ่งเป็นฟังก์ชันที่รวมตัวเลขจากช่วงที่ป้อน ในกรณีของฉัน ฟังก์ชัน LEN จะส่งคืนช่วง:

=SUMPRODUCT(LEN(A2:A6))

แน่นอน คุณสามารถรวมฟังก์ชัน SUM แทนได้ แต่ SUM ใน Google ชีตจะไม่ประมวลผลอาร์เรย์จากฟังก์ชันอื่นๆ เพื่อให้ใช้งานได้ คุณจะต้องเพิ่มฟังก์ชันอื่น – ArrayFormula:

=ArrayFormula(SUM(LEN(A2:A6)))

วิธีนับอักขระที่ไม่มีช่องว่างใน Google ชีต

ดังที่ได้กล่าวไปแล้ว Google ชีต ฟังก์ชัน LEN นับอักขระแต่ละตัวและทุกตัวที่มองเห็นรวมถึงช่องว่างด้วย

แต่จะเกิดอะไรขึ้นหากมีการเพิ่มช่องว่างพิเศษโดยไม่ได้ตั้งใจ และคุณไม่ต้องการพิจารณาช่องว่างเหล่านี้เป็นผลลัพธ์

สำหรับกรณีต่างๆ เช่น นี่คือฟังก์ชัน TRIM ใน Google ชีต ตรวจสอบข้อความสำหรับช่องว่างนำหน้า ต่อท้าย และซ้ำระหว่าง เมื่อ TRIM จับคู่กับ LEN ตัวหลังจะไม่นับช่องว่างคี่เหล่านั้นทั้งหมด

นี่คือตัวอย่าง ฉันได้เพิ่มช่องว่างในตำแหน่งต่างๆ ในคอลัมน์ A อย่างที่คุณเห็น Google ชีต LEN จะนับทั้งหมด:

=LEN(A2)

แต่ทันทีที่คุณผสานรวม TRIM สิ่งที่เพิ่มขึ้นมาทั้งหมด ช่องว่างคือละเว้น:

=LEN(TRIM(A2))

คุณสามารถดำเนินการต่อไปและทำให้สูตรของคุณไม่สนใจแม้แต่ช่องว่างระหว่างคำเหล่านั้น ฟังก์ชัน SUBSTITUTE จะช่วย แม้ว่าจุดประสงค์หลักคือการแทนที่อักขระหนึ่งตัวด้วยอักขระอื่น แต่มีเคล็ดลับในการลดช่องว่างอย่างสมบูรณ์:

• text_to_search คือช่วงที่คุณใช้: คอลัมน์ A หรือ A2 เพื่อความเป๊ะ
• search_for ควรเป็นอักขระเว้นวรรคในเครื่องหมายคำพูดคู่: " "
• replace_with ควรมีเครื่องหมายอัญประกาศว่าง หากคุณจะละเว้นการเว้นวรรค คุณต้องแทนที่ด้วยช่องว่าง (สตริงว่าง): ""
• occurence_number โดยปกติใช้เพื่อระบุอินสแตนซ์ จะเข้ามาแทนที่. แต่เนื่องจากฉันกำลังอธิบายวิธีนับอักขระโดยไม่มีการเว้นวรรค ฉันขอแนะนำให้คุณละเว้นอาร์กิวเมนต์นี้เนื่องจากไม่บังคับ

ตอนนี้ลองรวบรวมสิ่งเหล่านี้ทั้งหมดลงใน Google ชีต LEN แล้วคุณจะเห็นว่า ไม่คำนึงถึงช่องว่าง:

=LEN(SUBSTITUTE(A2, " ", ""))

Google ชีต: นับอักขระเฉพาะ

ใช้ Google ชีต LEN และ SUBSTITUTE ควบคู่กันเมื่อใดก็ตามที่คุณต้องการนับอักขระเฉพาะ ตัวอักษร หรือตัวเลข

ในตัวอย่างของฉัน ฉันจะหาจำนวนครั้งของตัวอักษร 's' และคราวนี้ ฉันจะเริ่มด้วยสูตรสำเร็จรูป:

=LEN(A2)-LEN(SUBSTITUTE(A2, "s", ""))

มาแยกย่อยเป็นส่วนๆ เพื่อทำความเข้าใจว่าทำงาน:

1. SUBSTITUTE(A2, "s", "") ค้นหาตัวอักษร 's' ใน A2 และแทนที่เหตุการณ์ทั้งหมดด้วย "ไม่มีอะไร" หรือสตริงว่าง ( "").
2. LEN(SUBSTITUTE(A2, "s", "") หาจำนวนอักขระทั้งหมดยกเว้น 's' ใน A2
3. LEN(A2) นับอักขระทั้งหมดใน A2
4. สุดท้าย คุณลบหนึ่งตัวออกจากอีกตัว

ผลต่างของผลลัพธ์แสดงจำนวน 's' ที่มี ในเซลล์:

หมายเหตุ คุณอาจสงสัยว่าทำไม B1 ถึงบอกว่ามีเพียง 1 's' ใน A2 ขณะที่คุณเห็น 3 อยู่

ประเด็นคือ ฟังก์ชัน SUBSTITUTE คำนึงถึงตัวพิมพ์เล็กและใหญ่ ฉันขอให้ใช้กรณีทั้งหมดของ 's' เป็นตัวพิมพ์เล็กและเป็นเช่นนั้น

หากต้องการให้มันละเว้นตัวพิมพ์และตัวพิมพ์เล็กทั้งตัวพิมพ์เล็กและตัวพิมพ์ใหญ่ คุณจะต้องเรียกใช้ฟังก์ชัน Google ชีตเพิ่มเติมอีกหนึ่งฟังก์ชัน สำหรับความช่วยเหลือ: LOWER

เคล็ดลับ ดูวิธีอื่นๆ ที่เปลี่ยนตัวพิมพ์ข้อความใน Google ชีต

ทำได้ง่ายๆ เช่นเดียวกับ Google ชีต LEN และ TRIM เพราะสิ่งที่ต้องทำคือข้อความ:

=LOWER(text)

และเพียงแค่เปลี่ยนสตริงข้อความทั้งหมดเป็น int o ตัวพิมพ์เล็ก เคล็ดลับนี้เป็นสิ่งที่คุณต้องใช้เพื่อให้ Google ชีตนับอักขระเฉพาะไม่ว่าจะตัวพิมพ์เล็กหรือใหญ่ก็ตาม:

=LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "s", ""))

เคล็ดลับ และเช่นเดิม หากต้องการนับจำนวนอักขระทั้งหมดในช่วง ให้รวม LEN ของคุณใน SUMPRODUCT:

=SUMPRODUCT(LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "s", "")))

นับคำใน Google ชีต

เมื่อถึงที่นั่น มีหลายคำในเซลล์ มีโอกาสที่คุณจะต้องใช้ตัวเลขแทนความยาวสตริงของ Google ชีต

และแม้ว่าจะมีหลายวิธีในการทำเช่นนั้น แต่วันนี้ฉันจะกล่าวถึงวิธีการทำงานของ Google ชีต LEN

จำสูตรที่ฉันใช้ในการนับอักขระเฉพาะใน Google ชีต? ในความเป็นจริงมันจะมีประโยชน์ที่นี่เช่นกัน เพราะฉันจะไม่นับคำอย่างแท้จริง ฉันจะนับจำนวนช่องว่างระหว่างคำ แล้วเติม 1 ดู:

=LEN(A2)-LEN(SUBSTITUTE((A2), " ", ""))+1

1. LEN(A2) นับ จำนวนตัวอักษรทั้งหมดในเซลล์
2. LEN(SUBSTITUTE((A2)," ","")) ลบช่องว่างทั้งหมดออกจากสตริงข้อความและนับจำนวนตัวอักษรที่เหลืออยู่
3. จากนั้นให้คุณลบหนึ่งคำออกจากอีกคำหนึ่ง และความแตกต่างที่คุณได้รับคือจำนวนช่องว่างในเซลล์
4. เนื่องจากคำต่างๆ มีจำนวนมากกว่าช่องว่างในประโยคเสมอ คุณจึงเพิ่ม 1 ต่อท้าย

Google ชีต: นับคำเฉพาะ

สุดท้าย ฉันต้องการแชร์สูตร Google ชีตที่คุณสามารถใช้เพื่อนับคำเฉพาะ

ฉันมีเพลงของ The Mock Turtle จาก Alice's Adventures in Wonderland:

ฉันอยากรู้ว่าคำว่า 'จะ' ปรากฏในแต่ละแถวกี่ครั้ง ฉันเชื่อว่าคุณจะไม่แปลกใจถ้าฉันบอกคุณว่าสูตรที่ฉันต้องการประกอบด้วยฟังก์ชันเดิม: Google ชีต LEN, SUBSTITUTE และ LOWER:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "will", "")))/LEN("will")

สูตรอาจ ดูน่ากลัวแต่รับรองว่าเข้าใจง่าย อดทนหน่อยนะ :)

1. เนื่องจากตัวพิมพ์ไม่ถนัดสำคัญกับฉัน ฉันใช้ LOWER(A2) เพื่อเปลี่ยนทุกอย่างเป็นตัวพิมพ์เล็ก
2. จากนั้นไปที่ SUBSTITUTE(LOWER(A2), "will",""))) – กำจัด 'will' ที่เกิดขึ้นทั้งหมดด้วยการแทนที่ด้วยสตริงว่าง ("")
3. หลังจากนั้น ฉันจะลบจำนวนอักขระที่ไม่มีคำว่า 'will' ออกจากความยาวสตริงทั้งหมด . จำนวนที่ฉันได้รับจะนับอักขระทั้งหมดใน 'will' ที่เกิดขึ้นทั้งหมดในแต่ละแถว

   ดังนั้น ถ้า 'จะ' ปรากฏขึ้นเพียงครั้งเดียว ตัวเลขคือ 4 เนื่องจากมีตัวอักษร 4 ตัวในคำนั้น หากปรากฏขึ้นสองครั้ง หมายเลขคือ 8 ไปเรื่อยๆ

4. สุดท้าย ฉันจะหารตัวเลขนี้ด้วยความยาวของคำว่า 'จะ' เพียงคำเดียว

เคล็ดลับ และอีกครั้ง หากคุณต้องการทราบจำนวนรวมของคำว่า 'จะ' ทั้งหมด ให้ใส่สูตรทั้งหมดด้วย SUMPRODUCT:

=SUMPRODUCT((LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "will", "")))/LEN("will"))

อย่างที่คุณเห็น กรณีทั้งหมดของการนับอักขระเหล่านี้ได้รับการแก้ไขด้วยรูปแบบเดียวกันของฟังก์ชันเดียวกันสำหรับ Google ชีต: LEN, SUBSTITUTE, LOWER และ SUMPRODUCT

หากสูตรบางสูตรยังทำให้คุณสับสน หรือหากคุณไม่เข้าใจ แน่ใจว่าจะใช้ทุกอย่างอย่างไรกับงานเฉพาะของคุณ อย่าอายและถามในส่วนความคิดเห็นด้านล่าง!