Иако се број речи и знакова у Гоогле табелама користи у ретким случајевима, то је и даље функционалност коју неки од нас очекују да ће видети директно у менију. Али за разлику од Гоогле докумената, за Гоогле табеле то је функција ЛЕН.

Иако постоји много различитих начина за бројање знакова у табелама, данашњи пост на блогу ће покрити функцију ЛЕН као њену главна сврха у табелама је да се – па, броји :) Међутим, ретко се користи самостално. У наставку ћете научити како да правилно користите Гоогле Схеетс ЛЕН и пронађете најтраженије формуле за израчунавање знакова у табелама.

Гоогле Схеетс ЛЕН функција – употреба и синтакса

главна и једина сврха функције ЛЕН у Гоогле табелама је добијање дужине стринга. Толико је једноставно да чак захтева само 1 аргумент:

• може узети или сам текст у двоструким наводницима:

  =LEN("Yggdrasil")

• или референца на ћелију са текстом од интереса:

  =LEN(A2)

Да видимо да ли постоје неке посебности у коришћењу функције у табелама.

Знак цоунт ин Гоогле Схеетс

Почећу са најједноставнијом операцијом: извршите бројање знакова у Гоогле Схеетс на најчешћи начин – упућивањем на ћелију са текстом помоћу функције ЛЕН.

И унесите формулу у Б2 и копирајте је низ целу колону да бисте пребројали знакове у сваком реду:

=LEN(A2)

Напомена. Функција ЛЕНизрачунава све знакове: слова, бројеве, размаке, знакове интерпункције, итд.

Можда мислите да бисте на сличан начин могли да извршите бројање знакова за цео опсег ћелија, овако: LEN(A2:A6) . Али, као колико год да је бизарно, не функционише једноставно на овај начин.

Да бисте збројили знакове у неколико ћелија, требало би да умотате свој ЛЕН у СУМПРОДУЦТ – функцију која збраја бројеве из унетих опсега. У мом случају, опсег враћа ЛЕН функција:

=SUMPRODUCT(LEN(A2:A6))

Наравно, уместо тога можете да уградите функцију СУМ. Али СУМ у Гоогле табелама не обрађује низове из других функција. Да би то функционисало, мораћете да додате још једну функцију – АрраиФормула:

=ArrayFormula(SUM(LEN(A2:A6)))

Како бројати знакове без размака у Гоогле табелама

Као што сам горе напоменуо, Гоогле табеле ЛЕН функција броји сваки знак који види укључујући размаке.

Али шта ако постоје додатни размаци додати грешком и не желите да их узмете у обзир за резултат?

За случајеве као што је ово, постоји функција ТРИМ у Гоогле табелама. Проверава да ли текст има почетне, задње и поновљене размаке између. Када је ТРИМ упарен са ЛЕН, овај други не рачуна све те непарне размаке.

Ево примера. Додао сам размаке на различитим позицијама у колони А. Као што видите, када је самостално, Гоогле табеле ЛЕН их све броји:

=LEN(A2)

Али чим интегришете ТРИМ, све додатне простори суигнорисано:

=LEN(TRIM(A2))

Можете ићи даље и учинити да ваша формула занемари чак и оне појединачне размаке између речи. Функција СУБСТИТУТЕ ће помоћи. Иако је његова главна сврха да замени један знак другим, постоји трик да се потпуно смањи размаци:

• тект_то_сеарцх је опсег са којим радите: колона А, или тачније А2 .
• тражи_за треба да буде размак у наводницима: " „
• реплаце_витх треба да садржи празне двоструке наводнике. Ако ћете игнорисати размаке, морате да их замените буквално ничим (празан стринг): ""
• број_појаве се обично користи за навођење инстанце да замени. Али пошто описујем како да бројим знакове без свих размака, предлажем да изоставите овај аргумент јер је опционалан.

Сада покушајте да све ово саставите у Гоогле табеле ЛЕН и видећете да размак се не узима у обзир:

=LEN(SUBSTITUTE(A2, " ", ""))

Гоогле табеле: број специфичних знакова

Исти тандем Гоогле табела ЛЕН и СУБСТИТУТЕ се користи кад год треба да пребројите одређене знакове , слова или бројеве.

У мојим примерима ћу сазнати број појављивања слова 'с'. И овог пута, почећу са готовом формулом:

=LEN(A2)-LEN(SUBSTITUTE(A2, "s", ""))

Хајде да је разбијемо на делове да разумемо какоради:

1. СУБСТИТУТЕ(А2, "с", "") тражи слово 'с' у А2 и замењује сва појављивања са "ништа", или празним стрингом ( "").
2. ЛЕН(СУБСТИТУТЕ(А2, "с", "") израчунава број свих знакова осим 'с' у А2.
3. ЛЕН(А2) броји све знакове у А2.
4. Коначно, одузимате један од другог.

Разлика резултата показује колико 'с' има у ћелији:

Напомена Можда се питате зашто Б1 каже да има само 1 ' у А2 док ви можете да видите 3?

Ствар је у томе што је функција ЗАМЕНА осетљива на велика и мала слова. Замолио сам га да узме све инстанце 'с' малим словима и тако је и урадио.

Да би игнорисао велика и мала слова и обрађивала слова у малим и великим словима, мораћете да позовете још једну функцију Гоогле табеле за помоћ: ЛОВЕР.

Савет. Погледајте друге начине на које можете променити велика и мала слова у Гоогле табелама.

Једноставно је као Гоогле табеле ЛЕН и ТРИМ јер све што је потребно је текст:

=LOWER(text)

И све што ради је да окреће цео текстуални низ у инт о мала слова. Овај трик је управо оно што вам треба да натерате Гоогле табеле да броје одређене знакове без обзира на њихова велика и мала слова:

=LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "s", ""))

Савет. И као и раније, да бисте пребројали укупан број специфичних знакова у опсегу, умотајте свој ЛЕН у СУМПРОДУЦТ:

=SUMPRODUCT(LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "s", "")))

Број речи у Гоогле табелама

Када постоји су више речи у ћелијама, шансе су да ћете морати да имате њихов број уместодужина стринга Гоогле табела.

И иако постоји више начина да се то уради, данас ћу поменути како Гоогле Схеетс ЛЕН ради свој посао.

Запамтите формулу коју сам користио за бројање одређених знакова у Гоогле табеле? У ствари, и овде ће добро доћи. Јер нећу буквално да бројим речи. Уместо тога, пребројаћу број размака између речи и онда једноставно додати 1. Погледајте:

=LEN(A2)-LEN(SUBSTITUTE((A2), " ", ""))+1

1. ЛЕН(А2) броји број свих знакова у ћелији.
2. ЛЕН(СУБСТИТУТЕ((А2)," ","")) уклања све размаке из текстуалног низа и броји преостале знакове.
3. Онда одузимате једно од другог, а разлика коју добијате је број размака у ћелији.
4. Пошто речи увек премашују размаке у реченици за један, додајете 1 на крају.

Гоогле табеле: бројите одређене речи

На крају, желео бих да поделим формулу Гоогле табела коју можете да користите за бројање одређених речи.

Овде имам Песму Лажне корњаче из Алисиних авантура у земљи чуда:

Желим да знам колико пута се реч 'воља' појављује у сваком реду. Верујем да се нећете изненадити ако вам кажем да се формула која ми треба састоји од истих функција као и пре: Гоогле табеле ЛЕН, СУБСТИТУТЕ и ЛОВЕР:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "will", "")))/LEN("will")

Формула може изгледа застрашујуће, али могу да вас уверим да је лако разумети, па будите стрпљиви :)

1. Пошто мала и велика слова текста нисубитно ми је, користим ЛОВЕР(А2) да све претворим у мала слова.
2. Онда иде СУБСТИТУТЕ(ЛОВЕР(А2), "ће",""))) – ослобађа се свих појављивања 'вилл' тако што их замењује празним стринговима ("").
3. Након тога одузимам број знакова без речи 'вилл' од укупне дужине стринга . Број који добијем броји све знакове у свим појављивањима 'воље' у сваком реду.

   Дакле, ако се 'воља' појави једном, број је 4 пошто реч има 4 слова. Ако се појави два пута, број је 8 итд.

4. На крају, делим овај број дужином једне речи „воља“.

Савет. И опет, ако бисте радије добили укупан број свих појављивања речи 'хоће', само приложите целу формулу са ЗУМПРОИЗВОД:

=SUMPRODUCT((LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "will", "")))/LEN("will"))

Као што видите , сви ови случајеви бројања знакова се решавају истим обрасцима истих функција за Гоогле табеле: ЛЕН, СУБСТИТУТЕ, ЛОВЕР и СУМПРОДУЦТ.

Ако вас неке формуле и даље збуњују, или ако нисте сигурни како да све примените на свој одређени задатак, немојте се стидети и питајте у одељку за коментаре испод!