Mafunzo yanaonyesha njia tofauti za kupata umri kutoka siku ya kuzaliwa katika Excel. Utajifunza kanuni chache za kukokotoa umri kama idadi ya miaka kamili, kupata umri kamili katika miaka, miezi na siku katika tarehe ya leo au tarehe fulani.

Hakuna chaguo za kukokotoa maalum za kukokotoa. umri katika Excel, hata hivyo kuna njia chache tofauti za kubadilisha tarehe ya kuzaliwa hadi umri. Mafunzo haya yataeleza faida na hasara za kila njia, yanaonyesha jinsi ya kutengeneza fomula kamili ya kukokotoa umri katika Excel na kuirekebisha ili kutatua baadhi ya kazi mahususi.

Jinsi ya kukokotoa umri kuanzia tarehe. ya kuzaliwa katika Excel

Katika maisha ya kila siku, swali " Una umri gani? " kwa kawaida humaanisha jibu linaloonyesha ni miaka mingapi umekuwa hai. Katika Microsoft Excel, unaweza kutengeneza fomula ya kuhesabu umri halisi katika miezi, siku, saa na hata dakika. Lakini hebu tuwe wa kitamaduni, na tujifunze jinsi ya kukokotoa umri kutoka kwa DOB katika miaka kwanza.

Mchanganyiko wa Msingi wa Excel kwa umri katika miaka

Je, unatambuaje umri wa mtu kwa kawaida? Kwa kuondoa tu tarehe ya kuzaliwa kutoka tarehe ya sasa. Fomula hii ya kawaida ya umri inaweza pia kutumika katika Excel.

Kwa kuchukulia tarehe ya kuzaliwa iko kwenye seli B2, fomula ya kukokotoa umri katika miaka huenda kama ifuatavyo:

=(TODAY()-B2)/365

The sehemu ya kwanza ya fomula (TODAY()-B2) inarudisha tofauti kati ya tarehe ya sasa na tarehe ya kuzaliwa ni siku, na kisha unagawanya hiyo.rejeleo la kisanduku au tarehe katika umbizo la mm/dd/yyyy.

Nimemaliza!

Mchanganyiko huwekwa kwenye kisanduku kilichochaguliwa kwa muda mfupi, na unabofya mara mbili kishikio cha kujaza ili kuinakili chini ya safu wima.

Ikiwa ungependa kuondoa vizio sifuri kama vile "siku 0", chagua kisanduku cha kuteua Usionyeshe ziro :

Ikiwa una hamu ya kujaribu kikokotoo hiki cha umri na pia kugundua nyongeza 60 zaidi za kuokoa muda za Excel, unakaribishwa kupakua toleo la majaribio la Ultimate Suite yetu mwishoni mwa chapisho hili.

Jinsi ya kuangazia umri fulani (chini ya au zaidi ya a umri maalum)

Katika hali fulani, huenda ukahitaji si tu kukokotoa umri katika Excel, lakini pia kuangazia seli ambazo zina umri chini ya au zaidi ya umri fulani.

Ikiwa fomula yako ya kukokotoa umri. hurejesha idadi ya miaka kamili, basi unaweza kuunda sheria ya kawaida ya umbizo la masharti kulingana na fomula rahisi kama hizi:

• Ili kuangazia umri sawa na au zaidi ya18: =$C2>=18
• Ili kuangazia umri wa chini ya miaka 18: =$C2<18

Ambapo C2 ndio seli ya juu zaidi katika safu wima ya Umri (bila kujumuisha kichwa cha safu).

Lakini vipi ikiwa fomula yako itaonyesha umri katika miaka na miezi, au katika miaka, miezi na siku? Katika hali hii, itabidi utengeneze sheria kulingana na fomula ya DATEDIF inayokokotoa umri kuanzia tarehe ya kuzaliwa katika miaka.

Tuseme tarehe za kuzaliwa ziko kwenye safu wima B kuanzia safu mlalo ya 2, fomula ni kama ifuatavyo:

• Ili kuangazia umri chini ya 18 (njano): =DATEDIF($B2, TODAY(),"Y")<18
• Ili kuangazia umri kati ya 18 na 65 (kijani): =AND(DATEDIF($B2, TODAY(),"Y")>=18, DATEDIF($B2, TODAY(),"Y")<=65)
• Ili kuangazia umri zaidi ya 65 (bluu): =DATEDIF($B2, TODAY(),"Y")>65

Ili kuunda sheria kulingana na fomula zilizo hapo juu, chagua seli au safu mlalo nzima ambazo ungependa kuangazia. , nenda kwa Nyumbani kichupo > Mitindo kikundi, na ubofye Uumbizaji wa Masharti > Kanuni Mpya… > Tumia fomula ya kuamua ni visanduku vipi vya umbizo .

Hatua za kina zinaweza kupatikana hapa: Jinsi ya kutengeneza sheria ya uumbizaji wa masharti kulingana na fomula.

Hivi ndivyo unavyohesabu umri katika Excel. Natumai fomula zilikuwa rahisi kwako kujifunza na utazijaribu katika laha zako za kazi. Asante kwa kusoma na kutumaini kukuona kwenye blogu yetu wiki ijayo!

Vipakuliwa vinavyopatikana

Mifano ya Kukokotoa Umri wa Excel (.xlsx file)

Ultimate Suite kwa siku 14 kikamilifu -toleo linalofanya kazi (.exe faili)

Mchanganyiko ni dhahiri na ni rahisi kukumbuka, hata hivyo, kuna tatizo dogo. Mara nyingi, hurejesha nambari ya desimali kama inavyoonyeshwa kwenye picha ya skrini iliyo hapa chini.

Ili kuonyesha idadi ya miaka kamili, tumia chaguo la kukokotoa la INT kufupisha desimali hadi nambari. nambari kamili iliyo karibu zaidi:

=INT((TODAY()-B2)/365)

Kasoro: Kutumia fomula hii ya umri katika Excel hutoa matokeo sahihi kabisa, lakini si kamili. Kugawanya kwa wastani wa idadi ya siku katika mwaka hufanya kazi vizuri mara nyingi, lakini wakati mwingine kunafanya umri kuwa mbaya. Kwa mfano, ikiwa mtu alizaliwa Februari 29 na leo ni Februari 28, fomula itamfanya mtu kuwa mkubwa zaidi kwa siku moja.

Kama mbadala, unaweza kugawanya kwa 365.25 badala ya 365 kwa kuwa kila mwaka wa nne kuna 366. siku. Walakini, njia hii pia sio kamili. Kwa mfano, ikiwa unahesabu umri wa mtoto ambaye bado hajaishi mwaka wa kurukaruka, ukigawanya na 365.25 hutoa matokeo yasiyo sahihi.

Kwa ujumla, kuondoa tarehe ya kuzaliwa kutoka tarehe ya sasa hufanya kazi vizuri. maisha ya kawaida, lakini sio njia bora katika Excel. Zaidi katika somo hili, utajifunza vipengele kadhaa maalum vinavyokokotoa umri bila dosari bila kujali mwaka.

Hesabu umri kuanzia tarehe ya kuzaliwa kwa kutumia kipengele cha YEARFRAC

Njia ya kuaminika zaidi ya kubadilisha DOB ili kuzeeka katika Excel ni kutumia kitendakazi cha YEARFRAC ambachohurejesha sehemu ya mwaka, yaani, idadi ya siku nzima kati ya tarehe mbili.

Sintaksia ya chaguo za kukokotoa za YEARFRAC ni kama ifuatavyo:

The hoja mbili za kwanza ziko wazi na hazihitaji maelezo ya ziada. Msingi ni hoja ya hiari inayofafanua msingi wa hesabu ya siku ya kutumia.

Ili kuunda fomula ya kweli kabisa, toa thamani zifuatazo kwa chaguo la kukokotoa la YEARFRAC:

• Tarehe_ya_kuanza - tarehe ya kuzaliwa.
• Tarehe_ya_mwisho - LEO() chaguo kurudisha tarehe ya leo.
• Msingi - tumia msingi 1 unaoiambia Excel kugawanya idadi halisi ya siku kwa mwezi kwa idadi halisi ya siku kwa mwaka.

Kwa kuzingatia yaliyo hapo juu, fomula ya Excel ya kukokotoa. umri kuanzia tarehe ya kuzaliwa ni kama ifuatavyo:

Ikizingatiwa kuwa tarehe ya kuzaliwa iko katika seli B2, fomula huchukua sura ifuatayo:

=YEARFRAC(B2, TODAY(), 1)

Kama katika mfano uliopita, matokeo ya chaguo za kukokotoa za YEARFRAC pia ni nambari ya desimali. Ili kurekebisha hili, tumia kitendakazi cha ROUNDDOWN kilicho na 0 katika hoja ya mwisho kwa sababu hutaki nafasi za desimali.

Kwa hivyo, hapa kuna fomula iliyoboreshwa ya YEARFRAC ya kukokotoa umri katika Excel:

=ROUNDDOWN(YEARFRAC(B2, TODAY(), 1), 0)

Kukokotoa umri katika Excel kwa kutumia DATEDIF

Njia moja zaidi ya kubadilisha tarehe ya kuzaliwa kuwa umri katika Excel ni kutumia chaguo la kukokotoa la DATEDIF:

Chaguo hili la kukokotoa linaweza kurudisha tofauti kati ya tarehe mbili katika vitengo mbalimbali vya saa kama vile miaka, miezi na siku, kulingana na thamani unayotoa katika hoja ya unit :

• Y - inarejesha idadi ya miaka kamili kati ya tarehe ya kuanza na mwisho.
• M - inarejesha idadi ya miezi kamili kati ya tarehe.
• D - inarejesha idadi ya siku kati ya tarehe mbili.
• YM - inarudi miezi , bila kuzingatia siku na miaka.
• MD - inarudisha tofauti katika siku , ikipuuza miezi na miaka.
• YD - inarudisha tofauti katika siku , ikipuuza miaka.

Kwa kuwa tunalenga kukokotoa umri katika miaka , tunatumia kitengo cha "y":

Katika mfano huu, DOB iko katika kisanduku B2, na unarejelea kisanduku hiki katika fomula ya umri wako:

=DATEDIF(B2, TODAY(), "y")

Hakuna chaguo za kukokotoa za ziada zinazohitajika katika kesi hii kwa sababu fomula ya DATEDIF yenye t kitengo cha "y" huhesabu idadi ya miaka kamili:

Jinsi ya kupata umri kutoka siku ya kuzaliwa katika miaka, miezi na siku

Kama ulivyoona hivi punde , kuhesabu umri kama idadi ya miaka kamili ambayo mtu ameishi ni rahisi, lakini haitoshi kila wakati. Ikiwa unataka kujua umri kamili, yaani, ni miaka mingapi, miezi na siku kati ya tarehe ya kuzaliwa ya mtu na tarehe ya sasa, andika 3.vitendaji tofauti vya DATEDIF:

1. Ili kupata idadi ya miaka: =DATEDIF(B2, TODAY(), "Y")
2. Ili kupata idadi ya miezi: =DATEDIF(B2, TODAY(), "YM")
3. Ili kupata idadi ya siku: =DATEDIF(B2,TODAY(),"MD")

Ambapo B2 ni tarehe ya kuzaliwa.

Na kisha, unganisha vitendaji vilivyo hapo juu katika fomula moja, kama hii:

=DATEDIF(B2,TODAY(),"Y") & DATEDIF(B2,TODAY(),"YM") & DATEDIF(B2,TODAY(),"MD")

Fomula iliyo hapo juu inarejesha nambari 3 (miaka, miezi, na siku) zikiwa zimeunganishwa katika mfuatano mmoja wa maandishi, kama inavyoonyeshwa kwenye picha ya skrini iliyo hapa chini:

Haina maana sana, uh. ? Ili kufanya matokeo kuwa na maana zaidi, tenganisha nambari na koma na ueleze maana ya kila thamani:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

Tokeo linaonekana bora zaidi sasa:

Mfumo huu hufanya kazi vizuri, lakini unaweza kuiboresha hata zaidi kwa kuficha thamani sifuri. Kwa hili, ongeza taarifa 3 za IF ambazo huangalia 0, moja kwa kila DATEDIF:

=IF(DATEDIF(B2, TODAY(),"y")=0,"",DATEDIF(B2, TODAY(),"y")&" years, ")& IF(DATEDIF(B2, TODAY(),"ym")=0,"",DATEDIF(B2, TODAY(),"ym")&" months, ")& IF(DATEDIF(B2, TODAY(),"md")=0,"",DATEDIF(B2, TODAY(),"md")&" days")

Picha ya skrini ifuatayo inaonyesha fomula ya mwisho ya umri ya Excel inayotumika - inarejesha umri katika miaka, miezi, na siku, kuonyesha thamani zisizo sifuri pekee:

Kidokezo. Iwapo unatafuta fomula ya Excel ya kukokotoa umri katika miaka na miezi , chukua fomula iliyo hapo juu na uondoe kizuizi cha mwisho cha IF(DATEDIF()) ambacho kinajumuisha siku.

Fomula mahususi za hesabu umri katika Excel

Kanuni za jumla za kukokotoa umri zilizojadiliwa hapo juu hufanya kazi vizuri katika hali nyingi. Katika hali zingine, hata hivyo, unaweza kuhitaji kitu maalum sana. Bila shaka, haiwezekani kufunika kilana kila hali, lakini mifano ifuatayo itakupa mawazo fulani kuhusu jinsi unavyoweza kurekebisha fomula ya umri kulingana na kazi yako mahususi.

Jinsi ya kuhesabu umri katika tarehe maalum katika Excel

Ikiwa unataka kujua umri wa mtu kwa tarehe fulani, tumia fomula ya umri ya DATEDIF iliyojadiliwa hapo juu, lakini badilisha TODAY() chaguo la kukokotoa katika hoja ya 2 na tarehe mahususi.

Kwa kuchukulia tarehe ya kuzaliwa iko katika B1, fomula ifuatayo itarejesha umri kuanzia tarehe 1 Januari 2020:

=DATEDIF(B1, "1/1/2020","Y") & " Years, " & DATEDIF(B1, "1/1/2020","YM") & " Months, " & DATEDIF(B1, "1/1/2020", "MD") & " Days"

Ili kuwezesha fomula yako ya umri kubadilika zaidi, unaweza kuweka tarehe katika kisanduku fulani na kurejelea kisanduku hicho katika fomula yako:

=DATEDIF(B1, B2,"Y") & " Years, "& DATEDIF(B1,B2,"YM") & " Months, "&DATEDIF(B1,B2, "MD") & " Days"

B1 iko wapi DOB, na B2 ndio tarehe unayotaka kukokotoa umri.

Hesabu umri katika muda fulani. year

Mchanganyiko huu unafaa katika hali ambapo tarehe kamili ya kukokotoa haijabainishwa, na unajua mwaka pekee.

Tuseme unafanya kazi na hifadhidata ya matibabu, na yako lengo ni kujua umri wa wagonjwa kwa wakati wao chini alifanyiwa uchunguzi kamili wa mwisho wa kimatibabu.

Ikizingatiwa kuwa tarehe za kuzaliwa ziko kwenye safu wima B kuanzia safu mlalo ya 3, na mwaka wa uchunguzi wa mwisho wa kimatibabu uko kwenye safu C, fomula ya kukokotoa umri huenda kama ifuatavyo:

=DATEDIF(B3,DATE(C3, 1, 1),"y")

Kwa sababu tarehe kamili ya uchunguzi wa kimatibabu haijafafanuliwa, unatumia chaguo la kukokotoa DATE kwa hoja ya tarehe na mwezi kiholela, k.m. TAREHE(C3, 1, 1).

TheChaguo za kukokotoa za DATE hutoa mwaka kutoka kwa kisanduku B3, kutengeneza tarehe kamili kwa kutumia nambari za mwezi na siku ulizotoa (Jan 1-Jan katika mfano huu), na kupitisha tarehe hiyo hadi DATEDIF. Kwa hivyo, unapata umri wa mgonjwa kufikia Januari 1 ya mwaka mahususi:

Tafuta tarehe mtu anapofikisha umri wa miaka N

Eti rafiki yako alizaliwa tarehe 8 Machi 1978. Unajuaje ni tarehe gani anamaliza umri wake wa miaka 50? Kwa kawaida, ungeongeza tu miaka 50 kwenye tarehe ya kuzaliwa ya mtu huyo. Katika Excel, unafanya vivyo hivyo kwa kutumia kitendakazi cha DATE:

=DATE(YEAR(B2) + 50, MONTH(B2), DAY(B2))

Ambapo B2 ni tarehe ya kuzaliwa.

Badala ya kuweka usimbaji kwa bidii idadi ya miaka katika tarehe ya kuzaliwa. fomula, unaweza kurejelea kisanduku fulani ambapo watumiaji wako wanaweza kuingiza idadi yoyote ya miaka (F1 katika picha ya skrini iliyo hapa chini):

Kukokotoa umri kutoka siku, mwezi na mwaka kwa tofauti. seli

Tarehe ya kuzaliwa inapogawanywa katika seli 3 tofauti (k.m. mwaka uko katika B3, mwezi katika C3 na siku katika D3), unaweza kuhesabu umri kwa njia hii:

• Pata tarehe ya kuzaliwa kwa kutumia vitendaji vya DATE na DATEVALUE:

  DATE(B3,MONTH(DATEVALUE(C3&"1")),D3)

• Pachika fomula iliyo hapo juu kwenye DATEDIF ili kukokotoa umri kuanzia tarehe ya kuzaliwa katika miaka, miezi, na siku: =DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "y") & " Years, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3),TODAY(), "ym") & " Months, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "md") & " Days"

  

Kwa mifano zaidi ya kukokotoa idadi ya siku kabla/baada ya tarehe, tafadhali angalia Jinsi ya kuhesabu siku tangu au hadi tarehe katika Excel.

Umri. kikokotoo katika Excel

Ikiwa ungependa kuwa na chakokikokotoo cha umri katika Excel, unaweza kutengeneza moja kwa kutumia fomula tofauti za DATEDIF zilizofafanuliwa hapa chini. Ikiwa ungependa kutoanzisha tena gurudumu, unaweza kutumia kikokotoo cha umri kilichoundwa na wataalamu wetu wa Excel.

Jinsi ya kuunda kikokotoo cha umri katika Excel

Sasa kwa kuwa unajua jinsi ya kutengeneza fomula ya umri katika Excel, unaweza kutengeneza kikokotoo maalum cha umri, kwa mfano hiki:

Kumbuka. Ili kutazama kitabu cha kazi kilichopachikwa, tafadhali ruhusu vidakuzi vya uuzaji.

Unachokiona hapo juu ni laha iliyopachikwa ya Excel Online, kwa hivyo jisikie huru kuweka tarehe yako ya kuzaliwa katika seli inayolingana, na utapata umri wako baada ya muda mfupi.

Kikokotoo hutumia fomula zifuatazo kukokotoa umri kulingana na tarehe ya kuzaliwa kwenye seli A3 na tarehe ya leo.

• Mchanganyiko katika B5 hukokotoa umri katika miaka, miezi na siku: =DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"
• Mchanganyiko katika B6 huhesabu umri katika miezi: =DATEDIF($B$3,TODAY(),"m")
• Mchanganuo katika B7 huhesabu umri katika siku: =DATEDIF($B$3,TODAY(),"d")

Ikiwa una uzoefu wa kutumia vidhibiti vya Fomu ya Excel, unaweza kuongeza chaguo la kukokotoa umri katika tarehe mahususi, kama inavyoonyeshwa kwenye picha ya skrini ifuatayo:

Kwa hili, ongeza vitufe kadhaa vya chaguo ( Kichupo cha Msanidi > Ingiza > Vidhibiti vya fomu > Kitufe cha Chaguo ), na uviunganishe kwenye kisanduku fulani. Kisha, andika fomula ya IF/DATEDIF ili kupata umri katika tarehe ya leo au tarehe iliyobainishwa na mtumiaji.

Mfumo huu hufanya kazi na zifuatazo.mantiki:

• Ikiwa kisanduku cha chaguo tarehe ya leo kimechaguliwa, thamani ya 1 inaonekana katika kisanduku kilichounganishwa (I5 katika mfano huu), na fomula ya umri huhesabiwa kulingana na tarehe ya leo. : IF($I$5=1, DATEDIF($B$3,TODAY(),"Y") & " Years, " & DATEDIF($B$3,TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days")
• Ikiwa kitufe cha chaguo Tarehe mahususi kimechaguliwa NA tarehe imeingizwa katika kisanduku B7, umri utahesabiwa kwa tarehe maalum: IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

Mwishowe. , weka vipengele vilivyo hapo juu kwenye kila kimoja, na utapata fomula kamili ya kukokotoa umri (katika B9):

=IF($I$5=1, DATEDIF($B$3, TODAY(), "Y") & " Years, " & DATEDIF($B$3, TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days", IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

Fomula katika B10 na B11 zinafanya kazi kwa mantiki sawa. Bila shaka, ni rahisi zaidi kwa sababu zinajumuisha kitendakazi kimoja tu cha DATEDIF ili kurejesha umri kama idadi ya miezi au siku kamili, mtawalia.

Ili kupata maelezo zaidi, ninakualika upakue Kikokotoo hiki cha Umri cha Excel na uchunguze. fomula katika seli B9:B11.

Pakua Kikokotoo cha Umri kwa Excel

Kikokotoo cha umri kilicho tayari kutumia kwa Excel

Watumiaji wa Ultimate Suite yetu hawana ili kujisumbua kuhusu kutengeneza kikokotoo cha umri wao katika Excel - ni mibofyo michache tu mbali:

1. Chagua kisanduku ambapo ungependa kuingiza fomula ya umri, nenda kwenye Zana za Ablebits kichupo > Tarehe & Muda kikundi, na ubofye Tarehe & Kitufe cha Mchawi wa Wakati

   

2. Tarehe & Mchawi wa Wakati utaanza, na utaenda moja kwa moja kwenye kichupo cha Umri .
3. Kwenye kichupo cha Umri , kuna vitu 3 vya wewe kubainisha:
   • 14> Takwimu za kuzaliwa kama a