Iako se broj riječi i znakova u Google tablicama koristi u rijetkim slučajevima, ipak je to funkcionalnost koju neki od nas očekuju da će vidjeti upravo u meniju. Ali za razliku od Google dokumenata, za Google Sheets to je funkcija LEN.

Iako postoji mnogo različitih načina za brojanje znakova u proračunskim tabelama, današnji blog post će pokriti LEN funkciju kao njenu glavna svrha u tabelama je – pa, računati :) Međutim, rijetko se koristi samostalno. U nastavku ćete naučiti kako pravilno koristiti Google Sheets LEN i pronaći najtraženije formule za izračunavanje znakova u proračunskim tabelama.

Google Sheets LEN funkcija – upotreba i sintaksa

glavna i jedina svrha funkcije LEN u Google Sheets je dobivanje dužine stringa. Toliko je jednostavno da čak zahtijeva samo 1 argument:

• može uzeti ili sam tekst u dvostrukim navodnicima:

  =LEN("Yggdrasil")

• ili referenca na ćeliju sa tekstom od interesa:

  =LEN(A2)

Da vidimo da li postoje neke posebnosti u korištenju funkcije u proračunskim tablicama.

Zak count u Google Sheets

Počeću s najjednostavnijom operacijom: izvršite brojanje znakova u Google Sheets na najčešći način – referenciranjem ćelije s tekstom pomoću funkcije LEN.

I unesite formulu u B2 i kopirajte je niz cijeli stupac da biste brojali znakove u svakom redu:

=LEN(A2)

Napomena. LEN funkcijaizračunava sve znakove: slova, brojeve, razmake, interpunkcijske znakove, itd.

Možda mislite da biste na sličan način mogli napraviti brojanje znakova za cijeli raspon ćelija, ovako: LEN(A2:A6) . Ali, kao koliko god bizarno bilo, ne radi jednostavno na ovaj način.

Da biste zbrojili znakove u nekoliko ćelija, trebali biste umotati svoj LEN u SUMPRODUCT – funkciju koja zbraja brojeve iz unesenih raspona. U mom slučaju, opseg vraća LEN funkcija:

=SUMPRODUCT(LEN(A2:A6))

Naravno, umjesto toga možete ugraditi funkciju SUM. Ali SUM u Google Sheets ne obrađuje nizove iz drugih funkcija. Da bi to funkcioniralo, morat ćete dodati još jednu funkciju – ArrayFormula:

=ArrayFormula(SUM(LEN(A2:A6)))

Kako brojati znakove bez razmaka u Google Sheets

Kao što sam gore napomenuo, Google Sheets LEN funkcija broji svaki znak koji vidi uključujući razmake.

Ali što ako postoje dodatni razmaci dodani greškom i ne želite ih uzeti u obzir za rezultat?

Za slučajeve kao što je ovo, postoji funkcija TRIM u Google Sheets. Provjerava da li tekst ima početne, zadnje i ponovljene razmake između. Kada je TRIM uparen sa LEN, potonji ne računa sve te neparne razmake.

Evo primjera. Dodao sam razmake na različitim pozicijama u koloni A. Kao što vidite, kada je samostalno, Google Sheets LEN ih sve broji:

=LEN(A2)

Ali čim integrišete TRIM, sve dodatne prostori suignorirano:

=LEN(TRIM(A2))

Možete ići dalje i učiniti da vaša formula zanemari čak i one pojedinačne razmake između riječi. Funkcija SUBSTITUTE će vam pomoći. Iako je njegova glavna svrha zamijeniti jedan znak drugim, postoji trik koji ga natjera da u potpunosti smanji razmake:

• text_to_search je raspon s kojim radite: stupac A, ili A2 točnije.
• traži_za trebao bi biti razmak u dvostrukim navodnicima: " "
• replace_with treba sadržavati prazne dvostruke navodnike. Ako ćete zanemariti razmake, trebate ih zamijeniti doslovno ničim (prazan niz): ""
• broj_pojavljivanja se obično koristi za navođenje instance zamijeniti. Ali pošto opisujem kako brojati znakove bez svih razmaka, predlažem da izostavite ovaj argument jer je opcionalan.

Sada pokušajte sve ovo sastaviti u Google Sheets LEN i vidjet ćete da razmak se ne uzima u obzir:

=LEN(SUBSTITUTE(A2, " ", ""))

Google Sheets: broj specifičnih znakova

Isti tandem Google Sheets LEN i SUBSTITUTE se koristi kad god trebate prebrojati određene znakove , slova ili brojeve.

U mojim primjerima, ja ću saznati broj pojavljivanja slova 's'. I ovog puta, počet ću s gotovom formulom:

=LEN(A2)-LEN(SUBSTITUTE(A2, "s", ""))

Razlomimo je na komade da shvatimo kakoradi:

1. SUBSTITUTE(A2, "s", "") traži slovo 's' u A2 i zamjenjuje sva pojavljivanja sa "ništa", ili praznim nizom ( "").
2. LEN(SUBSTITUTE(A2, "s", "") izračunava broj svih znakova osim 's' u A2.
3. LEN(A2) broji sve znakove u A2.
4. Konačno, oduzimate jedan od drugog.

Razlika rezultata pokazuje koliko 's' ima u ćeliji:

Napomena. Možda se pitate zašto B1 kaže da ima samo 1 's' u A2 dok možete vidjeti 3?

Stvar je u tome da je funkcija SUBSTITUTE osjetljiva na velika i mala slova. Zamolio sam ga da uzme sve instance 's' malim slovima i tako je i učinio.

Da ignoriše velika i mala slova teksta i obrađuje slova u malim i velikim slovima, morat ćete pozvati još jednu funkciju Google Sheets za pomoć: LOWER.

Savjet. Pogledajte druge načine za promjenu velikih i malih slova u Google Sheets.

Jednostavno je kao Google Sheets LEN i TRIM jer sve što je potrebno je tekst:

=LOWER(text)

I sve što radi je da okreće cijeli tekstualni niz u int o mala slova. Ovaj trik je upravo ono što vam treba da natjerate Google Sheets da broji određene znakove bez obzira na njihova velika i mala slova:

=LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "s", ""))

Savjet. I kao i prije, da izbrojite ukupan broj specifičnih znakova u rasponu, umotajte svoj LEN u SUMPRODUCT:

=SUMPRODUCT(LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "s", "")))

Broj riječi u Google tablicama

Kada postoji su više riječi u ćelijama, šanse su da ćete morati imati njihov broj umjestodužina stringa Google Sheets.

I iako postoji više načina za to, danas ću spomenuti kako Google Sheets LEN radi svoj posao.

Zapamtite formulu koju sam koristio za brojanje određenih znakova u Google tabele? U stvari, i ovdje će dobro doći. Jer neću bukvalno brojati riječi. Umjesto toga, izbrojat ću broj razmaka između riječi i onda jednostavno dodati 1. Pogledajte:

=LEN(A2)-LEN(SUBSTITUTE((A2), " ", ""))+1

1. LEN(A2) broji broj svih znakova u ćeliji.
2. LEN(SUBSTITUTE((A2)," ","")) uklanja sve razmake iz tekstualnog niza i broji preostale znakove.
3. Onda oduzmete jedno od drugog, a razlika koju dobijete je broj razmaka u ćeliji.
4. Pošto riječi uvijek premašuju razmake u rečenici za jedan, dodajete 1 na kraju.

Google Sheets: brojite određene riječi

Na kraju, želio bih podijeliti formulu Google Sheets koju možete koristiti za brojanje određenih riječi.

Ovdje imam Pjesmu Lažne kornjače iz Alisinih avantura u zemlji čudesa:

Želim znati koliko se puta riječ 'volja' pojavljuje u svakom redu. Vjerujem da se nećete iznenaditi ako vam kažem da se formula koja mi treba sastoji od istih funkcija kao i prije: Google Sheets LEN, SUBSTITUTE i LOWER:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "will", "")))/LEN("will")

Formula može izgleda zastrašujuće, ali uvjeravam vas da je lako razumjeti, pa se strpite sa mnom :)

1. Pošto mala i velika slova teksta nebitno mi je, koristim LOWER(A2) da sve pretvorim u mala slova.
2. Onda ide SUBSTITUTE(LOWER(A2), "će",""))) – oslobađa se svih pojavljivanja 'will' tako što ih zamjenjuje praznim nizovima ("").
3. Nakon toga oduzimam broj znakova bez riječi 'will' od ukupne dužine niza . Broj koji dobijem broji sve znakove u svim pojavljivanjima 'volje' u svakom redu.

   Dakle, ako se 'will' pojavi jednom, broj je 4 jer riječ ima 4 slova. Ako se pojavi dvaput, broj je 8 i tako dalje.

4. Konačno, podijelim ovaj broj dužinom jedne riječi 'će'.

Savjet. I opet, ako biste radije dobili ukupan broj svih pojavljivanja riječi 'hoće', samo priložite cijelu formulu u SUMPRODUCT:

=SUMPRODUCT((LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "will", "")))/LEN("will"))

Kao što možete vidjeti , svi ovi slučajevi brojanja znakova su riješeni istim obrascima istih funkcija za Google Sheets: LEN, SUBSTITUTE, LOWER i SUMPRODUCT.

Ako vas neke formule i dalje zbunjuju, ili ako niste sigurni kako sve primijeniti na svoj određeni zadatak, nemojte se stidjeti i pitajte u odjeljku za komentare ispod!