ਹਾਲਾਂਕਿ Google ਸ਼ੀਟਾਂ ਵਿੱਚ ਸ਼ਬਦ ਅਤੇ ਅੱਖਰ ਦੀ ਗਿਣਤੀ ਬਹੁਤ ਘੱਟ ਮਾਮਲਿਆਂ ਵਿੱਚ ਵਰਤੀ ਜਾਂਦੀ ਹੈ, ਇਹ ਅਜੇ ਵੀ ਕਾਰਜਕੁਸ਼ਲਤਾ ਹੈ ਜੋ ਸਾਡੇ ਵਿੱਚੋਂ ਕੁਝ ਮੀਨੂ ਵਿੱਚ ਸਹੀ ਦੇਖਣ ਦੀ ਉਮੀਦ ਕਰਦੇ ਹਨ। ਪਰ ਗੂਗਲ ਡੌਕਸ ਦੇ ਉਲਟ, ਗੂਗਲ ਸ਼ੀਟਾਂ ਲਈ, ਇਹ LEN ਫੰਕਸ਼ਨ ਹੈ ਜੋ ਅਜਿਹਾ ਕਰਦਾ ਹੈ।

ਹਾਲਾਂਕਿ ਸਪ੍ਰੈਡਸ਼ੀਟਾਂ ਵਿੱਚ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਦੇ ਬਹੁਤ ਸਾਰੇ ਵੱਖ-ਵੱਖ ਤਰੀਕੇ ਹਨ, ਅੱਜ ਦੀ ਬਲੌਗ ਪੋਸਟ LEN ਫੰਕਸ਼ਨ ਨੂੰ ਇਸ ਦੇ ਰੂਪ ਵਿੱਚ ਕਵਰ ਕਰੇਗੀ। ਟੇਬਲਾਂ ਵਿੱਚ ਮੁੱਖ ਉਦੇਸ਼ ਹੈ - ਚੰਗੀ ਤਰ੍ਹਾਂ, ਗਿਣਤੀ :) ਹਾਲਾਂਕਿ, ਇਹ ਸ਼ਾਇਦ ਹੀ ਕਦੇ ਆਪਣੇ ਆਪ ਵਰਤਿਆ ਗਿਆ ਹੋਵੇ। ਹੇਠਾਂ ਤੁਸੀਂ ਸਿੱਖੋਗੇ ਕਿ ਗੂਗਲ ਸ਼ੀਟਸ LEN ਦੀ ਸਹੀ ਵਰਤੋਂ ਕਿਵੇਂ ਕਰਨੀ ਹੈ ਅਤੇ ਸਪਰੈੱਡਸ਼ੀਟਾਂ ਵਿੱਚ ਅੱਖਰਾਂ ਦੀ ਗਣਨਾ ਕਰਨ ਲਈ ਸਭ ਤੋਂ ਵੱਧ ਲੋੜੀਂਦੇ ਫਾਰਮੂਲੇ ਕਿਵੇਂ ਲੱਭਣੇ ਹਨ।

Google ਸ਼ੀਟਸ LEN ਫੰਕਸ਼ਨ - ਵਰਤੋਂ ਅਤੇ ਸੰਟੈਕਸ

The Google ਸ਼ੀਟਾਂ ਵਿੱਚ LEN ਫੰਕਸ਼ਨ ਦਾ ਮੁੱਖ ਅਤੇ ਇੱਕੋ ਇੱਕ ਉਦੇਸ਼ ਸਤਰ ਦੀ ਲੰਬਾਈ ਪ੍ਰਾਪਤ ਕਰਨਾ ਹੈ। ਇਹ ਇੰਨਾ ਸਰਲ ਹੈ ਕਿ ਇਸ ਨੂੰ ਸਿਰਫ 1 ਆਰਗੂਮੈਂਟ ਦੀ ਲੋੜ ਹੈ:

• ਇਹ ਜਾਂ ਤਾਂ ਟੈਕਸਟ ਨੂੰ ਆਪਣੇ ਆਪ ਡਬਲ-ਕੋਟਸ ਵਿੱਚ ਲੈ ਸਕਦਾ ਹੈ:

  =LEN("Yggdrasil")

• ਜਾਂ ਦਿਲਚਸਪੀ ਦੇ ਟੈਕਸਟ ਵਾਲੇ ਸੈੱਲ ਦਾ ਹਵਾਲਾ:

  =LEN(A2)

ਆਓ ਦੇਖੀਏ ਕਿ ਕੀ ਸਪਰੈੱਡਸ਼ੀਟਾਂ ਵਿੱਚ ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰਨ ਵਿੱਚ ਕੋਈ ਵਿਸ਼ੇਸ਼ਤਾ ਹੈ।

ਅੱਖਰ Google ਸ਼ੀਟਾਂ ਵਿੱਚ ਗਿਣਤੀ ਕਰੋ

ਮੈਂ ਸਭ ਤੋਂ ਸਰਲ ਕਾਰਵਾਈ ਨਾਲ ਸ਼ੁਰੂ ਕਰਾਂਗਾ: Google ਸ਼ੀਟਾਂ ਵਿੱਚ ਇੱਕ ਅੱਖਰ ਦੀ ਗਿਣਤੀ ਸਭ ਤੋਂ ਆਮ ਤਰੀਕੇ ਨਾਲ ਕਰੋ – LEN ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰਕੇ ਟੈਕਸਟ ਦੇ ਨਾਲ ਇੱਕ ਸੈੱਲ ਦਾ ਹਵਾਲਾ ਦੇ ਕੇ।

I B2 ਵਿੱਚ ਫਾਰਮੂਲਾ ਦਾਖਲ ਕਰੋ ਅਤੇ ਹਰੇਕ ਕਤਾਰ ਵਿੱਚ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਇਸਨੂੰ ਪੂਰੇ ਕਾਲਮ ਵਿੱਚ ਕਾਪੀ ਕਰੋ:

=LEN(A2)

ਨੋਟ। LEN ਫੰਕਸ਼ਨਸਾਰੇ ਅੱਖਰਾਂ ਦੀ ਗਣਨਾ ਕਰਦਾ ਹੈ: ਅੱਖਰ, ਨੰਬਰ, ਸਪੇਸ, ਵਿਰਾਮ ਚਿੰਨ੍ਹ, ਆਦਿ।

ਤੁਸੀਂ ਸੋਚ ਸਕਦੇ ਹੋ ਕਿ ਇਸੇ ਤਰ੍ਹਾਂ ਤੁਸੀਂ ਸੈੱਲਾਂ ਦੀ ਪੂਰੀ ਰੇਂਜ ਲਈ ਇੱਕ ਅੱਖਰ ਦੀ ਗਿਣਤੀ ਕਰ ਸਕਦੇ ਹੋ, ਜਿਵੇਂ ਕਿ: LEN(A2:A6) । ਪਰ, ਜਿਵੇਂ ਕਿ ਜਿਵੇਂ ਕਿ ਇਹ ਅਜੀਬ ਹੈ, ਇਹ ਇਸ ਤਰੀਕੇ ਨਾਲ ਕੰਮ ਨਹੀਂ ਕਰਦਾ ਹੈ।

ਕਈ ਸੈੱਲਾਂ ਵਿੱਚ ਕੁੱਲ ਅੱਖਰਾਂ ਲਈ, ਤੁਹਾਨੂੰ ਆਪਣੇ LEN ਨੂੰ SUMPRODUCT ਵਿੱਚ ਲਪੇਟਣਾ ਚਾਹੀਦਾ ਹੈ - ਇੱਕ ਫੰਕਸ਼ਨ ਜੋ ਦਰਜ ਕੀਤੀਆਂ ਰੇਂਜਾਂ ਤੋਂ ਸੰਖਿਆਵਾਂ ਨੂੰ ਲੰਮਾ ਕਰਦਾ ਹੈ। ਮੇਰੇ ਕੇਸ ਵਿੱਚ, ਰੇਂਜ LEN ਫੰਕਸ਼ਨ ਦੁਆਰਾ ਵਾਪਸ ਕੀਤੀ ਜਾਂਦੀ ਹੈ:

=SUMPRODUCT(LEN(A2:A6))

ਬੇਸ਼ੱਕ, ਤੁਸੀਂ ਇਸਦੀ ਬਜਾਏ SUM ਫੰਕਸ਼ਨ ਨੂੰ ਸ਼ਾਮਲ ਕਰ ਸਕਦੇ ਹੋ। ਪਰ Google ਸ਼ੀਟਾਂ ਵਿੱਚ SUM ਹੋਰ ਫੰਕਸ਼ਨਾਂ ਤੋਂ ਐਰੇ ਦੀ ਪ੍ਰਕਿਰਿਆ ਨਹੀਂ ਕਰਦਾ ਹੈ। ਇਸਨੂੰ ਕੰਮ ਕਰਨ ਲਈ, ਤੁਹਾਨੂੰ ਇੱਕ ਹੋਰ ਫੰਕਸ਼ਨ ਜੋੜਨਾ ਪਵੇਗਾ - ਐਰੇ ਫਾਰਮੂਲਾ:

=ArrayFormula(SUM(LEN(A2:A6)))

Google ਸ਼ੀਟਾਂ ਵਿੱਚ ਖਾਲੀ ਥਾਂਵਾਂ ਤੋਂ ਬਿਨਾਂ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਿਵੇਂ ਕਰੀਏ

ਜਿਵੇਂ ਕਿ ਮੈਂ ਉੱਪਰ ਨੋਟ ਕੀਤਾ ਹੈ, ਗੂਗਲ ਸ਼ੀਟਾਂ LEN ਫੰਕਸ਼ਨ ਸਪੇਸ ਸਮੇਤ ਹਰ ਅੱਖਰ ਨੂੰ ਗਿਣਦਾ ਹੈ।

ਪਰ ਕੀ ਜੇ ਗਲਤੀ ਨਾਲ ਵਾਧੂ ਸਪੇਸ ਜੋੜ ਦਿੱਤੀ ਜਾਂਦੀ ਹੈ ਅਤੇ ਤੁਸੀਂ ਨਤੀਜੇ ਲਈ ਉਹਨਾਂ 'ਤੇ ਵਿਚਾਰ ਨਹੀਂ ਕਰਨਾ ਚਾਹੁੰਦੇ ਹੋ?

ਜਿਵੇਂ ਕੇਸਾਂ ਲਈ ਇਹ, Google ਸ਼ੀਟਾਂ ਵਿੱਚ TRIM ਫੰਕਸ਼ਨ ਹੈ। ਇਹ ਮੋਹਰੀ, ਪਿਛਾਂਹ ਅਤੇ ਦੁਹਰਾਉਣ ਵਾਲੀਆਂ ਥਾਂਵਾਂ ਲਈ ਟੈਕਸਟ ਦੀ ਜਾਂਚ ਕਰਦਾ ਹੈ। ਜਦੋਂ TRIM ਨੂੰ LEN ਨਾਲ ਜੋੜਿਆ ਜਾਂਦਾ ਹੈ, ਤਾਂ ਬਾਅਦ ਵਾਲਾ ਉਹਨਾਂ ਸਾਰੀਆਂ ਅਜੀਬ ਥਾਂਵਾਂ ਨੂੰ ਨਹੀਂ ਗਿਣਦਾ।

ਇੱਥੇ ਇੱਕ ਉਦਾਹਰਨ ਹੈ। ਮੈਂ ਕਾਲਮ A ਵਿੱਚ ਵੱਖ-ਵੱਖ ਸਥਿਤੀਆਂ ਵਿੱਚ ਖਾਲੀ ਥਾਂਵਾਂ ਜੋੜੀਆਂ ਹਨ। ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਦੇਖ ਸਕਦੇ ਹੋ, ਜਦੋਂ ਆਪਣੇ ਆਪ 'ਤੇ, Google ਸ਼ੀਟਸ LEN ਉਹਨਾਂ ਸਭ ਨੂੰ ਗਿਣਦਾ ਹੈ:

=LEN(A2)

ਪਰ ਜਿਵੇਂ ਹੀ ਤੁਸੀਂ TRIM ਨੂੰ ਏਕੀਕ੍ਰਿਤ ਕਰਦੇ ਹੋ, ਸਾਰੇ ਵਾਧੂ ਖਾਲੀ ਥਾਂਵਾਂ ਹਨਅਣਡਿੱਠ ਕੀਤਾ ਗਿਆ:

=LEN(TRIM(A2))

ਤੁਸੀਂ ਹੋਰ ਅੱਗੇ ਜਾ ਸਕਦੇ ਹੋ ਅਤੇ ਆਪਣੇ ਫਾਰਮੂਲੇ ਨੂੰ ਸ਼ਬਦਾਂ ਦੇ ਵਿਚਕਾਰ ਉਹਨਾਂ ਸਿੰਗਲ ਸਪੇਸ ਨੂੰ ਵੀ ਅਣਡਿੱਠ ਕਰ ਸਕਦੇ ਹੋ। SUBSTITUTE ਫੰਕਸ਼ਨ ਸਹਾਇਤਾ ਕਰੇਗਾ। ਹਾਲਾਂਕਿ ਇਸਦਾ ਮੁੱਖ ਉਦੇਸ਼ ਇੱਕ ਅੱਖਰ ਨੂੰ ਦੂਜੇ ਅੱਖਰ ਨਾਲ ਬਦਲਣਾ ਹੈ, ਇਸ ਨੂੰ ਪੂਰੀ ਤਰ੍ਹਾਂ ਖਾਲੀ ਕਰਨ ਲਈ ਇੱਕ ਚਾਲ ਹੈ:

• text_to_search ਉਹ ਰੇਂਜ ਹੈ ਜਿਸ ਨਾਲ ਤੁਸੀਂ ਕੰਮ ਕਰਦੇ ਹੋ: ਕਾਲਮ A, ਜਾਂ A2 ਸਟੀਕ ਹੋਣ ਲਈ।
• search_for ਡਬਲ-ਕੋਟਸ ਵਿੱਚ ਇੱਕ ਸਪੇਸ ਅੱਖਰ ਹੋਣਾ ਚਾਹੀਦਾ ਹੈ: " "
• replace_with ਵਿੱਚ ਖਾਲੀ ਡਬਲ-ਕੋਟ ਹੋਣੇ ਚਾਹੀਦੇ ਹਨ। ਜੇਕਰ ਤੁਸੀਂ ਸਪੇਸ ਨੂੰ ਨਜ਼ਰਅੰਦਾਜ਼ ਕਰਨ ਜਾ ਰਹੇ ਹੋ, ਤਾਂ ਤੁਹਾਨੂੰ ਉਹਨਾਂ ਨੂੰ ਸ਼ਾਬਦਿਕ ਤੌਰ 'ਤੇ ਕੁਝ ਵੀ (ਖਾਲੀ ਸਤਰ) ਨਾਲ ਬਦਲਣ ਦੀ ਲੋੜ ਹੈ: ""
• occurence_number ਨੂੰ ਆਮ ਤੌਰ 'ਤੇ ਉਦਾਹਰਨ ਦੇਣ ਲਈ ਵਰਤਿਆ ਜਾਂਦਾ ਹੈ। ਨੂੰ ਤਬਦੀਲ ਕਰਨ ਲਈ. ਪਰ ਕਿਉਂਕਿ ਮੈਂ ਵਰਣਨ ਕਰ ਰਿਹਾ ਹਾਂ ਕਿ ਸਾਰੀਆਂ ਖਾਲੀ ਥਾਂਵਾਂ ਤੋਂ ਬਿਨਾਂ ਅੱਖਰਾਂ ਨੂੰ ਕਿਵੇਂ ਗਿਣਿਆ ਜਾਵੇ, ਮੈਂ ਸੁਝਾਅ ਦਿੰਦਾ ਹਾਂ ਕਿ ਤੁਸੀਂ ਇਸ ਦਲੀਲ ਨੂੰ ਛੱਡ ਦਿਓ ਕਿਉਂਕਿ ਇਹ ਵਿਕਲਪਿਕ ਹੈ।

ਹੁਣ ਕੋਸ਼ਿਸ਼ ਕਰੋ ਅਤੇ ਇਹਨਾਂ ਸਭ ਨੂੰ Google ਸ਼ੀਟਾਂ LEN ਵਿੱਚ ਇਕੱਠਾ ਕਰੋ ਅਤੇ ਤੁਸੀਂ ਦੇਖੋਗੇ ਕਿ ਕੋਈ ਸਪੇਸ ਖਾਤੇ ਵਿੱਚ ਨਹੀਂ ਲਿਆ ਜਾਂਦਾ ਹੈ:

=LEN(SUBSTITUTE(A2, " ", ""))

Google ਸ਼ੀਟਾਂ: ਖਾਸ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰੋ

Google ਸ਼ੀਟਾਂ LEN ਅਤੇ SUBSTITUTE ਦਾ ਇੱਕੋ ਟੈਂਡਮ ਵਰਤਿਆ ਜਾਂਦਾ ਹੈ ਜਦੋਂ ਵੀ ਤੁਹਾਨੂੰ ਖਾਸ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਦੀ ਲੋੜ ਹੁੰਦੀ ਹੈ , ਅੱਖਰ, ਜਾਂ ਨੰਬਰ।

ਮੇਰੀਆਂ ਉਦਾਹਰਣਾਂ ਵਿੱਚ, ਮੈਂ ਅੱਖਰ 's' ਲਈ ਮੌਜੂਦਗੀ ਦੀ ਸੰਖਿਆ ਦਾ ਪਤਾ ਲਗਾਉਣ ਜਾ ਰਿਹਾ ਹਾਂ। ਅਤੇ ਇਸ ਵਾਰ, ਮੈਂ ਇੱਕ ਤਿਆਰ ਫਾਰਮੂਲੇ ਨਾਲ ਸ਼ੁਰੂ ਕਰਾਂਗਾ:

=LEN(A2)-LEN(SUBSTITUTE(A2, "s", ""))

ਆਓ ਇਸਨੂੰ ਸਮਝਣ ਲਈ ਇਸਨੂੰ ਟੁਕੜਿਆਂ ਵਿੱਚ ਵੰਡੀਏ ਕਿ ਇਹ ਕਿਵੇਂਕੰਮ ਕਰਦਾ ਹੈ:

1. SUBSTITUTE(A2, "s", "") A2 ਵਿੱਚ ਅੱਖਰ 's' ਦੀ ਖੋਜ ਕਰਦਾ ਹੈ ਅਤੇ "ਕੁਝ ਨਹੀਂ" ਜਾਂ ਖਾਲੀ ਸਤਰ (ਖਾਲੀ ਸਤਰ) ਨਾਲ ਸਾਰੀਆਂ ਘਟਨਾਵਾਂ ਨੂੰ ਬਦਲਦਾ ਹੈ ( "").
2. LEN(SUBSTITUTE(A2, "s", "") A2 ਵਿੱਚ 's' ਨੂੰ ਛੱਡ ਕੇ ਸਾਰੇ ਅੱਖਰਾਂ ਦੀ ਸੰਖਿਆ ਦਾ ਕੰਮ ਕਰਦਾ ਹੈ।
3. LEN(A2) A2 ਵਿੱਚ ਸਾਰੇ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਦਾ ਹੈ।
4. ਅੰਤ ਵਿੱਚ, ਤੁਸੀਂ ਇੱਕ ਨੂੰ ਦੂਜੇ ਤੋਂ ਘਟਾਉਂਦੇ ਹੋ।

ਨਤੀਜੇ ਵਿੱਚ ਅੰਤਰ ਦਿਖਾਉਂਦਾ ਹੈ ਕਿ ਕਿੰਨੇ 's' ਹਨ। ਸੈੱਲ ਵਿੱਚ:

ਨੋਟ। ਤੁਸੀਂ ਹੈਰਾਨ ਹੋ ਸਕਦੇ ਹੋ ਕਿ B1 ਕਿਉਂ ਕਹਿੰਦਾ ਹੈ ਕਿ A2 ਵਿੱਚ ਸਿਰਫ਼ 1 's' ਹੈ ਜਦੋਂ ਕਿ ਤੁਸੀਂ 3 ਨੂੰ ਦੇਖ ਸਕਦੇ ਹੋ?

ਗੱਲ ਇਹ ਹੈ ਕਿ ਸਬਸਟੀਟਿਊਟ ਫੰਕਸ਼ਨ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਹੈ। ਮੈਂ ਇਸਨੂੰ 's' ਦੇ ਸਾਰੇ ਉਦਾਹਰਨਾਂ ਨੂੰ ਛੋਟੇ ਅੱਖਰਾਂ ਵਿੱਚ ਲੈਣ ਲਈ ਕਿਹਾ ਅਤੇ ਇਸ ਤਰ੍ਹਾਂ ਹੋਇਆ।

ਇਸ ਨੂੰ ਟੈਕਸਟ ਕੇਸ ਨੂੰ ਨਜ਼ਰਅੰਦਾਜ਼ ਕਰਨ ਲਈ ਅਤੇ ਛੋਟੇ ਅਤੇ ਵੱਡੇ ਦੋਵਾਂ ਕੇਸਾਂ ਵਿੱਚ ਅੱਖਰਾਂ ਦੀ ਪ੍ਰਕਿਰਿਆ ਕਰਨ ਲਈ, ਤੁਹਾਨੂੰ ਇੱਕ ਹੋਰ Google ਸ਼ੀਟਸ ਫੰਕਸ਼ਨ ਨੂੰ ਕਾਲ ਕਰਨਾ ਹੋਵੇਗਾ। ਮਦਦ ਲਈ: LOWER।

ਟਿਪ। Google ਸ਼ੀਟਾਂ ਵਿੱਚ ਟੈਕਸਟ ਕੇਸ ਨੂੰ ਬਦਲਣ ਵਾਲੇ ਹੋਰ ਤਰੀਕੇ ਦੇਖੋ।

ਇਹ Google ਸ਼ੀਟਾਂ LEN ਅਤੇ TRIM ਵਾਂਗ ਸਧਾਰਨ ਹੈ ਕਿਉਂਕਿ ਇਸ ਲਈ ਸਿਰਫ਼ ਟੈਕਸਟ ਦੀ ਲੋੜ ਹੈ:

=LOWER(text)

ਅਤੇ ਇਹ ਸਭ ਕੁਝ ਕਰਦਾ ਹੈ ਪੂਰੀ ਟੈਕਸਟ ਸਤਰ ਨੂੰ ਇੰਟ ਕਰ ਦਿੰਦਾ ਹੈ o ਛੋਟੇ ਕੇਸ. ਇਹ ਚਾਲ ਬਿਲਕੁਲ ਉਹੀ ਹੈ ਜਿਸ ਦੀ ਤੁਹਾਨੂੰ Google ਸ਼ੀਟਾਂ ਨੂੰ ਖਾਸ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਲੋੜ ਹੈ ਭਾਵੇਂ ਉਹਨਾਂ ਦੇ ਟੈਕਸਟ ਕੇਸ:

=LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "s", ""))

ਟਿਪ। ਅਤੇ ਪਹਿਲਾਂ ਵਾਂਗ, ਰੇਂਜ ਵਿੱਚ ਕੁੱਲ ਖਾਸ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ, ਆਪਣੇ LEN ਨੂੰ SUMPRODUCT ਵਿੱਚ ਲਪੇਟੋ:

=SUMPRODUCT(LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "s", "")))

Google ਸ਼ੀਟਾਂ ਵਿੱਚ ਸ਼ਬਦਾਂ ਦੀ ਗਿਣਤੀ ਕਰੋ

ਜਦੋਂ ਉੱਥੇ ਹੋਵੇ ਸੈੱਲਾਂ ਵਿੱਚ ਕਈ ਸ਼ਬਦ ਹਨ, ਸੰਭਾਵਨਾ ਹੈ ਕਿ ਤੁਹਾਨੂੰ ਉਹਨਾਂ ਦੀ ਬਜਾਏ ਉਹਨਾਂ ਦੀ ਸੰਖਿਆ ਦੀ ਲੋੜ ਪਵੇਗੀGoogle ਸ਼ੀਟਾਂ ਦੀ ਸਤਰ ਦੀ ਲੰਬਾਈ।

ਅਤੇ ਭਾਵੇਂ ਅਜਿਹਾ ਕਰਨ ਦੇ ਕਈ ਤਰੀਕੇ ਹਨ, ਅੱਜ ਮੈਂ ਦੱਸਾਂਗਾ ਕਿ Google ਸ਼ੀਟਾਂ LEN ਕੰਮ ਕਿਵੇਂ ਕਰਦਾ ਹੈ।

ਉਹ ਫਾਰਮੂਲਾ ਯਾਦ ਰੱਖੋ ਜਿਸ ਵਿੱਚ ਮੈਂ ਖਾਸ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਵਰਤਿਆ ਸੀ। ਗੂਗਲ ਸ਼ੀਟਸ? ਅਸਲ ਵਿੱਚ, ਇਹ ਇੱਥੇ ਵੀ ਕੰਮ ਆਵੇਗਾ. ਕਿਉਂਕਿ ਮੈਂ ਸ਼ਾਬਦਿਕ ਤੌਰ 'ਤੇ ਸ਼ਬਦਾਂ ਦੀ ਗਿਣਤੀ ਨਹੀਂ ਕਰਨ ਜਾ ਰਿਹਾ ਹਾਂ. ਇਸਦੀ ਬਜਾਏ, ਮੈਂ ਸ਼ਬਦਾਂ ਦੇ ਵਿਚਕਾਰ ਖਾਲੀ ਥਾਂਵਾਂ ਦੀ ਗਿਣਤੀ ਕਰਾਂਗਾ ਅਤੇ ਫਿਰ ਸਿਰਫ਼ 1 ਜੋੜਾਂਗਾ। ਇੱਕ ਨਜ਼ਰ ਮਾਰੋ:

=LEN(A2)-LEN(SUBSTITUTE((A2), " ", ""))+1

1. LEN(A2) ਦੀ ਗਿਣਤੀ ਕਰਦਾ ਹੈ ਸੈੱਲ ਵਿੱਚ ਸਾਰੇ ਅੱਖਰਾਂ ਦੀ ਸੰਖਿਆ।
2. LEN(SUBSTITUTE((A2)," ","")) ਟੈਕਸਟ ਸਤਰ ਵਿੱਚੋਂ ਸਾਰੀਆਂ ਖਾਲੀ ਥਾਂਵਾਂ ਨੂੰ ਹਟਾਉਂਦਾ ਹੈ ਅਤੇ ਬਾਕੀ ਬਚੇ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਦਾ ਹੈ।
3. ਫਿਰ ਤੁਸੀਂ ਇੱਕ ਨੂੰ ਦੂਜੇ ਵਿੱਚੋਂ ਘਟਾਉਂਦੇ ਹੋ, ਅਤੇ ਤੁਹਾਨੂੰ ਜੋ ਅੰਤਰ ਮਿਲਦਾ ਹੈ ਉਹ ਸੈੱਲ ਵਿੱਚ ਖਾਲੀ ਥਾਂਵਾਂ ਦੀ ਸੰਖਿਆ ਹੈ।
4. ਕਿਉਂਕਿ ਸ਼ਬਦ ਹਮੇਸ਼ਾ ਇੱਕ ਵਾਕ ਵਿੱਚ ਖਾਲੀ ਥਾਂਵਾਂ ਨੂੰ ਇੱਕ ਕਰਕੇ ਵੱਧ ਕਰਦੇ ਹਨ, ਤੁਸੀਂ ਅੰਤ ਵਿੱਚ 1 ਜੋੜਦੇ ਹੋ।

Google ਸ਼ੀਟਾਂ: ਖਾਸ ਸ਼ਬਦਾਂ ਦੀ ਗਿਣਤੀ ਕਰੋ

ਅੰਤ ਵਿੱਚ, ਮੈਂ ਇੱਕ Google ਸ਼ੀਟ ਫਾਰਮੂਲਾ ਸਾਂਝਾ ਕਰਨਾ ਚਾਹਾਂਗਾ ਜਿਸਦੀ ਵਰਤੋਂ ਤੁਸੀਂ ਖਾਸ ਸ਼ਬਦਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਕਰ ਸਕਦੇ ਹੋ।

ਇੱਥੇ ਮੇਰੇ ਕੋਲ ਐਲਿਸਜ਼ ਐਡਵੈਂਚਰਜ਼ ਇਨ ਵੈਂਡਰਲੈਂਡ ਦਾ ਮੌਕ ਟਰਟਲ ਦਾ ਗੀਤ ਹੈ:

ਮੈਂ ਜਾਣਨਾ ਚਾਹੁੰਦਾ ਹਾਂ ਕਿ ਹਰ ਕਤਾਰ ਵਿੱਚ 'ਵਿਲ' ਸ਼ਬਦ ਕਿੰਨੀ ਵਾਰ ਦਿਖਾਈ ਦਿੰਦਾ ਹੈ। ਮੇਰਾ ਮੰਨਣਾ ਹੈ ਕਿ ਤੁਸੀਂ ਹੈਰਾਨ ਨਹੀਂ ਹੋਵੋਗੇ ਜੇਕਰ ਮੈਂ ਤੁਹਾਨੂੰ ਦੱਸਾਂ ਕਿ ਮੈਨੂੰ ਲੋੜੀਂਦੇ ਫਾਰਮੂਲੇ ਵਿੱਚ ਪਹਿਲਾਂ ਵਾਂਗ ਹੀ ਫੰਕਸ਼ਨਾਂ ਸ਼ਾਮਲ ਹਨ: Google ਸ਼ੀਟਾਂ LEN, SUBSTITUTE, ਅਤੇ LOWER:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "will", "")))/LEN("will")

ਫ਼ਾਰਮੂਲਾ ਡਰਾਉਣਾ ਦਿਖਾਈ ਦਿੰਦਾ ਹੈ ਪਰ ਮੈਂ ਤੁਹਾਨੂੰ ਯਕੀਨ ਦਿਵਾ ਸਕਦਾ ਹਾਂ ਕਿ ਇਹ ਸਮਝਣਾ ਆਸਾਨ ਹੈ, ਇਸ ਲਈ ਮੇਰੇ ਨਾਲ ਸਹਿਣ ਕਰੋ :)

1. ਕਿਉਂਕਿ ਟੈਕਸਟ ਕੇਸ ਨਹੀਂ ਹੈਮੇਰੇ ਲਈ ਮਹੱਤਵਪੂਰਨ ਹੈ, ਮੈਂ ਹਰ ਚੀਜ਼ ਨੂੰ ਛੋਟੇ ਅੱਖਰਾਂ ਵਿੱਚ ਬਦਲਣ ਲਈ LOWER(A2) ਦੀ ਵਰਤੋਂ ਕਰਦਾ ਹਾਂ।
2. ਫਿਰ SUBSTITUTE(LOWER(A2), "will",""))) – ਇਹ ਖਾਲੀ ਸਤਰ ("") ਨਾਲ ਬਦਲ ਕੇ 'ਇੱਛਾ' ਦੀਆਂ ਸਾਰੀਆਂ ਘਟਨਾਵਾਂ ਤੋਂ ਛੁਟਕਾਰਾ ਪਾਉਂਦਾ ਹੈ।
3. ਉਸ ਤੋਂ ਬਾਅਦ, ਮੈਂ ਕੁੱਲ ਸਤਰ ਦੀ ਲੰਬਾਈ ਤੋਂ 'will' ਸ਼ਬਦ ਤੋਂ ਬਿਨਾਂ ਅੱਖਰਾਂ ਦੀ ਸੰਖਿਆ ਨੂੰ ਘਟਾ ਦਿੰਦਾ ਹਾਂ। . ਮੈਨੂੰ ਜੋ ਨੰਬਰ ਮਿਲਦਾ ਹੈ ਉਹ ਹਰ ਕਤਾਰ ਵਿੱਚ 'ਇੱਛਾ' ਦੀਆਂ ਸਾਰੀਆਂ ਘਟਨਾਵਾਂ ਵਿੱਚ ਸਾਰੇ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਦਾ ਹੈ।

   ਇਸ ਤਰ੍ਹਾਂ, ਜੇਕਰ 'will' ਇੱਕ ਵਾਰ ਦਿਖਾਈ ਦਿੰਦਾ ਹੈ, ਤਾਂ ਸੰਖਿਆ 4 ਹੈ ਕਿਉਂਕਿ ਸ਼ਬਦ ਵਿੱਚ 4 ਅੱਖਰ ਹਨ। ਜੇ ਇਹ ਦੋ ਵਾਰ ਦਿਖਾਈ ਦਿੰਦਾ ਹੈ, ਤਾਂ ਸੰਖਿਆ 8 ਹੈ, ਅਤੇ ਇਸ ਤਰ੍ਹਾਂ ਹੀ।

   ਇਹ ਵੀ ਵੇਖੋ: ਐਕਸਲ ਵਿੱਚ ਸੈੱਲ ਤੋਂ ਟੈਕਸਟ ਜਾਂ ਅੱਖਰ ਨੂੰ ਕਿਵੇਂ ਹਟਾਉਣਾ ਹੈ
4. ਅੰਤ ਵਿੱਚ, ਮੈਂ ਇਸ ਸੰਖਿਆ ਨੂੰ ਸਿੰਗਲ ਸ਼ਬਦ 'will' ਦੀ ਲੰਬਾਈ ਨਾਲ ਵੰਡਦਾ ਹਾਂ।

ਨੁਕਤਾ। ਅਤੇ ਦੁਬਾਰਾ, ਜੇਕਰ ਤੁਸੀਂ 'will' ਸ਼ਬਦ ਦੇ ਸਾਰੇ ਦਿੱਖਾਂ ਦੀ ਕੁੱਲ ਸੰਖਿਆ ਪ੍ਰਾਪਤ ਕਰਨਾ ਚਾਹੁੰਦੇ ਹੋ, ਤਾਂ SUMPRODUCT:

=SUMPRODUCT((LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "will", "")))/LEN("will"))

ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਦੇਖ ਸਕਦੇ ਹੋ ਦੁਆਰਾ ਪੂਰੇ ਫਾਰਮੂਲੇ ਨੂੰ ਨੱਥੀ ਕਰੋ। , ਅੱਖਰ-ਗਿਣਤੀ ਦੇ ਇਹ ਸਾਰੇ ਕੇਸ Google ਸ਼ੀਟਾਂ ਲਈ ਇੱਕੋ ਜਿਹੇ ਫੰਕਸ਼ਨਾਂ ਦੇ ਸਮਾਨ ਪੈਟਰਨਾਂ ਦੁਆਰਾ ਹੱਲ ਕੀਤੇ ਜਾਂਦੇ ਹਨ: LEN, SUBSTITUTE, LOWER, ਅਤੇ SUMPRODUCT.

ਜੇਕਰ ਕੁਝ ਫਾਰਮੂਲੇ ਅਜੇ ਵੀ ਤੁਹਾਨੂੰ ਉਲਝਣ ਵਿੱਚ ਪਾਉਂਦੇ ਹਨ, ਜਾਂ ਜੇਕਰ ਤੁਸੀਂ ਨਹੀਂ ਹੋ ਯਕੀਨੀ ਬਣਾਓ ਕਿ ਤੁਹਾਡੇ ਖਾਸ ਕੰਮ ਲਈ ਹਰ ਚੀਜ਼ ਨੂੰ ਕਿਵੇਂ ਲਾਗੂ ਕਰਨਾ ਹੈ, ਸ਼ਰਮਿੰਦਾ ਨਾ ਹੋਵੋ ਅਤੇ ਹੇਠਾਂ ਦਿੱਤੇ ਟਿੱਪਣੀ ਭਾਗ ਵਿੱਚ ਪੁੱਛੋ!