જો કે Google શીટ્સમાં શબ્દ અને અક્ષરોની ગણતરી દુર્લભ કિસ્સાઓમાં થાય છે, તે હજી પણ કાર્યક્ષમતા છે જે આપણામાંથી કેટલાક મેનૂમાં જ જોવાની અપેક્ષા રાખે છે. પરંતુ Google ડૉક્સથી વિપરીત, Google શીટ્સ માટે, તે LEN ફંક્શન છે જે તે કરે છે.

સ્પ્રેડશીટ્સમાં અક્ષરોની ગણતરી કરવાની ઘણી અલગ રીતો હોવા છતાં, આજની બ્લોગ પોસ્ટ તેના તરીકે LEN ફંક્શનને આવરી લેશે. કોષ્ટકોનો મુખ્ય હેતુ છે – સારું, ગણતરી :) જો કે, તે ભાગ્યે જ તેના પોતાના પર ઉપયોગમાં લેવાય છે. નીચે તમે Google શીટ્સ LEN નો યોગ્ય રીતે ઉપયોગ કેવી રીતે કરવો અને સ્પ્રેડશીટ્સમાં અક્ષરોની ગણતરી કરવા માટે સૌથી વધુ જોઈતા સૂત્રો કેવી રીતે મેળવવું તે શીખી શકશો.

Google શીટ્સ LEN ફંક્શન – ઉપયોગ અને સિન્ટેક્સ

The Google શીટ્સમાં LEN ફંક્શનનો મુખ્ય અને એકમાત્ર હેતુ સ્ટ્રિંગ લંબાઈ મેળવવાનો છે. તે એટલું સરળ છે કે તેને ફક્ત 1 દલીલની જરૂર છે:

• તે ક્યાં તો ટેક્સ્ટને ડબલ-ક્વોટ્સમાં લઈ શકે છે:

  =LEN("Yggdrasil")

• અથવા રસના લખાણ સાથેના કોષનો સંદર્ભ:

  =LEN(A2)

ચાલો જોઈએ કે સ્પ્રેડશીટ્સમાં ફંક્શનનો ઉપયોગ કરવામાં કોઈ ખાસિયત છે કે કેમ.

અક્ષર Google શીટ્સમાં ગણતરી કરો

હું સૌથી સરળ ઑપરેશનથી પ્રારંભ કરીશ: Google શીટ્સમાં અક્ષરોની ગણતરી સૌથી સામાન્ય રીતે કરો - LEN ફંક્શનનો ઉપયોગ કરીને ટેક્સ્ટ સાથે સેલનો સંદર્ભ આપીને.

I B2 માં ફોર્મ્યુલા દાખલ કરો અને દરેક પંક્તિમાં અક્ષરોની ગણતરી કરવા માટે તેને સમગ્ર કૉલમમાં કૉપિ કરો:

=LEN(A2)

નોંધ. LEN કાર્યબધા અક્ષરોની ગણતરી કરે છે: અક્ષરો, સંખ્યાઓ, જગ્યાઓ, વિરામચિહ્નો, વગેરે.

તમે વિચારી શકો છો કે સમાન રીતે તમે કોષોની સમગ્ર શ્રેણી માટે આ રીતે અક્ષર ગણતરી કરી શકો છો, જેમ કે: LEN(A2:A6) . પરંતુ, તે ગમે તેટલું વિચિત્ર છે, તે આ રીતે કામ કરતું નથી.

કેટલાક કોષોમાં કુલ અક્ષરો માટે, તમારે તમારા LEN ને SUMPRODUCT માં લપેટી લેવું જોઈએ - તે કાર્ય કે જે દાખલ કરેલ શ્રેણીઓમાંથી સંખ્યાઓને વધારે છે. મારા કિસ્સામાં, શ્રેણી LEN ફંક્શન દ્વારા પરત કરવામાં આવે છે:

=SUMPRODUCT(LEN(A2:A6))

અલબત્ત, તમે તેના બદલે SUM ફંક્શનને સામેલ કરી શકો છો. પરંતુ Google શીટ્સમાં SUM અન્ય કાર્યોમાંથી એરે પર પ્રક્રિયા કરતું નથી. તેને કામ કરવા માટે, તમારે બીજું ફંક્શન ઉમેરવું પડશે - ArrayFormula:

=ArrayFormula(SUM(LEN(A2:A6)))

Google શીટ્સમાં ખાલી જગ્યાઓ વગર અક્ષરોની ગણતરી કેવી રીતે કરવી

મેં ઉપર નોંધ્યું તેમ, Google શીટ્સ LEN ફંક્શન સ્પેસ સહિત તે જુએ છે તે દરેક અક્ષરની ગણતરી કરે છે.

પરંતુ જો ભૂલથી વધારાની જગ્યાઓ ઉમેરવામાં આવી હોય અને તમે તેને પરિણામ માટે ધ્યાનમાં લેવા માંગતા ન હોવ તો શું?

જેવા કેસો માટે આ, Google શીટ્સમાં TRIM ફંક્શન છે. તે આગળ, પાછળની, અને વચ્ચેની પુનરાવર્તિત જગ્યાઓ માટે ટેક્સ્ટને તપાસે છે. જ્યારે TRIM ને LEN સાથે જોડી દેવામાં આવે છે, ત્યારે બાદમાં તે બધી વિષમ જગ્યાઓની ગણતરી થતી નથી.

અહીં એક ઉદાહરણ છે. મેં કૉલમ A માં અલગ-અલગ પોઝિશન્સમાં જગ્યાઓ ઉમેરી છે. તમે જોઈ શકો છો કે, Google શીટ્સ LEN તે બધાની ગણતરી કરે છે:

=LEN(A2)

પરંતુ જેમ જેમ તમે TRIMને એકીકૃત કરો છો, તેમ તેમ તમામ વધારાના જગ્યાઓ છેઅવગણવામાં આવ્યું:

=LEN(TRIM(A2))

તમે આગળ જઈ શકો છો અને તમારા ફોર્મ્યુલાને શબ્દો વચ્ચેની તે એકલ જગ્યાઓને પણ અવગણી શકો છો. SUBSTITUTE કાર્ય મદદ કરશે. જો કે તેનો મુખ્ય હેતુ એક અક્ષરને બીજા અક્ષર સાથે બદલવાનો છે, તે ખાલી જગ્યાઓને સંપૂર્ણપણે ઘટાડવા માટે એક યુક્તિ છે:

• text_to_search એ શ્રેણી છે જેની સાથે તમે કામ કરો છો: કૉલમ A, અથવા A2 ચોક્કસ છે.
• શોધ_માટે ડબલ-અવતરણોમાં સ્પેસ અક્ષર હોવો જોઈએ: " "
• replace_with માં ખાલી ડબલ-ક્વોટ્સ હોવા જોઈએ. જો તમે સ્પેસને અવગણવા જઈ રહ્યાં છો, તો તમારે તેને શાબ્દિક રીતે કંઈપણ (ખાલી સ્ટ્રિંગ) સાથે બદલવાની જરૂર છે: ""
• occurence_number નો ઉપયોગ સામાન્ય રીતે દાખલાનો ઉલ્લેખ કરવા માટે થાય છે. બદલવાનું. પરંતુ હું બધી જગ્યાઓ વિના અક્ષરોની ગણતરી કેવી રીતે કરવી તેનું વર્ણન કરું છું, તેથી હું તમને આ દલીલને છોડી દેવાનું સૂચન કરું છું કારણ કે તે વૈકલ્પિક છે.

હવે આ બધાને Google શીટ્સ LEN માં એસેમ્બલ કરવાનો પ્રયાસ કરો અને તમે તે જોશો. કોઈ જગ્યા ધ્યાનમાં લેવામાં આવતી નથી:

=LEN(SUBSTITUTE(A2, " ", ""))

Google શીટ્સ: ચોક્કસ અક્ષરોની ગણતરી કરો

જ્યારે પણ તમને ચોક્કસ અક્ષરોની ગણતરી કરવાની જરૂર હોય ત્યારે Google શીટ્સ LEN અને SUBSTITUTE નો સમાન ટેન્ડમ વપરાય છે , અક્ષરો, અથવા સંખ્યાઓ.

મારા ઉદાહરણોમાં, હું અક્ષર 's' માટે ઘટનાઓની સંખ્યા શોધવા જઈ રહ્યો છું. અને આ વખતે, હું એક તૈયાર ફોર્મ્યુલાથી શરૂઆત કરીશ:

=LEN(A2)-LEN(SUBSTITUTE(A2, "s", ""))

ચાલો તે કેવી રીતે સમજવા માટે તેને ટુકડાઓમાં તોડી નાખીએ.કામ કરે છે:

1. SUBSTITUTE(A2, "s", "") A2 માં અક્ષર 's' શોધે છે અને બધી ઘટનાઓને "કંઈ નથી", અથવા ખાલી શબ્દમાળા ( "").
2. LEN(SUBSTITUTE(A2, "s", "") A2 માં 's' સિવાયના તમામ અક્ષરોની સંખ્યા નક્કી કરે છે.
3. LEN(A2) A2 માં બધા અક્ષરોની ગણતરી કરે છે.
4. છેવટે, તમે એક બીજામાંથી બાદ કરો.

પરિણામ તફાવત બતાવે છે કે કેટલા 'ઓ' છે. સેલમાં:

નોંધ. તમને આશ્ચર્ય થશે કે શા માટે B1 કહે છે કે A2 માં માત્ર 1 's' છે જ્યારે તમે 3 જોઈ શકો છો?

વાત એ છે કે, SUBSTITUTE ફંક્શન કેસ-સેન્સિટિવ છે. મેં તેને 's' ના તમામ ઉદાહરણોને લોઅરકેસમાં લેવા કહ્યું અને તે કર્યું.

તેને ટેક્સ્ટ કેસને અવગણવા અને લોઅર અને અપર બંને કેસમાં અક્ષરોની પ્રક્રિયા કરવા માટે, તમારે વધુ એક Google શીટ્સ ફંક્શનને કૉલ કરવો પડશે મદદ માટે: LOWER.

ટીપ. Google શીટ્સમાં ટેક્સ્ટ કેસ બદલવાની અન્ય રીતો જુઓ.

તે Google શીટ્સ LEN અને TRIM જેટલું જ સરળ છે કારણ કે તેના માટે ફક્ત ટેક્સ્ટની જરૂર છે:

=LOWER(text)

અને તે ફક્ત સમગ્ર ટેક્સ્ટ સ્ટ્રીંગને પૂર્ણ કરે છે ઓ લોઅર કેસ. આ યુક્તિ તમને Google શીટ્સને ચોક્કસ અક્ષરોની ગણતરી કરવા માટે જરૂરી છે, પછી ભલેને તેમના ટેક્સ્ટ કેસ:

=LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "s", ""))

ટીપ. અને પહેલાની જેમ, શ્રેણીમાં ચોક્કસ અક્ષરોની કુલ ગણતરી કરવા માટે, તમારા LEN ને SUMPRODUCT માં લપેટો:

=SUMPRODUCT(LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "s", "")))

Google શીટ્સમાં શબ્દો ગણો

જ્યારે કોષોમાં બહુવિધ શબ્દો છે, સંભવ છે કે તમારે તેના બદલે તેમની સંખ્યા હોવી જરૂરી છેGoogle શીટ્સની સ્ટ્રિંગ લંબાઈ.

અને આમ કરવાની બહુવિધ રીતો હોવા છતાં, આજે હું ઉલ્લેખ કરીશ કે Google શીટ્સ LEN કેવી રીતે કાર્ય કરે છે.

મેં ચોક્કસ અક્ષરોની ગણતરી કરવા માટે ઉપયોગમાં લીધેલું સૂત્ર યાદ રાખો Google શીટ્સ? હકીકતમાં, તે અહીં પણ કામમાં આવશે. કારણ કે હું શબ્દોની શાબ્દિક ગણતરી કરવા જઈ રહ્યો નથી. તેના બદલે, હું શબ્દો વચ્ચે ખાલી જગ્યાઓની સંખ્યા ગણીશ અને પછી ફક્ત 1 ઉમેરીશ. એક નજર નાખો:

=LEN(A2)-LEN(SUBSTITUTE((A2), " ", ""))+1

1. LEN(A2) કોષમાંના તમામ અક્ષરોની સંખ્યા.
2. LEN(SUBSTITUTE((A2)," ","")) ટેક્સ્ટ સ્ટ્રીંગમાંથી બધી જગ્યાઓ દૂર કરે છે અને બાકીના અક્ષરોની ગણતરી કરે છે.
3. પછી તમે બીજામાંથી એક બાદબાકી કરો છો, અને તમને જે તફાવત મળે છે તે કોષમાં ખાલી જગ્યાઓની સંખ્યા છે.
4. શબ્દો હંમેશા એક વાક્યમાં ખાલી જગ્યાઓ કરતાં વધુ હોવાથી, તમે અંતે 1 ઉમેરો છો.

Google શીટ્સ: ચોક્કસ શબ્દોની ગણતરી કરો

આખરે, હું Google શીટ્સ ફોર્મ્યુલા શેર કરવા માંગુ છું જેનો ઉપયોગ તમે ચોક્કસ શબ્દોની ગણતરી કરવા માટે કરી શકો.

અહીં મારી પાસે એલિસ એડવેન્ચર્સ ઇન વન્ડરલેન્ડનું ધ મોક ટર્ટલનું ગીત છે:

હું જાણવા માંગુ છું કે દરેક પંક્તિમાં 'વિલ' શબ્દ કેટલી વાર દેખાય છે. હું માનું છું કે જો હું તમને કહું કે મને જે ફોર્મ્યુલાની જરૂર છે તે પહેલાની જેમ જ ફંક્શન ધરાવે છે: Google શીટ્સ LEN, SUBSTITUTE અને LOWER:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "will", "")))/LEN("will")

સૂત્ર કદાચ ડરામણી લાગે છે પરંતુ હું તમને ખાતરી આપી શકું છું કે તે સમજવું સરળ છે, તેથી મારી સાથે સહન કરો :)

1. કારણ કે ટેક્સ્ટ કેસ નથીમારા માટે મહત્વપૂર્ણ છે, હું દરેક વસ્તુને લોઅરકેસમાં ફેરવવા માટે LOWER(A2) નો ઉપયોગ કરું છું.
2. પછી SUBSTITUTE(LOWER(A2), "will",""))) – તે ખાલી શબ્દમાળાઓ ("") વડે બદલીને 'વિલ' ની બધી ઘટનાઓથી છૂટકારો મેળવે છે.
3. તે પછી, હું શબ્દમાળાની કુલ લંબાઈમાંથી 'વિલ' શબ્દ વગરના અક્ષરોની સંખ્યા બાદ કરું છું. . મને જે નંબર મળે છે તે દરેક પંક્તિમાં 'ઇચ્છા' ની તમામ ઘટનાઓમાં તમામ અક્ષરોની ગણતરી કરે છે.

   આમ, જો 'વિલ' એકવાર દેખાય છે, તો સંખ્યા 4 છે કારણ કે શબ્દમાં 4 અક્ષરો છે. જો તે બે વાર દેખાય છે, તો સંખ્યા 8 છે, અને તેથી વધુ.

4. આખરે, હું આ સંખ્યાને એક શબ્દ 'વિલ'ની લંબાઈથી વિભાજિત કરું છું.

ટીપ. અને ફરીથી, જો તમે 'વિલ' શબ્દના તમામ દેખાવની કુલ સંખ્યા મેળવવા માંગતા હો, તો ફક્ત SUMPRODUCT દ્વારા સમગ્ર સૂત્રને બંધ કરો:

=SUMPRODUCT((LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "will", "")))/LEN("will"))

જેમ તમે જોઈ શકો છો. , અક્ષર-ગણતરીનાં આ તમામ કેસો Google શીટ્સ માટે સમાન કાર્યોની સમાન પેટર્ન દ્વારા ઉકેલવામાં આવે છે: LEN, SUBSTITUTE, LOWER, અને SUMPRODUCT.

જો કેટલાક સૂત્રો તમને હજુ પણ મૂંઝવણમાં મૂકે છે, અથવા જો તમે નથી ખાતરી કરો કે તમારા ચોક્કસ કાર્ય માટે બધું કેવી રીતે લાગુ કરવું, શરમાશો નહીં અને નીચેના ટિપ્પણીઓ વિભાગમાં પૂછો!