Hoci sa počet slov a znakov v hárkoch Google používa len v ojedinelých prípadoch, stále ide o funkciu, ktorú niektorí z nás očakávajú priamo v ponuke. Na rozdiel od Dokumentov Google však v prípade hárkov Google túto funkciu vykonáva funkcia LEN.

Hoci existuje mnoho rôznych spôsobov, ako počítať znaky v tabuľkách, dnešný príspevok na blogu sa bude venovať funkcii LEN, keďže jej hlavným účelom v tabuľkách je - no, počítať :) Sama o sebe sa však takmer nepoužíva. Nižšie sa dozviete, ako správne používať funkciu LEN v tabuľkách Google Sheets a nájdete najvyhľadávanejšie vzorce na výpočet znakov v tabuľkách.

Funkcia LEN v tabuľkách Google - použitie a syntax

Hlavným a jediným účelom funkcie LEN v tabuľkách Google je získanie dĺžky reťazca. Je taká jednoduchá, že dokonca vyžaduje iba 1 argument:

• môže prijať buď samotný text v dvojitých úvodzovkách:

  =LEN("Yggdrasil")

• alebo odkaz na bunku so zaujímavým textom:

  =LEN(A2)

Pozrime sa, či existujú nejaké zvláštnosti pri používaní funkcie v tabuľkách.

Počet znakov v hárkoch Google

Začnem najjednoduchšou operáciou: v tabuľkách Google Sheets spočítam znaky najbežnejším spôsobom - odkazom na bunku s textom pomocou funkcie LEN.

Zadám vzorec do B2 a skopírujem ho do celého stĺpca, aby sa počítali znaky v každom riadku:

=LEN(A2)

Poznámka: Funkcia LEN počíta so všetkými znakmi: písmenami, číslicami, medzerami, interpunkčnými znamienkami atď.

Možno vás napadne, že podobným spôsobom by ste mohli spočítať znaky pre celý rozsah buniek, napríklad takto: LEN(A2:A6) . Ale, akokoľvek je to bizarné, takto to jednoducho nefunguje.

Ak chcete sčítať znaky vo viacerých bunkách, mali by ste funkciu LEN zabaliť do funkcie SUMPRODUCT - funkcie, ktorá sčíta čísla zo zadaných rozsahov. V mojom prípade je rozsah vrátený funkciou LEN:

=SUMPRODUKT(LEN(A2:A6))

Samozrejme, namiesto toho by ste mohli začleniť funkciu SUM. SUM v Google Sheets však nespracúva polia z iných funkcií. Aby to fungovalo, budete musieť pridať ďalšiu funkciu - ArrayFormula:

=ArrayFormula(SUM(LEN(A2:A6)))

Ako počítať znaky bez medzier v hárkoch Google

Ako som uviedol vyššie, funkcia LEN v hárkoch Google počíta každý znak vrátane medzier.

Ale čo ak sú omylom pridané ďalšie medzery a vy ich nechcete zohľadniť pri výsledku?

Pre takéto prípady je v tabuľkách Google Sheets k dispozícii funkcia TRIM. Kontroluje text, či sa v ňom nenachádzajú úvodné, koncové a opakujúce sa medzery. Keď je funkcia TRIM spojená s funkciou LEN, táto funkcia nezapočítava všetky tieto nepárne medzery.

Tu je príklad. Pridával som medzery na rôzne pozície v stĺpci A. Ako vidíte, keď je to samo o sebe, Google Sheets LEN ich všetky spočíta:

=LEN(A2)

Po integrácii funkcie TRIM sa však všetky dodatočné medzery ignorujú:

=LEN(TRIM(A2))

Môžete ísť ešte ďalej a prinútiť vzorec, aby nebral do úvahy ani tie jednotlivé medzery medzi slovami. Pomôže vám s tým funkcia SUBSTITUTE. Hoci jej hlavným účelom je nahradiť jeden znak iným, existuje trik, vďaka ktorému medzery úplne zredukuje:

• text_to_search je rozsah, s ktorým pracujete: stĺpec A alebo A2 presnejšie povedané.
• search_for by mal byť znak medzery v dvojitých úvodzovkách: " "
• replace_with by mali obsahovať prázdne dvojité úvodzovky. Ak chcete ignorovať medzery, musíte ich nahradiť doslova ničím (prázdnym reťazcom): ""
• occurence_number sa zvyčajne používa na zadanie inštancie, ktorá sa má nahradiť. Keďže však popisujem, ako počítať znaky bez všetkých medzier, odporúčam tento argument vynechať, pretože je nepovinný.

Teraz ich skúste všetky zložiť do hárkov Google LEN a uvidíte, že sa nezohľadňuje žiadna medzera:

=LEN(SUBSTITUTE(A2, " ", ""))

Tabuľky Google: počítanie konkrétnych znakov

Rovnaký tandem LEN a SUBSTITUTE v hárkoch Google sa používa vždy, keď potrebujete spočítať konkrétne znaky, písmená alebo čísla.

V mojich príkladoch budem zisťovať počet výskytov písmena "s". A tentoraz začnem s pripraveným vzorcom:

=LEN(A2)-LEN(SUBSTITUTE(A2, "s", ""))

Rozdeľme ho na časti, aby sme pochopili, ako funguje:

1. SUBSTITUTE(A2, "s", "") vyhľadá písmeno 's' v A2 a nahradí všetky výskyty písmenom "nič" alebo prázdnym reťazcom ("").
2. LEN(SUBSTITUTE(A2, "s", "") vypočíta počet všetkých znakov okrem 's' v A2.
3. LEN(A2) počíta všetky znaky v A2.
4. Nakoniec odčítate jeden od druhého.

Rozdiel vo výsledku ukazuje, koľko "s" sa nachádza v bunke:

Poznámka: Možno sa čudujete, prečo B1 hovorí, že v A2 je len 1 "s", zatiaľ čo vy vidíte 3?

Ide o to, že funkcia SUBSTITUTE rozlišuje veľké a malé písmená. Požiadal som ju, aby všetky prípady 's' písala malými písmenami, a tak to aj urobila.

Ak chcete, aby ignoroval veľké a malé písmená textu a spracovával písmená v malých aj veľkých písmenách, budete musieť zavolať na pomoc ešte jednu funkciu Tabuliek Google: LOWER.

Tip. Pozrite si ďalšie spôsoby zmeny veľkosti písmen textu v hárkoch Google.

Je to rovnako jednoduché ako v tabuľke Google Sheets LEN a TRIM, pretože všetko, čo potrebuje, je text:

=LOWER(text)

A jediné, čo urobí, je, že celý textový reťazec zmení na malé písmená. Tento trik je presne to, čo potrebujete na to, aby hárky Google počítali konkrétne znaky bez ohľadu na veľkosť písmen v texte:

=LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "s", "")

Tip. A ako predtým, ak chcete spočítať celkový počet konkrétnych znakov v rozsahu, zabaľte LEN do SUMPRODUCT:

=SUMPRODUCT(LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "s", ""))

Počítanie slov v hárkoch Google

Ak je v bunkách viac slov, je pravdepodobné, že namiesto dĺžky reťazca v tabuľke Google Sheets budete potrebovať ich počet.

Hoci existuje viacero spôsobov, ako to urobiť, dnes spomeniem, ako túto úlohu vykonáva Google Sheets LEN.

Pamätáte si vzorec, ktorý som použil na počítanie konkrétnych znakov v tabuľkách Google? V skutočnosti sa bude hodiť aj tu. Nebudem totiž doslova počítať slová. Namiesto toho spočítam počet medzier medzi slovami a potom jednoducho pripočítam 1. Pozrite sa:

=LEN(A2)-LEN(SUBSTITUTE((A2), " ", ""))+1

1. LEN(A2) počíta počet všetkých znakov v bunke.
2. LEN(SUBSTITUTE((A2)," ","") odstráni z textového reťazca všetky medzery a spočíta zvyšné znaky.
3. Potom odčítate jedno od druhého a rozdiel, ktorý dostanete, je počet medzier v bunke.
4. Keďže počet slov vo vete vždy prevyšuje počet medzier o jednu, na konci sa pridá 1.

Tabuľky Google: počítanie konkrétnych slov

Na záver by som sa s vami rád podelil o vzorec z hárkov Google, ktorý môžete použiť na počítanie konkrétnych slov.

Tu mám Pieseň posmešnej korytnačky z Aliciiných dobrodružstiev v krajine zázrakov:

Chcem vedieť, koľkokrát sa v každom riadku objaví slovo "will". Verím, že vás neprekvapí, keď vám poviem, že vzorec, ktorý potrebujem, pozostáva z rovnakých funkcií ako predtým: Google Sheets LEN, SUBSTITUTE a LOWER:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "will", "")))/LEN("will")

Vzorec môže vyzerať desivo, ale môžem vás uistiť, že je ľahko pochopiteľný, takže vydržte :)

1. Keďže mi na veľkosti písmen v texte nezáleží, používam LOWER(A2) aby sa všetko zmenilo na malé písmená.
2. Potom ide SUBSTITUTE(LOWER(A2), "will","")) - zbaví sa všetkých výskytov 'will' tým, že ich nahradí prázdnymi reťazcami ("").
3. Potom od celkovej dĺžky reťazca odpočítam počet znakov bez slova "will". Číslo, ktoré dostanem, počíta všetky znaky vo všetkých výskytoch slova "will" v každom riadku.

   Ak sa teda slovo "will" objaví raz, číslo je 4, pretože v slove sú 4 písmená. Ak sa objaví dvakrát, číslo je 8 atď.

4. Nakoniec tento počet vydelím dĺžkou jedného slova "will".

Tip: Ak chcete získať celkový počet všetkých výskytov slova "will", uzavrite celý vzorec pomocou SUMPRODUCT:

=SUMPRODUCT((LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "will", "")))/LEN("will"))

Ako vidíte, všetky tieto prípady počtu znakov sa riešia rovnakými vzormi rovnakých funkcií pre tabuľky Google: LEN, SUBSTITUTE, LOWER a SUMPRODUCT.

Ak vás niektoré vzorce stále mätú alebo si nie ste istí, ako všetko aplikovať na vašu konkrétnu úlohu, nehanbite sa a opýtajte sa v sekcii komentárov nižšie!