Tot i que el recompte de paraules i caràcters a Fulls de càlcul de Google s'utilitza en casos excepcionals, encara és la funcionalitat que alguns de nosaltres esperem veure directament al menú. Però a diferència de Google Docs, per a Google Sheets, és la funció LEN la que fa això.

Tot i que hi ha moltes maneres diferents de comptar els caràcters als fulls de càlcul, l'entrada del bloc d'avui tractarà la funció LEN com a L'objectiu principal de les taules és - bé, comptar :) No obstant això, gairebé mai s'utilitza per si sol. A continuació aprendràs a utilitzar Google Sheets LEN correctament i trobar les fórmules més buscades per calcular caràcters en fulls de càlcul.

Funció LEN de Google Sheets: ús i sintaxi

El principal i l'únic propòsit de la funció LEN a Google Sheets és obtenir la longitud de la cadena. És tan senzill que fins i tot només requereix 1 argument:

• pot agafar el propi text entre cometes dobles:

  =LEN("Yggdrasil")

• o una referència a una cel·la amb el text d'interès:

  =LEN(A2)

A veure si hi ha alguna peculiaritat en utilitzar la funció en fulls de càlcul.

Caràcter. comptar a Google Sheets

Començaré amb l'operació més senzilla: fer un recompte de caràcters a Google Sheets de la manera més habitual: fent referència a una cel·la amb el text mitjançant la funció LEN.

I introduïu la fórmula a B2 i copieu-la a tota la columna per comptar els caràcters de cada fila:

=LEN(A2)

Nota. La funció LENcalcula tots els caràcters: lletres, números, espais, signes de puntuació, etc.

Potser pensar que d'una manera similar podríeu fer un recompte de caràcters per a tot el rang de cel·les, com aquest: LEN(A2:A6) . Però, com Per estrany que sigui, no funciona simplement d'aquesta manera.

Per sumar caràcters en diverses cel·les, hauríeu d'embolicar el vostre LEN a SUMPRODUCT: la funció que suma els números dels intervals introduïts. En el meu cas, l'interval el retorna la funció LEN:

=SUMPRODUCT(LEN(A2:A6))

Per descomptat, podeu incorporar la funció SUMA. Però SUM a Google Sheets no processa matrius d'altres funcions. Perquè funcioni, haureu d'afegir una altra funció: ArrayFormula:

=ArrayFormula(SUM(LEN(A2:A6)))

Com comptar caràcters sense espais a Google Sheets

Com he assenyalat anteriorment, Google Sheets La funció LEN compta tots i cadascun dels caràcters que veu, inclosos els espais.

Però, què passa si hi ha espais addicionals afegits per error i no els voleu tenir en compte per al resultat?

Per a casos com ara això, hi ha la funció TRIM a Google Sheets. Comprova el text per si hi ha espais inicials, posteriors i repetits entremig. Quan TRIM es combina amb LEN, aquest últim no compta tots aquests espais estranys.

Aquí teniu un exemple. He afegit espais en diferents posicions a la columna A. Com podeu veure, quan és sol, Google Sheets LEN els compta tots:

=LEN(A2)

Però tan bon punt integreu TRIM, tot extra els espais sónignorat:

=LEN(TRIM(A2))

Pots anar més enllà i fer que la teva fórmula no tingui en compte fins i tot els espais únics entre paraules. La funció de SUBSTITUT ajudarà. Tot i que el seu propòsit principal és substituir un caràcter per un altre, hi ha un truc per reduir els espais completament:

• text_to_search és l'interval amb el qual treballeu: columna A, o A2 per ser exactes.
• cerca_per hauria de ser un espai entre cometes dobles: " "
• replace_with hauria de contenir cometes dobles buides. Si voleu ignorar els espais, haureu de substituir-los per literalment res (cadena buida): ""
• occurrence_number normalment s'utilitza per especificar la instància. per reemplaçar. Però com que estic descrivint com comptar els caràcters sense tots els espais, us suggereixo que ometeu aquest argument, ja que és opcional.

Ara proveu de reunir-los a Google Sheets LEN i ho veureu. no es té en compte cap espai:

=LEN(SUBSTITUTE(A2, " ", ""))

Fulls de Google: comptar caràcters específics

S'utilitza el mateix tàndem de fulls de càlcul de Google LEN i SUBSTITUTE sempre que necessiteu comptar caràcters específics , lletres o números.

En els meus exemples, esbrinaré el nombre d'ocurrències de la lletra 's'. I aquesta vegada, començaré amb una fórmula ja feta:

=LEN(A2)-LEN(SUBSTITUTE(A2, "s", ""))

Anem-la a trossos per entendre comfunciona:

1. SUBSTITUTE(A2, "s", "") cerca la lletra 's' a A2 i substitueix totes les aparicions per "res" o una cadena buida ( "").
2. LEN(SUBSTITUTE(A2, "s", "") calcula el nombre de tots els caràcters excepte les 's' a A2.
3. LEN(A2) compta tots els caràcters d'A2.
4. Finalment, se'n resta un de l'altre.

La diferència del resultat mostra quantes "s" hi ha. a la cel·la:

Nota. Potser us preguntareu per què B1 diu que només hi ha 1 's' a A2 mentre que podeu veure'n 3?

El fet és que la funció SUBSTITUTE distingeix entre majúscules i minúscules. Li vaig demanar que prengués totes les instàncies de "s" en minúscules i així ho va fer.

Per fer que ignori les majúscules i minúscules del text i processés lletres tant en minúscules com en majúscules, haureu de trucar a una funció més de Fulls de càlcul de Google per obtenir ajuda: BAIX.

Consell. Consulteu altres maneres de canviar les majúscules i minúscules del text a Fulls de càlcul de Google.

És tan senzill com LEN i TRIM de Fulls de càlcul de Google perquè tot el que requereix és el text:

=LOWER(text)

I tot el que fa és convertir tota la cadena de text int o minúscula. Aquest truc és exactament el que necessiteu perquè Fulls de càlcul de Google compti caràcters específics, independentment de les majúscules i minúscules:

=LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "s", ""))

Consell. I com abans, per comptar el total de caràcters específics de l'interval, emboliqueu el vostre LEN a SUMPRODUCT:

=SUMPRODUCT(LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "s", "")))

Compteu paraules a Google Sheets

Quan hi hagi Hi ha diverses paraules a les cel·les, és probable que hàgiu de tenir el seu número en lloc dela longitud de la cadena de fulls de càlcul de Google.

I encara que hi ha diverses maneres de fer-ho, avui esmentaré com fa la feina de Google Sheets LEN.

Recordeu la fórmula que vaig utilitzar per comptar caràcters específics en Fulls de càlcul de Google? De fet, aquí també serà útil. Perquè no comptaré literalment paraules. En comptes d'això, comptaré el nombre d'espais entre les paraules i després simplement afegiré 1. Fes una ullada:

=LEN(A2)-LEN(SUBSTITUTE((A2), " ", ""))+1

1. LEN(A2) compta el nombre de tots els caràcters de la cel·la.
2. LEN(SUBSTITUTE((A2)," ","")) elimina tots els espais de la cadena de text i compta els caràcters restants.
3. Després se'n resta un de l'altre, i la diferència que s'obté és el nombre d'espais de la cel·la.
4. Com que les paraules sempre superen els espais d'una frase per un, afegeix 1 al final.

Fulls de càlcul de Google: comptar paraules específiques

Finalment, m'agradaria compartir una fórmula de Fulls de càlcul de Google que podeu utilitzar per comptar paraules específiques.

Aquí tinc The Mock Turtle's Song de Les aventures d'Alícia al país de les meravelles:

Vull saber quantes vegades apareix la paraula "voluntarà" a cada fila. Crec que no us sorprendrà si us dic que la fórmula que necessito consta de les mateixes funcions que abans: Google Sheets LEN, SUBSTITUTE i LOWER:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "will", "")))/LEN("will")

La fórmula pot sembla espantós, però us puc assegurar que és fàcil d'entendre, així que patiu amb mi :)

1. Com que el text no ésm'importa, faig servir MINÚLLA(A2) per convertir-ho tot en minúscules.
2. Després passa a SUBSTITUT(MINÚLLA(A2), "serà", ""))) : elimina totes les aparicions de "will" substituint-les per cadenes buides ("").
3. Després, resta el nombre de caràcters sense la paraula "will" de la longitud total de la cadena. . El nombre que obtinc compta tots els caràcters de totes les aparicions de "voluntad" a cada fila.

   Per tant, si "will" apareix una vegada, el número és 4, ja que hi ha 4 lletres a la paraula. Si apareix dues vegades, el número és 8, i així successivament.

4. Finalment, divideixo aquest nombre per la longitud de la paraula "voluntarà".

Consell. I, de nou, si preferiu obtenir el nombre total de totes les aparicions de la paraula "voluntarà", només cal que adjunteu la fórmula sencera per SUMPRODUCT:

=SUMPRODUCT((LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "will", "")))/LEN("will"))

Com podeu veure , tots aquests casos de recompte de caràcters es resolen amb els mateixos patrons de les mateixes funcions per a Fulls de càlcul de Google: LEN, SUBSTITUTE, LOWER i SUMPRODUCT.

Si algunes fórmules encara et confonen, o si no ho ets Assegureu-vos de com aplicar-ho tot a la vostra tasca particular, no tingueu vergonya i pregunteu a la secció de comentaris a continuació!