যদিও Google পত্রকগুলিতে শব্দ এবং অক্ষর গণনা বিরল ক্ষেত্রে ব্যবহার করা হয়, তবুও এটি এমন কার্যকারিতা যা আমাদের মধ্যে কেউ কেউ সরাসরি মেনুতে দেখতে পাবে। কিন্তু Google ডক্সের বিপরীতে, Google পত্রকগুলির জন্য, এটি LEN ফাংশন যা এটি করে৷

যদিও স্প্রেডশীটে অক্ষর গণনা করার বিভিন্ন উপায় রয়েছে, আজকের ব্লগ পোস্টটি LEN ফাংশনটিকে তার হিসাবে কভার করবে টেবিলের মূল উদ্দেশ্য হল – ভাল, গণনা করা :) যাইহোক, এটি নিজে থেকে খুব কমই ব্যবহৃত হয়। নিচে আপনি শিখবেন কিভাবে Google Sheets LEN সঠিকভাবে ব্যবহার করতে হয় এবং স্প্রেডশীটে অক্ষর গণনা করার জন্য সবচেয়ে কাঙ্খিত সূত্রগুলি খুঁজে বের করতে হয়।

Google শীট LEN ফাংশন – ব্যবহার এবং সিনট্যাক্স

Google শীটে LEN ফাংশনের প্রধান এবং একমাত্র উদ্দেশ্য হল স্ট্রিং দৈর্ঘ্য পাওয়া। এটি এতই সহজ যে এটির জন্য শুধুমাত্র 1টি আর্গুমেন্টের প্রয়োজন হয়:

• এটি টেক্সটটিকেই ডাবল-কোটে নিতে পারে:

  =LEN("Yggdrasil")

• অথবা আগ্রহের টেক্সট সহ একটি কক্ষের রেফারেন্স:

  =LEN(A2)

আসুন স্প্রেডশীটে ফাংশনটি ব্যবহার করার ক্ষেত্রে কোন বিশেষত্ব আছে কিনা তা দেখা যাক।

চরিত্র Google পত্রকগুলিতে গণনা করুন

আমি সবচেয়ে সহজ অপারেশন দিয়ে শুরু করব: গুগল শীটে একটি অক্ষর গণনা করুন সবচেয়ে সাধারণ উপায়ে - LEN ফাংশন ব্যবহার করে পাঠ্য সহ একটি সেল উল্লেখ করে৷

আমি B2 তে সূত্রটি প্রবেশ করান এবং প্রতিটি সারিতে অক্ষর গণনা করতে সমগ্র কলামের নিচে অনুলিপি করুন:

=LEN(A2)

নোট। LEN ফাংশনসমস্ত অক্ষর গণনা করে: অক্ষর, সংখ্যা, স্পেস, বিরাম চিহ্ন, ইত্যাদি।

আপনি মনে করতে পারেন যে একইভাবে আপনি কোষের সম্পূর্ণ পরিসরের জন্য একটি অক্ষর গণনা করতে পারেন, যেমন: LEN(A2:A6) । কিন্তু, যেমন এটি যেমন উদ্ভট, এটি কেবল এইভাবে কাজ করে না৷

বিভিন্ন কক্ষের মোট অক্ষরগুলির জন্য, আপনাকে SUMPRODUCT-এ আপনার LEN মোড়ানো উচিত - যে ফাংশনটি প্রবেশ করা রেঞ্জ থেকে সংখ্যাগুলিকে লম্বা করে৷ আমার ক্ষেত্রে, পরিসরটি LEN ফাংশন দ্বারা ফেরত দেওয়া হয়:

=SUMPRODUCT(LEN(A2:A6))

অবশ্যই, আপনি পরিবর্তে SUM ফাংশন অন্তর্ভুক্ত করতে পারেন। কিন্তু Google পত্রকের SUM অন্যান্য ফাংশন থেকে অ্যারে প্রক্রিয়া করে না। এটি কাজ করার জন্য, আপনাকে অন্য একটি ফাংশন যোগ করতে হবে - ArrayFormula:

=ArrayFormula(SUM(LEN(A2:A6)))

Google Sheets-এ স্পেস ছাড়া অক্ষরগুলি কীভাবে গণনা করা যায়

যেমন আমি উপরে উল্লেখ করেছি, Google Sheets LEN ফাংশন শূন্যস্থান সহ এটি দেখা প্রতিটি অক্ষরকে গণনা করে৷

কিন্তু যদি ভুলবশত অতিরিক্ত স্পেস যোগ হয়ে যায় এবং আপনি ফলাফলের জন্য সেগুলি বিবেচনা করতে না চান?

এর মতো ক্ষেত্রে এটি, গুগল শীটে TRIM ফাংশন রয়েছে। এটি লিডিং, ট্র্যালিং এবং এর মধ্যে পুনরাবৃত্ত স্থানগুলির জন্য পাঠ্য পরীক্ষা করে। যখন TRIM-কে LEN-এর সাথে পেয়ার করা হয়, তখন পরেরটি সেই সব বিজোড় স্পেস গণনা করে না৷

এখানে একটি উদাহরণ দেওয়া হল৷ আমি কলাম A-তে বিভিন্ন অবস্থানে স্পেস যোগ করেছি। আপনি দেখতে পাচ্ছেন, যখন নিজে থেকে, Google পত্রক LEN সেগুলিকে গণনা করে:

=LEN(A2)

কিন্তু যত তাড়াতাড়ি আপনি TRIM একত্রিত করবেন, সমস্ত অতিরিক্ত স্পেস হয়উপেক্ষা করা হয়েছে:

=LEN(TRIM(A2))

আপনি আরও এগিয়ে যেতে পারেন এবং আপনার সূত্রটিকে এমনকি শব্দগুলির মধ্যে সেই একক স্পেসগুলিকে উপেক্ষা করতে পারেন৷ SUBSTITUTE ফাংশন সাহায্য করবে। যদিও এর মূল উদ্দেশ্য হল একটি অক্ষরকে অন্য অক্ষর দিয়ে প্রতিস্থাপন করা, তবে এটিকে সম্পূর্ণরূপে স্পেস কমাতে একটি কৌশল রয়েছে:

• text_to_search আপনি যে পরিসরের সাথে কাজ করেন: কলাম A, অথবা A2 সঠিক হতে হবে।
• search_for ডাবল-উদ্ধৃতিতে একটি স্পেস অক্ষর হওয়া উচিত: " "
• replace_with -এ খালি ডবল-উদ্ধৃতি থাকা উচিত। আপনি যদি স্পেস উপেক্ষা করতে যাচ্ছেন, তাহলে আপনাকে আক্ষরিক অর্থে কিছুই (খালি স্ট্রিং) দিয়ে প্রতিস্থাপন করতে হবে: ""
• occurence_number সাধারণত উদাহরণ নির্দিষ্ট করতে ব্যবহৃত হয় প্রতিস্থাপন করতে. কিন্তু যেহেতু আমি বর্ণনা করছি কিভাবে সমস্ত স্পেস ছাড়াই অক্ষর গণনা করা যায়, তাই আমি আপনাকে এই যুক্তিটি বাদ দেওয়ার পরামর্শ দিচ্ছি কারণ এটি ঐচ্ছিক৷

এখন চেষ্টা করুন এবং Google পত্রক LEN-এ এগুলি একত্রিত করুন এবং আপনি এটি দেখতে পাবেন। কোনো স্থান বিবেচনায় নেওয়া হয় না:

=LEN(SUBSTITUTE(A2, " ", ""))

Google পত্রক: নির্দিষ্ট অক্ষর গণনা করুন

Google পত্রক LEN এবং SUBSTITUTE-এর একই ট্যান্ডেম ব্যবহার করা হয় যখনই আপনি নির্দিষ্ট অক্ষর গণনা করতে চান , অক্ষর, বা সংখ্যা।

আমার উদাহরণে, আমি 's' অক্ষরের জন্য উপস্থিতির সংখ্যা খুঁজে বের করতে যাচ্ছি। এবং এইবার, আমি একটি রেডিমেড ফর্মুলা দিয়ে শুরু করব:

=LEN(A2)-LEN(SUBSTITUTE(A2, "s", ""))

আসুন এটিকে টুকরো টুকরো করে বোঝা যাক কিভাবে এটিকাজ করে:

1. SUBSTITUTE(A2, "s", "") A2 তে 's' অক্ষর খোঁজে এবং "কিছুই না" বা খালি স্ট্রিং দিয়ে সমস্ত ঘটনা প্রতিস্থাপন করে ( "").
2. LEN(SUBSTITUTE(A2, "s", "") A2-তে 's' বাদে সমস্ত অক্ষরের সংখ্যা নির্ধারণ করে।
3. LEN(A2) A2-তে সমস্ত অক্ষর গণনা করে।
4. অবশেষে, আপনি একটি থেকে অন্যটি বিয়োগ করেন।

ফলাফলের পার্থক্য দেখায় কতগুলি 'গুলি' আছে ঘরে:

দ্রষ্টব্য। আপনি ভাবতে পারেন কেন B1 বলে যে A2 তে শুধুমাত্র 1 's' আছে যখন আপনি 3 দেখতে পাচ্ছেন?

ব্যাপারটি হল, SUBSTITUTE ফাংশনটি কেস-সংবেদনশীল। আমি এটিকে 's'-এর সমস্ত দৃষ্টান্ত ছোট হাতের অক্ষরে নিতে বলেছি এবং তাই হয়েছে৷

এটি টেক্সট কেসকে উপেক্ষা করতে এবং ছোট এবং বড় উভয় ক্ষেত্রেই অক্ষর প্রক্রিয়াকরণ করতে, আপনাকে আরও একটি Google পত্রক ফাংশন কল করতে হবে সাহায্যের জন্য: LOWER৷

টিপ৷ Google পত্রকগুলিতে পাঠ্যের কেস পরিবর্তন করার অন্যান্য উপায়গুলি দেখুন৷

এটি Google পত্রক LEN এবং TRIM-এর মতোই সহজ কারণ এটির জন্য যা প্রয়োজন তা হল পাঠ্য:

=LOWER(text)

এবং এটি যা করে তা হল পুরো টেক্সট স্ট্রিং int ঘুরিয়ে দেওয়া o ছোট হাতের অক্ষর। এই কৌশলটি ঠিক আপনার Google পত্রককে নির্দিষ্ট অক্ষর গণনা করার জন্য তাদের পাঠ্য ক্ষেত্রে যাই হোক না কেন:

=LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "s", ""))

টিপ। এবং আগের মতই, পরিসরে মোট নির্দিষ্ট অক্ষর গণনা করতে, আপনার LEN SUMPRODUCT এ মুড়ে দিন:

=SUMPRODUCT(LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "s", "")))

Google পত্রকগুলিতে শব্দ গণনা করুন

যখন কক্ষে একাধিক শব্দ আছে, সম্ভবত আপনার পরিবর্তে তাদের সংখ্যা থাকতে হবেGoogle শীট স্ট্রিং দৈর্ঘ্য।

এবং এটি করার একাধিক উপায় থাকলেও, আজ আমি উল্লেখ করব কিভাবে Google পত্রক LEN কাজ করে।

আমি যে সূত্রে নির্দিষ্ট অক্ষর গণনা করতাম তা মনে রাখবেন গুগল শীট? আসলে, এটি এখানেও কাজে আসবে। কারণ আমি আক্ষরিক অর্থে শব্দ গণনা করতে যাচ্ছি না। পরিবর্তে, আমি শব্দগুলির মধ্যে শূন্যস্থানের সংখ্যা গণনা করব এবং তারপরে কেবল 1 যোগ করব। একবার দেখুন:

=LEN(A2)-LEN(SUBSTITUTE((A2), " ", ""))+1

1. LEN(A2) গণনা করে কক্ষের সমস্ত অক্ষরের সংখ্যা।
2. LEN(SUBSTITUTE((A2)," ","")) পাঠ্য স্ট্রিং থেকে সমস্ত স্পেস সরিয়ে দেয় এবং অবশিষ্ট অক্ষর গণনা করে।
3. তারপর আপনি অন্যটি থেকে একটি বিয়োগ করবেন, এবং আপনি যে পার্থক্যটি পাবেন তা হল কক্ষের স্পেস সংখ্যা৷
4. যেহেতু শব্দগুলি সর্বদা একটি বাক্যে একটি করে স্পেস সংখ্যা ছাড়িয়ে যায়, আপনি শেষে 1 যোগ করুন৷

Google পত্রক: নির্দিষ্ট শব্দ গণনা করুন

অবশেষে, আমি একটি Google পত্রক সূত্র শেয়ার করতে চাই যা আপনি নির্দিষ্ট শব্দ গণনা করতে ব্যবহার করতে পারেন।

এখানে আমার কাছে অ্যালিসের অ্যাডভেঞ্চারস ইন ওয়ান্ডারল্যান্ডের দ্য মক টার্টলের গান আছে:

আমি জানতে চাই প্রতিটি সারিতে 'উইল' শব্দটি কতবার উপস্থিত হয়েছে। আমি বিশ্বাস করি আপনি অবাক হবেন না যদি আমি আপনাকে বলি যে আমার প্রয়োজনীয় সূত্রটি আগের মতো একই ফাংশন নিয়ে গঠিত: Google পত্রক LEN, SUBSTITUTE, এবং LOWER:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "will", "")))/LEN("will")

সূত্রটি হতে পারে দেখতে ভীতিকর কিন্তু আমি আপনাকে আশ্বস্ত করতে পারি যে এটি বোঝা সহজ, তাই আমার সাথে সহ্য করুন :)

1. যেহেতু টেক্সট কেস নেইআমার কাছে গুরুত্বপূর্ণ, আমি সবকিছুকে ছোট হাতের অক্ষরে পরিণত করতে LOWER(A2) ব্যবহার করি।
2. তারপর সাবস্টিটিউট(নিম্ন(A2), "will",""))) – এটি খালি স্ট্রিং ("") দিয়ে প্রতিস্থাপন করে 'ইচ্ছা'-এর সমস্ত ঘটনা থেকে মুক্তি পায়।
3. এর পরে, আমি মোট স্ট্রিং দৈর্ঘ্য থেকে 'ইচ্ছা' শব্দটি ছাড়া অক্ষরের সংখ্যা বিয়োগ করি . আমি যে সংখ্যাটি পেয়েছি তা প্রতিটি সারিতে 'ইচ্ছা'-এর সমস্ত ঘটনার সমস্ত অক্ষর গণনা করে।

   এভাবে, 'will' একবার উপস্থিত হলে, শব্দটিতে 4টি অক্ষর থাকায় সংখ্যাটি 4 হয়। যদি এটি দুইবার প্রদর্শিত হয়, সংখ্যাটি 8, এবং তাই।

4. অবশেষে, আমি এই সংখ্যাটিকে একক শব্দ 'will'-এর দৈর্ঘ্য দিয়ে ভাগ করি।

টিপ। এবং আবার, আপনি যদি 'ইচ্ছা' শব্দের সমস্ত উপস্থিতির মোট সংখ্যা পেতে চান তবে শুধুমাত্র SUMPRODUCT দ্বারা সম্পূর্ণ সূত্রটি ঘেরাও করুন:

=SUMPRODUCT((LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "will", "")))/LEN("will"))

যেমন আপনি দেখতে পাচ্ছেন , অক্ষর-গণনার এই সমস্ত ক্ষেত্রে Google পত্রকের জন্য একই ফাংশনগুলির একই প্যাটার্ন দ্বারা সমাধান করা হয়: LEN, SUBSTITUTE, LOWER, এবং SUMPRODUCT৷

যদি কিছু সূত্র এখনও আপনাকে বিভ্রান্ত করে, বা আপনি যদি না হন আপনার নির্দিষ্ট কাজের জন্য সবকিছু কীভাবে প্রয়োগ করবেন তা নিশ্চিত করুন, লজ্জা পাবেন না এবং নীচের মন্তব্য বিভাগে জিজ্ঞাসা করুন!