Google Sheets қолданбасындағы сөздер мен таңбалар саны сирек жағдайларда пайдаланылғанымен, бұл әлі де кейбіреулеріміз мәзірде көргісі келетін функция. Бірақ Google Docs-тан айырмашылығы, Google Sheets үшін бұл LEN функциясы болып табылады.

Электрондық кестелердегі таңбаларды санаудың әртүрлі тәсілдері бар болса да, бүгінгі блог жазбасы оның ретінде LEN функциясын қарастырады. Кестелердегі негізгі мақсат – жақсы, санау :) Дегенмен, ол өздігінен қолданылмайды. Төменде сіз Google Sheets LEN қалай дұрыс пайдалану керектігін және электрондық кестелердегі таңбаларды есептеу үшін ең қажет формулаларды табуды үйренесіз.

Google Sheets LEN функциясы – пайдалану және синтаксис

Google Sheets-тегі LEN функциясының негізгі және жалғыз мақсаты - жол ұзындығын алу. Ол соншалықты қарапайым, ол тіпті тек 1 аргументті қажет етеді:

• ол мәтіннің өзін қос тырнақшаға ала алады:

  =LEN("Yggdrasil")

• немесе қызықтыратын мәтіні бар ұяшыққа сілтеме:

  =LEN(A2)

Электрондық кестелерде функцияны пайдаланудың қандай да бір ерекшеліктері бар-жоғын көрейік.

Таңба Google Sheets қолданбасында санау

Мен ең қарапайым әрекеттен бастаймын: Google Sheets қолданбасында таңбаларды санауды ең көп таралған әдіс – LEN функциясын пайдаланып мәтіні бар ұяшыққа сілтеме жасау арқылы жасаңыз.

I формуланы B2 мәніне енгізіп, әр жолдағы таңбаларды санау үшін оны бүкіл бағанға көшіріңіз:

=LEN(A2)

Ескерту. LEN функциясыбарлық таңбаларды есептейді: әріптерді, сандарды, бос орындарды, тыныс белгілерін және т.б.

Сіз дәл осылай ұяшықтардың барлық ауқымы үшін таңбаларды санауды жасауға болады деп ойлауыңыз мүмкін, мысалы: LEN(A2:A6) . Бірақ, Біртүрлі болғанымен, ол осылай жұмыс істемейді.

Бірнеше ұяшықтағы таңбаларды жинақтау үшін LEN-ді SUMPRODUCT-ке орау керек – енгізілген ауқымдардағы сандарды есептейтін функция. Менің жағдайда ауқым LEN функциясы арқылы қайтарылады:

=SUMPRODUCT(LEN(A2:A6))

Әрине, оның орнына SUM функциясын қосуға болады. Бірақ Google Sheets ішіндегі SUM басқа функциялардың массивтерін өңдемейді. Оның жұмыс істеуі үшін сізге басқа функция қосу керек болады – ArrayFormula:

=ArrayFormula(SUM(LEN(A2:A6)))

Google Sheets ішіндегі бос орынсыз таңбаларды қалай санауға болады

Жоғарыда атап өткенімдей, Google Sheets LEN функциясы бос орындарды қоса алғанда, көретін әрбір таңбаны санайды.

Бірақ қателікпен қосымша бос орындар қосылып, оларды нәтиже ретінде қарастырғыңыз келмесе ше?

Мына сияқты жағдайлар үшін бұл Google Sheets ішінде TRIM функциясы бар. Ол мәтіннің арасындағы алдыңғы, кейінгі және қайталанатын бос орындардың бар-жоғын тексереді. TRIM LEN-мен жұптастырылған кезде, соңғысы барлық тақ бос орындарды санамайды.

Мысал мынада. Мен A бағанында әртүрлі орындарда бос орындар қостым. Көріп отырғаныңыздай, Google Sheets LEN өз бетінше олардың барлығын санайды:

=LEN(A2)

Бірақ TRIM біріктірген бойда барлығы қосымша бос орындар болып табыладыеленбейді:

=LEN(TRIM(A2))

Сіз әрі қарай жүріп, формулаңызды сөздер арасындағы жалғыз бос орындарды да ескермеуге болады. SUBSTITUTE функциясы көмектеседі. Оның негізгі мақсаты бір таңбаны екіншісімен ауыстыру болса да, оны бос орындарды толығымен азайтуға көмектесетін амал бар:

• іздейтін_мәтін - сіз жұмыс істейтін ауқым: A бағаны немесе дәлірек айтқанда A2 .
• іздеу_қос тырнақшадағы бос орын таңбасы болуы керек: " "
• replace_with бос қос тырнақшалардан тұруы керек. Бос орындарды елемеу керек болса, оларды сөзбе-сөз ешнәрсемен ауыстыру керек (бос жол): ""
• кездесу_саны әдетте дананы көрсету үшін пайдаланылады. ауыстыру. Бірақ мен барлық бос орынсыз таңбаларды қалай санау керектігін сипаттап жатқандықтан, бұл аргументті алып тастауды ұсынамын, себебі ол міндетті емес.

Енді осының барлығын Google Sheets LEN ішіне жинап көріңіз, сонда сіз мұны көресіз. бос орын ескерілмейді:

=LEN(SUBSTITUTE(A2, " ", ""))

Google Sheets: нақты таңбаларды санау

Google Sheets LEN және SUBSTITUTE бірдей тандемі белгілі бір таңбаларды санау қажет болғанда пайдаланылады. , әріптер немесе сандар.

Менің мысалдарымда мен 's' әрпінің жиі кездесетін санын анықтаймын. Ал бұл жолы мен дайын формуладан бастайын:

=LEN(A2)-LEN(SUBSTITUTE(A2, "s", ""))

Оның қалай екенін түсіну үшін оны бөлшектеп көрейік.жұмыс істейді:

1. SUBSTITUTE(A2, "s", "") A2 ішінен 's' әрпін іздейді және барлық көріністерді "ештеңе" немесе бос жолмен ауыстырады ( "").
2. LEN(SUBSTITUTE(A2, "s", "") A2 файлындағы "s" таңбаларынан басқа барлық таңбалардың санын шығарады.
3. LEN(A2) A2 пішіміндегі барлық таңбаларды санайды.
4. Соңында екіншісінен біреуін шегереді.

Нәтижелердің айырмашылығы қанша «'» бар екенін көрсетеді. ұяшықта:

Ескертпе.Сіз 3-ті көріп тұрғанда B1 неліктен A2-де тек 1 «бар» дейді?

Мәселе мынада, SUBSTITUTE функциясы регистрді ескереді. Мен одан «s» әрпінің барлық даналарын кіші әріппен алуын сұрадым, солай істеді.

Мәтін регистрін елемеу және кіші және үлкен әріптердегі әріптерді өңдеу үшін тағы бір Google Sheets функциясына қоңырау шалу керек. анықтама үшін: LOWER.

Кеңес. Google Sheets қолданбасында мәтін регистрін өзгертудің басқа жолдарын қараңыз.

Бұл Google Sheets LEN және TRIM сияқты қарапайым, өйткені оған тек мәтін қажет:

=LOWER(text)

Және ол барлық мәтін жолын int айналдырады. o кіші әріп. Бұл трюк Google Sheets мәтіндік регистріне қарамастан нақты таңбаларды санау үшін қажет нәрсе:

=LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "s", ""))

Кеңес. Бұрынғыдай, ауқымдағы нақты таңбалардың жалпы санын санау үшін LEN-ді SUMPRODUCT ішіне ораңыз:

=SUMPRODUCT(LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "s", "")))

Google Sheets-тегі сөздерді санау

Онда ұяшықтардағы бірнеше сөз болса, олардың орнына олардың саны қажет болуы мүмкінGoogle Sheets жолының ұзындығы.

Сонымен бірге мұны істеудің бірнеше жолы болса да, мен бүгін Google Sheets LEN тапсырманы қалай орындайтынын айтып беремін.

Мен нақты таңбаларды санау үшін пайдаланған формуланы есте сақтаңыз. Google Sheets? Шындығында, бұл жерде де пайдалы болады. Өйткені мен сөздерді тура санамаймын. Оның орнына сөздер арасындағы бос орындар санын санаймын, содан кейін жай ғана 1 қосамын. Қарап көріңіз:

=LEN(A2)-LEN(SUBSTITUTE((A2), " ", ""))+1

1. LEN(A2) ұяшықтағы барлық таңбалардың саны.
2. LEN(SUBSTITUTE((A2)," ","")) мәтін жолындағы барлық бос орындарды жояды және қалған таңбаларды санайды.
3. Одан кейін бірін екіншісінен шегесіз, ал сіз алатын айырмашылық ұяшықтағы бос орындардың саны болып табылады.
4. Сөздер әрқашан сөйлемдегі бос орындардан бір артық болғандықтан, соңына 1 қосасыз.

Google Sheets: нақты сөздерді санау

Соңында, мен нақты сөздерді санау үшін пайдалануға болатын Google Sheets формуласымен бөліскім келеді.

Міне, менде «Алисаның ғажайыптар еліндегі бастан кешкен оқиғалары» фильміндегі «Жалған тасбақаның әні» бар:

Мен «ерік» сөзінің әр жолда қанша рет кездесетінін білгім келеді. Маған қажет формуланың бұрынғыдай функциялардан тұратынын айтсам, таң қалмайсыз деп ойлаймын: Google Sheets LEN, SUBSTITUTE және LOWER:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "will", "")))/LEN("will")

Формула қорқынышты көрінеді, бірақ мен оны түсіну оңай деп сендіремін, сондықтан маған шыдаңыз :)

1. Себебі мәтін регистрінде емесмен үшін маңызды, мен бәрін кіші әріпке айналдыру үшін LOWER(A2) пернесін қолданамын.
2. Содан кейін SUBSTITUTE(LOWER(A2), "will",""))) – ол бос жолдармен ("") ауыстыру арқылы "ерік"-тің барлық кездесулерінен құтылады.
3. Осыдан кейін жалпы жол ұзындығынан "ерік" сөзі жоқ таңбалар санын шегеремін. . Мен алатын сан әрбір жолдағы «ерік» барлық көріністеріндегі барлық таңбаларды санайды.

   Осылайша, егер 'will' бір рет пайда болса, сөзде 4 әріп болғандықтан, сан 4 болады. Егер ол екі рет пайда болса, сан 8 болады және т.б.

4. Соңында мен бұл санды «ерік» деген жалғыз сөздің ұзындығына бөлемін.

Кеңес. Тағы да, егер сіз «ерік» сөзінің барлық көріністерінің жалпы санын алғыңыз келсе, барлық формуланы SUMPRODUCT арқылы қосыңыз:

=SUMPRODUCT((LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "will", "")))/LEN("will"))

Көріп отырғаныңыздай , таңбаларды санаудың барлық осы жағдайлары Google Sheets үшін бірдей функциялардың бірдей үлгілерімен шешіледі: LEN, SUBSTITUTE, LOWER және SUMPRODUCT.

Кейбір формулалар сізді әлі де шатастырса немесе сіз шатастырмайтын болсаңыз Барлығын нақты тапсырмаңызға қалай қолдануға болатынын біліңіз, ұялмаңыз және төмендегі түсініктемелер бөлімінде сұраңыз!