Ačkoli se počet slov a znaků v Tabulkách Google používá jen výjimečně, stále se jedná o funkci, kterou někteří z nás očekávají přímo v nabídce. Na rozdíl od Dokumentů Google to však v případě Tabulek Google dělá funkce LEN.

Přestože existuje mnoho různých způsobů, jak počítat znaky v tabulkách, dnešní příspěvek se bude zabývat funkcí LEN, protože jejím hlavním účelem v tabulkách je - no, počítat :) Sama o sobě se však téměř nepoužívá. Níže se dozvíte, jak správně používat funkci LEN v tabulkách Google Sheets, a najdete nejvyhledávanější vzorce pro výpočet znaků v tabulkách.

Funkce LEN v Tabulkách Google - použití a syntaxe

Hlavním a jediným účelem funkce LEN v tabulkách Google je zjištění délky řetězce. Je tak jednoduchá, že dokonce vyžaduje pouze 1 argument:

• může přebírat buď samotný text ve dvojitých uvozovkách:

  =LEN("Yggdrasil")

• nebo odkaz na buňku se zajímavým textem:

  =LEN(A2)

Podívejme se, zda existují nějaké zvláštnosti při používání funkce v tabulkových procesorech.

Počet znaků v tabulkách Google

Začnu tou nejjednodušší operací: v tabulkách Google Sheets spočítáte znaky nejběžnějším způsobem - odkazem na buňku s textem pomocí funkce LEN.

Zadám vzorec do B2 a zkopíruji ho dolů do celého sloupce, aby se počítaly znaky v každém řádku:

=LEN(A2)

Poznámka: Funkce LEN počítá všechny znaky: písmena, číslice, mezery, interpunkční znaménka atd.

Možná vás napadne, že podobným způsobem byste mohli spočítat znaky pro celý rozsah buněk, například takto: LEN(A2:A6) . Ale jakkoli je to bizarní, takhle to prostě nefunguje.

Chcete-li sečíst znaky v několika buňkách, měli byste funkci LEN zabalit do funkce SUMPRODUCT - funkce, která sečte čísla ze zadaných rozsahů. V mém případě je rozsah vrácen funkcí LEN:

=SOUČIN(LEN(A2:A6))

Samozřejmě byste místo toho mohli začlenit funkci SUMA. Ale funkce SUMA v Tabulkách Google nezpracovává pole z jiných funkcí. Aby to fungovalo, budete muset přidat další funkci - ArrayFormula:

=ArrayFormula(SUM(LEN(A2:A6)))

Jak počítat znaky bez mezer v Tabulkách Google

Jak jsem uvedl výše, funkce LEN v tabulkách Google počítá každý znak, který vidí, včetně mezer.

Ale co když jsou omylem přidány mezery navíc a vy je nechcete brát v úvahu pro výsledek?

Pro takové případy je v tabulkách Google k dispozici funkce TRIM, která kontroluje, zda se v textu nevyskytují počáteční, koncové a opakující se mezery. Pokud je funkce TRIM spojena s funkcí LEN, nepočítá všechny tyto liché mezery.

Zde je příklad. Přidala jsem mezery na různá místa ve sloupci A. Jak vidíte, pokud je tabulka Google LEN počítá sama, počítá je všechny:

=LEN(A2)

Jakmile však integrujete funkci TRIM, budou všechny mezery navíc ignorovány:

=LEN(TRIM(A2))

Můžete jít ještě dál a přimět vzorec, aby nebral v úvahu ani ty jednotlivé mezery mezi slovy. Pomůže vám s tím funkce SUBSTITUTE. Ačkoli jejím hlavním účelem je nahradit jeden znak jiným, existuje trik, jak ji přimět, aby mezery zcela redukovala:

• text_to_search je rozsah, se kterým pracujete: sloupec A nebo A2 přesněji řečeno.
• search_for by měl být znak mezery ve dvojitých uvozovkách: " "
• replace_with by měly obsahovat prázdné dvojité uvozovky. Pokud chcete ignorovat mezery, musíte je nahradit doslova ničím (prázdným řetězcem): ""
• occurence_number se obvykle používá k určení instance, která se má nahradit. Protože však popisuji, jak počítat znaky bez všech mezer, doporučuji tento argument vynechat, protože je nepovinný.

Nyní je zkuste všechny sestavit do tabulky LEN v aplikaci Google Sheets a uvidíte, že se nezohledňuje žádná mezera:

=LEN(SUBSTITUTE(A2, " ", ""))

Tabulky Google: počítání konkrétních znaků

Stejný tandem LEN a SUBSTITUTE v tabulkách Google se používá vždy, když potřebujete spočítat určité znaky, písmena nebo čísla.

Ve svých příkladech budu zjišťovat počet výskytů písmene s. A tentokrát začnu s hotovým vzorcem:

=LEN(A2)-LEN(SUBSTITUTE(A2, "s", ""))

Rozdělme si ji na části, abychom pochopili, jak funguje:

1. SUBSTITUTE(A2, "s", "") vyhledá písmeno 's' v A2 a nahradí všechny výskyty písmenem "nic" nebo prázdným řetězcem ("").
2. LEN(SUBSTITUTE(A2, "s", "") zjistí počet všech znaků kromě 's' v A2.
3. LEN(A2) počítá všechny znaky v A2.
4. Nakonec jedno od druhého odečtete.

Rozdíl ve výsledku ukazuje, kolik "s" je v buňce:

Poznámka: Možná vás zajímá, proč B1 říká, že v A2 je pouze 1 "s", zatímco vy vidíte 3?

Jde o to, že funkce SUBSTITUTE rozlišuje malá a velká písmena. Požádal jsem ji, aby všechny případy 's' psala malými písmeny, a tak to udělala.

Chcete-li, aby ignoroval velká a malá písmena a zpracovával písmena malá i velká, musíte zavolat na pomoc ještě jednu funkci Tabulky Google: LOWER.

Tip. Podívejte se na další způsoby změny velikosti písmen textu v Tabulkách Google.

Je to stejně jednoduché jako v tabulkách Google LEN a TRIM, protože k tomu stačí pouze text:

=LOWER(text)

A jediné, co udělá, je, že celý textový řetězec změní na malá písmena. Tento trik je přesně to, co potřebujete, aby Tabulky Google počítaly konkrétní znaky bez ohledu na velikost písmen v textu:

=LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "s", ""))

Tip. A stejně jako dříve, chcete-li spočítat celkový počet konkrétních znaků v rozsahu, zabalte LEN do SUMPRODUCT:

=SUMPRODUCT(LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "s", "")))

Počítání slov v tabulkách Google

Pokud je v buňkách více slov, je pravděpodobné, že místo délky řetězce v tabulkách Google budete potřebovat jejich počet.

A přestože existuje více způsobů, jak to udělat, dnes se zmíním o tom, jak to dělá Google Sheets LEN.

Vzpomínáte si na vzorec, který jsem použil pro počítání konkrétních znaků v tabulkách Google? Ve skutečnosti se bude hodit i zde. Nebudu totiž počítat slova doslova. Místo toho spočítám počet mezer mezi slovy a pak jednoduše přičtu 1. Podívejte se:

=LEN(A2)-LEN(SUBSTITUTE((A2), " ", ""))+1

1. LEN(A2) spočítá počet všech znaků v buňce.
2. LEN(SUBSTITUTE((A2)," ","")) odstraní z textového řetězce všechny mezery a spočítá zbývající znaky.
3. Pak jedno odečtete od druhého a rozdíl, který získáte, je počet mezer v buňce.
4. Protože počet slov ve větě vždy převyšuje počet mezer o jednu, přidejte na konec 1.

Tabulky Google: počítání konkrétních slov

Nakonec bych se s vámi rád podělil o vzorec v tabulkách Google, který můžete použít k počítání konkrétních slov.

Tady mám Píseň posměšné želvy z Alenčiných dobrodružství v říši divů:

Chci vědět, kolikrát se v každém řádku objeví slovo "will". Věřím, že vás nepřekvapí, když vám řeknu, že vzorec, který potřebuji, se skládá ze stejných funkcí jako předtím: LEN, SUBSTITUTE a LOWER listu Google:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "will", "")))/LEN("will")

Vzorec může vypadat děsivě, ale mohu vás ujistit, že je snadno pochopitelný, takže vydržte :)

1. Protože mi na velikosti písmen textu nezáleží, používám LOWER(A2) aby se vše změnilo na malá písmena.
2. Pak jde SUBSTITUTE(LOWER(A2), "will",""))) - zbaví se všech výskytů slova 'will' tím, že je nahradí prázdnými řetězci ("").
3. Poté od celkové délky řetězce odečtu počet znaků bez slova "will". Číslo, které dostanu, počítá všechny znaky ve všech výskytech slova "will" v každém řádku.

   Pokud se tedy slovo "will" objeví jednou, je číslo 4, protože v tomto slově jsou 4 písmena. Pokud se objeví dvakrát, je číslo 8 atd.

4. Nakonec toto číslo vydělím délkou jediného slova "will".

Tip: Pokud chcete získat celkový počet všech výskytů slova "will", stačí celý vzorec uzavřít pomocí SUMPRODUCT:

=SUMPRODUCT((LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "will", "")))/LEN("will"))

Jak vidíte, všechny tyto případy počtu znaků se řeší stejnými vzory stejných funkcí pro tabulky Google: LEN, SUBSTITUTE, LOWER a SUMPRODUCT.

Pokud vás některé vzorce stále matou nebo si nejste jisti, jak vše aplikovat na váš konkrétní úkol, nestyďte se a zeptejte se v komentářích níže!