Denne vejledning viser, hvordan du laver en Excel-formel for procentvis stigning eller fald og bruger den med både positive og negative tal.

I Microsoft Excel er der 6 forskellige funktioner til at beregne varians. Ingen af dem er dog egnet til at beregne den procentvise forskel mellem to celler. De indbyggede funktioner er designet til at finde varians i klassisk forstand, dvs. hvor langt et sæt værdier er spredt fra deres gennemsnit. En procentvis varians er noget andet. I denne artikel finder du den rigtigeformel til beregning af procentvis ændring i Excel.

Hvad er procentvis ændring?

Procentvis ændring, aka procentvis afvigelse eller forskel , er en proportional ændring mellem to værdier, en oprindelig værdi og en ny værdi.

Formlen for procentvis ændring beregner, hvor meget noget ændrer sig procentvis mellem to perioder. Du kan f.eks. beregne variansen mellem salget i år og sidste år, mellem en prognose og den observerede temperatur, mellem en budgetteret omkostning og den reelle omkostning.

Hvis du f.eks. tjente 1.000 dollars i januar og 1.200 dollars i februar, er forskellen altså en indtægtsstigning på 200 dollars. Men hvor meget er det i procent? For at finde ud af det bruger du en formel for procentvis ændring.

Excel formel for procentvis ændring

Der findes to grundlæggende formler til at finde den procentvise forskel mellem to tal.

Klassisk formel for procentvis afvigelse

Her er den almindeligt anvendte formel til beregning af den procentvise ændring:

I matematik udfører man normalt tre trin for at beregne den procentvise variation mellem to numeriske værdier:

1. Træk den nye værdi fra den gamle værdi.
2. Divider forskellen med det gamle tal.
3. Multiplicer resultatet med 100.

I Excel kan du springe det sidste trin over ved at anvende Procentdel format.

Excel formel for procentvis ændring

Og her er en enklere formel for procentvis ændring i Excel, der giver det samme resultat.

Sådan beregnes procentvis ændring i Excel

For at finde den procentvise forskel mellem to tal i Excel kan du bruge en af ovenstående formler. Lad os sige, at du har det anslåede salg i kolonne B og det faktiske salg i kolonne C. Hvis vi antager, at det anslåede tal er "basisværdien", og det faktiske tal er den "nye" værdi, får formlerne denne form:

=(C3-B3)/B3

eller

=C3/B3-1

Ovenstående formler sammenligner tallene i række 3. Hvis du vil beregne ændringsprocenten i hele kolonnen, skal du gøre følgende:

1. Indtast formlen for den procentvise forskel i en hvilken som helst tom celle i række 3, f.eks. i D3 eller E3.
2. Klik på formularcellen, mens formlen er markeret, og klik på Procent stil knappen på båndet eller tryk på genvejstasten Ctrl + Shift + %. Dette konverterer det returnerede decimaltal til procent.
3. Træk formlen ned over så mange rækker som nødvendigt.

Når du har kopieret formlen, får du en kolonne med procentvise ændringer fra dine data.

Sådan fungerer Excel-formlen for procentvis ændring

Når du foretager beregningerne manuelt, tager du en gammel (oprindelig) værdi og en ny værdi, finder forskellen mellem dem og dividerer den med den oprindelige værdi. For at få resultatet i procent skal du gange det med 100.

Hvis den oprindelige værdi f.eks. er 120 og den nye værdi er 150, kan den procentvise forskel beregnes på denne måde:

=(150-120)/120

=30/120

=0.25

0.25*100 = 25%

Anvendelse af den Procentdel talformatet i Excel viser et decimaltal automatisk som en procentdel, og derfor udelades *100-delen.

Excel-formel for procentvis stigning/nedgang

Da procentvis stigning eller fald blot er et særligt tilfælde af procentvis varians, beregnes det med den samme formel:

Eller

For at beregne f.eks. procentvis stigning mellem to værdier (B2 og C2), er formlen:

=(C2-B2)/B2

Eller

=C2/B2-1

En formel til beregning af den procentvis fald er nøjagtig den samme.

Excel procentvis ændring absolut værdi

Som standard returnerer formlen for procentvis variation i Excel en positiv værdi for procentvis stigning og en negativ værdi for procentvis fald. For at få den procentvise ændring som en absolutte værdi uden hensyn til dens fortegn, indpakkes formlen i ABS-funktionen på følgende måde:

I vores tilfælde har formlen følgende form:

=ABS((C3-B3)/B3)

Denne vil også fungere fint:

=ABS(C3/B3-1)

Beregne rabatprocent

Dette eksempel viser endnu en praktisk anvendelse af Excel-formlen for procentvis ændring - nemlig at beregne en rabatprocent. Så husk dette, når I skal ud at handle, mine damer:

rabat % = (nedsat pris - normal pris) / normal pris

rabat % = nedsat pris / normal pris - 1

En procentvis rabat vises som en negativ værdi, fordi den nye rabatpris er mindre end den oprindelige pris. Hvis du vil have resultatet vist som en positivt tal , indlejre formler i ABS-funktionen, som vi gjorde i det foregående eksempel:

=ABS((C2-B2)/B2)

Beregn værdien efter procentvis ændring

For at få en værdi efter den procentvise stigning eller fald er den generelle formel:

Lad os antage, at du har de oprindelige værdier i kolonne B og den procentvise forskel i kolonne C. For at beregne den nye værdi efter den procentvise ændring er formlen i D2 kopieret ned som følger:

=B2*(1+C2)

Først finder du den samlede procentdel, der skal ganges med den oprindelige værdi. Du skal blot lægge procentdelen til 1 (1+C2). Derefter ganger du den samlede procentdel med de oprindelige tal for at få det ønskede resultat.

Som du kan se, fungerer denne løsning fint for både procentvise stigninger og fald:

Til øge eller reducere en hel kolonne med en bestemt procent Hvis du f.eks. vil øge alle værdierne i kolonne B med 5 %, skal du indtaste nedenstående formel i C2 og derefter trække den ned over de resterende rækker:

=B2*(1+5%)

Her skal du blot gange den oprindelige værdi med 105 %, hvilket giver en værdi, der er 5 % højere.

For nemheds skyld kan du indtaste procentværdien i en foruddefineret celle (F2) og henvise til denne celle. Tricket er at låse cellehenvisningen med $-tegnet, så formlen kopieres korrekt:

=B2*(1+$F$2)

Fordelen ved denne fremgangsmåde er, at du kun behøver at ændre værdien i en enkelt celle for at øge en kolonne med en anden procentdel. Da alle formler er knyttet til denne celle, vil de automatisk blive genberegnet.

Beregning af procentvis varians med negative værdier

Hvis nogle af dine værdier er repræsenteret af negative tal, vil den traditionelle procentdifferenceformel ikke fungere korrekt. En almindeligt accepteret løsning er at gøre nævneren til et positivt tal ved hjælp af ABS-funktionen.

Her er en generisk Excel-formel til procentvis ændring med negative tal:

Med den gamle værdi i B2 og den nye værdi i C2 lyder den rigtige formel således:

=(C2-B2)/ABS(B2)

Bemærk: Selv om denne ABS-regulering teknisk set er korrekt, kan formlen give misvisende resultater, hvis den oprindelige værdi er negativ og den nye værdi er positiv og omvendt.

Excel procentvis ændring divideret med nul-fejl (#DIV/0)

Hvis dit datasæt indeholder nulværdier, vil du sandsynligvis støde på en fejl ved at dividere med nul (#DIV/0!), når du beregner procentvis ændring i Excel, fordi du ikke kan dividere et tal med nul i matematik. IFERROR-funktionen kan hjælpe dig med at løse dette problem. Afhængigt af dine forventninger til det endelige resultat kan du bruge en af følgende løsninger.

Løsning 1: hvis den gamle værdi er nul, returneres 0

Hvis den gamle værdi er nul, vil den procentvise ændring være 0 %, uanset om den nye værdi er nul eller ej.

=IFERROR((C2-B2)/B2, 0)

eller

=IFERROR(C2/B2-1, 0)

Løsning 2: hvis den gamle værdi er nul, returneres 100 %

Denne løsning implementerer en anden tilgang, hvor man antager, at den nye værdi er vokset med 100 % fra nul:

=IFERROR((C2-B2)/B2, 1)

=IFERROR(C2/B2-1, 1)

I dette tilfælde vil den procentvise forskel være 100 %, hvis den gamle værdi er nul (række 5) eller begge værdier er nul (række 9).

Når man ser på de fremhævede poster nedenfor, bliver det tydeligt, at ingen af de to formler er perfekte:

For at få bedre resultater kan du kombinere de to formler til én ved hjælp af den indlejrede IF-erklæring:

=IF(C20, IFERROR((C2-B2)/B2, 1), IFERROR((C2-B2)/B2, 0))

Denne forbedrede formel vil vende tilbage:

• Den procentvise ændring er 0%, hvis både den gamle og den nye værdi er nul.
• Den procentvise ændring er 100 %, hvis den gamle værdi er nul, og den nye værdi ikke er nul.

Sådan beregner du en procentvis stigning eller fald i Excel. Hvis du vil have praktisk erfaring, er du velkommen til at downloade vores prøvearbejdsbog nedenfor. Tak for læsningen og håber at se dig på vores blog i næste uge!

Arbejdsbog til download

Excel-formel for procentvis stigning/nedgang - eksempler (.xlsx-fil)