Dizze tutorial lit sjen hoe't jo in Excel-formule meitsje foar persintaazje ferheging of fermindering en it brûke mei sawol positive as negative sifers.

Yn Microsoft Excel binne d'r 6 ferskillende funksjes foar berekkenjen fariânsje. Net ien fan har is lykwols geskikt foar it berekkenjen fan it persintaazje ferskil tusken twa sellen. De ynboude funksjes binne ûntworpen om fariânsje te finen yn 'e klassike sin, oftewol hoe fier in set wearden ferspraat is fan har gemiddelde. In persintaazje fariaasje is wat oars. Yn dit artikel fine jo de juste formule foar it berekkenjen fan persintaazje feroaring yn Excel.

Wat is persintaazje feroaring?

Percent feroaring, aka persintaazje fariânsje of ferskil , is in evenredige feroaring tusken twa wearden, in orizjinele wearde en in nije wearde.

Prosintferoaringsformule berekkent hoefolle wat feroaret tusken twa perioaden persintaazjewiis. Jo kinne bygelyks fariânsje berekkenje tusken ferkeap yn dit jier en ferline jier, tusken in prognose en waarnommen temperatuer, tusken in begrutting kosten en de echte.

Yn jannewaris hawwe jo bygelyks $1.000 fertsjinne en yn febrewaris $1.200 , dus it ferskil is in ferheging fan $ 200 yn fertsjinsten. Mar hoefolle is dat yn termen fan persintaazje? Om dat út te finen, brûke jo in formule foar persintaazje feroaring.

Formule foar feroaring fan Excel persintaazje

D'r binne twa basisformules om it persintaazje ferskil tusken twa te finengetallen.

Klassike formule foar persintaazje fariânsje

Hjir is de algemien brûkte formule om de persintaazje feroaring te berekkenjen:

( nije_wearde - âlde_wearde ) / âlde_wearde

Yn wiskunde soene jo normaal 3 stappen útfiere om de persintaazje fariânsje te berekkenjen tusken twa numerike wearden:

1. Troch de nije ôf wearde fan de âlde.
2. Diel it ferskil troch it âlde getal.
3. Fermannichfâldigje it resultaat mei 100.

Yn Excel slaan jo de lêste stap oer troch it tapassen fan it Percentage -formaat.

Excel persintaazje feroaring formule

En hjir is in ienfâldiger formule foar persintaazje feroaring yn Excel dy't itselde resultaat jout.

nije_wearde / âlde_wearde - 1

Hoe kinne jo persintaazje feroaring yn Excel berekkenje

Om it persintaazje ferskil tusken twa nûmers yn Excel te finen, kinne jo brûke ien fan 'e boppesteande formules. Litte wy sizze dat jo de rûsde ferkeap hawwe yn kolom B en werklike ferkeap yn kolom C. Oannimme dat it rûsde oantal de "baseline" wearde is en de werklike is de "nije" wearde, hawwe de formules dizze foarm:

=(C3-B3)/B3

of

=C3/B3-1

De boppesteande formules fergelykje de nûmers yn rige 3. Om it persintaazje feroaring yn 'e hiele kolom te berekkenjen, moatte jo dit dwaan:

1. Fier de formule foar persintaazje ferskil yn yn elke lege sel yn rige 3, sis yn D3 of E3.
2. Mei de formulesel selektearre, klikje op de Percent Style knop op delint of druk op de Ctrl + Shift + % fluchtoets. Dit sil it weromjûne desimale getal konvertearje nei persintaazje.
3. Sleep de formule nei ûnderen oer safolle rigen as nedich.

Nei it kopiearjen fan de formule, krije jo in persintaazje feroaring kolom fan jo gegevens.

Hoe't Excel persintaazje feroaring formule wurket

As jo ​​de berekkeningen mei de hân dogge, soene jo in âlde (oarspronklike) wearde en in nije wearde nimme, it ferskil fine tusken har en diel it troch de oarspronklike wearde. Om it resultaat as persintaazje te krijen, soene jo it mei 100 fermannichfâldigje.

As bygelyks de begjinwearde 120 is en de nije wearde 150, kin it persintaazje ferskil op dizze manier berekkene wurde:

=(150-120)/120

=30/120

=0.25

0.25*100 = 25%

It tapassen fan it Percentage getalformaat yn Excel lit automatysk in desimaal getal as persintaazje werjaan , dêrom wurdt it *100-diel weilitten.

Excel-formule foar persintaazje ferheging /fermindering

As persintaazje ferheging of fermindering gewoan in bepaald gefal fan persintaazje fariânsje is, wurdt it berekkene mei deselde formule:

( nije_wearde - begjinwearde ) / begjinwearde

Of

nije_wearde / begjinwearde - 1

Om bygelyks de persintaazje ferheging te berekkenjen tusken twa wearden (B2 en C2), is de formule:

=(C2-B2)/B2

Of

=C2/B2-1

In formule om de persintaazje fermindering te berekkenjen is krekt itselde.

Excel persintaazjeabsolute wearde feroarje

Standert jout de formule foar persintaazje fariânsje yn Excel in positive wearde foar persintaazje ferheging en in negative wearde foar persintaazje fermindering. Om de persintaazje feroaring te krijen as in absolute wearde sûnder rekken mei it teken, wikkel de formule sa yn 'e ABS-funksje:

ABS(( new_value - old_value ) / old_value)

Yn ús gefal nimt de formule dizze foarm oan:

=ABS((C3-B3)/B3)

Dizze sil ek goed wurkje:

=ABS(C3/B3-1)

Berekkenje koartingspersintaazje

Dit foarbyld lit noch ien praktysk gebrûk sjen fan de formule foar feroaring fan Excel persintaazje - it útwurkjen fan in koartingspersintaazje. Dus, froulju, as jo winkelje, tink dan oan dit:

discount % = (discounted price - regular price) / regular price

discount % = discounted price / regular price - 1

In koartingspersintaazje wurdt werjûn as in negative wearde, om't de nije koartingspriis lytser is as de initial priis. Om it resultaat út te jaan as in posityf getal , nêst formules binnen de ABS-funksje lykas wy diene yn it foarige foarbyld:

=ABS((C2-B2)/B2)

Berekkenje de wearde nei persintaazje feroaring

Om in wearde te krijen nei de persintaazjeferheging of fermindering, is de generike formule:

initial_value *(1+ percent_change )

Stel dat jo it orizjineel hawwe wearden yn kolom B en it persintaazje ferskil yn kolom C. Om de nije wearde nei de persintaazje feroaring te berekkenjen, is de formule yn D2 dy't nei ûnderen kopiearre is:

=B2*(1+C2)

Earst fine jo it totale persintaazje dêr moat mei fermannichfâldige wurdede oarspronklike wearde. Foegje hjirfoar gewoan it persintaazje ta oan 1 (1+C2). En dan fermannichfâldigje jo it totale persintaazje mei de oarspronklike nûmers om it winske resultaat te krijen.

Sa't jo sjen kinne, wurket dizze oplossing moai foar sawol persintaazjeferheging as -fermindering:

To in hiele kolom fergrutsje of ferminderje mei in bepaald persintaazje , kinne jo de persintaazjewearde direkt yn in formule leverje. Sis, om alle wearden yn kolom B mei 5% te ferheegjen, fier de formule hjirûnder yn C2 yn, en sleep it dan nei ûnderen oer de oerbleaune rigen:

=B2*(1+5%)

Hjir fermannichfâldigje jo gewoan de orizjinele wearde mei 105%, wat in wearde produsearret dy't 5% heger is.

Foar it gemak kinne jo de persintaazjewearde ynfiere yn in foarbepaalde sel (F2) en ferwize nei dy sel. De trúk is it beskoatteljen fan de selferwizing mei $ teken, sadat de formule korrekt kopiearret:

=B2*(1+$F$2)

It foardiel fan dizze oanpak is dat om in kolom mei in oar persintaazje te ferheegjen, jo allinich hoege te feroarjen de wearde yn ien sel. Om't alle formules oan dy sel keppele binne, wurde se automatysk opnij berekkene.

Berekkenje persintaazje fariânsje mei negative wearden

As guon fan jo wearden wurde fertsjintwurdige troch negative sifers, sil de tradisjonele persintaazje ferskil formule ferkeard wurkje. In algemien akseptearre oplossing is om de neamer in posityf getal te meitsjen mei help fan de ABS-funksje.

Hjir is in generyske Excel-formule foarpersint feroaring mei negative sifers:

( nije_wearde - âlde_wearde ) / ABS( âlde_wearde )

Mei de âlde wearde yn B2 en de nije wearde yn C2 giet de echte formule as folget:

=(C2-B2)/ABS(B2)

Opmerking. Hoewol dizze ABS-oanpassing technysk korrekt is, kin de formule misliedende resultaten produsearje yn it gefal dat de oarspronklike wearde negatyf is en nije wearde is posityf, en oarsom.

Excel persintaazje feroaring divyzje troch nul flater (#DIV/0)

As jo ​​gegevensset nul wearden befettet, sille jo wierskynlik in divyzje troch nul-flater (#DIV/0!) rinne by it berekkenjen fan persintaazjeferoaring yn Excel, om't jo in getal net kinne diele troch nul yn wiskunde. De IFERROR-funksje kin helpe om dit probleem te oerwinnen. Ofhinklik fan jo ferwachtings foar it einresultaat, brûk ien fan de folgjende oplossingen.

Oplossing 1: as de âlde wearde nul is, werom 0

As de âlde wearde nul is, feroaret it persintaazje soe 0% wêze, nettsjinsteande oft de nije wearde nul is of net.

=IFERROR((C2-B2)/B2, 0)

of

=IFERROR(C2/B2-1, 0)

Oplossing 2: as de âlde wearde is nul, werom 100%

Dizze oplossing ymplementearret in oare oanpak oannommen dat de nije wearde is groeid mei 100% begjinnend fan nul:

=IFERROR((C2-B2)/B2, 1)

=IFERROR(C2/B2-1, 1)

Yn dit gefal soe it persintaazje ferskil 100% wêze as de âlde wearde nul is (rige 5) of beide wearden binne nullen (rige 9).

As jo ​​nei de markearre records hjirûnder sjogge, wurdt it dúdlik. dat gjin formule isperfekt:

Om bettere resultaten te krijen, kinne jo de twa formules kombinearje yn ien mei de geneste IF-statement:

=IF(C20, IFERROR((C2-B2)/B2, 1), IFERROR((C2-B2)/B2, 0))

Dizze ferbettere formule sil weromkomme:

• It persintaazje feroaret as 0% as sawol de âlde as de nije wearden nul binne.
• It persintaazje feroaret as 100% as de âlde wearde nul is en de nije wearde is net nul.

Dat is hoe't jo in persintaazje ferheging of fermindering kinne berekkenje yn Excel. Foar praktyske ûnderfining binne jo wolkom om ús foarbyldwurkboek hjirûnder te downloaden. Ik tankje jo foar it lêzen en hoopje jo nije wike op ús blog te sjen!

Oefeningswurkboek foar download

Excel-formule foar persintaazje ferheging / fermindering - foarbylden (.xlsx-bestân)