Este tutorial muestra cómo hacer una fórmula de Excel para el porcentaje de aumento o disminución y utilizarla tanto con números positivos como negativos.

En Microsoft Excel, hay 6 funciones diferentes para calcular la varianza. Sin embargo, ninguna de ellas es adecuada para calcular la diferencia porcentual entre dos celdas. Las funciones incorporadas están diseñadas para hallar la varianza en el sentido clásico, es decir, cuánto se separa un conjunto de valores de su media. La varianza porcentual es algo diferente. En este artículo, encontrará elfórmula para calcular el porcentaje de cambio en Excel.

¿Qué es la variación porcentual?

Variación porcentual, alias desviación porcentual o diferencia es un cambio proporcional entre dos valores, un valor original y un nuevo valor.

Por ejemplo, se puede calcular la variación entre las ventas de este año y las del año pasado, entre una temperatura prevista y la observada, entre un coste presupuestado y el real.

Por ejemplo, en enero ganaste 1.000 $ y en febrero 1.200 $, por lo que la diferencia es un aumento de 200 $ en los ingresos. Pero, ¿cuánto es eso en términos de porcentaje? Para averiguarlo, utiliza una fórmula de cambio porcentual.

Fórmula Excel de cambio porcentual

Existen dos fórmulas básicas para hallar la diferencia porcentual entre dos números.

Fórmula clásica de la varianza porcentual

Esta es la fórmula generalmente utilizada para calcular el cambio porcentual:

En matemáticas, normalmente se realizan 3 pasos para calcular la varianza porcentual entre dos valores numéricos cualesquiera:

1. Resta el nuevo valor del anterior.
2. Divide la diferencia por el número anterior.
3. Multiplica el resultado por 100.

En Excel, se omite el último paso aplicando la función Porcentaje formato.

Fórmula Excel de cambio porcentual

Y aquí hay una fórmula más simple para el cambio porcentual en Excel que devuelve el mismo resultado.

Cómo calcular el porcentaje de cambio en Excel

Para hallar la diferencia porcentual entre dos números en Excel, puede utilizar cualquiera de las fórmulas anteriores. Supongamos que tiene las ventas estimadas en la columna B y las ventas reales en la columna C. Asumiendo que el número estimado es el valor "base" y el real es el valor "nuevo", las fórmulas toman esta forma:

=(C3-B3)/B3

o

=C3/B3-1

Las fórmulas anteriores comparan los números de la fila 3. Para calcular el porcentaje de cambio en toda la columna, esto es lo que hay que hacer:

1. Introduzca la fórmula de diferencia porcentual en cualquier celda en blanco de la fila 3, por ejemplo en D3 o E3.
2. Con la celda de la fórmula seleccionada, haga clic en el botón Porcentaje Estilo de la cinta de opciones o pulse la combinación de teclas Ctrl + Mayús + % para convertir el número decimal devuelto en porcentaje.
3. Arrastre la fórmula hacia abajo tantas filas como sea necesario.

Después de copiar la fórmula, obtendrás una columna de porcentaje de cambio de tus datos.

Cómo funciona la fórmula de cambio porcentual de Excel

Al realizar los cálculos manualmente, se tomaría un valor antiguo (original) y un valor nuevo, se hallaría la diferencia entre ambos y se dividiría por el valor original. Para obtener el resultado en porcentaje, se multiplicaría por 100.

Por ejemplo, si el valor inicial es 120 y el nuevo valor es 150, la diferencia porcentual puede calcularse de este modo:

=(150-120)/120

=30/120

=0.25

0.25*100 = 25%

Aplicación de la Porcentaje El formato de número en Excel muestra un número decimal como porcentaje automáticamente, por lo que se omite la parte *100.

Fórmula Excel para el porcentaje de aumento/disminución

Como el porcentaje de aumento o disminución no es más que un caso particular de la varianza porcentual, se calcula con la misma fórmula:

O

Por ejemplo, para calcular el aumento porcentual entre dos valores (B2 y C2), la fórmula es:

=(C2-B2)/B2

O

=C2/B2-1

Una fórmula para calcular el Porcentaje de disminución es exactamente la misma.

Excel cambio porcentual valor absoluto

Por defecto, la fórmula de variación porcentual en Excel devuelve un valor positivo para el aumento porcentual y un valor negativo para la disminución porcentual. Para obtener el cambio porcentual como un valor absoluto sin tener en cuenta su signo, envuelva la fórmula en la función ABS de la siguiente manera:

En nuestro caso, la fórmula adopta esta forma:

=ABS((C3-B3)/B3)

Este también funcionará bien:

=ABS(C3/B3-1)

Calcular el porcentaje de descuento

Este ejemplo muestra un uso práctico más de la fórmula de cambio porcentual de Excel: calcular un porcentaje de descuento. Así que, señoras, cuando vayan de compras, recuerden esto:

descuento % = (precio con descuento - precio normal) / precio normal

descuento % = precio con descuento / precio normal - 1

Un porcentaje de descuento se muestra como un valor negativo porque el nuevo precio con descuento es menor que el precio inicial. Para mostrar el resultado como un número positivo anidar fórmulas dentro de la función ABS como hicimos en el ejemplo anterior:

=ABS((C2-B2)/B2)

Calcular el valor tras el cambio porcentual

Para obtener un valor después del porcentaje de aumento o disminución, la fórmula genérica es:

Supongamos que tienes los valores originales en la columna B y la diferencia porcentual en la columna C. Para calcular el nuevo valor después del cambio porcentual, la fórmula en D2 copiada es:

=B2*(1+C2)

En primer lugar, se calcula el porcentaje global que hay que multiplicar por el valor original. Para ello, basta con sumar el porcentaje a 1 (1+C2). A continuación, se multiplica el porcentaje global por los números originales para obtener el resultado deseado.

Como puede ver, esta solución funciona bien tanto para el aumento como para la disminución porcentual:

A aumentar o disminuir una columna entera en un porcentaje determinado Por ejemplo, para incrementar todos los valores de la columna B en un 5%, introduzca la siguiente fórmula en C2 y, a continuación, arrástrela hacia abajo por las filas restantes:

=B2*(1+5%)

En este caso, basta con multiplicar el valor original por 105%, lo que produce un valor un 5% superior.

Para mayor comodidad, puede introducir el valor del porcentaje en una celda predefinida (F2) y hacer referencia a esa celda. El truco está en bloquear la referencia de la celda con el signo $, para que la fórmula se copie correctamente:

=B2*(1+$F$2)

La ventaja de este enfoque es que para aumentar una columna en otro porcentaje, sólo tiene que cambiar el valor en una única celda. Como todas las fórmulas están vinculadas a esa celda, se recalcularán automáticamente.

Cálculo de la varianza porcentual con valores negativos

Si algunos de sus valores están representados por números negativos, la fórmula tradicional de diferencia porcentual no funcionará correctamente. Una solución comúnmente aceptada es hacer que el denominador sea un número positivo con la ayuda de la función ABS.

He aquí una fórmula genérica de Excel para el cambio porcentual con números negativos:

Con el valor antiguo en B2 y el nuevo en C2, la fórmula real es la siguiente:

=(C2-B2)/ABS(B2)

Nota. Aunque este ajuste de ABS es técnicamente correcto, la fórmula puede producir resultados engañosos en caso de que el valor original sea negativo y el nuevo positivo, y viceversa.

Error de división por cero del cambio porcentual de Excel (#DIV/0)

Si su conjunto de datos contiene valores cero, es probable que se encuentre con un error de división por cero (#DIV/0!) al calcular el cambio porcentual en Excel, ya que no se puede dividir un número por cero en matemáticas. La función IFERROR puede ayudar a superar este problema. Dependiendo de sus expectativas para el resultado final, utilice una de las siguientes soluciones.

Solución 1: si el valor antiguo es cero, devolver 0

Si el valor antiguo es cero, el porcentaje de cambio sería 0% independientemente de si el nuevo valor es cero o no.

=IFERROR((C2-B2)/B2, 0)

o

=IFERROR(C2/B2-1, 0)

Solución 2: si el valor antiguo es cero, devuelve 100%.

Esta solución aplica otro enfoque suponiendo que el nuevo valor ha crecido un 100% partiendo de cero:

=IFERROR((C2-B2)/B2, 1)

=IFERROR(C2/B2-1, 1)

En este caso, la diferencia porcentual sería del 100% si el valor antiguo es cero (fila 5) o si ambos valores son ceros (fila 9).

Si se observan los registros resaltados a continuación, resulta evidente que ninguna de las dos fórmulas es perfecta:

Para obtener mejores resultados, puede combinar las dos fórmulas en una utilizando la sentencia IF anidada:

=IF(C20, IFERROR((C2-B2)/B2, 1), IFERROR((C2-B2)/B2, 0))

Esta fórmula mejorada volverá:

• El porcentaje de cambio es 0% si tanto el valor antiguo como el nuevo son ceros.
• El porcentaje de cambio como 100% si el valor antiguo es cero y el nuevo valor no es cero.

Así es como se calcula un aumento o una disminución porcentual en Excel. Para obtener experiencia práctica, puedes descargarte nuestro libro de ejercicios de ejemplo. Te doy las gracias por leer y espero verte en nuestro blog la semana que viene.

Cuaderno de prácticas para descargar

Fórmula Excel para el aumento/disminución porcentual - ejemplos (archivo .xlsx)