Tutorial ini menunjukkan berbagai cara untuk mendapatkan usia dari ulang tahun di Excel. Anda akan mempelajari beberapa rumus untuk menghitung usia sebagai jumlah tahun lengkap, mendapatkan usia yang tepat dalam tahun, bulan dan hari pada tanggal hari ini atau tanggal tertentu.

Tidak ada fungsi khusus untuk menghitung usia di Excel, namun ada beberapa cara berbeda untuk mengubah tanggal lahir menjadi usia. Tutorial ini akan menjelaskan kelebihan dan kekurangan masing-masing cara, menunjukkan cara membuat rumus penghitungan usia yang sempurna di Excel dan mengubahnya untuk menyelesaikan beberapa tugas tertentu.

Cara menghitung usia dari tanggal lahir di Excel

Dalam kehidupan sehari-hari, pertanyaan " Berapa umur Anda? " biasanya menyiratkan jawaban yang menunjukkan berapa tahun Anda telah hidup. Di Microsoft Excel, Anda dapat membuat rumus untuk menghitung usia yang tepat dalam hitungan bulan, hari, jam, dan bahkan menit. Tapi mari kita menjadi tradisional, dan pelajari cara menghitung usia dari DOB dalam tahun terlebih dahulu.

Rumus Excel dasar untuk usia dalam tahun

Bagaimana biasanya Anda mengetahui usia seseorang? Cukup dengan mengurangi tanggal lahir dari tanggal sekarang. Rumus usia konvensional ini juga dapat digunakan di Excel.

Dengan asumsi tanggal lahir ada di sel B2, rumus untuk menghitung usia dalam tahun adalah sebagai berikut:

=(HARI INI()-B2)/365

Bagian pertama dari rumus (TODAY()-B2) mengembalikan selisih antara tanggal saat ini dan tanggal lahir adalah hari, dan kemudian Anda membagi angka itu dengan 365 untuk mendapatkan jumlah tahun.

Rumusnya jelas dan mudah diingat, namun, ada masalah kecil. Dalam kebanyakan kasus, rumus ini mengembalikan angka desimal seperti yang ditunjukkan pada gambar di bawah.

Untuk menampilkan jumlah tahun lengkap, gunakan fungsi INT untuk membulatkan desimal ke bawah ke bilangan bulat terdekat:

=INT((HARI INI()-B2)/365)

Kekurangan: Menggunakan rumus usia ini di Excel menghasilkan hasil yang cukup akurat, tetapi tidak sempurna. Membagi dengan jumlah rata-rata hari dalam setahun bekerja dengan baik sebagian besar waktu, tetapi terkadang membuat usia menjadi salah. Misalnya, jika seseorang lahir pada 29 Februari dan hari ini adalah 28 Februari, rumus tersebut akan membuat seseorang satu hari lebih tua.

Sebagai alternatif, Anda bisa membagi dengan 365,25, bukan 365, karena setiap tahun keempat memiliki 366 hari. Namun demikian, pendekatan ini juga tidak sempurna. Contohnya, jika Anda menghitung usia seorang anak yang belum hidup dalam tahun kabisat, membagi dengan 365,25 akan menghasilkan hasil yang salah.

Secara keseluruhan, mengurangi tanggal lahir dari tanggal sekarang berfungsi dengan baik dalam kehidupan normal, tetapi bukan pendekatan yang ideal di Excel. Lebih lanjut dalam tutorial ini, Anda akan mempelajari beberapa fungsi khusus yang menghitung usia tanpa cacat terlepas dari tahunnya.

Hitung usia dari tanggal lahir dengan fungsi YEARFRAC

Cara yang lebih andal untuk mengonversi DOB ke usia di Excel adalah menggunakan fungsi YEARFRAC yang mengembalikan pecahan tahun, yaitu jumlah hari penuh antara dua tanggal.

Sintaks fungsi YEARFRAC adalah sebagai berikut:

Dua argumen pertama sudah jelas dan hampir tidak memerlukan penjelasan tambahan. Dasar adalah argumen opsional yang mendefinisikan basis hitungan hari yang akan digunakan.

Untuk membuat rumus usia yang benar secara sempurna, berikan nilai berikut ke fungsi YEARFRAC:

• Start_date - tanggal lahir.
• End_date - TODAY() berfungsi untuk mengembalikan tanggal hari ini.
• Dasar - menggunakan dasar 1 yang memberitahu Excel untuk membagi jumlah hari aktual per bulan dengan jumlah hari aktual per tahun.

Mempertimbangkan hal di atas, rumus Excel untuk menghitung usia dari tanggal lahir adalah sebagai berikut:

Dengan mengasumsikan tanggal lahir berada di sel B2, rumusnya mengambil bentuk berikut:

=YEARFRAC(B2, HARI INI(), 1)

Seperti pada contoh sebelumnya, hasil dari fungsi YEARFRAC juga merupakan angka desimal. Untuk memperbaikinya, gunakan fungsi ROUNDDOWN dengan 0 di argumen terakhir karena Anda tidak menginginkan tempat desimal.

Jadi, inilah rumus YEARFRAC yang ditingkatkan untuk menghitung usia di Excel:

=ROUNDDOWN(YEARFRAC(B2, TODAY(), 1), 0)

Hitung usia di Excel dengan DATEDIF

Satu lagi cara untuk mengubah tanggal lahir menjadi usia di Excel adalah menggunakan fungsi DATEDIF:

Fungsi ini bisa mengembalikan perbedaan antara dua tanggal dalam berbagai unit waktu seperti tahun, bulan dan hari, tergantung pada nilai yang Anda berikan di unit argumen:

• Y - mengembalikan jumlah tahun yang lengkap antara tanggal mulai dan akhir.
• M - mengembalikan jumlah bulan lengkap di antara tanggal-tanggal tersebut.
• D - mengembalikan jumlah hari di antara kedua tanggal tersebut.
• YM - kembali bulan , mengabaikan hari dan tahun.
• MD - mengembalikan perbedaan dalam hari , mengabaikan bulan dan tahun.
• YD - mengembalikan perbedaan dalam hari , mengabaikan tahun.

Karena kita bertujuan untuk menghitung usia di tahun , kita menggunakan unit "y":

Dalam contoh ini, DOB berada di cell B2, dan kamu mereferensikan cell ini dalam rumus umurmu:

=DATEDIF(B2, TODAY(), "y")

Tidak ada fungsi pembulatan tambahan yang diperlukan dalam kasus ini karena rumus DATEDIF dengan unit "y" menghitung jumlah tahun penuh:

Cara mendapatkan usia dari ulang tahun dalam tahun, bulan dan hari

Seperti yang baru saja Anda lihat, menghitung usia sebagai jumlah tahun penuh yang telah dijalani orang itu mudah, tetapi tidak selalu cukup. Jika Anda ingin mengetahui usia yang tepat, yaitu berapa tahun, bulan, dan hari yang ada di antara tanggal lahir seseorang dan tanggal saat ini, tulis 3 fungsi DATEDIF yang berbeda:

1. Untuk mendapatkan jumlah tahun: =DATEDIF(B2, TODAY(), "Y")
2. Untuk mendapatkan jumlah bulan: =DATEDIF(B2, TODAY(), "YM")
3. Untuk mendapatkan jumlah hari: =DATEDIF(B2,TODAY(), "MD")

Di mana B2 adalah tanggal lahir.

Dan kemudian, gabungkan fungsi-fungsi di atas dalam satu rumus, seperti ini:

=DATEDIF(B2,TODAY(), "Y") & DATEDIF(B2,TODAY(), "YM") & DATEDIF(B2,TODAY(), "MD")

Rumus di atas mengembalikan 3 angka (tahun, bulan, dan hari) digabungkan dalam satu string teks, seperti yang ditunjukkan pada gambar di bawah:

Untuk membuat hasilnya lebih bermakna, pisahkan angka-angka dengan koma dan tentukan arti masing-masing nilai:

=DATEDIF(B2,TODAY(), "Y") & " Tahun, " & DATEDIF(B2,TODAY(), "YM") & " Bulan, " & DATEDIF(B2,TODAY(), "MD") & " Hari"

Hasilnya terlihat jauh lebih baik sekarang:

Rumus ini berfungsi dengan baik, tetapi Anda dapat meningkatkannya lebih jauh dengan menyembunyikan nilai nol. Untuk ini, tambahkan 3 pernyataan IF yang memeriksa 0, satu per setiap DATEDIF:

=IF(DATEDIF(B2, TODAY(), "y")=0,""",DATEDIF(B2, TODAY(), "y")&" tahun, ")& IF(DATEDIF(B2, TODAY(), "ym")=0,"",DATEDIF(B2, TODAY(), "ym")&" bulan, ")& IF(DATEDIF(B2, TODAY(), "md")=0,"",DATEDIF(B2, TODAY(), "md")&" hari")

Tangkapan layar berikut mendemonstrasikan rumus usia Excel akhir dalam tindakan - ini mengembalikan usia dalam tahun, bulan, dan hari, hanya menampilkan bukan nol nilai:

Tip. Jika Anda mencari rumus Excel untuk menghitung usia di tahun dan bulan , ambil rumus di atas dan hapus blok IF(DATEDIF()) terakhir yang menghitung hari.

Rumus khusus untuk menghitung usia di Excel

Rumus perhitungan usia generik yang dibahas di atas bekerja dengan baik dalam banyak kasus. Namun, dalam beberapa situasi, Anda mungkin memerlukan sesuatu yang sangat spesifik. Tentu saja, tidak mungkin untuk mencakup setiap skenario, tetapi contoh-contoh berikut ini akan memberi Anda beberapa ide tentang bagaimana Anda dapat mengubah rumus usia tergantung pada tugas khusus Anda.

Cara menghitung usia pada tanggal tertentu di Excel

Jika Anda ingin mengetahui usia seseorang pada tanggal tertentu, gunakan rumus usia DATEDIF yang dibahas di atas, tetapi ganti fungsi TODAY () di argumen ke-2 dengan tanggal tertentu.

Dengan mengasumsikan tanggal lahir di B1, rumus berikut ini akan mengembalikan usia per 1 Januari 2020:

=DATEDIF(B1, "1/1/2020", "Y") & " Tahun, " & DATEDIF(B1, "1/1/2020", "YM") & " Bulan, " & DATEDIF(B1, "1/1/2020", "MD") & " Hari"

Untuk membuat rumus umurmu lebih fleksibel, kamu bisa memasukkan tanggal di suatu cell dan mereferensikan cell tersebut dalam rumusmu:

=DATEDIF(B1, B2, "Y") & "Tahun," & DATEDIF(B1,B2, "YM") & "Bulan," & DATEDIF(B1,B2, "MD") & "Hari"

Di mana B1 adalah DOB, dan B2 adalah tanggal di mana Anda ingin menghitung usia.

Menghitung usia pada tahun tertentu

Rumus ini berguna dalam situasi ketika tanggal lengkap untuk menghitung tidak ditentukan, dan Anda hanya mengetahui tahunnya.

Katakanlah Anda bekerja dengan database medis, dan tujuan Anda adalah untuk mengetahui usia pasien pada saat mereka menjalani pemeriksaan medis lengkap terakhir.

Dengan mengasumsikan tanggal lahir berada di kolom B yang dimulai dari baris ke-3, dan tahun pemeriksaan medis terakhir berada di kolom C, maka rumus penghitungan usia adalah sebagai berikut:

=DATEDIF(B3,DATE(C3, 1, 1), "y")

Karena tanggal pasti pemeriksaan medis tidak ditentukan, Anda menggunakan fungsi DATE dengan argumen tanggal dan bulan sembarang, misalnya DATE(C3, 1, 1).

Fungsi DATE mengekstrak tahun dari sel B3, membuat tanggal lengkap menggunakan nomor bulan dan hari yang Anda berikan (1-Jan dalam contoh ini), dan meneruskan tanggal tersebut ke DATEDIF. Hasilnya, Anda mendapatkan usia pasien pada tanggal 1 Januari tahun tertentu:

Cari tahu tanggal ketika seseorang mencapai usia N tahun

Misalkan teman Anda lahir pada tanggal 8 Maret 1978. Bagaimana Anda tahu pada tanggal berapa dia menyelesaikan 50 tahun usianya? Biasanya, Anda cukup menambahkan 50 tahun ke tanggal lahir orang tersebut. Di Excel, Anda melakukan hal yang sama menggunakan fungsi DATE:

=DATE(TAHUN(B2) + 50, BULAN(B2), HARI(B2))

Di mana B2 adalah tanggal lahir.

Alih-alih melakukan hard-coding angka tahun dalam rumusnya, kamu bisa mereferensikan cell tertentu di mana penggunamu bisa memasukkan angka tahun berapapun (F1 pada screenshot di bawah):

Hitung usia dari hari, bulan, dan tahun dalam sel yang berbeda

Ketika tanggal lahir dibagi menjadi 3 sel yang berbeda (misalnya tahun di B3, bulan di C3 dan hari di D3), Anda dapat menghitung usia dengan cara ini:

• Dapatkan tanggal lahir dengan menggunakan fungsi DATE dan DATEVALUE:

  DATE(B3,MONTH(DATEVALUE(C3& "1")),D3)

• Sematkan rumus di atas ke dalam DATEDIF untuk menghitung usia dari tanggal lahir dalam tahun, bulan, dan hari: =DATEDIF(DATE(B3, MONTH(DATEVALUE(C3& "1"))), D3), TODAY(), "y") & " Tahun," & DATEDIF(DATE(DATE(B3, MONTH(DATEVALUE(C3& "1"))), D3),TODAY(), "ym") & " Bulan," & DATEDIF(DATE(DATE(B3, MONTH(DATEVALUE(C3& "1"))), D3), TODAY(), "md") & " Hari"

  

Untuk contoh lebih lanjut tentang menghitung jumlah hari sebelum / sesudah tanggal, silakan lihat Bagaimana menghitung hari sejak atau sampai tanggal di Excel.

Kalkulator usia di Excel

Jika Anda ingin memiliki kalkulator usia Anda sendiri di Excel, Anda dapat membuatnya dengan menggunakan beberapa rumus DATEDIF yang berbeda yang dijelaskan di bawah ini. Jika Anda lebih suka tidak menemukan kembali roda, Anda dapat menggunakan kalkulator usia yang dibuat oleh profesional Excel kami.

Cara membuat kalkulator usia di Excel

Sekarang setelah Anda tahu cara membuat rumus usia di Excel, Anda dapat membuat kalkulator usia khusus, misalnya yang ini:

Catatan. Untuk melihat buku kerja yang disematkan, harap izinkan cookie pemasaran.

Apa yang Anda lihat di atas adalah lembar Excel Online yang disematkan, jadi silakan masukkan tanggal lahir Anda di sel yang sesuai, dan Anda akan mendapatkan usia Anda sebentar lagi.

Kalkulator menggunakan rumus berikut untuk menghitung usia berdasarkan tanggal lahir di sel A3 dan tanggal hari ini.

• Formula dalam B5 menghitung usia dalam tahun, bulan, dan hari: =DATEDIF(B2,TODAY(), "Y") & " Tahun, " & DATEDIF(B2,TODAY(), "YM") & " Bulan, " & DATEDIF(B2,TODAY(), "MD") & " Hari"
• Formula dalam B6 menghitung usia dalam bulan: =DATEDIF($B$3,TODAY(), "m")
• Formula dalam B7 menghitung usia dalam hari: =DATEDIF($B$3,TODAY(), "d")

Jika Anda memiliki pengalaman dengan kontrol Formulir Excel, Anda dapat menambahkan opsi untuk menghitung usia pada tanggal tertentu, seperti yang ditunjukkan pada tangkapan layar berikut:

Untuk ini, tambahkan beberapa tombol opsi ( Tab Pengembang > Sisipkan > Kontrol formulir > Tombol Opsi ), dan menautkannya ke beberapa sel. Dan kemudian, tulis rumus IF/DATEDIF untuk mendapatkan usia baik pada tanggal hari ini atau pada tanggal yang ditentukan oleh pengguna.

Rumus ini bekerja dengan logika berikut:

• Jika Tanggal hari ini kotak opsi dipilih, nilai 1 muncul di sel yang ditautkan (I5 dalam contoh ini), dan rumus usia menghitung berdasarkan tanggal hari ini: IF($I$5=1, DATEDIF($B$3,TODAY(), "Y") & " Tahun, " & DATEDIF($B$3,TODAY(), "YM") & " Bulan, " & DATEDIF($B$3, TODAY(), "MD") & " Hari")
• Jika Tanggal tertentu dipilih DAN tanggal dimasukkan di sel B7, usia dihitung pada tanggal yang ditentukan: IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7, "Y") & " Tahun, " & DATEDIF($B$3, $B$7, "YM") & " Bulan, " & DATEDIF($B$3, $B$7, "MD") & " Hari", ""))

Akhirnya, sarangkan fungsi-fungsi di atas ke dalam satu sama lain, dan Anda akan mendapatkan rumus perhitungan usia yang lengkap (dalam B9):

=IF($I$5=1, DATEDIF($B$3, TODAY(), "Y") & " Tahun, " & DATEDIF($B$3, TODAY(), "YM") & " Bulan, " & DATEDIF($B$3, TODAY(), "MD") & " Hari", IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7, "Y") & " Tahun, " & DATEDIF($B$3, $B$7, "YM") & " Bulan, " & DATEDIF($B$3, $B$7, "MD") & " Hari", ""))

Rumus-rumus dalam B10 dan B11 bekerja dengan logika yang sama. Tentu saja, rumus-rumus ini jauh lebih sederhana karena mereka hanya menyertakan satu fungsi DATEDIF untuk mengembalikan usia masing-masing sebagai jumlah bulan atau hari lengkap.

Untuk mempelajari detailnya, saya mengundang Anda untuk mengunduh Kalkulator Usia Excel ini dan menyelidiki rumus di sel B9: B11.

Unduh Kalkulator Usia untuk Excel

Kalkulator usia siap pakai untuk Excel

Pengguna Ultimate Suite kami tidak perlu repot-repot membuat kalkulator usia mereka sendiri di Excel - hanya dengan beberapa klik saja:

1. Pilih sel tempat Anda ingin menyisipkan rumus usia, buka Alat Ablebits tab> Tanggal &; Waktu kelompok, dan klik tombol Tanggal &; Wisaya Waktu tombol.

   

2. Date & Time Wizard akan dimulai, dan Anda langsung masuk ke Date & Time Wizard. Usia tab.
3. Pada Usia tab, ada 3 hal yang harus Anda tentukan:
   • Data kelahiran sebagai referensi sel atau tanggal dalam format mm/dd/yyyy.
   • Usia pada tanggal hari ini atau tanggal tertentu .
   • Pilih apakah akan menghitung usia dalam hari, bulan, tahun, atau usia yang tepat.
4. Klik Masukkan rumus tombol.

Selesai!

Formula disisipkan di sel yang dipilih sesaat, dan Anda mengklik dua kali gagang isian untuk menyalinnya ke bawah kolom.

Seperti yang mungkin telah Anda perhatikan, rumus yang dibuat oleh kalkulator usia Excel kami lebih kompleks daripada yang telah kita bahas sejauh ini, tetapi ini melayani unit waktu tunggal dan jamak seperti "hari" dan "hari".

Jika Anda ingin menyingkirkan satuan nol seperti "0 hari", pilih Jangan menunjukkan unit nol kotak centang:

Jika Anda penasaran untuk menguji kalkulator usia ini serta untuk menemukan 60 add-in yang lebih menghemat waktu untuk Excel, Anda dipersilakan untuk mengunduh versi uji coba Ultimate Suite kami di akhir posting ini.

Cara menyoroti usia tertentu (di bawah atau di atas usia tertentu)

Dalam beberapa situasi, Anda mungkin tidak hanya perlu menghitung usia di Excel, tetapi juga menyorot sel yang berisi usia yang di bawah atau di atas usia tertentu.

Jika rumus kalkulasi usiamu mengembalikan jumlah tahun lengkap, maka kamu bisa membuat aturan pemformatan bersyarat biasa berdasarkan rumus sederhana seperti ini:

• Untuk menyoroti usia yang sama dengan atau lebih besar dari 18: =$C2>=18
• Untuk menyoroti usia di bawah 18 tahun: =$C2<18

Di mana C2 adalah sel paling atas dalam kolom Umur (tidak termasuk tajuk kolom).

Tetapi bagaimana jika rumus Anda menampilkan usia dalam tahun dan bulan, atau dalam tahun, bulan, dan hari? Dalam hal ini, Anda harus membuat aturan berdasarkan rumus DATEDIF yang menghitung usia dari tanggal lahir dalam tahun.

Andaikan tanggal lahir berada di kolom B yang dimulai dari baris 2, maka rumusnya adalah sebagai berikut:

• Untuk menyoroti usia di bawah 18 (kuning): =DATEDIF($B2, TODAY(), "Y")<18
• Untuk menyoroti usia antara 18 dan 65 (hijau): =AND(DATEDIF($B2, TODAY(), "Y")>=18, DATEDIF($B2, TODAY(), "Y")<=65)
• Untuk menyoroti usia lebih dari 65 (biru): =DATEDIF($B2, TODAY(), "Y")>65

Untuk membuat aturan berdasarkan rumus di atas, pilih sel atau seluruh baris yang ingin Anda sorot, buka Rumah tab> Gaya kelompok, dan klik Pemformatan Bersyarat > Aturan Baru... > Gunakan formula untuk menentukan sel mana yang akan diformat .

Langkah-langkah detailnya dapat ditemukan di sini: Cara membuat aturan pemformatan bersyarat berdasarkan rumus.

Saya harap rumus-rumus ini mudah dipelajari dan Anda akan mencobanya di lembar kerja Anda. Terima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!

Unduhan yang tersedia

Contoh Perhitungan Usia Excel (file .xlsx)

Ultimate Suite 14 hari versi yang berfungsi penuh (file .exe)