Mục lục
Hướng dẫn này cho biết cách tạo công thức Excel để tăng hoặc giảm phần trăm và sử dụng công thức đó với cả số dương và số âm.
Trong Microsoft Excel, có 6 hàm khác nhau để tính toán phương sai. Tuy nhiên, không có phương pháp nào phù hợp để tính phần trăm chênh lệch giữa hai ô. Các hàm sẵn có được thiết kế để tìm phương sai theo nghĩa cổ điển, tức là khoảng cách mà một tập hợp các giá trị trải ra so với mức trung bình của chúng. Phương sai phần trăm là một cái gì đó khác biệt. Trong bài viết này, bạn sẽ tìm thấy công thức phù hợp để tính phần trăm thay đổi trong Excel.
Phần trăm thay đổi là gì?
Phần trăm thay đổi, hay còn gọi là phương sai phần trăm hoặc chênh lệch , là sự thay đổi theo tỷ lệ giữa hai giá trị, giá trị ban đầu và giá trị mới.
Công thức thay đổi phần trăm tính toán mức độ thay đổi của một thứ gì đó giữa hai giai đoạn theo tỷ lệ phần trăm. Ví dụ: bạn có thể tính toán chênh lệch giữa doanh số bán hàng trong năm nay và năm trước, giữa nhiệt độ dự báo và nhiệt độ quan sát được, giữa chi phí dự toán và chi phí thực tế.
Ví dụ: vào tháng 1, bạn kiếm được 1.000 đô la và trong tháng 2 là 1.200 đô la , do đó, sự khác biệt là thu nhập tăng $200. Nhưng đó là bao nhiêu về tỷ lệ phần trăm? Để tìm ra điều đó, bạn sử dụng công thức thay đổi phần trăm. 
Công thức thay đổi phần trăm Excel
Có hai công thức cơ bản để tìm chênh lệch phần trăm giữa haisố.
Công thức phương sai phần trăm cổ điển
Đây là công thức thường được sử dụng để tính phần trăm thay đổi:
( new_value - old_value ) / old_valueTrong toán học, bạn thường thực hiện 3 bước để tính phương sai phần trăm giữa hai giá trị số bất kỳ:
- Trừ đi giá trị mới giá trị cũ.
- Chia số chênh lệch cho số cũ.
- Nhân kết quả với 100.
Trong Excel, bạn bỏ qua bước cuối cùng bằng cách áp dụng định dạng Tỷ lệ phần trăm .
Công thức thay đổi phần trăm Excel
Và đây là công thức đơn giản hơn cho thay đổi phần trăm trong Excel trả về kết quả tương tự.
new_value / old_value - 1Cách tính phần trăm thay đổi trong Excel
Để tìm chênh lệch phần trăm giữa hai số trong Excel, bạn có thể sử dụng một trong hai công thức trên. Giả sử bạn có doanh số ước tính ở cột B và doanh số thực tế ở cột C. Giả sử con số ước tính là giá trị "cơ sở" và thực tế là giá trị "mới", các công thức sẽ có dạng sau:
=(C3-B3)/B3
hoặc
=C3/B3-1
Các công thức trên so sánh các số ở hàng 3. Để tính phần trăm thay đổi trong toàn bộ cột, bạn cần làm như sau:
- Nhập công thức chênh lệch phần trăm vào bất kỳ ô trống nào trong hàng 3, chẳng hạn như ở D3 hoặc E3.
- Với ô công thức đã chọn, nhấp vào nút Kiểu phần trăm trên cácribbon hoặc nhấn phím tắt Ctrl + Shift + %. Thao tác này sẽ chuyển đổi số thập phân được trả về thành tỷ lệ phần trăm.
- Kéo công thức xuống trên bao nhiêu hàng tùy ý.
Sau khi sao chép công thức xuống, bạn sẽ thấy cột thay đổi phần trăm từ dữ liệu của bạn. 
Cách thức hoạt động của công thức thay đổi phần trăm Excel
Khi thực hiện tính toán theo cách thủ công, bạn sẽ lấy một giá trị cũ (gốc) và một giá trị mới, tìm sự khác biệt giữa chúng và chia nó cho giá trị ban đầu. Để có được kết quả dưới dạng phần trăm, bạn sẽ nhân nó với 100.
Ví dụ: nếu giá trị ban đầu là 120 và giá trị mới là 150, thì phần trăm chênh lệch có thể được tính theo cách này:
=(150-120)/120
=30/120
=0.25
0.25*100 = 25%
Áp dụng định dạng số Percentage trong Excel sẽ tự động hiển thị số thập phân dưới dạng phần trăm , do đó, phần *100 bị bỏ qua.
Công thức Excel cho phần trăm tăng/giảm
Vì phần trăm tăng hoặc giảm chỉ là một trường hợp cụ thể của phương sai phần trăm nên nó được tính bằng cùng một công thức:
( new_value - initial_value ) / initial_valueHoặc
new_value / initial_value - 1Ví dụ: để tính phần trăm tăng giữa hai giá trị (B2 và C2), công thức là:
=(C2-B2)/B2
Hoặc
=C2/B2-1 
Công thức tính phần trăm giảm hoàn toàn giống nhau. 
Phần trăm Excelthay đổi giá trị tuyệt đối
Theo mặc định, công thức phương sai phần trăm trong Excel trả về giá trị dương cho phần trăm tăng và giá trị âm cho phần trăm giảm. Để nhận được phần trăm thay đổi dưới dạng giá trị tuyệt đối mà không quan tâm đến dấu của nó, hãy bọc công thức trong hàm ABS như sau:
ABS(( new_value - old_value ) / old_value)Trong trường hợp của chúng tôi, công thức có dạng sau:
=ABS((C3-B3)/B3)
Công thức này cũng sẽ hoạt động tốt:
=ABS(C3/B3-1) 
Tính phần trăm chiết khấu
Ví dụ này cho thấy một cách sử dụng thực tế hơn của công thức thay đổi phần trăm trong Excel - tính ra phần trăm chiết khấu. Vì vậy, các bạn nữ khi đi mua sắm, hãy nhớ điều này:
discount % = (discounted price - regular price) / regular price
discount % = discounted price / regular price - 1
Phần trăm giảm giá được hiển thị dưới dạng giá trị âm vì giá chiết khấu mới nhỏ hơn giá chiết khấu giá ban đầu. Để xuất kết quả dưới dạng số dương , hãy lồng các công thức bên trong hàm ABS như chúng ta đã làm trong ví dụ trước:
=ABS((C2-B2)/B2) 
Tính toán giá trị sau khi phần trăm thay đổi
Để nhận giá trị sau khi tăng hoặc giảm phần trăm, công thức chung là:
initial_value *(1+ percent_change )Giả sử bạn có giá trị gốc các giá trị trong cột B và chênh lệch tỷ lệ phần trăm trong cột C. Để tính giá trị mới sau khi thay đổi tỷ lệ phần trăm, công thức trong D2 được sao chép xuống là:
=B2*(1+C2)
Trước tiên, bạn tìm tỷ lệ phần trăm tổng thể cần phải được nhân vớigiá trị ban đầu. Đối với điều này, chỉ cần thêm phần trăm vào 1 (1+C2). Sau đó, bạn nhân tỷ lệ phần trăm tổng thể với các số ban đầu để có được kết quả mong muốn.
Như bạn có thể thấy, giải pháp này hoạt động tốt cho cả tăng và giảm tỷ lệ phần trăm: 
Đến tăng hoặc giảm toàn bộ cột theo một phần trăm nhất định , bạn có thể cung cấp giá trị phần trăm trực tiếp trong một công thức. Giả sử, để tăng tất cả các giá trị trong cột B lên 5%, hãy nhập công thức bên dưới vào C2, sau đó kéo công thức xuống các hàng còn lại:
=B2*(1+5%)
Ở đây, bạn chỉ cần nhân giá trị gốc thêm 105%, điều này tạo ra giá trị cao hơn 5%.
Để thuận tiện, bạn có thể nhập giá trị phần trăm vào một ô được xác định trước (F2) và tham chiếu đến ô đó. Mẹo là khóa tham chiếu ô bằng ký hiệu $, vì vậy công thức sẽ sao chép chính xác:
=B2*(1+$F$2)
Ưu điểm của phương pháp này là để tăng một cột thêm một tỷ lệ phần trăm, bạn chỉ cần thay đổi giá trị trong một ô duy nhất. Vì tất cả các công thức được liên kết với ô đó nên chúng sẽ tự động tính toán lại. 
Tính phương sai phần trăm với giá trị âm
Nếu một số giá trị của bạn được biểu thị bằng số âm, thì công thức chênh lệch phần trăm truyền thống sẽ hoạt động không chính xác. Một giải pháp thường được chấp nhận là biến mẫu số thành một số dương với sự trợ giúp của hàm ABS.
Dưới đây là công thức Excel chung chophần trăm thay đổi với số âm:
( new_value - old_value ) / ABS( old_value )Với giá trị cũ trong B2 và giá trị mới trong C2, công thức thực như sau:
=(C2-B2)/ABS(B2) 
Lưu ý. Mặc dù điều chỉnh ABS này đúng về mặt kỹ thuật, nhưng công thức có thể tạo ra kết quả sai lệch trong trường hợp giá trị ban đầu là âm và giá trị mới là dương và ngược lại.
Excel phần trăm thay đổi chia cho lỗi 0 (#DIV/0)
Nếu tập dữ liệu của bạn chứa các giá trị bằng 0, bạn có khả năng gặp phải lỗi chia cho 0 (#DIV/0!) khi tính phần trăm thay đổi trong Excel vì bạn không thể chia một số cho 0 trong toán học. Hàm IFERROR có thể giúp khắc phục vấn đề này. Tùy thuộc vào kỳ vọng của bạn đối với kết quả cuối cùng, hãy sử dụng một trong các giải pháp sau.
Giải pháp 1: nếu giá trị cũ bằng 0, trả về 0
Nếu giá trị cũ bằng 0, phần trăm thay đổi sẽ là 0% bất kể giá trị mới có bằng 0 hay không.
=IFERROR((C2-B2)/B2, 0)
hoặc
=IFERROR(C2/B2-1, 0)
Giải pháp 2: nếu giá trị cũ bằng 0, trả về 100%
Giải pháp này thực hiện một cách tiếp cận khác giả định rằng giá trị mới đã tăng 100% bắt đầu từ 0:
=IFERROR((C2-B2)/B2, 1)
=IFERROR(C2/B2-1, 1)
Trong trường hợp này, chênh lệch phần trăm sẽ là 100% nếu giá trị cũ bằng 0 (hàng 5) hoặc cả hai giá trị đều bằng 0 (hàng 9).
Nhìn vào các bản ghi được đánh dấu bên dưới, điều này trở nên rõ ràng rằng cả hai công thức đều khôngperfect: 
Để có kết quả tốt hơn, bạn có thể kết hợp hai công thức thành một bằng cách sử dụng câu lệnh IF lồng nhau:
=IF(C20, IFERROR((C2-B2)/B2, 1), IFERROR((C2-B2)/B2, 0))
Công thức cải tiến này sẽ trả về:
- Tỷ lệ phần trăm thay đổi thành 0% nếu cả giá trị cũ và mới đều bằng 0.
- Tỷ lệ phần trăm thay đổi thành 100% nếu giá trị cũ bằng 0 và giá trị mới khác 0.
Đó là cách tính phần trăm tăng hoặc giảm trong Excel. Để có trải nghiệm thực tế, bạn có thể tải xuống sổ làm việc mẫu của chúng tôi bên dưới. Tôi cảm ơn bạn đã đọc và hy vọng sẽ gặp bạn trên blog của chúng tôi vào tuần tới!
Sách bài tập thực hành để tải xuống
Công thức Excel để tăng/giảm phần trăm - ví dụ (tệp .xlsx)
