ટ્યુટોરીયલ એક્સેલ VLOOKUP કેસ-સંવેદનશીલ કેવી રીતે બનાવવું તે સમજાવે છે, ટેક્સ્ટ કેસને અલગ પાડતા કેટલાક અન્ય સૂત્રો દર્શાવે છે અને દરેક કાર્યની શક્તિ અને મર્યાદાઓ દર્શાવે છે.

હું દરેક એક્સેલ વપરાશકર્તા જાણે છે કે એક્સેલમાં વર્ટિકલ લુકઅપ કયું કાર્ય કરે છે. સાચું, તે VLOOKUP છે. જો કે, બહુ ઓછા લોકો જાણે છે કે એક્સેલનું VLOOKUP કેસ-સંવેદનશીલ છે, એટલે કે તે લોઅરકેસ અને અપરકેસ અક્ષરોને સમાન અક્ષરો તરીકે વર્તે છે.

અહીં એક ઝડપી ઉદાહરણ છે જે VLOOKUPની ટેક્સ્ટ કેસને અલગ પાડવાની અસમર્થતા દર્શાવે છે. ધારો કે જો તમારી પાસે સેલ A2 માં "બિલ" અને A4 માં "બિલ" છે. નીચેનું સૂત્ર "બિલ" પકડશે કારણ કે તે લુકઅપ એરેમાં પ્રથમ આવે છે અને B2 માંથી મેળ ખાતી કિંમત પરત કરે છે.

=VLOOKUP("Bill", A2:B4, 2, FALSE)

આમાં આગળ. લેખ, હું તમને VLOOKUP કેસ-સંવેદનશીલ બનાવવાની રીત બતાવીશ. અમે એક્સેલમાં કેસ-સેન્સિટિવ મેચ કરી શકે તેવા કેટલાક અન્ય ફંક્શન્સનું પણ અન્વેષણ કરીશું.

કેસ-સેન્સિટિવ VLOOKUP ફોર્મ્યુલા

ઉપર જણાવ્યા મુજબ, સામાન્ય VLOOKUP ફોર્મ્યુલા અક્ષર કેસને ઓળખતો નથી. જો કે, એક્સેલ VLOOKUP ને કેસ-સેન્સિટિવ બનાવવાની એક રીત છે, જેમ કે નીચેના ઉદાહરણમાં દર્શાવવામાં આવ્યું છે.

ધારો કે તમારી પાસે કૉલમ A માં આઇટમ ID છે અને તમે આઇટમની કિંમત અને ટિપ્પણી ખેંચવા માંગો છો કૉલમ B અને Cમાંથી. સમસ્યા એ છે કે ID માં લોઅરકેસ અને અપરકેસ અક્ષરો બંનેનો સમાવેશ થાય છે. ઉદાહરણ તરીકે, A4 (001Tvci3u) અને A5 (001Tvci3U) ના મૂલ્યો માત્રઅનુક્રમે છેલ્લું અક્ષર, "u" અને "U",.

જ્યારે "001Tvci3 U " જોઈએ, ત્યારે પ્રમાણભૂત VLOOKUP ફોર્મ્યુલા $90 આઉટપુટ કરે છે જે "001Tvci3 u સાથે સંકળાયેલ છે. " કારણ કે તે લુકઅપ એરેમાં "001Tvci3 U " પહેલા આવે છે. પરંતુ આ તમે ઇચ્છો તે નથી, ખરું?

=VLOOKUP(F2, A2:C7, 2, FALSE)

એક્સેલમાં કેસ-સંવેદનશીલ લુકઅપ કરવા માટે, અમે VLOOKUP, પસંદ કરો અને ચોક્કસને જોડીએ છીએ કાર્યો:

આ સામાન્ય સૂત્ર તમામ પરિસ્થિતિઓમાં સંપૂર્ણ રીતે કામ કરે છે. તમે જમણેથી ડાબે પણ જોઈ શકો છો, જે નિયમિત VLOOKUP ફોર્મ્યુલા કરી શકતું નથી. આ સરળ અને ભવ્ય ઉકેલ સૂચવવા બદલ પૌરિયાને અભિનંદન!

અમારા કિસ્સામાં, વાસ્તવિક સૂત્રો નીચે મુજબ છે.

કિંમત F3 માં ખેંચવા માટે:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), B2:B7), 2, FALSE)

કોમેન્ટ F4 મેળવવા માટે:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7), 2, FALSE)

નોંધ. એક્સેલ 365 સિવાયના તમામ એક્સેલ વર્ઝનમાં, આ માત્ર એરે ફોર્મ્યુલા તરીકે કામ કરે છે, તેથી તેને યોગ્ય રીતે પૂર્ણ કરવા માટે Ctrl + Shift + Enter દબાવવાનું યાદ રાખો. એક્સેલ 365 માં, ડાયનેમિક એરેના સમર્થનને કારણે, તે નિયમિત ફોર્મ્યુલા તરીકે પણ કામ કરે છે.

આ ફોર્મ્યુલા કેવી રીતે કામ કરે છે:

મુખ્ય ભાગ જે યુક્તિ કરે છે તે છે નેસ્ટેડ EXACT સાથે ફોર્મ્યુલા પસંદ કરો:

CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7)

અહીં, EXACT ફંક્શન A2:A7 માં દરેક મૂલ્યની સામે F2 માં મૂલ્યની તુલના કરે છે અને જો તે અક્ષર કેસ સહિત બરાબર સમાન હોય તો TRUE પરત કરે છે,FALSE અન્યથા:

{FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}

CHOOSE ની index_num દલીલ માટે, અમે એરે કોન્સ્ટન્ટ {1,2} નો ઉપયોગ કરીએ છીએ. પરિણામે, ફંક્શન ઉપરોક્ત એરેમાંથી લોજિકલ મૂલ્યો અને C2:C7 માંથી મૂલ્યોને દ્વિ-પરિમાણીય એરેમાં આ રીતે જોડે છે:

{FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}

VLOOKUP ફંક્શન તેને ત્યાંથી લે છે અને 2-પરિમાણીય એરેની 1લી કૉલમમાં લુકઅપ મૂલ્ય (જે સાચું છે) માટે શોધે છે (તાર્કિક મૂલ્યો દ્વારા રજૂ કરવામાં આવે છે) અને 2જી કૉલમમાંથી મેળ આપે છે, જે અમે શોધી રહ્યાં છીએ તે કિંમત છે:

VLOOKUP(TRUE, {FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}, 2, 0)

કેસ-સેન્સિટિવ XLOOKUP ફોર્મ્યુલા

Microsoft 365 સબ્સ્ક્રાઇબર્સ એક્સેલમાં કેસ-સેન્સિટિવ લુકઅપ પણ સરળ ફોર્મ્યુલા સાથે કરી શકે છે. જેમ તમે અનુમાન કરી શકો છો, હું VLOOKUP ના વધુ શક્તિશાળી અનુગામી વિશે વાત કરી રહ્યો છું - XLOOKUP ફંક્શન.

કારણ કે XLOOKUP લુકઅપ અને રીટર્ન એરે પર અલગથી કાર્ય કરે છે, અમને પહેલાની દ્વિ-પરિમાણીય એરે યુક્તિની જરૂર નથી. ઉદાહરણ. ખાલી, lookup_array દલીલ માટે EXACT નો ઉપયોગ કરો:

છેલ્લી દલીલ ("મળ્યું નથી") વૈકલ્પિક છે. તે માત્ર વ્યાખ્યાયિત કરે છે કે જો કોઈ મેળ ન મળે તો કઈ કિંમત પરત કરવી. જો તમે તેને છોડી દો છો, તો ફોર્મ્યુલામાં કંઈ નહીં મળે તો પ્રમાણભૂત #N/A ભૂલ પરત કરવામાં આવશે.

અમારા નમૂના કોષ્ટક માટે, આ કેસ-સંવેદનશીલ XLOOKUP ફોર્મ્યુલા છે જેનો ઉપયોગ કરવો જોઈએ.

F3 માં કિંમત મેળવવા માટે:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), B2:B7, "Not found")

ને કાઢવા માટેટિપ્પણી F4:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), C2:C7, "Not found")

આ ફોર્મ્યુલા કેવી રીતે કામ કરે છે:

પહેલાના ઉદાહરણની જેમ, ચોક્કસ વળતર TRUE અને FALSE મૂલ્યોની શ્રેણી, જ્યાં TRUE કેસ-સંવેદનશીલ મેચોનું પ્રતિનિધિત્વ કરે છે. XLOOKUP સાચા મૂલ્ય માટે ઉપરોક્ત એરે શોધે છે અને return_array માંથી મેચ પરત કરે છે. મહેરબાની કરીને નોંધ કરો, જો લુકઅપ કોલમમાં બે કે તેથી વધુ બરાબર સમાન મૂલ્યો હોય (લેટર કેસ સહિત), તો ફોર્મ્યુલા પ્રથમ મળેલ મેચ પરત કરશે.

XLOOKUP મર્યાદા : ફક્ત ઉપલબ્ધ Excel 365 અને Excel 2021 માં.

SUMPRODUCT - મેચિંગ નંબર્સ પરત કરવા માટે કેસ-સંવેદનશીલ લુકઅપ

જેમ તમે મથાળામાંથી સમજો છો, SUMPRODUCT એ બીજું એક્સેલ ફંક્શન છે જે કેસ-સંવેદનશીલ લુકઅપ કરી શકે છે. , પરંતુ તે ફક્ત સંખ્યાત્મક મૂલ્યો પરત કરી શકે છે. જો આ તમારો કેસ નથી, તો પછી INDEX MATCH ઉદાહરણ પર જાઓ જે તમામ ડેટા પ્રકારો માટે ઉકેલ પૂરો પાડે છે.

જેમ તમે કદાચ જાણો છો, એક્સેલનું SUMPRODUCT ઉલ્લેખિત એરેમાં ઘટકોનો ગુણાકાર કરે છે અને ઉત્પાદનોનો સરવાળો આપે છે. અમે કેસ સેન્સિટિવ લુકઅપ ઇચ્છતા હોવાથી, અમે પ્રથમ એરે મેળવવા માટે EXACT ફંક્શનનો ઉપયોગ કરીએ છીએ:

=SUMPRODUCT((EXACT(A2:A7,F2) * (B2:B7)))

અફસોસની વાત એ છે કે SUMPRODUCT ફંક્શન ટેક્સ્ટ મેચ પરત કરી શકતું નથી કારણ કે ટેક્સ્ટ મૂલ્યોનો ગુણાકાર કરી શકાતો નથી. આ કિસ્સામાં, તમને #VALUE મળશે! નીચેના સ્ક્રીનશોટમાં સેલ F4ની જેમ ભૂલ:

આ ફોર્મ્યુલા કેવી રીતે કામ કરે છે:

VLOOKUP ઉદાહરણની જેમ, ચોક્કસ કાર્ય તપાસોA2:A7 માં તમામ મૂલ્યોની સામે F2 ની કિંમત અને કેસ-સંવેદનશીલ મેચો માટે TRUE પરત કરે છે, અન્યથા FALSE:

SUMPRODUCT(({FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}*{155;186;90;54;159;28}))

મોટા ભાગના સૂત્રોમાં, Excel TRUE થી 1 અને FALSE ને 0 નું મૂલ્યાંકન કરે છે તેથી, જ્યારે SUMPRODUCT એ બે એરેના ઘટકોને સમાન સ્થિતિમાં ગુણાકાર કરે છે, ત્યારે તમામ બિન-મેચ (FALSE) શૂન્ય બની જાય છે:

SUMPRODUCT({0;0;0;54;0;0})

પરિણામે, સૂત્ર આમાંથી સંખ્યા પરત કરે છે કૉલમ B કે જે કૉલમ A.

SUMPRODUCT મર્યાદા માં ચોક્કસ કેસ-સંવેદનશીલ મેચને અનુરૂપ છે: માત્ર આંકડાકીય મૂલ્યો પરત કરી શકે છે.

ઇન્ડેક્સ મેચ - માટે કેસ-સંવેદનશીલ લુકઅપ તમામ ડેટા પ્રકારો

આખરે, અમે એક મર્યાદા-મુક્ત કેસ-સંવેદનશીલ લુકઅપ ફોર્મ્યુલા મેળવવાની નજીક છીએ જે તમામ એક્સેલ વર્ઝન અને તમામ ડેટા સેટ્સ પર કામ કરે છે.

આ ઉદાહરણ માત્ર એટલા માટે જ નથી કે છેલ્લામાં આવે છે. શ્રેષ્ઠ છેલ્લા માટે સાચવવામાં આવે છે, પણ કારણ કે તમે અગાઉના ઉદાહરણોમાં જે જ્ઞાન મેળવ્યું છે તે તમને કેસ-સંવેદનશીલ મેચ ઇન્ડેક્સ ફોર્મ્યુલાને વધુ સારી રીતે સમજવામાં મદદ કરી શકે છે.

ઇન્ડેક્સ અને મેચ ફંક્શન્સનું સંયોજન ઘણીવાર ઉપયોગમાં લેવાય છે ભૂતપૂર્વ માં VLOOKUP માટે વધુ લવચીક અને બહુમુખી વિકલ્પ તરીકે cel. નીચેનો લેખ સારો કામ કરે છે (આશા છે કે :) આ બે કાર્યો એકસાથે કેવી રીતે કાર્ય કરે છે તે સમજાવે છે - VLOOKUP ને બદલે INDEX MATCH નો ઉપયોગ કરવો.

અહીં, હું તમને મુખ્ય મુદ્દાઓ યાદ અપાવીશ:

• MATCH ફંક્શન ઉલ્લેખિત લુકઅપ એરેમાં લુકઅપ વેલ્યુ શોધે છે અને તેની સંબંધિત સ્થિતિ પરત કરે છે.
• સંબંધિતલુકઅપ વેલ્યુની સ્થિતિ સીધી INDEX ફંક્શનની row_num દલીલ પર જાય છે જે તેને તે પંક્તિમાંથી મૂલ્ય પરત કરવાની સૂચના આપે છે.

ટેક્સ્ટ કેસને ઓળખવા માટે ફોર્મ્યુલા માટે, તમારે ફક્ત ક્લાસિક INDEX MATCH સંયોજનમાં વધુ એક કાર્ય ઉમેરવાની જરૂર છે. દેખીતી રીતે, તમારે ફરીથી ચોક્કસ કાર્યની જરૂર છે:

F3 માં વાસ્તવિક સૂત્ર છે:

=INDEX(B2:B7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

F4 માં, અમે આનો ઉપયોગ કરી રહ્યા છીએ:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

કૃપા કરીને યાદ રાખો કે તે ફક્ત આ રીતે કાર્ય કરે છે એક્સેલ 365 સિવાયના તમામ વર્ઝનમાં એરે ફોર્મ્યુલા છે, તેથી Ctrl + Shift + Enter કીને એકસાથે દબાવીને તેને દાખલ કરવાની ખાતરી કરો. જો યોગ્ય રીતે કરવામાં આવે તો, ફોર્મ્યુલા નીચે સ્ક્રીનશોટમાં બતાવ્યા પ્રમાણે સર્પાકાર કૌંસમાં બંધ થઈ જશે:

આ ફોર્મ્યુલા કેવી રીતે કાર્ય કરે છે:

અગાઉના તમામ ઉદાહરણોની જેમ, EXACT એ A2:A7 માં દરેક મૂલ્ય માટે TRUE પરત કરે છે જે F2 ની કિંમત સાથે બરાબર મેળ ખાય છે. અમે મેચના લુકઅપ_વેલ્યુ માટે TRUE નો ઉપયોગ કરતા હોવાથી, તે ચોક્કસ કેસ-સંવેદનશીલ મેચની સંબંધિત સ્થિતિ પરત કરે છે, જે ચોક્કસ રીતે B2:B7 માંથી મેચ પરત કરવા માટે INDEXની જરૂર છે.

એડવાન્સ્ડ કેસ-સેન્સિટિવ લુકઅપ ફોર્મ્યુલા

ઉપરોક્ત ઇન્ડેક્સ મેચ ફોર્મ્યુલા સંપૂર્ણ લાગે છે, બરાબર? પરંતુ હકીકતમાં, એવું નથી. ચાલો હું તમને શા માટે બતાવું.

ધારો કે લુકઅપ વેલ્યુને અનુરૂપ રીટર્ન કોલમમાં કોષ ખાલી છે. ફોર્મ્યુલા શું પરત કરશે? કંઈ નહીં.અને હવે, ચાલો જોઈએ કે તે ખરેખર શું આપે છે:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

અરેરે, ફોર્મ્યુલા શૂન્ય આપે છે! કદાચ, ફક્ત ટેક્સ્ટ મૂલ્યો સાથે કામ કરતી વખતે તે ખરેખર મહત્વનું નથી. જો કે, જો તમારી વર્કશીટમાં સંખ્યાઓ હોય અને તેમાંથી કેટલાક વાસ્તવિક શૂન્ય હોય, તો આ એક સમસ્યા છે.

સત્યમાં, અગાઉ ચર્ચા કરાયેલા અન્ય તમામ લુકઅપ ફોર્મ્યુલા એ જ રીતે વર્તે છે. પરંતુ હવે તમને એક દોષરહિત સૂત્ર જોઈએ છે, શું તમે નથી?

કેસ-સંવેદનશીલ ઇન્ડેક્સ મેચ ફોર્મ્યુલાને એકદમ પરફેક્ટ બનાવવા માટે, તમે તેને IF ફંક્શનમાં લપેટી શકો છો જે તપાસે છે કે રીટર્ન સેલ ખાલી છે કે નહીં અને તેમાં કંઈપણ પરત કરતું નથી આ કેસ:

=IF(INDIRECT("C"&(1+MATCH(TRUE,EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "")

ઉપરોક્ત સૂત્રમાં:

• "C" એ વળતર કૉલમ છે.
• "1" એ સંખ્યા છે જે MATCH ફંક્શન દ્વારા પરત કરવામાં આવેલ સેલની રિલેટિવ પોઝિશન ને વાસ્તવિક સેલ એડ્રેસ માં ફેરવે છે.

ઉદાહરણ તરીકે, અમારા મેચ ફંક્શનમાં લુકઅપ એરે A2:A7 છે, એટલે કે સેલ A2 ની સાપેક્ષ સ્થિતિ "1" છે, કારણ કે આ એરેમાં પ્રથમ કોષ છે. પરંતુ વાસ્તવમાં, લુકઅપ એરે પંક્તિ 2 માં શરૂ થાય છે. તફાવતની ભરપાઈ કરવા માટે, અમે 1 ઉમેરીએ છીએ, તેથી INDIRECT ફંક્શન જમણા કોષમાંથી મૂલ્ય આપશે.

નીચેના સ્ક્રીનશોટ સુધારેલ કેસ-સંવેદનશીલ INDEX દર્શાવે છે MATCH ફોર્મ્યુલા ક્રિયામાં છે.

જો રિટર્ન સેલ ખાલી હોય, તો ફોર્મ્યુલા કંઈપણ આઉટપુટ કરતું નથી (ખાલી સ્ટ્રિંગ):

જો રીટર્ન સેલમાં શૂન્ય હોય , ફોર્મ્યુલા 0 પરત કરે છે:

જો તમે તેના બદલેજ્યારે રિટર્ન સેલ ખાલી હોય ત્યારે અમુક સંદેશ પ્રદર્શિત કરો, IF ની છેલ્લી દલીલમાં ખાલી સ્ટ્રિંગ ("")ને અમુક ટેક્સ્ટ સાથે બદલો:

=IF(INDIRECT("C"&(1+MATCH(TRUE, EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "There is nothing to return, sorry.")

કેસ-સંવેદનશીલ VLOOKUP ને સરળ રીતે કરો

અમારા એક્સેલ માટેના અલ્ટીમેટ સ્યુટના વપરાશકર્તાઓ પાસે એક વિશિષ્ટ સાધન છે જે મોટા અને જટિલ કોષ્ટકોમાં જોવાનું સરળ અને તણાવમુક્ત બનાવે છે. શ્રેષ્ઠ બાબત એ છે કે મર્જ ટુ કોષ્ટકો પાસે કેસ-સંવેદનશીલ વિકલ્પ છે, અને નીચેનું ઉદાહરણ તેને ક્રિયામાં બતાવે છે.

ધારો કે તમે Qty ખેંચવા માંગો છો. અનન્ય આઇટમ IDના આધારે લુકઅપ કોષ્ટકમાંથી મુખ્ય કોષ્ટક પર જાઓ:

તમે શું કરો છો તે મર્જ કોષ્ટકો ચલાવવાનું છે. વિઝાર્ડ કરો અને આ પગલાંઓ કરો:

1. નવો ડેટા ખેંચવા માટે મુખ્ય કોષ્ટક પસંદ કરો.
2. નવો ડેટા ક્યાં જોવો તે લુકઅપ કોષ્ટક પસંદ કરો.
3. એક અથવા વધુ કી કૉલમ પસંદ કરો (અમારા કિસ્સામાં આઇટમ ID). અને કેસ-સેન્સિટિવ મેચિંગ બોક્સને ચેક કરવાનું સુનિશ્ચિત કરો.

એક ક્ષણ પછી, તમને ઇચ્છિત પરિણામ મળશે :)

ટેક્સ્ટ કેસને ધ્યાનમાં રાખીને એક્સેલમાં કેવી રીતે લુકઅપ કરવું તે છે. હું વાંચવા બદલ તમારો આભાર માનું છું અને આગામી અઠવાડિયે તમને અમારા બ્લોગ પર મળવાની આશા રાખું છું!

ડાઉનલોડ માટે પ્રેક્ટિસ વર્કબુક

કેસ-સેન્સિટિવ VLOOKUP ઉદાહરણો (.xlsx ફાઇલ)