Krijst in protte #N/A-flaters yn jo wurkblêden en binne jo nijsgjirrich om te witten oft d'r in manier is om ynstee in oanpaste tekst wer te jaan? IFNA-formule is de oplossing dy't jo nedich binne.

As in Excel-formule wat net kin identifisearje of fine, smyt it de #N/A-flater. Om sa'n flater te fangen en te ferfangen troch in brûkerfreonlik berjocht, kinne jo de IFNA-funksje brûke. Mei oare wurden, #N/A is de manier fan Excel om te sizzen dat de wearde dy't jo sykje net oanwêzich is yn 'e referearre dataset. IFNA is jo manier om dy flater op te fangen en te behanneljen.

IFNA-funksje yn Excel

De Excel IFNA-funksje is bedoeld foar it fangen en behanneljen fan #N/A-flaters. As in formule evaluearret nei #N/A, trapet IFNA dy flater en ferfangt it mei in oanpaste wearde dy't jo oantsjutte; jout oars in normaal resultaat fan de formule werom.

IFNA-syntaksis

De syntaksis fan de IFNA-funksje is as folget:

Wêr:

Wearde (fereaske) - de formule, wearde of ferwizing om te kontrolearjen op in #N/A-flater.

Wearde_if_na (ferplicht) - de wearde om werom te kommen as in #N/A flater ûntdutsen wurdt.

Gebrûksnotysjes

• De IFNA-funksje behannelet allinich #N/A sûnder oare flaters te ûnderdrukken.
• As it argumint wearde in arrayformule is, jout IFNA in array fan resultaten werom, ien per sel, lykas werjûn yn dit foarbyld.

IFNA-beskikberens

De IFNA-funksje waard yntrodusearre ynExcel 2013 en is beskikber yn alle folgjende ferzjes ynklusyf Excel 2016, Excel 2019, Excel 2021, en Microsoft 365.

Yn eardere ferzjes kinne jo #N/A flaters fange troch de IF- en ISNA-funksjes tegearre te brûken.

Hoe kinne jo IFNA-funksje brûke yn Excel

Om IFNA effektyf te brûken yn Excel, folgje dizze generyske oanpak:

1. Yn it earste argumint ( wearde ), set in formule beynfloede troch de #N/A flater.
2. Yn it twadde argumint ( value_if_na ), typ de tekst dy't jo weromjaan wolle ynstee fan de standert flaternotaasje. Om in lege sel werom te jaan as neat fûn wurdt, leverje dan in lege tekenrige (""") oan.

Om oanpaste tekst werom te jaan, is de generike formule:

Om in blanke sel werom te jaan, is de generyske formule:

Litte wy sjen hoe't it wurket op in ienfâldich foarbyld. Stel yn 'e tabel hjirûnder dat jo wolle witte hoe't in skoare fan in opjûne studint ûnder oaren rangearret. Sûnt de gegevens wurde sorteare troch de kolom Score fan heechste nei leechste, sil de rang oerienkomme mei de relative posysje fan 'e studint yn' e tabel. En om de posysje te krijen, kinne jo de MATCH-funksje yn syn ienfâldichste foarm brûke:

=MATCH(E1, A2:A10, 0)

Om't de opsykwearde (Neal) net beskikber is yn 'e opsykarray (A2:A10), der komt in #N/A-flater op.

By dizze flater tsjinkomme, kinne sûnder ûnderfining brûkers tinke dat der wat mis is mei deformule, en jo as wurkboekmakker krije in protte fragen. Om dit foar te kommen, kinne jo eksplisyt oanjaan dat de formule korrekt is, it kin gewoan de wearde net fine wêr't jo nei sykje. Dat, jo nêst de MATCH-formule yn it earste argumint fan IFNA en typ yn it twadde argumint jo oanpaste tekst, "Net fûn" yn ús gefal:

=IFNA(MATCH(E1, A2:A10, 0), "Not found")

No, ynstee fan de standert flaternotaasje, jo eigen tekst wurdt werjûn yn in sel, dy't brûkers ynformearje dat de opsykwearde net oanwêzich is yn 'e dataset:

Hoe kinne jo IFNA brûke mei VLOOKUP

Meastentiids komt de #N/A-flater foar yn funksjes dy't sykje nei wat lykas VLOOKUP, HLOOKUP, LOOKUP, en MATCH. De ûndersteande foarbylden dekke in pear typyske gebrûksgefallen.

Foarbyld 1. Basis IFNA VLOOKUP formule

Om #N/A flaters te fangen dy't foarkomme as VLOOKUP gjin wedstriid kin fine, kontrolearje it resultaat mei help fan IFNA en spesifisearje de wearde te werjaan ynstee fan de flater. De gewoane praktyk is om de IFNA-funksje om jo besteande VLOOKUP-formule te wikkeljen mei dizze syntaksis:

Stel yn ús foarbyldtabel dat jo wolle ophelje in skoare fan in bepaalde studint (E1). Hjirfoar brûke jo dizze klassike VLOOKUP-formule:

=VLOOKUP(E1, A2:B10, 2, FALSE)

It probleem is dat Neal it eksamen net naam, dêrom stiet syn namme net yn 'e list, en fansels slagget VLOOKUP net te finen in wedstriid.

Om de flater te ferbergjen, hawwe wyWrap VLOOKUP yn IFNA sa:

=IFNA(VLOOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

No liket it resultaat net sa yntimidearjend foar de brûker en is it folle ynformatyfr:

Foarbyld 2. IFNA VLOOKUP om oer meardere blêden op te sykjen

De IFNA-funksje is ek handich foar it útfieren fan de saneamde sekwinsjele of keatling opsykjen oer meardere blêden of ferskate wurkboeken. It idee is dat jo op dizze manier in pear ferskillende IFNA(VLOOKUP(...))-formules yn elkoar nestelje:

As in primêre VLOOKUP neat fynt, rint de IFNA-funksje de folgjende VLOOKUP oant de winske wearde fûn is. As alle opsykjen mislearje, sil de formule de opjûne tekst werombringe.

Stel dat jo de skoares fan ferskate klassen yn ferskate blêden hawwe (neamd Klasse A , Klasse B , en Klasse C ). Jo doel is om de skoare te krijen fan in bepaalde studint, waans namme wurdt ynfierd yn sel B1 yn jo hjoeddeistige wurkblêd. Om de taak te ferfoljen, brûk dizze formule:

=IFNA(VLOOKUP(B1, 'Class A'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class B'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class C'!A2:B5, 2, FALSE), "Not found")))

De formule siket opfolgjend op foar de opjûne namme yn trije ferskillende blêden yn 'e folchoarder fan VLOOKUP's wurde nested en bringt de earste fûn oerienkomst:

Foarbyld 3. IFNA mei INDEX MATCH

Op in fergelykbere wize kin IFNA #N/A flaters fange dy't generearre binne troch oare opsykfunksjes. Litte wy it as foarbyld brûke tegearre mei de INDEX MATCHformule:

=IFNA(INDEX(B2:B10, MATCH(E1, A2:A10, 0)), "Not found")

De essinsje fan 'e formule is itselde as yn alle eardere foarbylden - INDEX MATCH docht in opsykjen, en IFNA evaluearret it resultaat en fangt in #N/A-flater as de ferwiisde wearde is net fûn.

IFNA om meardere resultaten werom te jaan

Yn gefal de ynderlike funksje (d.w.s. de formule pleatst yn de wearde argumint) jout meardere wearden werom, IFNA sil elke weromjûne wearde yndividueel testen en in array fan resultaten útfiere. Bygelyks:

=IFNA(VLOOKUP(D2:D4, A2:B10, 2, FALSE), "Not found")

Yn Dynamic Array Excel (Microsoft 365 en Excel 2021), spilet in reguliere formule yn 'e boppeste sel (E2) automatysk alle resultaten yn 'e oanbuorjende sellen (yn termen fan Excel, wurdt it in spillbereik neamd).

Yn pre-dynamyske ferzjes (Excel 2019 en leger), kin in ferlykber effekt berikt wurde troch it brûken fan in multy-sel-array formule, dy't foltôge wurdt mei de fluchtoets Ctrl + Shift + Enter.

Wat is it ferskil tusken IFNA en IFERROR?

Ofhinklik fan de oarsaak fan de probleem, in Excel-formule kin ferskate flaters triggerje lykas #N/A, #NAME, #VALUE, #REF, #DIV/0, #NUM, en oaren. De IFERROR-funksje fangt al dy flaters, wylst IFNA beheind is ta allinich #N/A. Hokker is better om te kiezen? Dat hinget fan de situaasje ôf.

As jo ​​ elk soarte fan flater ûnderdrukke wolle, brûk dan de IFERROR-funksje. It is benammen nuttich yn komplekse berekkeningen as in formulebefettet ferskate funksjes dy't ferskate flaters generearje kinne.

Mei opsykfunksjes kinne jo better IFNA brûke, om't it allinich in oanpast resultaat toant as in opsykwearde net fûn is en de ûnderlizzende net ferberget problemen mei de formule sels.

Om it ferskil te yllustrearjen, litte wy ús basis IFNA VLOOKUP-formule werombringe en "tafallich" de namme fan de funksje ferkeard stavere (VLOKUP ynstee fan VLOOKUP).

=IFNA(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

IFNA ûnderdrukt dizze flater net, dus jo kinne dúdlik sjen dat der wat mis is mei ien fan 'e funksjenammen:

No, litte wy sjen wat der bart as jo brûke IFERROR:

=IFERROR(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

Hmm ... it seit dat Olivia it eksamen net naam, wat net wier is! Dit komt om't de IFERROR-funksje de #NAME? flater en jout ynstee de oanpaste tekst werom. Yn dizze situaasje jout it net allinich ferkearde ynformaasje, mar ferberget ek it probleem mei de formule.

Dat is hoe't jo IFNA-formule brûke yn Excel. Ik tankje jo foar it lêzen en sjoch út nei jo te sjen op ús blog nije wike!

Beskikbere downloads

Excel IFNA-formulefoarbylden (.xlsx-bestân)