Rapida maniero transformi gamon da ĉeloj en ununuran vicon helpe de la TOROW funkcio.

Microsoft Excel 365 enkondukis plurajn novajn funkciojn. fari diversajn manipuladojn per tabeloj. Kun TOROW, vi povas fari gamon-al-vicajn transformojn en neniu tempo. Jen listo de taskoj kiujn ĉi tiu nova funkcio povas plenumi:

Excel TOROW-funkcio

La TOROW-funkcio en Excel estas uzata por konverti tabelon aŭ gamon da ĉeloj en unu vico.

La funkcio prenas entute tri argumentojn, el kiuj nur la unua estas bezonata.

TOROW(tabelo, [ignori], [skani_per_kolumno])

Kie:

Tabelo (postula) - tabelo aŭ intervalo por transformi en ununuran vicon.

Ignori (laŭvola) - determinas ĉu ignori malplenojn aŭ/kaj eraroj. Povas preni unu el ĉi tiuj valoroj:

• 0 aŭ ellasita (defaŭlte) - konservi ĉiujn valorojn
• 1 - ignori malplenajn
• 2 - ignori erarojn
• 3 - ignori malplenajn kaj erarojn

Skani_per_kolumno (laŭvola) - difinas kiel skani la tabelon:

• FALSA aŭ ellasita (defaŭlte) - skani la tabelon horizontale laŭ vico.
• VERA - skani la tabelon vertikale laŭ kolumno.

Konsiloj:

• Por transformi tabelon. en unu kolumnon, uzu la funkcion TOCOL.
• Por antaŭformi la inversan vicon-al-tabelan transformon, uzu aŭ la funkcion WRAPCOLS por envolvi en kolumnojn aŭ la funkcion WRAPROWS por envolvi.tabelo en vicojn.
• Por igi vicojn en kolumnojn, uzu la funkcion TRANSPOSE.

TOROW havebleco

TOROW estas nova funkcio, kiu estas subtenata nur en Excel. por Microsoft 365 (por Vindozo kaj Mac) kaj Excel por la reto.

Baza TOROW-formulo en Excel

Por fari simplan gamon al vica transformo, uzu la TOROW-formulon en sia baza formo. Por tio, vi devas difini nur la unuan argumenton ( tabelo ).

Ekzemple, por turni dudimensian tabelon konsistantan el 3 kolumnoj kaj 3 vicoj en ununuran vicon, la formulo estas:

=TOROW(A3:C6)

Vi enigas la formulon en nur unu ĉelon (A10 en nia kazo), kaj ĝi aŭtomate verŝas en tiom da ĉeloj kiom necesas por teni ĉiujn rezultojn. En Excel-esprimoj, la eliga intervalo ĉirkaŭita de maldika blua bordo nomiĝas verŝintervalo.

Kiel ĉi tiu formulo funkcias:

Unue, provizita gamo da ĉeloj estas transformita en dudimensian tabelon. Bonvolu rimarki la komo-limigitajn kolumnojn kaj punktokomo-disigitajn vicojn:

{"Apple","Banana","Cherry";1,2,3;4,5,6;7,8,9}

Tiam, la TOROW-funkcio legas la tabelon de maldekstre dekstren kaj konvertas ĝin en unudimensian horizontalan tabelon:

{"Apple","Banana","Cherry",1,2,3,4,5,6,7,8,9}

La rezulto iras al ĉelo A10, el kiu ĝi verŝas en la najbaran ĉelon dekstren.

Transformu gamon al vico ignorante malplenajn kaj erarojn

Defaŭlte, la funkcio TOROW konservas ĉiujn valorojn de la fonta tabelo, inkluzive de malplenaj ĉeloj kajeraroj. En la eligo, nul valoroj aperas anstataŭ malplenaj ĉeloj, kio povas esti sufiĉe konfuza.

Por ekskludi malplenajn , agordu la argumenton ignori al 1:

=TOROW(A3:C5, 1)

Por ignori erarojn , starigu la argumenton ignori al 2:

=TOROW(A3:C5, 2)

Por salti ambaŭ, blankoj kaj eraroj , uzu 3 por la argumento ignori :

=TOROW(A3:C5, 3)

La suba bildo montras ĉiujn tri scenarojn en ago:

Legi tabelon horizontale aŭ vertikale

Kun la defaŭlta konduto, la TOROW-funkcio prilaboras la tabelon horizontale de maldekstre dekstren. Por skani la valorojn laŭ kolumno de supre ĝis malsupre, vi agordas la 3-an argumenton ( scan_by_column ) al VERA aŭ 1.

Ekzemple, por legi la fontan gamon laŭ vico, la formulo en E3 estas:

=TOROW(A3:C5)

Por skani la gamon laŭ kolumno, la formulo en E8 estas:

=TOROW(A3:C5, ,TRUE)

En ambaŭ kazoj, la rezultaj tabeloj estas la sama grandeco, sed la valoroj estas aranĝitaj en malsama ordo.

Kunfandi plurajn gamojn en unu vicon

Por kombini plurajn nenajbarajn intervalojn en ununuran vicon, vi unue staku ilin horizontale aŭ vertikale en ununuran tabelon helpe de HSTACK aŭ VSTACK, respektive. , kaj poste uzu la funkcion TOROW por konverti la kombinitan tabelon en vicon.

Laŭ via komerca logiko, unu el la sekvaj formuloj plenumos la taskon.

Staku tabelojn horizontale kaj konverti per vico

Kun la unuagamo en A3:C4 kaj la dua gamo en A8:C9, la suba formulo stakos la du gamojn horizontale en ununuran tabelon, kaj poste transformos ĝin al vico leganta la valorojn de maldekstre dekstren. La rezulto estas en E3 en la suba bildo.

=TOROW(HSTACK(A3:C4, A8:C9))

Staki tabelojn horizontale kaj konverti laŭ kolumno

Por legi la staplitan tabelon vertikale de supre malsupre, vi agordas la 3-an argumenton de TOROW al VERA kiel montrite en E5 en la suba bildo:

=TOROW(HSTACK(A3:C4, A8:C9), ,TRUE)

Staku tabelojn vertikale kaj konvertu laŭ vico

Por almeti ĉiun postan tabelon al la fundo de la antaŭa tabelo kaj legu la kombinitan tabelon horizontale, la formulo en E12 estas:

=TOROW(VSTACK(A3:C4, A8:C9))

Staku tabelojn vertikale kaj konverti per kolumno

Por aldoni ĉiun postan tabelon al la fundo de la antaŭa kaj skani la kombinitan tabelon vertikale, la formulo estas:

=TOROW(VSTACK(A3:C4, A8:C9), ,TRUE)

Por pli bone kompreni la logikon, observu la malsaman ordon de valoroj en la rezultaj tabeloj:

Eltiru unikajn valorojn de gamo en vicon

Komencante kun Microsoft Excel 2016, ni havas mirindan funkcion, nomitan UNIKA, kiu povas facile akiri unikajn valorojn de ununura kolumno. aŭ vico. Tamen, ĝi ne povas trakti plurkolumnajn tabelojn. Por venki ĉi tiun limigon, uzu la UNIKAjn kaj TOROW-funkciojn kune.

Ekzemple, por ĉerpi ĉiujn malsamajn (distingajn) valorojn el la intervalo A2:C7 kaj meti la rezultojn en unu vicon, laformulo estas:

=UNIQUE(TOROW(A2:C7), TRUE)

Ĉar TOROW liveras unudimensian horizontalan tabelon, ni starigas la duan ( per_col ) argumenton de UNIKA al VERA por kompari la kolumnojn kontraŭ ĉiu. alia.

Se vi volas la rezultojn aranĝitajn en alfabeta ordo, envolvu la supran formulon en la funkcio SORT:

=SORT(UNIQUE(TOROW(A2:C7), TRUE), , ,TRUE )

Kiel ĉe UNIQUE, la by_col argumento de SORT ankaŭ estas agordita al VERA.

TOROW-alternativo por Excel 365 - 2010

En Excel-versioj kie la TOROW-funkcio ne disponeblas, vi povas transformi gamon en ununuran vicon uzante kombinaĵon de kelkaj malsamaj funkcioj kiuj funkcias en pli malnovaj versioj. Ĉi tiuj solvoj estas pli kompleksaj, sed ili funkcias.

Por skani la intervalon horizontale, la ĝenerala formulo estas:

INDEX( gamo , KVOCIENTO(KOLONON (A1)-1, COLUMNS( gamo ))+1, MOD(KOLONO(A1)-1, COLUMS( gamo ))+1)

Por skani la intervalon vertikale, la ĝenerala formulo estas :

INDEX( gamo , MOD(KOLONNO(A1)-1, KOLUMNOJ( gamo ))+1, KVOCIENTO(KOLONNO (A1)-1, KOLUMNOJ( gamo ))+1)

Por nia ekzempla datumaro en A3:C5, la formuloj prenas ĉi tiun formon:

Por skani la intervalon laŭ vico:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Ĉi tiu formulo estas alternativo al la TOROW-funkcio kun la 3-a argumento agordita al FALSO aŭ ellasita:

=TOROW(A3:C5)

Skani la intervalon per kolumno:

=INDEX($A$3:$C$5, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

Ĉi tiu formulo estas ekvivalenta al la funkcio TOROW kun la 3-a argumento agordita alVERA:

=TOROW(A3:C5, ,TRUE)

Bonvolu noti, ke male al la dinamika tabel-funkcio TOROW, ĉi tiuj tradiciaj formuloj devas esti enigitaj en ĉiu ĉelo, kie vi volas, ke la rezultoj aperu. En nia kazo, la unua formulo (laŭ vico) iras al E3 kaj estas kopiita tra M3. La dua formulo (laŭ kolumno) alteriĝas en E8 kaj estas trenita tra M8.

Por ke la formuloj kopiu ĝuste, ni ŝlosas la intervalon uzante absolutajn referencojn ($A$3:$C$5). Nomita intervalo ankaŭ taŭgas.

Se vi kopiis la formulojn al pli da ĉeloj ol bezonate, #REF! eraro aperos en "ekstraj" ĉeloj. Por ripari tion, envolvu vian formulon en la funkcio IFERROR tiel:

=IFERROR(INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1), "")

Kiel funkcias ĉi tiuj formuloj

Malsupre estas detala malkonstruo. de la unua formulo, kiu aranĝas la valorojn laŭ vico:

=INDEX($A$3:$C$5, QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1, MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1)

En la kerno de la formulo, ni uzas la INDEX-funkcion por akiri la valoron de ĉelo bazita sur ĝia relativa pozicio en la intervalo.

La vicnumero estas kalkulita per ĉi tiu formulo:

QUOTIENT(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

La ideo estas produkti ripetantan sinsekvon kiel 1,1 ,1,2,2,2,3,3,3, … kie ĉiu nombro ripetas tiom da fojoj kiom estas kolumnoj en la fonta gamo. Kaj jen kiel ni faras ĉi tion:

QUOCIENT liveras la entjeran parton de divido.

Por numeralo , ni uzas KOLONON(A1)-1, kiu liveras serian. nombro de 0 en la unua ĉelo kie la formulo estas enigita al n (tuta nombro da valoroj en la intervalominus 1) en la lasta ĉelo kie la formulo eniris. En ĉi tiu ekzemplo, ni havas 0 en E2 kaj 8 en M3.

Por denominatoro , ni uzas KOLONONS($A$3:$C$5)). Ĉi tio liveras konstantan nombron egalan al la nombro da kolumnoj en via intervalo (3 en nia kazo).

Kiel rezulto, la funkcio QUOCIENT liveras 0 en la unuaj 3 ĉeloj (E3:G3), al kiuj ni ni aldonu 1, do la vicnumero estas 1.

Por la sekvaj 3 ĉeloj (H3:J3), KVOCIENTO liveras 1, kaj +1 donas la vicnumero 2. Kaj tiel plu.

Por kalkuli la kolumnan nombron , vi konstruas taŭgan nombrosekvencon uzante la MOD-funkcion:

MOD(COLUMN(A1)-1, COLUMNS($A$3:$C$5))+1

Ĉar estas 3 kolumnoj en nia gamo, la vico devas aspekti kiel : 1,2,3,1,2,3,...

La MOD-funkcio resendas la reston post divido.

En E3, MOD(KOLONON(A1)-1, KOLUMNOS($) A$3:$C$5))+

iĝas

MOD(1-1, 3)+1)

kaj redonas 1.

En F3, MOD(KOLUNO(B1)-1, KOLUMNOS($A$3:$C$5))+

iĝas

MOD(2-1, 3)+1)

kaj redonas 2.

Post kiam la vico kaj kolumnombroj estas establitaj, INDEX facile prenas la valoron ĉe la intersekco de tiu vico kaj kolumno.

En E3, INDEX($A$3) :$C$5, 1, 1) liveras valoron de la 1-a vico kaj la 1-a kolumno de la referenca intervalo, t.e. de ĉelo A3.

En F3, INDEX($A$3:$C$5, 1, 2) liveras valoron el la 1-a vico kaj la 2-a kolumno, t.e. el la ĉelo B3.

Kaj tiel plu.

La dua formulo, kiu skanas la gamon laŭ kolumno, funkcias ensimila maniero. La diferenco estas, ke ni uzas MOD por kalkuli la vican nombron kaj KVOCIENTO por eltrovi la kolumnumeron.

TOROW-funkcio ne funkcias

Se la TOROW-funkcio rezultigas eraron, ĝi estas plej verŝajne estos unu el ĉi tiuj kialoj:

#NAME? eraro

Kun la plej multaj Excel-funkcioj, ĉu #NOMO? eraro estas klara indiko, ke la nomo de la funkcio estas misliterumita. Kun TOROW, ĝi ankaŭ povas signifi, ke la funkcio ne disponeblas en via Excel. Se via Excel-versio estas alia ol 365, provu uzi TOROW-alternativon.

#NUM-eraro

#NUM-eraro indikas, ke la redonita tabelo ne povas konveni en vicon. Plej ofte tio okazas kiam vi referencas tutajn kolumnojn kaj/aŭ vicojn anstataŭ pli malgrandan gamon.

#SPILL error

En la plej multaj kazoj, #SPILL-eraro sugestas, ke la vico kie vi enigis la formulon ne havas sufiĉe da malplenaj ĉeloj por verŝi la rezultojn en. Se la najbaraj ĉeloj estas videble malplenaj, certigu, ke ne estas spacoj aŭ aliaj ne-presantaj signoj en ili. Por pliaj informoj, vidu Kion signifas #SPILL-eraro en Excel.

Tiel vi uzas la funkcion TOROW en Excel por konverti 2-dimensian tabelon aŭ gamon en ununuran vicon. Mi dankas vin pro legado kaj esperas vidi vin en nia blogo venontsemajne!

Praktiku laborlibron por elŝuto

Excel TOROW-funkcio - formulekzemploj (.xlsx-dosiero)