Təlimat sizə Excel-də "Əgər uyğunluq" düsturunu qurmağı öyrədəcək, beləliklə o, məntiqi dəyərləri, fərdi mətni və ya başqa xanadan dəyəri qaytarır.

Baxmaq üçün Excel düsturu. iki xana uyğunlaşsa, A1=B1 qədər sadə ola bilər. Bununla belə, bu açıq-aşkar həllin işləmədiyi və ya gözlədiyinizdən fərqli nəticələr verməyəcəyi fərqli hallar ola bilər. Bu dərslikdə biz Excel-də xanaları müqayisə etməyin müxtəlif yollarını müzakirə edəcəyik ki, siz öz tapşırığınız üçün optimal həll yolu tapa biləsiniz.

Excel-də iki xananın uyğun olub-olmadığını necə yoxlamaq olar

Excel If match formulunun bir çox variantı mövcuddur. Sadəcə aşağıdakı nümunələri nəzərdən keçirin və ssenariniz üçün ən uyğun olanı seçin.

İki xana bərabərdirsə, DOĞRU qaytarın

Ən sadə " Bir xana digərinə bərabərdirsə, onda doğrudur" Excel düsturu belədir:

xana A= xana B

Məsələn, hər sətirdə A və B sütunlarındakı xanaları müqayisə etmək üçün bu düsturu daxil edin C2 yazın və sonra onu sütunun aşağısına köçürün:

=A2=B2

Nəticədə iki xana eyni olarsa DOĞRU, əks halda YANLIŞ alacaqsınız:

Qeydlər:

• Bu düstur iki Boolean dəyəri qaytarır: əgər iki xana bərabərdirsə - TRUE; bərabər deyilsə - YANLIŞ. Yalnız DOĞRU dəyərləri qaytarmaq üçün növbəti misalda göstərildiyi kimi IF ifadəsində istifadə edin.
• Bu düstur hərflərə həssas deyil , ona görə də böyük və kiçik hərfləri eyni simvol kimi qəbul edir. Əgər mətnböyük hərfi nəzərə alan bu düsturdan istifadə edin.

İki xana uyğun gəlirsə, dəyəri qaytarın

İki xana uyğun gələrsə, öz dəyərinizi qaytarmaq üçün bu nümunədən istifadə edərək IF ifadəsi qurun. :

IF( xana A = xana B , dəyər_əgər_əgər, dəyər_əgər_yanlış)

Məsələn, A2 və B2-ni müqayisə etmək və eyni dəyərləri ehtiva edərsə, "bəli" qaytarmaq , "yox" əks halda, formula belədir:

=IF(A2=B2, "yes", "no")

Əgər siz yalnız xanalar bərabər olduqda dəyəri qaytarmaq istəyirsinizsə, value_if_false üçün boş sətir ("") təmin edin .

Uyğundursa, bəli :

=IF(A2=B2, "yes", "")

Uyğundursa, DOĞRU:

=IF(A2=B2, TRUE, "")

Qeyd. Məntiqi dəyəri TRUE qaytarmaq üçün onu qoşa dırnaq içərisində qoymayın. Qoşa dırnaq işarələrindən istifadə məntiqi dəyəri adi mətn sətirinə çevirəcək.

Əgər bir xana digərinə bərabərdirsə, başqa xananı qaytarın

Və burada bu xüsusi tapşırığı həll edən Excel if match düsturunun variasiyası var: iki xanadakı dəyərləri müqayisə edin və əgər data uyğun gəlir, sonra başqa xanadan dəyəri kopyalayın.

Excel dilində o, belə tərtib olunub:

IF( xana A = xana B , C xanası , "")

Məsələn, A və B sütunlarındakı elementləri yoxlamaq və mətn uyğun gələrsə, C sütunundan dəyər qaytarmaq üçün D2-dəki düstur aşağıya köçürülür:

=IF(A2=B2, C2, "")

İki xananın uyğun olub-olmadığını yoxlamaq üçün hərf-həssas düstur

Həssas mətn dəyərləri ilə məşğul olduğunuz vəziyyətdə DƏMƏN istifadə edinhərf registi də daxil olmaqla xanaları tam olaraq müqayisə etmək funksiyası:

ƏGƏR(EXACT( xana A , xana B ), dəyər_əgər_əgər, dəyər_əgər_yanlış)

Məsələn, müqayisə etmək A2 və B2-dəki elementləri seçin və mətn tam uyğun gəlirsə "bəli" qaytarın, hər hansı bir fərq aşkar edilərsə, "yox" qaytarın, bu düsturdan istifadə edə bilərsiniz:

=IF(EXACT(A2, B2), "Yes", "No")

Birdən çox xananın olub olmadığını necə yoxlamaq olar bərabərdir

İki xananın müqayisəsində olduğu kimi, uyğunluqlar üçün birdən çox xananın yoxlanılması da bir neçə fərqli yolla həyata keçirilə bilər.

Və bir neçə xananın uyğun olub-olmadığını yoxlamaq üçün düstur

bir neçə dəyərin uyğun olub olmadığını yoxlayın, iki və ya daha çox məntiqi testlə AND funksiyasından istifadə edə bilərsiniz:

AND( xana A = xana B , xana A = C xanası, …)

Məsələn, A2, B2 və C2 xanalarının bərabər olub olmadığını görmək üçün düstur belədir:

=AND(A2=B2, A2=C2)

Dinamik massivdə Excel (365 və 2021) aşağıdakı sintaksisdən də istifadə edə bilərsiniz. Excel 2019 və daha aşağı versiyalarda bu, yalnız Ctrl + Shift + Enter düymələrini birlikdə basmaqla tamamlanan ənənəvi CSE massiv düsturu kimi işləyəcək.

=AND(A2=B2:C2)

Hər iki AND düsturunun nəticəsi məntiqi dəyərlər DOĞRU və YANLIŞ.

Öz dəyərlərinizi qaytarmaq üçün AND-ı IF funksiyasına bu şəkildə sarın:

=IF(AND(A2=B2:C2), "yes", "")

Hər üç xana varsa, bu düstur "bəli" qaytarır. bərabərdir, əks halda boş xana.

Birdən çox sütunun uyğun olub-olmadığını yoxlamaq üçün COUNTIF düsturu

Birdən çox uyğunluğu yoxlamağın başqa yolu bu formada COUNTIF funksiyasından istifadə etməkdir:

COUNTIF( aralıq , xana )= n

Burada aralıq bir-biri ilə müqayisə ediləcək xanalar diapazonudur, xana diapazondakı hər hansı tək xanadır və n diapazondakı xanaların sayıdır.

Nümunə məlumat dəstimiz üçün düstur bu formada yazıla bilər. :

=COUNTIF(A2:C2, A2)=3

Əgər siz çoxlu sütunları müqayisə edirsinizsə, SÜTUNLAR funksiyası sizin üçün avtomatik olaraq xanaların sayını (n) əldə edə bilər:

=COUNTIF(A2:C2, A2)=COLUMNS(A2:C2)

Və ƏGƏR funksiyası istədiyiniz hər şeyi nəticə olaraq qaytarmağınıza kömək edəcək:

=IF(COUNTIF(A2:C2, A2)=3, "All match", "")

Birdən çox uyğunluq üçün hərf-həssas düstur

İki xananı yoxlamaqda olduğu kimi, biz də hərf halı da daxil olmaqla, dəqiq müqayisəni yerinə yetirmək üçün EXACT funksiyasından istifadə edin. Çoxsaylı xanaları idarə etmək üçün EXACT aşağıdakı kimi VƏ funksiyasına daxil edilməlidir:

VƏ(EXACT( aralıq , xana ))

Excel 365 və Excel 2021-də , dinamik massivləri dəstəklədiyinə görə bu, normal düstur kimi işləyir. Excel 2019 və daha aşağı versiyalarda, onu massiv düsturu etmək üçün Ctrl + Shift + Enter düymələrini basmağı unutmayın.

Məsələn, A2:C2 xanalarının eyni dəyərləri ehtiva etdiyini yoxlamaq üçün bir halda -həssas düstur:

=AND(EXACT(A2:C2, A2))

IF ilə birlikdə bu formanı alır:

=IF(AND(EXACT(A2:C2, A2)), "Yes", "No")

Xananın diapazondakı hər hansı xanaya uyğun olub olmadığını yoxlayın

Xüceyrənin verilmiş diapazondakı hər hansı xana ilə uyğun olub-olmadığını görmək üçün aşağıdakı düsturlardan birini istifadə edin:

VEYA funksiyası

İstifadə etmək daha yaxşıdır 2 - 3 xananı yoxlamaq üçün.

OR( hüceyrə A = hüceyrə B , hüceyrə A = hüceyrə C , hüceyrə A = D xanası , …)

Excel 365 və Excel 2021 bu sintaksisi də başa düşür:

OR( cell = aralıq )

Excel 2019-da və aşağı, bu Ctrl + Shift + Enter qısayoluna basaraq massiv düsturu kimi daxil edilməlidir.

COUNTIF funksiyası

COUNTIF( aralıq , xana )>0

Məsələn, A2-nin B2:D2-dəki hər hansı xanaya bərabər olub olmadığını yoxlamaq üçün bu düsturlardan hər hansı biri yerinə yetirəcək:

=OR(A2=B2, A2=C2, A2=D2)

=OR(A2=B2:D2)

=COUNTIF(B2:D2, A2)>0

Excel 2019 və ya daha aşağı versiyanı istifadə edirsinizsə, düzgün nəticələri təqdim etmək üçün ikinci OR düsturunu əldə etmək üçün Ctrl + Shift + Enter düymələrini sıxmağı unutmayın.

Bəli/Xeyr və ya istədiyiniz hər hansı digər dəyərləri qaytarmaq üçün siz nə edəcəyinizi bilirsiniz - yuxarıdakı düsturlardan birini IF funksiyasının məntiqi testində yerləşdirin. Məsələn:

=IF(COUNTIF(B2:D2, A2)>0, "Yes", "No")

Ətraflı məlumat üçün lütfən, diapazonda dəyərin olub-olmadığını yoxlayın.

İki diapazonun bərabər olub olmadığını yoxlayın

Müqayisə etmək üçün iki diapazonu xanadan-xanaya yazın və müvafiq mövqelərdəki bütün xanalar uyğun gəlirsə, məntiqi dəyəri TRUE qaytarın, AND funksiyasının məntiqi testinə bərabər ölçülü diapazonları təqdim edin:

VƏ( aralıq A = aralıq B )

Məsələn, B3:F6-da A Matrisini və B11:F14-də B Matrisini müqayisə etmək üçün düstur belədir:

=AND(B3:F6= B11:F14)

To nəticə olaraq Bəli / Xeyr alın, aşağıdakı ƏGƏR VƏ kombinasiyasından istifadə edin:

=IF(AND(B3:F6=B11:F14), "Yes", "No")

Əgər uyğunluq düsturunu belə istifadə etmək olarExcel-də. Oxuduğunuz üçün sizə təşəkkür edirəm və sizi gələn həftə bloqumuzda görməyə ümid edirəm!

İş dəftərini məşq edin

Excel-də hüceyrələr uyğun gəlirsə - formula nümunələri (.xlsx faylı)