Tabela e përmbajtjes
Nëse jeni duke kërkuar për një funksion Excel për të marrë ditën e javës nga data, keni zbritur në faqen e duhur. Ky udhëzues do t'ju mësojë se si të përdorni formulën WEEKDAY në Excel për të kthyer një datë në një emër të ditës së javës, për të filtruar, theksuar dhe numëruar fundjavat ose ditët e punës dhe më shumë.
Ka një sërë funksionesh për punoni me datat në Excel. Funksioni i ditës së javës (WEEKDAY) është veçanërisht i dobishëm për planifikimin dhe planifikimin, për shembull për të përcaktuar kornizën kohore të një projekti dhe për të hequr automatikisht fundjavat nga totali. Pra, le t'i kalojmë shembujt një nga një dhe të shohim se si ata mund t'ju ndihmojnë të përballeni me detyra të ndryshme të lidhura me datat në Excel.
DITA E JAVE - Funksioni Excel për ditën e javë
Funksioni Excel WEEKDAY përdoret për të kthyer ditën e javës nga një datë e caktuar.
Rezultati është një numër i plotë, që varion nga 1 (e diel) në 7 (e shtunë) si parazgjedhje . Nëse logjika e biznesit tuaj kërkon një numërim të ndryshëm, mund ta konfiguroni formulën që të fillojë numërimin me çdo ditë tjetër të javës.
Funksioni WEEKDAY është i disponueshëm në të gjitha versionet e Excel 365 deri në vitin 2000.
Sintaksa e funksionit WEEKDAY është si më poshtë:
WEEKDAY(numri_serial, [tipi_i_kthimit])Ku:
Numri_Serial (kërkohet) - data që dëshironi të konvertoni në numrin e ditës së javës. Mund të jepet si një numër serial që përfaqëson datën, si një varg teksti në formatqë Excel e kupton, si referencë për qelizën që përmban datën, ose duke përdorur funksionin DATE.
Tipi_Kthimi (opsionale) - përcakton se cilën ditë të javës do të përdoret si dita e parë . Nëse hiqet, vendoset si parazgjedhje në javën Diell-Sat.
Këtu është një listë e të gjitha vlerave të mbështetura return_type :
| Return_type | Numri u kthye |
|---|---|
| 1 ose u hoq | Nga 1 (e diel) deri në 7 (e shtunë) |
| 2 | Nga 1 (e hënë) deri në 7 (e diel) |
| 3 | Nga 0 (e hënë) deri në 6 (e diel) |
| 11 | Nga 1 (e hënë) deri në 7 (e diel) |
| 12 | Nga 1 (e martë) në 7 (e hënë) |
| 13 | Nga 1 (e mërkurë) deri në 7 (e martë) |
| 14 | Nga 1 (e enjte) deri në 7 (e mërkurë) |
| 15 | Nga 1 (e premte) deri në 7 (e enjte) |
| 16 | Nga 1 (e shtunë) deri në 7 (e premte) |
| 17 | Nga 1 (e diel) deri në 7 (e shtunë) |
Shënim. Vlerat return_type 11 deri 17 u prezantuan në Excel 2010 dhe për këtë arsye ato nuk mund të përdoren në versionet e mëparshme.
Formula bazë WEEKDAY në Excel
Për fillestarët, le të shohim se si për të përdorur formulën WEEKDAY në formën e saj më të thjeshtë për të marrë numrin e ditës nga data.
Për shembull, për të marrë ditën e javës nga data në C4 me parazgjedhjen e javës së diel - të shtunën, formula është:
<0 0> =WEEKDAY(C4)Nëse keni një numër serialduke përfaqësuar datën (p.sh. të sjellë nga funksioni DATEVALUE), ju mund ta fusni atë numër direkt në formulën:
=WEEKDAY(45658)
Gjithashtu, mund të shkruani datën si një varg teksti të mbyllur në thonjëza direkt në formulë. Vetëm sigurohuni që të përdorni formatin e datës që Excel pret dhe mund të interpretojë:
=WEEKDAY("1/1/2025")
Ose, jepni datën e burimit në një mënyrë 100% të besueshme duke përdorur funksionin DATE:
=WEEKDAY(DATE(2025, 1,1))
Për të përdorur hartën e ditës ndryshe nga parazgjedhja Sun-Sat, futni një numër të përshtatshëm në argumentin e dytë. Për shembull, për të filluar numërimin e ditëve nga e hëna, formula është:
=WEEKDAY(C4, 2)
Në imazhin më poshtë, të gjitha formulat kthejnë ditën e javës që korrespondon me 1 janar 2025, që është ruhet si numri 45658 brenda në Excel. Në varësi të vlerës së vendosur në argumentin e dytë, formulat nxjerrin rezultate të ndryshme. 
Në pamje të parë, mund të duket se numrat e kthyer nga funksioni WEEKDAY kanë shumë pak kuptim praktik. Por le ta shohim nga një kënd tjetër dhe të diskutojmë disa formula që zgjidhin detyrat e jetës reale.
Si të konvertohet data e Excel në emrin e ditës së javës
Sipas dizajnit, funksioni Excel WEEKDAY kthen ditën e javës si numër. Për ta kthyer numrin e ditës së javës në emër të ditës, përdorni funksionin TEXT.
Për të marrë emrat e ditës së plotë , përdorni kodin e formatit "dddd":
TEXT(WEEKDAY( data ), "dddd")Për t'u kthyer shkurtuaremrat e ditëve , kodi i formatit është "ddd":
TEXT(WEEKDAY( data ), "ddd")Për shembull, për të kthyer datën në A3 në emrin e ditës së javës , formula është:
=TEXT(WEEKDAY(A3), "dddd")
Ose
=TEXT(WEEKDAY(A3), "ddd") 
Një zgjidhje tjetër e mundshme është përdorimi i WEEKDAY së bashku me funksionin CHOOSE.
Për shembull, për të marrë një emër të shkurtuar të ditës së javës nga data në A3, formula shkon si më poshtë:
=CHOOSE(WEEKDAY(A3),"Sun","Mon","Tus","Wed","Thu","Fri","Sat")
Këtu, WEEKDAY kthen një numër serial nga 1 (dielli) në 7 (sht. ) dhe CHOOSE zgjedh vlerën përkatëse nga lista. Meqenëse data në A3 (e mërkurë) korrespondon me 4, CHOOSE nxjerr "Të mërkurën", e cila është vlera e 4-të në listë. 
Megjithëse formula CHOOSE është pak më e rëndë për t'u konfiguruar, ajo ofron më shumë fleksibilitet duke ju lejuar të nxirrni emrat e ditëve në çdo format që dëshironi. Në shembullin e mësipërm, ne tregojmë emrat e shkurtuar të ditëve. Në vend të kësaj, ju mund të dorëzoni emrat e plotë, shkurtesat e personalizuara apo edhe emrat e ditëve në një gjuhë tjetër.
Këshillë. Një mënyrë tjetër e thjeshtë për të kthyer një datë në emrin e ditës së javës është duke aplikuar një format të personalizuar të datës. Për shembull, formati i kodit "dddd, mmmm d, yyyy" do të ketë datën e shfaqur si " E premte, 3 janar 2025 " ndërsa "dddd" do të tregojë vetëm " E premte " .
Formula e Excel WEEKDAY për të gjetur dhe filtruar ditët e punës dhe fundjavat
Kur keni të bëni me një listë të gjatë datash, mund të dëshironi të dini se cilat janë ditë pune dhe cilat janë fundjavë.
Për të identifikuar fundjavat dhe ditët e javës në Excel, ndërtoni një deklaratë IF me funksionin e ndërlidhur WEEKDAY. Për shembull:
=IF(WEEKDAY(A3, 2)<6, "Workday", "Weekend")
Kjo formulë shkon në qelizën A3 dhe kopjohet në aq qeliza sa të nevojitet.
Në formulën WEEKDAY, ju vendosni tipi_kthimi në 2, që korrespondon me javën e hënë-diell ku e hëna është dita 1. Pra, nëse numri i ditës së javës është më i vogël se 6 (nga e hëna në të premte), formula kthen "Ditë pune", përndryshe - "Fundjavë". 
Për të filtruar fundjavat ose ditët e punës , aplikoni filtrin e Excel-it në grupin tuaj të të dhënave (skedën Data > Filter ) dhe zgjidhni ose "Fundjavë" ose "Workday".
Në pamjen e ekranit më poshtë, ne kemi ditët e javës të filtruara, kështu që vetëm fundjavat janë të dukshme: 
Nëse ndonjë zyrë rajonale e organizatës suaj punon në një orar tjetër ku ditët e pushimit janë të ndryshme nga e shtuna dhe e diela, ju mund ta rregulloni lehtësisht formulën WEEKDAY sipas nevojave tuaja duke specifikuar një lloj_kthimi të ndryshëm .
Për shembull, për të trajtuar E shtunë dhe Të hënën si fundjavë, cakto lloji_kthimi në 12, kështu që do të marrësh llojin e javës "e martë (1) deri të hënën (7)":
=IF(WEEKDAY(A2, 12)<6, "Workday", "Weekend")
Si të nënvizoni ditët e punës të fundjavës dhe në Excel
Për të dalluar fundjavat dhe ditët e punës në fletën tuaj të punës me një shikim, mund t'i merrni ato automatikisht të hijezuara me ngjyra të ndryshme. Për këtë, përdorni formulën ditë jave/fundjavë të diskutuar në shembullin e mëparshëm meFormatimi i kushtëzuar i Excel. Siç nënkuptohet kushti, ne kemi nevojë vetëm për funksionin bazë WEEKDAY pa mbështjellësin IF.
Për të theksohen fundjavat (e shtunë dhe e diel):
=WEEKDAY($A2, 2)<6
Për të theksuar ditët e punës (e hënë - e premte):
=WEEKDAY($A2, 2)>5
Ku A2 është qeliza e sipërme majtas e diapazonit të zgjedhur.
Për të konfiguroni rregullin e formatimit të kushtëzuar, hapat janë:
- Zgjidhni listën e datave (në rastin tonë A2:A15).
- Në skedën Home , në grupin Stilet , kliko Formatimi i kushtëzuar > Rregulli i ri .
- Në dialogun Rregulli i ri i formatimit kutinë, zgjidhni Përdor një formulë për të përcaktuar se cilat qeliza të formatohen .
- Në kutinë Formati ku kjo formulë është e vërtetë, fut formulën e sipërpërmendur për fundjavat ose ditëve të javës.
- Klikoni butonin Format dhe zgjidhni formatin e dëshiruar.
- Klikoni OK dy herë për të ruajtur ndryshimet dhe mbyllni dritaret e dialogut.
Për informacion të detajuar për secilin hap, ju lutemi shikoni Si të konfiguroni formatimi i kushtëzuar me formulë.
Rezultati duket mjaft i bukur, apo jo? 
Si të numërohen ditët e javës dhe fundjavat në Excel
Për të marrë numrin e ditëve të javës ose fundjavave në listën e datave, mund të përdorni funksionin WEEKDAY në kombinim me SUM. Për shembull:
Për të numëruar fundjavat , formula në D3 është:
=SUM(--(WEEKDAY(A3:A20, 2)>5))
Për numëruar ditët e javës ,formula në D4 merr këtë formë:
=SUM(--(WEEKDAY(A3:A20, 2)<6))
Në Excel 365 dhe Excel 2021 që trajtojnë vargjet në mënyrë origjinale, kjo funksionon si një formulë e rregullt siç tregohet në pamjen e ekranit më poshtë. Në Excel 2019 dhe më herët, shtypni Ctrl + Shift + Enter për ta bërë atë një formulë grupi. 
Si funksionojnë këto formula:
Funksioni WEEKDAY me tipi_kthimi i vendosur në 2 e kthen numrin e ditës nga 1 (e hënë) në 7 (dielli ) për çdo datë në diapazonin A3:A20. Shprehja logjike kontrollon nëse numrat e kthyer janë më të mëdhenj se 5 (për fundjavë) ose më pak se 6 (për ditët e javës). Rezultati i këtij operacioni është një grup vlerash TRUE dhe FALSE.
Negacioni i dyfishtë (--) i detyron vlerat logjike në 1 dhe 0. Dhe funksioni SUM i mbledh ato. Duke qenë se 1 (E VËRTETË) përfaqëson ditët që duhen numëruar dhe 0 (FALSE) ditët që duhen injoruar, ju merrni rezultatin e dëshiruar.
Këshillë. Për të llogaritur ditët e javës ndërmjet dy datave , përdorni funksionin NETWORKDAYS ose NETWORKDAYS.INTL.
Nëse ditë jave atëherë, nëse e shtunë ose e diel atëherë
Së fundi, le të diskutojmë pak më shumë rast specifik që tregon se si të përcaktohet dita e javës dhe nëse është e shtunë ose e diel atëherë bëni diçka, nëse është ditë jave atëherë bëni diçka tjetër.
IF(WEEKDAY( qeliza , 2)> 5, if_weekend_then , if_weekday_then )Supozoni se po llogaritni pagesat për punonjësit që kanë bërë disa punë shtesë në ditët e tyre të pushimit, kështu që ju duhetpër të aplikuar tarifa të ndryshme pagesash për ditët e punës dhe fundjavat. Kjo mund të bëhet duke përdorur deklaratën e mëposhtme IF:
- Në argumentin testi_logjik , vendosni funksionin WEEKDAY që kontrollon nëse një ditë e caktuar është ditë pune apo fundjavë. <. 28>Në argumentin value_if_true , shumëzo numrin e orëve të punës me normën e fundjavës (G4).
- Në argumentin value_if_false , shumëzo numrin e orëve të punës sipas normës së ditës së punës (G3).
Formula e plotë në D3 merr këtë formë:
=IF(WEEKDAY(B3, 2)>5, C3*$G$4, C3*$G$3)
Që formula të kopjohet saktë në qelizat e mëposhtme, sigurohuni që të kyçni adresat e qelisë së tarifës me shenjën $ (si $G$4). 
Funksioni WEEKDAY nuk funksionon
Në përgjithësi, ka dy gabime të zakonshme që një formulë WEEKDAY mund të kthejë:
#VALUE! ndodh gabimi nëse:
- Numri_Serial ose tipi_i_kthimit është jonumerik.
- Numri_Serial është jashtë diapazoni i datave të mbështetura (1900 deri në 9999).
#NUM! ndodh gabimi kur tipi_kthimi është jashtë kufijve të lejuar (1-3 ose 11-17).
Kjo është mënyra se si të përdoret funksioni WEEKDAY në Excel për të manipuluar ditët e javës. Në artikullin vijues, ne do të eksplorojmë funksionet e Excel për të operuar në njësi më të mëdha kohore si javë, muaj dhe vite. Ju lutemi qëndroni të sintonizuar dhe faleminderit që lexoni!
Praktikoni librin e punës për shkarkim
formula WEEKDAY në Excel - shembuj (.xlsxskedar)
