Artikulli tregon disa mënyra të ndryshme për të marrë vlerën maksimale në Excel bazuar në një ose disa kushte që specifikoni.

Në tutorialin tonë të mëparshëm, ne shikuam përdorimet e zakonshme i funksionit MAX i cili është krijuar për të kthyer numrin më të madh në një grup të dhënash. Sidoqoftë, në disa situata, mund t'ju duhet të zbuloni më tej të dhënat tuaja për të gjetur vlerën maksimale bazuar në kritere të caktuara. Kjo mund të bëhet duke përdorur disa formula të ndryshme dhe ky artikull shpjegon të gjitha mënyrat e mundshme.

Formula Excel MAX IF

Deri kohët e fundit, Microsoft Excel nuk kishte një Funksioni i integruar MAX IF për të marrë vlerën maksimale bazuar në kushtet. Me prezantimin e MAXIFS në Excel 2019, ne mund të bëjmë max me kusht në një mënyrë të thjeshtë.

Në Excel 2016 dhe versionet e mëparshme, ju ende duhet të krijoni formulën tuaj të grupit duke kombinuar MAX funksion me një deklaratë IF:

Për të parë se si kjo MAX e përgjithshme Nëse formula funksionon në të dhëna reale, ju lutemi merrni parasysh shembullin e mëposhtëm. Supozoni se keni një tabelë me rezultatet e kërcimit së gjati të disa studentëve. Tabela përfshin të dhënat për tre raunde, dhe ju po kërkoni rezultatin më të mirë të një atleti të caktuar, thotë Jacob. Me emrat e studentëve në A2:A10 dhe distancat në C2:C10, formula merr këtë formë:

=MAX(IF(A2:A10="Jacob", C2:C10))

Ju lutemi mbani në mend se një formulë grupiduhet të futet gjithmonë duke shtypur njëkohësisht tastet Ctrl + Shift + Enter. Si rezultat, ai rrethohet automatikisht me kllapa kaçurrelë siç tregohet në pamjen e mëposhtme (shtypja e kllapave me dorë nuk do të funksionojë!).

Në fletët e punës së jetës reale, është më e përshtatshme të futësh kriterin në disa qelizë, në mënyrë që të mund ta ndryshoni lehtësisht gjendjen pa ndryshuar formulën. Pra, ne shtypim emrin e dëshiruar në F1 dhe marrim rezultatin e mëposhtëm:

=MAX(IF(A2:A10=F1, C2:C10))

Si funksionon kjo formulë

Në logjikë testimi i funksionit IF, krahasojmë listën e emrave (A2:A10) me emrin e synuar (F1). Rezultati i këtij operacioni është një grup i TRUE dhe FALSE, ku vlerat TRUE përfaqësojnë emra që përputhen me emrin e synuar (Jacob):

{FALSE;FALSE;FALSE;TRUE;TRUE;TRUE;FALSE;FALSE;FALSE}

Për vlerën_ if_true argument, ne japim rezultatet e kërcimit së gjati (C2:C10), kështu që nëse testi logjik vlerësohet në TRUE, numri përkatës nga kolona C kthehet. Argumenti value_ if_false është hequr, që do të thotë thjesht do të ketë një vlerë FALSE kur kushti nuk plotësohet:

{FALSE;FALSE;FALSE;5.48;5.42;5.57;FALSE;FALSE;FALSE}

Ky grup i jepet funksionit MAX, i cili kthen numrin maksimal duke injoruar vlerat FALSE.

Këshillë. Për të parë grupet e brendshme të diskutuara më sipër, zgjidhni pjesën përkatëse të formulës në fletën tuaj të punës dhe shtypni tastin F9. Për të dalë nga mënyra e vlerësimit të formulës, shtypni tastin Esc.

Formula MAX IF me shumëfishkriteret

Në situatën kur ju duhet të gjeni vlerën maksimale bazuar në më shumë se një kusht, mund të:

Përdorni pohime të ndërlidhura IF për të përfshirë kritere shtesë:

Ose trajtoni kritere të shumta duke përdorur operacionin e shumëzimit:

Le të themi se keni rezultatet e djemve dhe vajzave në një tabelë të vetme dhe dëshironi të gjeni kërcimin më të gjatë midis vajzave në raundin 3. Për ta bërë atë , ne futim kriterin e parë (femër) në G1, kriterin e dytë (3) në G2 dhe përdorim formulat e mëposhtme për të gjetur vlerën maksimale:

=MAX(IF(B2:B16=G1, IF(C2:C16=G2, D2:D16)))

=MAX(IF((B2:B16=G1)*(C2:C16=G2), D2:D16))

Meqenëse të dyja janë formula grupi, mos harroni të shtypni Ctrl + Shift + Enter për t'i plotësuar ato në mënyrë korrekte.

Siç tregohet në pamjen e mëposhtme të ekranit, formulat prodhojnë të njëjtin rezultat, kështu që cila prej tyre do të përdoret është një çështje e ju preferenca juaj personale. Për mua, formula me logjikën Boolean është më e lehtë për t'u lexuar dhe ndërtuar - ajo ju lejon të shtoni sa më shumë kushte që dëshironi pa futur funksione shtesë IF.

Si funksionojnë këto formula

Formula e parë përdor dy funksione IF të mbivendosur për të vlerësuar dy kritere. Në testin logjik të deklaratës së parë IF, krahasojmë vlerat në kolonën Gjinia(B2:B16) me kriterin në G1 ("Femër"). Rezultati është një grup vlerash TRUE dhe FALSE ku TRUE përfaqëson të dhëna që përputhen me kriterin:

{FALSE; FALSE; FALSE; TRUE; TRUE; TRUE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE; TRUE; TRUE; TRUE}

Në mënyrë të ngjashme, funksioni i dytë IF kontrollon vlerat në kolonën Round (C2 :C16) kundrejt kriterit në G2.

Për argumentin value_if_true në deklaratën e dytë IF, ne japim rezultatet e kërcimit së gjati (D2:D16), dhe në këtë mënyrë marrim artikujt që kanë TRUE në dy grupet e para në pozicionet përkatëse (d.m.th. artikujt ku gjinia është "femër" dhe e rrumbullakët është 3):

{FALSE; FALSE; FALSE; FALSE; FALSE; 4.63; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE; 4.52}

Ky grup përfundimtar shkon në funksionin MAX dhe ai kthen numrin më të madh.

Formula e dytë vlerëson të njëjtat kushte brenda një testi të vetëm logjik dhe operacioni i shumëzimit funksionon si operatori AND:

Kur vlerat TRUE dhe FALSE përdoren në çdo operacion aritmetik, ato konvertohen në 1 dhe 0, përkatësisht. Dhe për shkak se shumëzimi me 0 jep gjithmonë zero, grupi që rezulton ka 1 vetëm kur të gjitha kushtet janë TË VËRTETA. Ky grup vlerësohet në testin logjik të funksionit IF, i cili kthen distancat që korrespondojnë me 1 elementët (TRUE).

MAX IF pa grup

Shumë përdorues të Excel, duke përfshirë edhe mua, janë paragjykoni kundër formulave të grupeve dhe përpiquni t'i hiqni qafe ato kudo që të jetë e mundur. Për fat të mirë, Microsoft Excel ka disa funksione që trajtojnë grupin në mënyrë origjinale, dhe ne mund të përdorim një të tillëe funksioneve të tilla, përkatësisht SUMPRODUCT, si lloj "mbështjellësi" rreth MAX.

Formula e përgjithshme MAX IF pa grup është si më poshtë:

Natyrisht, mund të shtoni më shumë çifte të diapazonit/kritereve nëse nevojiten.

Për të parë formulën në veprim, do të përdorim të dhënat nga shembulli i mëparshëm. Qëllimi është të arrihet kërcimi maksimal i një atleteje në raundin 3:

=SUMPRODUCT(MAX(((B2:B16=G1) * (C2:C16=G2) * (D2:D16))))

Kjo formulë konkurrohet me një shtypje normale të tastierës Enter dhe jep të njëjtin rezultat si formula MAX IF e grupit:

Duke hedhur një vështrim më të afërt në pamjen e mësipërme të ekranit, mund të vëreni se kërcimet e pavlefshme të shënuara me "x" në shembujt e mëparshëm tani kanë 0 vlera në rreshtat 3, 11 dhe 15 , dhe seksioni tjetër shpjegon pse.

Si funksionon kjo formulë

Ashtu si me formulën MAX IF, ne vlerësojmë dy kritere duke krahasuar secilën vlerë në gjininë (B2:B16) dhe të rrumbullakët ( C2:C16) kolona me kriteret në qelizat G1 dhe G2. Rezultati janë dy vargje me vlera TRUE dhe FALSE. Shumëzimi i elementeve të vargjeve në të njëjtat pozicione konverton TRUE dhe FALSE në 1 dhe 0, përkatësisht, ku 1 përfaqëson artikujt që plotësojnë të dy kriteret. Vargu i tretë i shumëzuar përmban rezultatet e kërcimit së gjati (D2:D16). Dhe për shkak se shumëzimi me 0 jep zero, vetëm artikujt që kanë 1 (E VËRTETË) në pozicionet përkatësembijetoj:

{0; 0; 0; 0; 0; 4.63; 0; 0; 0; 0; 0; 0; 0; 0; 4.52}

Në rast se range_max përmban ndonjë vlerë teksti, operacioni i shumëzimit kthen gabimin #VALUE për shkak të të cilit e gjithë formula nuk do të funksionojë.

Funksioni MAX e merr atë nga këtu dhe kthen numrin më të madh që plotëson kushtet e specifikuara. Vargu që rezulton i përbërë nga një element i vetëm {4.63} shkon në funksionin SUMPRODUCT dhe nxjerr numrin maksimal në një qelizë.

Shënim. Për shkak të logjikës së saj specifike, formula funksionon me paralajmërimet e mëposhtme:

• Sfera ku kërkoni vlerën më të lartë duhet të përmbajë vetëm numra. Nëse ka ndonjë vlerë teksti, një #VALUE! është kthyer gabimi.
• Formula nuk mund të vlerësojë gjendjen "jo e barabartë me zero" në një grup të dhënash negative. Për të gjetur vlerën maksimale duke injoruar zerat, përdorni një formulë MAX IF ose funksion MAXIFS.

Formula Excel MAX IF me logjikën OSE

Për të gjetur vlerën maksimale kur ndonjë nga kushtet e specifikuara është plotësuar, përdorni formulën tashmë të njohur të grupit MAX IF me logjikën Boolean, por shtoni kushtet në vend që t'i shumëzoni ato.

Përndryshe, mund të përdorni formulën e mëposhtme jo-vargësh :

Si shembull, le të punojmërezultati më i mirë në raundet 2 dhe 3. Ju lutemi vini re se në gjuhën Excel, detyra është formuluar ndryshe: ktheni vlerën maksimale nëse raundi është ose 2 ose 3.

Me raundet e renditura në B2:B10 , rezultatet në C2:C10 dhe kriteret në F1 dhe H1, formula shkon si më poshtë:

=MAX(IF((B2:B10=F1) + (B2:B10=H1), C2:C10))

Futni formulën duke shtypur kombinimin e tastit Ctrl + Shift + Enter dhe do të merrni ky rezultat:

Vlera maksimale me të njëjtat kushte mund të gjendet gjithashtu duke përdorur këtë formulë jo të grupit:

=SUMPRODUCT(MAX(((B2:B10=F1) + (B2:B10=H1)) * C2:C10))

Megjithatë, ne duhet të zëvendësojmë të gjitha vlerat "x" në kolonën C me zero në këtë rast, sepse SUMPRODUCT MAX funksionon vetëm me të dhëna numerike:

Si funksionojnë këto formula

Formula e grupit funksionon saktësisht në të njëjtën mënyrë si MAX IF me logjikën AND përveç që ju bashkoni kriteret duke përdorur veprimin e mbledhjes në vend të shumëzimit. Në formulat e vargjeve, mbledhja funksionon si operator OSE:

Shtimi i dy vargjeve të TRUE dhe FALSE (të cilat rezultojnë nga kontrollimi i vlerave në B2:B10 kundrejt kritereve në F1 dhe H1) prodhon një grup me 1 dhe 0 ku 1 përfaqëson artikujt për të cilët secili kusht është TRUE dhe 0 përfaqëson artikujt për të cilët të dy kushtet janë FALSE. Si rezultat, funksioni IF "mban" të gjithë artikujt në C2:C10 ( vlera_nëse_true ) për të cilat çdo kusht është TRUE (1); artikujt e mbetur zëvendësohen me FALSE sepseArgumenti value_if_false nuk është specifikuar.

Formula jo-arrit funksionon në mënyrë të ngjashme. Dallimi është se në vend të testit logjik të IF, ju shumëzoni elementet e grupit 1 dhe 0 me elementët e grupit të rezultateve të kërcimit së gjati (C2:C10) në pozicionet përkatëse. Kjo anulon artikujt që nuk plotësojnë asnjë kusht (kanë 0 në grupin e parë) dhe mban artikujt që plotësojnë një nga kushtet (kanë 1 në grupin e parë).

MAXIFS – mënyrë e thjeshtë për të gjetur më të lartën vlera me kushte

Përdoruesit e Excel 2019, 2021 dhe Excel 365 janë të lirë nga telashet e zbutjes së vargjeve për të ndërtuar formulën e tyre MAX IF. Këto versione të Excel-it ofrojnë funksionin e shumëpritur MAXIFS që bën gjetjen e vlerës më të madhe me kushtet e lojës së fëmijëve.

Në argumentin e parë të MAXIFS, ju futni diapazonin në të cilin duhet të gjendet vlera maksimale (D2: D16 në rastin tonë), dhe në argumentet pasuese mund të futni deri në 126 çifte varg/kritere. Për shembull:

=MAXIFS(D2:D16, B2:B16, G1, C2:C16, G2)

Siç tregohet në pamjen e mëposhtme të ekranit, kjo formulë e thjeshtë nuk ka asnjë problem me përpunimin e diapazonit që përmban vlera numerike dhe tekstuale:

Për informacion të detajuar rreth këtij funksioni, ju lutemi shihni funksionin Excel MAXIFS me shembuj formulash.

Kështu mund të gjeni vlerën maksimale me kushtet në Excel. Ju falënderoj që lexoni dhe shpresoj t'ju shohim në blogun tonë në vazhdimjavë!

Praktikoni librin e punës për shkarkim

Shembuj të formulave të Excel MAX IF (skedari .xlsx)