Το σεμινάριο εξηγεί τα βασικά στοιχεία της αναζήτησης στο Excel, παρουσιάζει τα δυνατά και αδύνατα σημεία κάθε συνάρτησης αναζήτησης του Excel και παρέχει μια σειρά παραδειγμάτων που θα σας βοηθήσουν να αποφασίσετε ποιος τύπος αναζήτησης είναι καλύτερο να χρησιμοποιηθεί σε μια συγκεκριμένη κατάσταση.

Η αναζήτηση μιας συγκεκριμένης τιμής μέσα σε ένα σύνολο δεδομένων είναι μία από τις πιο συνηθισμένες εργασίες στο Excel. Και όμως, δεν υπάρχει κανένας "καθολικός" τύπος αναζήτησης κατάλληλος για όλες τις περιπτώσεις. Ο λόγος είναι ότι ο όρος "αναζήτηση" μπορεί να υποδηλώνει μια ποικιλία διαφορετικών πραγμάτων: μπορείτε να αναζητήσετε κάθετα σε μια στήλη, οριζόντια σε μια γραμμή ή στην τομή μιας γραμμής και μιας στήλης, να αναζητήσετε με ένα ή περισσότερα κριτήρια, να επιστρέψετε τηνπρώτη ή πολλαπλές αντιστοιχίες, κάντε αναζήτηση με ή χωρίς ευαισθησία στην πεζότητα, και ούτω καθεξής.

Σε αυτή τη σελίδα, θα βρείτε μια λίστα με τις πιο βασικές λειτουργίες του Excel Lookup με παραδείγματα τύπων και αναλυτικά σεμινάρια που συνδέονται για την αναφορά σας.

Excel Lookup - τα βασικά

Πριν καταδυθούμε στις μυστικές ανατροπές των τύπων αναζήτησης του Excel, ας ορίσουμε τους βασικούς όρους για να διασφαλίσουμε ότι είμαστε πάντα στην ίδια σελίδα.

Αναζήτηση - αναζήτηση μιας συγκεκριμένης τιμής σε έναν πίνακα δεδομένων.

Τιμή αναζήτησης - μια τιμή για αναζήτηση.

Τιμή επιστροφής (matching value ή match) - μια τιμή στην ίδια θέση με την τιμή αναζήτησης αλλά σε άλλη στήλη ή γραμμή (ανάλογα με το αν κάνετε κάθετη ή οριζόντια αναζήτηση).

Πίνακας αναζήτησης Στην επιστήμη των υπολογιστών, ένας πίνακας αναζήτησης είναι ένας πίνακας δεδομένων, ο οποίος χρησιμοποιείται γενικά για την αντιστοίχιση τιμών εισόδου σε τιμές εξόδου. Όσον αφορά αυτό το σεμινάριο, ένας πίνακας αναζήτησης του Excel δεν είναι τίποτε άλλο παρά μια σειρά κελιών όπου αναζητάτε μια τιμή αναζήτησης.

Κύριο τραπέζι (κύριος πίνακας) - ένας πίνακας στον οποίο αντλείτε τις τιμές που ταιριάζουν.

Ο πίνακας αναζήτησης και ο κύριος πίνακας μπορεί να έχουν διαφορετική δομή και μέγεθος, ωστόσο θα πρέπει πάντα να περιέχουν τουλάχιστον ένα κοινό μοναδικό αναγνωριστικό , δηλαδή μια στήλη ή μια γραμμή που περιέχει πανομοιότυπα δεδομένα, ανάλογα με το αν θέλετε να εκτελέσετε κάθετη ή οριζόντια αναζήτηση.

Το ακόλουθο στιγμιότυπο οθόνης δείχνει ένα δείγμα πίνακα αναζήτησης που θα χρησιμοποιηθεί σε πολλά από τα παρακάτω παραδείγματα.

Λειτουργίες αναζήτησης του Excel

Ακολουθεί μια σύντομη επισκόπηση των πιο δημοφιλών τύπων για την εκτέλεση αναζήτησης στο Excel, των κύριων πλεονεκτημάτων και μειονεκτημάτων τους.

Λειτουργία LOOKUP

Η συνάρτηση LOOKUP του Excel μπορεί να εκτελέσει τους απλούστερους τύπους κάθετων και οριζόντιων αναζητήσεων.

Πλεονεκτήματα : Εύκολο στη χρήση.

Μειονεκτήματα : Περιορισμένη λειτουργικότητα, δεν μπορεί να λειτουργήσει με μη ταξινομημένα δεδομένα (απαιτεί ταξινόμηση της στήλης/σειράς αναζήτησης σε αύξουσα σειρά).

Για περισσότερες πληροφορίες, ανατρέξτε στην ενότητα Πώς να χρησιμοποιήσετε τη λειτουργία LOOKUP του Excel.

Λειτουργία VLOOKUP

Είναι μια βελτιωμένη έκδοση της συνάρτησης LOOKUP ειδικά σχεδιασμένη για να κάνει κάθετη αναζήτηση σε στήλες.

Πλεονεκτήματα : Σχετικά εύκολο στη χρήση, μπορεί να λειτουργήσει με ακριβή και κατά προσέγγιση αντιστοίχιση.

Μειονεκτήματα : Δεν μπορεί να κοιτάξει στα αριστερά του, σταματά να λειτουργεί όταν μια στήλη εισάγεται ή αφαιρείται από τον πίνακα αναζήτησης, μια τιμή αναζήτησης δεν μπορεί να υπερβαίνει τους 255 χαρακτήρες, απαιτεί μεγάλη επεξεργαστική ισχύ σε μεγάλα σύνολα δεδομένων.

Για περισσότερες πληροφορίες, ανατρέξτε στο σεμινάριο VLOOKUP του Excel για αρχάριους.

Λειτουργία HLOOKUP

Είναι ένα οριζόντιο αντίστοιχο του VLOOKUP που αναζητά μια τιμή στην πρώτη γραμμή του πίνακα αναζήτησης και επιστρέφει την τιμή στην ίδια θέση από μια άλλη γραμμή.

Πλεονεκτήματα : Εύκολο στη χρήση, μπορεί να επιστρέψει ακριβείς και κατά προσέγγιση αντιστοιχίες.

Μειονεκτήματα : Μπορεί να κάνει αναζήτηση μόνο στην πιο πάνω γραμμή του πίνακα αναζήτησης, επηρεάζεται από την εισαγωγή ή τη διαγραφή γραμμών, η τιμή αναζήτησης πρέπει να είναι κάτω από 255 χαρακτήρες.

Για περισσότερες πληροφορίες, ανατρέξτε στην ενότητα Πώς να χρησιμοποιήσετε το HLOOKUP στο Excel.

VLOOKUP MATCH / HLOOKUP MATCH

Μια δυναμική αναφορά στήλης ή γραμμής που δημιουργείται από τη MATCH καθιστά αυτόν τον τύπο αναζήτησης του Excel απρόσβλητο στις αλλαγές που γίνονται στο σύνολο δεδομένων. Με άλλα λόγια, με λίγη βοήθεια από τη MATCH, οι συναρτήσεις VLOOKUP και HLOOKUP μπορούν να επιστρέφουν σωστές τιμές ανεξάρτητα από το πόσες στήλες/γραμμές έχουν εισαχθεί ή διαγραφεί από έναν πίνακα αναζήτησης.

Τύπος για κάθετη αναζήτηση

Τύπος για οριζόντια αναζήτηση

Πλεονεκτήματα : Βελτίωση σε σχέση με τις κανονικές φόρμουλες Hlookup και Vlookup, οι οποίες είναι απρόσβλητες από την εισαγωγή ή τη διαγραφή δεδομένων.

Μειονεκτήματα : Δεν είναι πολύ ευέλικτη, απαιτεί μια συγκεκριμένη δομή δεδομένων (η τιμή αναζήτησης που παρέχεται στη συνάρτηση MATCH πρέπει να είναι ακριβώς ίση με το όνομα της στήλης επιστροφής), δεν μπορεί να λειτουργήσει με τιμές αναζήτησης που υπερβαίνουν τους 255 χαρακτήρες.

Για περισσότερες πληροφορίες και παραδείγματα τύπων, ανατρέξτε στην ενότητα:

• Excel Vlookup και Match
• Excel Hlookup και Match

ΑΝΤΙΣΤΟΊΧΙΣΗ OFFSET

Ένας πιο πολύπλοκος αλλά πιο ισχυρός τύπος αναζήτησης, απαλλαγμένος από πολλούς περιορισμούς των Vlookup και Hlookup.

Τύπος για V-Lookup

Πού:

• n - είναι η μετατόπιση της στήλης αναζήτησης, δηλαδή ο αριθμός των στηλών που πρέπει να μετακινηθούν από το σημείο εκκίνησης στη στήλη αναζήτησης.
• m - είναι η μετατόπιση της στήλης επιστροφής, δηλαδή ο αριθμός των στηλών που πρέπει να μετακινηθούν από το σημείο εκκίνησης στη στήλη επιστροφής.

Τύπος για H-Lookup

Πού:

• n - είναι η μετατόπιση της γραμμής αναζήτησης, δηλαδή ο αριθμός των γραμμών που πρέπει να μετακινηθούν από το σημείο εκκίνησης στη γραμμή αναζήτησης.
• m - είναι η μετατόπιση της γραμμής επιστροφής, δηλαδή ο αριθμός των γραμμών που πρέπει να μετακινηθούν από το σημείο εκκίνησης στη γραμμή επιστροφής.

Τύπος για αναζήτηση πίνακα (ανά γραμμή και στήλη)

Προσέξτε ότι πρόκειται για τύπο πίνακα, ο οποίος εισάγεται πατώντας ταυτόχρονα τα πλήκτρα Ctrl + Shift + Enter.

Πλεονεκτήματα : Επιτρέπει την εκτέλεση μιας αριστερής Vlookup, μιας ανώτερης Hlookup και μιας αμφίδρομης αναζήτησης (με τιμές στήλης και γραμμής), χωρίς να επηρεάζεται από αλλαγές στο σύνολο δεδομένων.

Μειονεκτήματα : Πολύπλοκη και δύσκολη στη μνήμη σύνταξη.

Για περισσότερες πληροφορίες και παραδείγματα τύπων, ανατρέξτε στην ενότητα: Χρήση της συνάρτησης OFFSET στο Excel

INDEX MATCH

Είναι ο καλύτερος τρόπος για να κάνετε κάθετη ή οριζόντια αναζήτηση στο Excel που μπορεί να αντικαταστήσει τους περισσότερους από τους παραπάνω τύπους. Ο τύπος Index Match είναι η προσωπική μου προτίμηση και τον χρησιμοποιώ για όλες σχεδόν τις αναζητήσεις μου στο Excel.

Τύπος για V-Lookup

Τύπος για H-Lookup

Τύπος για αναζήτηση πίνακα

Μια επέκταση του κλασικού τύπου Index Match για να επιστρέφει μια τιμή στο σημείο τομής μιας συγκεκριμένης στήλης και γραμμής:

Μειονεκτήματα : Μόνο ένα - πρέπει να θυμάστε τη σύνταξη του τύπου.

Πλεονεκτήματα : Ο πιο ευέλικτος τύπος Lookup στο Excel, ανώτερος από τις συναρτήσεις Vlookup, Hlookup και Lookup από πολλές απόψεις:

• Μπορεί να κάνει αριστερή και ανώτερη αναζήτηση.
• Επιτρέπει την ασφαλή επέκταση ή συρρίκνωση του πίνακα αναζήτησης με την εισαγωγή ή διαγραφή στηλών και γραμμών.
• Κανένα όριο στο μέγεθος της τιμής αναζήτησης.
• Λειτουργεί ταχύτερα. Επειδή ένας τύπος αντιστοιχίας ευρετηρίου αναφέρεται σε στήλες/σειρές και όχι σε ολόκληρο πίνακα, απαιτεί λιγότερη επεξεργαστική ισχύ και δεν θα επιβραδύνει το Excel σας.

Για περισσότερες πληροφορίες, ανατρέξτε εδώ:

• INDEX MATCH ως καλύτερη εναλλακτική λύση για το VLOOKUP
• Τύπος INDEX MATCH MATCH για δισδιάστατη αναζήτηση

Πίνακας σύγκρισης του Excel Lookup

Όπως βλέπετε, δεν είναι όλοι οι τύποι Lookup του Excel ισοδύναμοι, ορισμένοι μπορούν να χειριστούν έναν αριθμό διαφορετικών αναζητήσεων, ενώ άλλοι μπορούν να χρησιμοποιηθούν μόνο σε μια συγκεκριμένη κατάσταση. Ο παρακάτω πίνακας περιγράφει τις δυνατότητες κάθε τύπου Lookup στο Excel.

Παραδείγματα τύπων αναζήτησης του Excel

Το πρώτο βήμα για να αποφασίσετε ποιος τύπος θα χρησιμοποιηθεί σε μια συγκεκριμένη κατάσταση είναι να καθορίσετε το είδος της αναζήτησης που θέλετε να εκτελέσετε. Παρακάτω θα βρείτε παραδείγματα τύπων για τους πιο δημοφιλείς τύπους αναζήτησης:

Κάθετη αναζήτηση σε στήλες

Μια κάθετη αναζήτηση ή Vlookup είναι η διαδικασία εύρεσης μιας τιμής αναζήτησης σε μια στήλη και επιστροφής μιας τιμής στην ίδια γραμμή από μια άλλη στήλη. Η αναζήτηση Vlookup στο Excel μπορεί να γίνει με διάφορους τρόπους, όπως:

Λειτουργία VLOOKUP

Εάν οι τιμές της αναζήτησης βρίσκονται στην αριστερή στήλη του πίνακα και δεν σκοπεύετε να κάνετε δομικές αλλαγές στο σύνολο δεδομένων σας (ούτε να προσθέσετε ούτε να διαγράψετε στήλες), μπορείτε να χρησιμοποιήσετε με ασφάλεια έναν κανονικό τύπο Vlookup:

=VLOOKUP(G2, $A$2:$E$6, 5, FALSE)

Όπου G2 είναι η τιμή αναζήτησης, A2:E6 στον πίνακα αναζήτησης και E είναι η στήλη επιστροφής.

VLOOKUP MATCH

Εάν εργάζεστε με έναν "μεταβλητό" πίνακα αναζήτησης του Excel, όπου οι στήλες μπορούν να εισαχθούν και να διαγραφούν ανά πάσα στιγμή, κάντε τον τύπο Vlookup απρόσβλητο σε αυτές τις αλλαγές ενσωματώνοντας τη συνάρτηση Match που δημιουργεί μια δυναμική αναφορά στήλης αντί ενός "σκληρά κωδικοποιημένου" αριθμού δείκτη:

=VLOOKUP(F2,$A$1:$D$6, MATCH($G$1,$A$1:$D$1, 0), FALSE)

INDEX MATCH - Αριστερή αναζήτηση

Είναι ο αγαπημένος μου τύπος που χειρίζεται τις αναζητήσεις από δεξιά προς αριστερά με ευκολία και λειτουργεί άψογα, ανεξάρτητα από το πόσες στήλες προσθέτετε ή διαγράφετε.

Για παράδειγμα, για να αναζητήσετε στη στήλη Β την τιμή στο Η2 και να επιστρέψετε μια αντιστοιχία από τη στήλη ΣΤ, χρησιμοποιήστε αυτόν τον τύπο:

=INDEX($F$2:$F$6,(MATCH(H2,$B$2:$B$6,0)))

Σημείωση. Όταν σκοπεύετε να χρησιμοποιήσετε έναν τύπο Vlookup σε περισσότερα από ένα κελιά, θα πρέπει πάντα να κλειδώστε την αναφορά του πίνακα αναζήτησης χρησιμοποιώντας το σύμβολο $ (απόλυτη αναφορά κελιού), έτσι ώστε ο τύπος να αντιγράφεται σωστά σε άλλα κελιά.

Οριζόντια αναζήτηση σε σειρές

Η οριζόντια αναζήτηση είναι μια "μετατοπισμένη" έκδοση της κάθετης αναζήτησης που αναζητά σε ένα σύνολο δεδομένων οριζόντια διατεταγμένο. Με άλλα λόγια, αναζητά την τιμή αναζήτησης σε μια γραμμή και επιστρέφει μια τιμή στην ίδια θέση από μια άλλη γραμμή.

Αν υποθέσουμε ότι η τιμή αναζήτησης βρίσκεται στο B9, ο πίνακας αναζήτησης είναι B1:F5 και θέλετε να επιστρέψετε μια αντίστοιχη τιμή από τη γραμμή 5, χρησιμοποιήστε έναν από τους ακόλουθους τύπους:

Λειτουργία HLOOKUP

Μπορεί να κοιτάξει προς τα πάνω μόνο σε όλη την πάνω σειρά στο σύνολο των δεδομένων σας.

=HLOOKUP(B8, $B$1:$F$5, 5, FALSE)

HLOOKUP MATCH

Όπως και το καθαρό Hlookup, αυτός ο τύπος μπορεί να κάνει αναζήτηση μόνο στην πιο πάνω γραμμή, αλλά σας επιτρέπει να ασφαλής εισαγωγή ή διαγραφή γραμμών στον πίνακα αναζήτησης.

=HLOOKUP(B8, $B$1:$F$5, MATCH($A$9, $A$1:$A$5, 0), FALSE)

Όπου Α1:Α5 είναι οι επικεφαλίδες των γραμμών και Α9 είναι το όνομα της γραμμής από την οποία θέλετε να επιστρέψετε τα αποτελέσματα.

INDEX MATCH

Μπορεί κοιτάξτε επάνω σε οποιαδήποτε σειρά και δεν έχει κανέναν από τους περιορισμούς των παραπάνω τύπων.

=INDEX($B$5:$F$5,(MATCH(B8,$B$1:$F$1,0)))

Αναζήτηση δύο διαστάσεων (με βάση τις τιμές γραμμής και στήλης)

Αναζήτηση δύο διαστάσεων (ή αλλιώς αναζήτηση μήτρας , διπλή αναζήτηση ή Αναζήτηση 2 κατευθύνσεων ) επιστρέφει μια τιμή με βάση τις αντιστοιχίες τόσο στις γραμμές όσο και στις στήλες. Με άλλα λόγια, ένας τύπος αναζήτησης 2 διαστάσεων αναζητά μια τιμή στο σημείο τομής μιας καθορισμένης γραμμής και στήλης.

Υποθέτοντας ότι ο πίνακας αναζήτησης είναι A1:E6, το κελί H2 περιέχει την τιμή που πρέπει να ταιριάζει στις γραμμές και το H3 περιέχει την τιμή που πρέπει να ταιριάζει στις στήλες, οι ακόλουθοι τύποι θα λειτουργήσουν άψογα:

Τύπος INDEX MATCH MATCH :

=INDEX($A$1:$E$6, MATCH(H2,$A$1:$A$6,0), MATCH(H3,$A$1:$E$1,0))

Τύπος OFFSET MATCH MATCH :

=OFFSET($A$1,MATCH(H2,$A$2:$A$6,0),MATCH(H3,$B$1:$E$1,0))

Εκτός από τους παραπάνω τύπους, υπάρχουν μια χούφτα άλλοι τρόποι για να εκτελέσετε αναζήτηση πίνακα στο Excel, και μπορείτε να βρείτε πλήρεις λεπτομέρειες στο Πώς να κάνετε αναζήτηση 2 κατευθύνσεων στο Excel.

Τρισδιάστατη αναζήτηση

Τρισδιάστατη αναζήτηση σημαίνει αναζήτηση με 3 διαφορετικές τιμές αναζήτησης. Σε ένα σύνολο δεδομένων παρακάτω, υποθέτοντας ότι θέλετε να αναζητήσετε ένα συγκεκριμένο έτος (H2), στη συνέχεια ένα συγκεκριμένο όνομα εντός των δεδομένων του έτους (H3) και στη συνέχεια να επιστρέψετε μια τιμή για έναν συγκεκριμένο μήνα (H4).

Η εργασία μπορεί να πραγματοποιηθεί με τον ακόλουθο τύπο πίνακα (θυμηθείτε να πατήσετε Ctrl + Shift + Enter για να τον ολοκληρώσετε σωστά):

=INDEX($A$1:$E$12,MIN(IF((ROW($A$1:$A$12)>MATCH(H2,$A$1:$A$12,0))*($A$1:$A$12=H3),ROW($A$1:$A$12),"")),MATCH(H4,$A$1:$E$1,0))

Αναζήτηση με πολλαπλά κριτήρια

Για να μπορέσουμε να αξιολογήσουμε πολλαπλά κριτήρια, θα πρέπει να τροποποιήσουμε τον κλασικό τύπο Index Match έτσι ώστε να μετατραπεί σε τύπο πίνακα:

Με τον πίνακα αναζήτησης που βρίσκεται στο A1:C11, ας βρούμε μια αντιστοιχία με 2 κριτήρια: αναζητήστε στη στήλη A μια τιμή στο κελί F1 και στη στήλη B μια τιμή στο κελί F2:

=INDEX($A$1:$C$11, MATCH(1, (F1=$A$1:$A$11) * (F2=$B$1:$B$11),0), 3)

Ως συνήθως, πατάτε Ctrl + Shift + Enter για να αξιολογηθεί ο τύπος ως τύπος πίνακα.

Για την αναλυτική εξήγηση της λογικής του τύπου, ανατρέξτε στην ενότητα INDEX MATCH για αναζήτηση με πολλαπλά κριτήρια.

Αναζήτηση για επιστροφή πολλαπλών τιμών

Όποια συνάρτηση αναζήτησης του Excel και αν χρησιμοποιήσετε (LOOKUP, VLOOKUP ή HLOOKUP), μπορεί να επιστρέψει μόνο μία αντιστοιχία. Για να λάβετε όλες τις αντιστοιχίες που βρέθηκαν, θα πρέπει να χρησιμοποιήσετε 6 διαφορετικές συναρτήσεις που συνδυάζονται σε έναν τύπο πίνακα:

Πού:

• m είναι ο αριθμός γραμμής του πρώτου κελιού στην περιοχή επιστροφής μείον 1.
• n είναι ο αριθμός γραμμής του πρώτου κελιού του τύπου μείον 1.

Με την τιμή αναζήτησης να βρίσκεται στο κελί E2, την περιοχή αναζήτησης στο A2:A11, την περιοχή επιστροφής στο B2:B11 και το πρώτο κελί του τύπου στη γραμμή 2, ο τύπος αναζήτησης παίρνει την ακόλουθη μορφή:

=IFERROR(INDEX($B$2:$B$11, SMALL(IF($E$2 =$A$2:$A$11, ROW($B$2:$B$11 )- 1,""), ROW() - 1 )),"")

Για να επιστρέψει ο τύπος πολλαπλές αντιστοιχίες, τον πληκτρολογείτε στο πρώτο κελί (F2), πατάτε Ctrl + Shift + Enter , και στη συνέχεια αντιγράφετε τον τύπο σε άλλα κελιά στη στήλη.

Για λεπτομερή εξήγηση του παραπάνω τύπου και άλλων τρόπων επιστροφής πολλαπλών τιμών, ανατρέξτε στην ενότητα Πώς να επιστρέψετε πολλαπλά αποτελέσματα με Vlookup.

Φωλιασμένη αναζήτηση (από 2 πίνακες αναζήτησης)

Σε περιπτώσεις που ο κύριος πίνακας και ο πίνακας αναζήτησης από τον οποίο θέλετε να αντλήσετε δεδομένα δεν έχουν κοινή στήλη, μπορείτε να χρησιμοποιήσετε έναν πρόσθετο πίνακα αναζήτησης για να δημιουργήσετε αντιστοιχίες, όπως εδώ:

Για να ανακτήσετε τις τιμές από το Ποσό στήλη στο Lookup_table2 , χρησιμοποιείτε τον ακόλουθο τύπο:

=VLOOKUP(VLOOKUP(A2, Lookup_table1!$A$1:$B$6, 2, FALSE), Lookup_table2!$A$1:$B$6, 2, FALSE)

Όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης, ο τύπος εμφωλευμένης αναζήτησης λειτουργεί τέλεια:

Διαδοχικά Vlookups από πολλαπλά φύλλα

Για να εκτελέσετε διαδοχικές αναζητήσεις Vlookup με βάση το αν μια προηγούμενη αναζήτηση ήταν επιτυχής ή αποτυχημένη, χρησιμοποιήστε εμφωλευμένες συναρτήσεις IFERROR μαζί με VLOOKUPs για να αξιολογήσετε πολλαπλές συνθήκες μία προς μία:

Εάν το πρώτο Vlookup αποτύχει, το IFERROR παγιδεύει το σφάλμα και εκτελεί ένα άλλο Vlookup. Εάν ούτε το δεύτερο Vlookup δεν βρει τίποτα, το δεύτερο IFERROR παγιδεύει το σφάλμα και εκτελεί το τρίτο Vlookup κ.ο.κ. Εάν όλα τα Vlookup αποτύχουν, το τελευταίο IFERROR επιστρέφει "δεν βρέθηκε" ή οποιοδήποτε άλλο μήνυμα παρέχετε στον τύπο.

Για παράδειγμα, ας προσπαθήσουμε να αντλήσουμε το ποσό από 3 διαφορετικά φύλλα:

=IFERROR(VLOOKUP(B1,A6:B9,2,0), IFERROR(VLOOKUP(B1,D6:E9,2,0), IFERROR(VLOOKUP(B1,G6:H9,2,0), "Δεν βρέθηκε")))

Το αποτέλεσμα θα μοιάζει κάπως έτσι:

Για περισσότερες πληροφορίες, ανατρέξτε στην ενότητα Πώς να χρησιμοποιήσετε τις ένθετες συναρτήσεις IFERROR στο Excel.

Αναζήτηση με ευαισθησία στην πεζότητα

Όπως πιθανώς γνωρίζετε, όλες οι συναρτήσεις αναζήτησης του Excel είναι από τη φύση τους μη ευαίσθητες στα πεζά και κεφαλαία. Για να αναγκάσετε τον τύπο αναζήτησης να διακρίνει μεταξύ πεζών και κεφαλαίων κειμένων, χρησιμοποιήστε είτε την LOOKUP είτε την INDEX MATCH σε συνδυασμό με τη συνάρτηση EXACT. Προσωπικά επιλέγω την INDEX MATCH επειδή δεν απαιτεί ταξινόμηση των τιμών στη στήλη αναζήτησης, όπως κάνει η συνάρτηση LOOKUP, μπορεί να εκτελέσει και από αριστερά προς τα δεξιάκαι αναζητήσεις από δεξιά προς τα αριστερά και λειτουργεί τέλεια για όλους τους τύπους δεδομένων.

Με το G2 να είναι η τιμή αναζήτησης, το A - η στήλη για την αναζήτηση και το E - η στήλη για την επιστροφή των αντιστοιχιών, ο τύπος αναζήτησης με ευαισθησία στην πεζότητα έχει ως εξής:

=INDEX($E$2:$E$6, MATCH(TRUE, EXACT($A$2:$A$6,G2),0))

Δεδομένου ότι είναι ένα τύπος συστοιχίας , φροντίστε να πατήσετε Ctrl + Shift + Enter για να το ολοκληρώσετε σωστά.

Για περισσότερα παραδείγματα τύπων, ανατρέξτε στην ενότητα Πώς να κάνετε αναζήτηση με βάση την πεζότητα στο Excel.

Αναζήτηση μερικής αντιστοίχισης συμβολοσειράς

Η αναζήτηση με μερική αντιστοίχιση είναι μία από τις πιο δύσκολες εργασίες στο Excel για την οποία δεν υπάρχει καθολική λύση. Το ποιος τύπος θα χρησιμοποιηθεί εξαρτάται από το είδος των διαφορών που υπάρχουν μεταξύ των τιμών αναζήτησης και των τιμών της στήλης που θέλετε να αναζητήσετε. Στις περισσότερες περιπτώσεις, θα χρησιμοποιήσετε τη συνάρτηση LEFT, RIGHT ή MID για να εξάγετε το κοινό μέρος των τιμών και στη συνέχεια να παρέχετε αυτό το μέρος στη συνάρτηση lookup_value όρισμα της συνάρτησης Vlookup, όπως γίνεται στον ακόλουθο τύπο:

=VLOOKUP(RIGHT(D2,4), $A$2:$B$6, 2, FALSE)

Όπου D2 είναι η τιμή αναζήτησης, A2:B6 είναι ο πίνακας αναζήτησης και 2 είναι ο αριθμός δείκτη της στήλης από την οποία θα επιστραφούν οι αντιστοιχίες.

Για άλλους τρόπους εκτέλεσης μιας μερικής αναζήτησης στο Excel, ανατρέξτε στην ενότητα Πώς να συγχωνεύσετε δύο φύλλα εργασίας με μερική αντιστοίχιση.

Με αυτόν τον τρόπο χρησιμοποιείτε τις συναρτήσεις Lookup στο Excel. Για να ρίξετε μια πιο προσεκτική ματιά στους τύπους που συζητούνται σε αυτό το σεμινάριο, μπορείτε να κατεβάσετε τα παραδείγματα τύπων Lookup του Excel.

Τρόπος αναζήτησης χωρίς τύπους στο Excel

Είναι αυτονόητο ότι η αναζήτηση στο Excel δεν είναι μια ασήμαντη εργασία. Αν κάνετε τα πρώτα σας βήματα στην εκμάθηση του βασιλείου του Excel, οι τύποι αναζήτησης μπορεί να φαίνονται αρκετά συγκεχυμένοι και δύσκολοι στην κατανόηση. Αλλά σας παρακαλώ, μην αποθαρρύνεστε, αυτές οι δεξιότητες δεν έρχονται φυσικά στην πλειονότητα των χρηστών!

Για να διευκολύνουμε τους αρχάριους, δημιουργήσαμε ένα ειδικό εργαλείο, το Merge Tables Wizard, το οποίο μπορεί να αναζητήσει, να αντιστοιχίσει και να συγχωνεύσει πίνακες χωρίς ούτε έναν τύπο. Επιπλέον, παρέχει μια σειρά από πραγματικά μοναδικές επιλογές από τις οποίες μπορούν να επωφεληθούν ακόμη και προχωρημένοι χρήστες του Excel:

• Αναζήτηση κατά πολλαπλά κριτήρια , δηλαδή να χρησιμοποιείτε μία ή περισσότερες στήλες ως μοναδικό αναγνωριστικό(-ά).
• Ενημέρωση τιμές σε υπάρχουσες στήλες και προσθέστε νέα στήλες από τον πίνακα αναζήτησης.
• Επιστροφή πολλαπλοί αγώνες Όταν χρησιμοποιείται σε συνδυασμό με τον Οδηγό συνδυασμού σειρών, μπορεί ακόμη και να επιστρέψει πολλαπλά αποτελέσματα σε ένα μόνο κελί, διαχωρισμένα με κόμμα ή με άλλο τρόπο (ένα παράδειγμα μπορείτε να βρείτε εδώ).
• Και άλλα.

Η εργασία με τον Οδηγό Συγχώνευσης Πινάκων είναι εύκολη και διαισθητική. Το μόνο που έχετε να κάνετε είναι:

1. Επιλέξτε τον κύριο πίνακα από τον οποίο θέλετε να αντλήσετε τις αντίστοιχες τιμές.
2. Επιλέξτε τον πίνακα αναζήτησης από τον οποίο θα αντλήσετε τις αντιστοιχίες.
3. Ορίστε μία ή περισσότερες κοινές στήλες.
4. Επιλέξτε τις στήλες που θα ενημερωθούν ή/και θα προστεθούν στο τέλος του πίνακα.
5. Προαιρετικά, επιλέξτε μία ή περισσότερες πρόσθετες επιλογές συγχώνευσης.
6. Κάντε κλικ στο Τέλος και θα έχετε αποτέλεσμα σε λίγο!

Αν είστε περίεργοι να δοκιμάσετε το πρόσθετο στα δικά σας φύλλα εργασίας, μπορείτε να κατεβάσετε μια δοκιμαστική έκδοση της Ultimate Suite που περιλαμβάνει όλα τα εργαλεία εξοικονόμησης χρόνου για το Excel (συνολικά 70+ εργαλεία και 300+ λειτουργίες!).

Διαθέσιμες λήψεις

Παραδείγματα τύπων αναζήτησης του Excel (.xlsx αρχείο)

Ultimate Suite 14 ημερών πλήρως λειτουργική έκδοση (.exe αρχείο)