يشرح البرنامج التعليمي أساسيات البحث في Excel ، ويوضح نقاط القوة والضعف لكل دالة Excel Lookup ويقدم عددًا من الأمثلة لمساعدتك في تحديد صيغة البحث الأفضل لاستخدامها في موقف معين.

يعد البحث عن قيمة محددة ضمن مجموعة بيانات أحد أكثر المهام شيوعًا في Excel. ومع ذلك ، لا توجد صيغة بحث "عالمية" مناسبة لجميع المواقف. هناك سبب هو أن مصطلح "بحث" قد يشير إلى مجموعة متنوعة من الأشياء المختلفة: يمكنك البحث عموديًا في عمود ، أو أفقيًا في صف أو عند تقاطع صف وعمود ، والبحث بمعيار واحد أو عدة معايير ، وإرجاع أول ما تم العثور عليه تطابق أو تطابقات متعددة ، قم بإجراء بحث حساس لحالة الأحرف أو غير حساس لحالة الأحرف ، وما إلى ذلك.

في هذه الصفحة ، ستجد قائمة بأهم وظائف Excel Lookup مع أمثلة للصيغ وبرامج تعليمية متعمقة مرتبط للرجوع إليه.

Excel Lookup - الأساسيات

قبل أن نتعمق في التقلبات الغامضة لصيغ Excel Lookup ، دعنا نحدد المصطلحات الأساسية للتأكد من أننا دائمًا على نفس الصفحة.

بحث - البحث عن قيمة محددة في جدول البيانات.

قيمة البحث - قيمة للبحث لـ.

إرجاع القيمة (مطابقة القيمة أو المطابقة) - قيمة في نفس الموضع مثل قيمة البحث ولكن في عمود أو صف آخر (بناءً على ما إذا كنت تفعل ذلك عموديًا أم أفقيًافي Excel.

البحث ثلاثي الأبعاد

البحث ثلاثي الأبعاد يعني البحث بثلاث قيم بحث مختلفة. في مجموعة البيانات أدناه ، لنفترض أنك تريد البحث عن سنة معينة (H2) ، ثم عن اسم محدد ضمن بيانات تلك السنة (H3) ، ثم إرجاع قيمة لشهر معين (H4).

يمكن إنجاز المهمة باستخدام صيغة الصفيف التالية (يرجى تذكر الضغط على Ctrl + Shift + Enter لإكمالها بشكل صحيح):

=INDEX($A$1:$E$12,MIN(IF((ROW($A$1:$A$12)>MATCH(H2,$A$1:$A$12,0))*($A$1:$A$12=H3),ROW($A$1:$A$12),"")),MATCH(H4,$A$1:$E$1,0))

بحث بمعايير متعددة

لكي نتمكن من تقييم معايير متعددة ، سنحتاج إلى تعديل صيغة مطابقة الفهرس الكلاسيكية بحيث تتحول إلى صيغة صفيف:

INDEX ( lookup_table، MATCH (1، ( lookup_value1= lookup_column1) * ( lookup_value2= lookup_column2) *…، 0)، return_column_number)

مع وجود جدول البحث في A1: C11 ، دعنا نعثر على تطابق بمعيارين: البحث في العمود A عن قيمة في الخلية F1 ، والعمود B عن قيمة في الخلية F2:

=INDEX($A$1:$C$11, MATCH(1, (F1=$A$1:$A$11) * (F2=$B$1:$B$11),0), 3)

كالعادة ، تضغط على Ctrl + Shift + Enter ليتم تقييم الصيغة كصيغة صفيف.

للحصول على شرح مفصل لـ منطق mula ، يرجى الاطلاع على INDEX MATCH للبحث بمعايير متعددة.

ابحث لإرجاع قيم متعددة

أيًا كانت وظيفة Excel Lookup التي تستخدمها (LOOKUP أو VLOOKUP أو HLOOKUP) ، يمكن إرجاعها فقط مباراة واحدة. للحصول على جميع المطابقات التي تم العثور عليها ، يجب عليك استخدام 6دالات مختلفة مدمجة في صيغة مصفوفة:

IFERROR (INDEX ( return_range، SMALL (IF ( lookup_value= lookup_range، ROW ( return_range) - m، "")، ROW () - n))، "")

المكان:

• m هو رقم صف الخلية الأولى في نطاق الإرجاع ناقص 1.
• n هو رقم صف خلية الصيغة الأولى مطروحًا منه 1.

مع وجود قيمة البحث الموجودة في الخلية E2 ، ونطاق البحث في A2: A11 ، ونطاق الإرجاع في B2: B11 ، وأول خلية معادلة في الصف 2 ، تأخذ صيغة البحث الشكل التالي:

=IFERROR(INDEX($B$2:$B$11, SMALL(IF($E$2 =$A$2:$A$11, ROW($B$2:$B$11 )- 1,""), ROW() - 1 )),"")

لكي ترجع الصيغة العديد من التطابقات ، أدخلها في الخلية الأولى (F2) ، واضغط على Ctrl + Shift + Enter ، ثم انسخ الصيغة إلى خلايا أخرى أسفل العمود.

للحصول على شرح مفصل للصيغة أعلاه والطرق الأخرى لإرجاع قيم متعددة ، يرجى الاطلاع على كيفية Vlookup لإرجاع نتائج متعددة.

بحث متداخل (من جدولي بحث)

في المواقف التي يكون فيها الجدول الرئيسي وجدول البحث من wh التي تريد سحب البيانات ليس لها عمود مشترك ، يمكنك استخدام جدول بحث إضافي لإنشاء مطابقات ، مثل هذا:

لاسترداد القيم من العمود في Lookup_table2 ، يمكنك استخدام الصيغة التالية:

=VLOOKUP(VLOOKUP(A2, Lookup_table1!$A$1:$B$6, 2, FALSE), Lookup_table2!$A$1:$B$6, 2, FALSE)

كما هو موضح في لقطة الشاشة أدناه ، تعمل صيغة البحث المتداخلة لدينا بشكل مثالي:

عمليات البحث المتسلسلة من عدة مراتأوراق

لإجراء عمليات بحث متسلسلة استنادًا إلى نجاح البحث السابق أو فشله ، استخدم وظائف IFERROR المتداخلة مع VLOOKUPs لتقييم شروط متعددة واحدًا تلو الآخر:

IFERROR (VLOOKUP ( …) ، IFERROR (VLOOKUP ( …) ، IFERROR (VLOOKUP ( …) ، "غير موجود")))

إذا فشل VLOOKUP الأول ، فإن IFERROR يعوض الخطأ ويعمل Vlookup آخر. إذا لم يعثر Vlookup الثاني على أي شيء أيضًا ، فإن IFERROR الثاني يكتشف الخطأ ويقوم بتشغيل Vlookup الثالث ، وهكذا. إذا فشلت جميع Vlookups ، فإن آخر IFERROR يُرجع "غير موجود" أو أي رسالة أخرى تقدمها إلى الصيغة.

كمثال ، دعنا نحاول سحب المبلغ من 3 أوراق مختلفة:

=IFERROR(VLOOKUP(B1,A6:B9,2,0), IFERROR(VLOOKUP(B1,D6:E9,2,0), IFERROR(VLOOKUP(B1,G6:H9,2,0), "Not found")))

ستبدو النتيجة مشابهة لما يلي:

لمزيد من المعلومات ، يرجى الاطلاع على كيفية استخدام وظائف IFERROR المتداخلة في Excel.

بحث حساس لحالة الأحرف

كما تعلم على الأرجح ، جميع وظائف Excel Lookup حساسة لحالة الأحرف بطبيعتها. لفرض صيغة البحث على التمييز بين الأحرف الصغيرة والنص الكبير ، استخدم إما LOOKUP أو INDEX MATCH مع الدالة EXACT. أنا شخصياً أختار INDEX MATCH لأنه لا يتطلب قيم الفرز في عمود البحث كما تفعل وظيفة LOOKUP ، ويمكنه إجراء عمليات البحث من اليسار إلى اليمين ومن اليمين إلى اليسار ، ويعمل بشكل مثالي لجميع أنواع البيانات.

INDEX ( return_column، MATCH (TRUE ،EXACT ( lookup_column، lookup_value)، 0))

مع كون G2 هي قيمة البحث ، العمود A للبحث عنه والعمود E لإرجاع التطابقات من ، تظهر صيغة البحث الحساسة لحالة الأحرف كما يلي:

=INDEX($E$2:$E$6, MATCH(TRUE, EXACT($A$2:$A$6,G2),0))

نظرًا لأنها صيغة صفيف ، تأكد من الضغط على Ctrl + Shift + Enter لإكمالها بشكل صحيح.

لمزيد من أمثلة الصيغ ، يرجى الاطلاع على كيفية إجراء بحث حساس لحالة الأحرف في Excel.

البحث عن مطابقة جزئية للسلسلة

البحث عن طريق جزئي المطابقة هي واحدة من أصعب المهام في Excel والتي لا يوجد لها حل عالمي. تعتمد الصيغة التي يجب استخدامها على نوع الاختلافات الموجودة بين قيم البحث والقيم في العمود للبحث فيها. في معظم الحالات ، يمكنك استخدام الدالة LEFT أو RIGHT أو MID لاستخراج الجزء المشترك من القيم ، و ثم قم بتزويد هذا الجزء إلى الوسيطة lookup_value الخاصة بوظيفة Vlookup كما هو الحال في الصيغة التالية:

=VLOOKUP(RIGHT(D2,4), $A$2:$B$6, 2, FALSE)

حيث D2 هي قيمة البحث ، A2: B6 هي جدول البحث و 2 في رقم الفهرس للعمود لإرجاع المطابقات منه.

للحصول على طرق أخرى لإجراء بحث عن تطابق جزئي في Excel ، يرجى الاطلاع على كيفية الدمج ورقتي عمل بالمطابقة الجزئية.

هذه هي الطريقة التي تستخدم بها وظائف البحث في Excel. لإلقاء نظرة فاحصة على الصيغ التي تمت مناقشتها في هذا البرنامج التعليمي ، فنحن نرحب بك لتنزيل صيغة Excel Lookup الخاصة بناأمثلة.

طريقة خالية من الصيغة لإجراء بحث في Excel

وغني عن القول أن بحث Excel ليس مهمة تافهة. إذا كنت تتخذ خطواتك الأولى في تعلم مجال Excel ، فقد تبدو صيغ البحث مربكة للغاية ويصعب فهمها. لكن من فضلك ، لا تشعر بالإحباط ، فهذه المهارات لا تأتي بشكل طبيعي لغالبية المستخدمين!

لتسهيل الأمور على المبتدئين ، أنشأنا أداة خاصة ، معالج دمج الجداول ، يمكنها البحث والمطابقة ودمج الجداول بدون صيغة واحدة. بالإضافة إلى ذلك ، فإنه يوفر عددًا من الخيارات الفريدة حقًا التي يمكن لمستخدمي Excel المتقدمين الاستفادة منها:

• ابحث عن طريق معايير متعددة ، أي استخدم عمودًا واحدًا أو عدة أعمدة كمعرف فريد (s).
• تحديث قيم في الأعمدة الموجودة و إضافة أعمدة جديدة من جدول البحث.
• إرجاع مباريات متعددة في صفوف منفصلة. عند استخدامه مع معالج الجمع بين الصفوف ، يمكنه حتى إرجاع نتائج متعددة في خلية واحدة أو فاصلة أو مفصولة بطريقة أخرى (يمكن العثور على مثال هنا).
• والمزيد.

يعد العمل باستخدام معالج جداول الدمج أمرًا سهلاً وبديهيًا. كل ما عليك فعله هو:

1. حدد الجدول الرئيسي الخاص بك حيث تريد سحب القيم المطابقة.
2. حدد جدول البحث لسحب التطابقات منه.
3. حدد عمودًا مشتركًا واحدًا أو أكثر.
4. اختر الأعمدة المراد تحديثها أو / وإضافتها إلى نهايةالجدول.
5. اختياريًا ، حدد خيارًا واحدًا أو أكثر من خيارات الدمج الإضافية.
6. انقر فوق إنهاء وستحصل على نتيجة بعد قليل!

إذا كنت مهتمًا بتجربة الوظيفة الإضافية في أوراق العمل الخاصة بك ، فنحن نرحب بك لتنزيل إصدار تجريبي من Ultimate Suite الذي يتضمن جميع أدوات توفير الوقت لبرنامج Excel (في إجمالي ، أكثر من 70 أداة و 300+ ميزات!).

التنزيلات المتاحة

أمثلة صيغة بحث Excel (ملف .xlsx)

Ultimate Suite إصدار كامل الوظائف لمدة 14 يومًا (ملف exe.)

بحث).

جدول البحث . في علوم الكمبيوتر ، يعد جدول البحث مصفوفة من البيانات ، تُستخدم عمومًا لتعيين قيم الإدخال إلى قيم الإخراج. فيما يتعلق بهذا البرنامج التعليمي ، فإن جدول بحث Excel ليس سوى نطاق من الخلايا حيث تبحث عن قيمة بحث.

الجدول الرئيسي (الجدول الرئيسي) - الجدول الذي تريد سحب قيم المطابقة.

قد يكون لجدول البحث والجدول الرئيسي بنية وحجم مختلفين ، ومع ذلك يجب أن يشتملوا دائمًا على معرّف فريد واحد على الأقل ، أي عمود أو صف يحتوي على بيانات متطابقة ، بناءً على ما إذا كنت تريد إجراء بحث عمودي أو أفقي.

تُظهر لقطة الشاشة التالية نموذجًا لجدول البحث الذي سيتم استخدامه في العديد من الأمثلة أدناه.

وظائف بحث Excel

فيما يلي نظرة عامة سريعة على الصيغ الأكثر شيوعًا لإجراء البحث في Excel ، ومزاياها وعيوبها الرئيسية.

وظيفة LOOKUP

يمكن لوظيفة LOOKUP في Excel إجراء أبسط أنواع عمليات البحث الرأسية والأفقية. وظيفة ، لا يمكن العمل مع البيانات التي لم يتم فرزها (يتطلب فرز ر هو بحث في العمود / الصف بترتيب تصاعدي).

لمزيد من المعلومات ، يرجى الاطلاع على كيفية استخدام وظيفة Excel LOOKUP.

وظيفة VLOOKUP

إنها نسخة محسنة من LOOKUP وظيفة مصممة خصيصًا لإجراء بحث عمودي في

الايجابيات : سهل الاستخدام نسبيًا ، يمكن أن يعمل بمطابقة تامة وتقريبية.

سلبيات : لا يمكن النظر إلى يساره ، يتوقف العمل عند إدراج عمود في جدول البحث أو إزالته منه ، لا يمكن أن تتجاوز قيمة البحث 255 حرفًا ، وتتطلب قدرًا كبيرًا من قوة المعالجة على مجموعات البيانات الكبيرة.

لمزيد من المعلومات ، يرجى الاطلاع على برنامج Excel VLOOKUP التعليمي للمبتدئين.

دالة HLOOKUP

إنها نظير أفقي لـ VLOOKUP يبحث عن قيمة في الصف الأول من جدول البحث ويعيد القيمة في نفس الموضع من صف آخر.

الايجابيات : سهل الاستخدام ، يمكنه إرجاع التطابقات الدقيقة والتقريبية.

سلبيات : يمكن البحث فقط في الصف العلوي من جدول البحث ، ويتأثر بالإدراج أو حذف الصفوف ، يجب أن تكون قيمة البحث أقل من 255 حرفًا.

لمزيد من المعلومات ، يرجى الاطلاع على كيفية استخدام HLOOKUP في Excel.

VLOOKUP MATCH / HLOOKUP MATCH

A عمود ديناميكي أو مرجع صف تم إنشاؤه بواسطة MATCH يجعل هذا Excel صغيرًا صيغة okup محصنة ضد التغييرات التي تم إجراؤها في مجموعة البيانات. بمعنى آخر ، مع بعض المساعدة من MATCH ، يمكن أن تُرجع الدالتان VLOOKUP و HLOOKUP القيم الصحيحة بغض النظر عن عدد الأعمدة / الصفوف التي تم إدراجها أو حذفها من جدول بحث.

صيغة البحث العمودي

VLOOKUP ( lookup_value، lookup_table، MATCH ( return_column_name، column_headers، 0)، FALSE)

صيغة البحث الأفقي

HLOOKUP ( lookup_value، lookup_table، MATCH ( return_row_name، row_headers، 0)، FALSE)

الايجابيات : تحسين على صيغ Hlookup و Vlookup العادية المحصنة ضد إدخال البيانات أو حذفها.

السلبيات : غير مرن للغاية ، يتطلب بنية بيانات محددة (يجب أن تكون قيمة البحث المقدمة إلى دالة MATCH مساوية تمامًا لاسم عمود الإرجاع) ، ولا يمكن العمل مع قيم البحث التي تتجاوز 255 حرفًا.

لمزيد من المعلومات وأمثلة على الصيغ ، يرجى الاطلاع على:

• Excel Vlookup and Match
• Excel Hlookup and Match

OFFSET MATCH

أكثر تعقيدًا ولكن أكثر قوة صيغة البحث ، خالية من العديد من قيود Vlookup و Hlookup.

صيغة V-Lookup

OFFSET ( lookup_table، MATCH ( lookup_value، OFFSET ( lookup_table، 0، n، ROWS ( lookup_table)، 1)، 0) -1، m، 1، 1)

حيث:

• n - هو إزاحة عمود البحث ، i. ه. عدد الأعمدة المراد نقلها من نقطة البداية إلى عمود البحث.
• m - هو إزاحة عمود الإرجاع ، i. ه. عدد الأعمدة المراد نقلها من نقطة البداية إلى عمود العودة.

صيغة H-Lookup

OFFSET ( lookup_table، m، MATCH ( lookup_value، OFFSET ( lookup_table، n، 0، 1، COLUMNS ( lookup_table))، 0) -1، 1، 1)

المكان:

• n - هو إزاحة صف البحث ، i. ه. عدد الصفوف المراد نقلها من نقطة البداية إلى صف البحث.
• m - هو إزاحة صف العودة ، i. ه. عدد الصفوف المراد نقلها من نقطة البداية إلى صف العودة.

صيغة بحث المصفوفة (حسب الصف والعمود)

{= OFFSET ( نقطة البداية، MATCH ( vertical_lookup_value، lookup_column، 0)، MATCH ( orizontal_lookup_value، lookup_row، 0))}

يرجى الانتباه إلى أن هذه صيغة مصفوفة يتم إدخالها بالضغط على Ctrl + Shift + Enter مفاتيح في نفس الوقت.

الايجابيات : يسمح بإجراء Vlookup على الجانب الأيسر ، و Hlookup العلوي ، والبحث ثنائي الاتجاه (حسب قيم العمود والصف) ، غير متأثر بالتغييرات في البيانات مجموعة.

Cons : بناء الجملة معقد ويصعب تذكره.

لمزيد من المعلومات وأمثلة الصيغ ، يرجى الاطلاع على: استخدام دالة OFFSET في Excel

INDEX MATCH

إنها أفضل طريقة لإجراء بحث رأسي أو أفقي في Excel يمكن أن تحل محل معظم الصيغ المذكورة أعلاه. صيغة مطابقة الفهرس هي مفضلاتي الشخصية وأنا أستخدمها في جميع عمليات بحث Excel الخاصة بي تقريبًا.

معادلة V-Lookup

INDEX ( return_column، MATCH ( lookup_value، lookup_column، 0))

Formula for H-Lookup

INDEX ( return_row، MATCH ( lookup_value، lookup_row، 0))

صيغة بحث المصفوفة

Anامتداد صيغة مطابقة الفهرس الكلاسيكية لإرجاع قيمة عند تقاطع عمود وصف معين:

INDEX ( lookup_table، MATCH ( vertical_lookup_value، lookup_column، 0)، MATCH ( orizontal_lookup_value، lookup_row، 0))

Cons : واحد فقط - عليك أن تتذكر بناء جملة الصيغة.

0 14>

يسمح بتمديد أو طي جدول البحث بأمان عن طريق إدراج أو حذف الأعمدة والصفوف.

لا يوجد حد لحجم قيمة البحث.

يعمل بشكل أسرع. نظرًا لأن صيغة مطابقة الفهرس تشير إلى الأعمدة / الصفوف بدلاً من الجدول بأكمله ، فإنها تتطلب طاقة معالجة أقل ولن تؤدي إلى إبطاء Excel.

لمزيد من المعلومات ، يرجى مراجعة:

• INDEX MATCH كبديل أفضل لـ VLOOKUP
• صيغة INDEX MATCH للبحث ثنائي الأبعاد

جدول مقارنة بحث Excel

كما ترى ، ليست كل صيغ Excel Lookup متكافئة ، فبعضها يمكنه التعامل مع عدد من عمليات البحث المختلفة بينما لا يمكن استخدام البعض الآخر إلا في موقف معين. يوضح الجدول أدناه إمكانيات كل صيغة بحث في Excel.

الصيغة	البحث العمودي	البحث الأيسر	البحث الأفقي	البحث العلوي	المصفوفةبحث	يسمح بإدخال / حذف البيانات
بحث	✓		✓
Vlookup	✓
Hlookup			✓
Vlookup Match	✓					✓
Hlookup Match			✓			✓
تطابق الإزاحة	✓	✓	✓	✓		✓
تطابق الإزاحة					✓	✓
تطابق الفهرس	✓	✓	✓	✓		✓
مطابقة الفهرس					✓	✓

أمثلة صيغة بحث Excel

الخطوة الأولى في تحديد الصيغة التي يجب استخدامها في موقف معين هي تحديد نوع البحث الذي تريد إجراؤه. ستجد أدناه أمثلة للصيغ لأنواع البحث الأكثر شيوعًا:

البحث العمودي في الأعمدة

البحث العمودي أو Vlookup هو عملية البحث عن قيمة بحث في عمود واحد وإرجاع قيمة في نفس الصف من عمود آخر. يمكن إجراء Vlookup في Excel بعدة طرق ، بما في ذلك:

وظيفة VLOOKUP

إذا كانت قيم البحث موجودة في العمود الأيسر من الجدول ، ولم تكن تخطط للقيام بأي منها التغييرات الهيكلية لمجموعة البيانات الخاصة بك (لا تقم بإضافة أعمدة أو حذفها) ، يمكنك استخدام صيغة Vlookup العادية بأمان:

=VLOOKUP(G2, $A$2:$E$6, 5, FALSE)

حيث G2 هي قيمة البحث ، A2: E6 في جدول البحث ، و E هي عمود الإرجاع.

VLOOKUP MATCH

إذا كنت تعمل باستخدام جدول بحث Excel "متغير" حيث يمكن إدراج الأعمدة وحذفها في أي وقت ، اجعل صيغة Vlookup محصنة ضد تلك التغييرات من خلال تضمين دالة Match التي تنشئ مرجع عمود ديناميكيًا بدلاً من رقم فهرس "مضمّن":

=VLOOKUP(F2,$A$1:$D$6, MATCH($G$1,$A$1:$D$1, 0), FALSE)

INDEX MATCH - البحث الأيسر

إنها صيغتي المفضلة التي تتعامل مع عمليات البحث من اليمين إلى اليسار بسهولة وتعمل بشكل لا تشوبه شائبة بغض النظر عن عدد الأعمدة التي تضيفها أو تحذفها.

على سبيل المثال ، للبحث في العمود B للقيمة في H2 وإرجاع تطابق من العمود F ، استخدم هذه الصيغة:

=INDEX($F$2:$F$6,(MATCH(H2,$B$2:$B$6,0)))

ملاحظة. عندما تخطط لاستخدام صيغة Vlookup في أكثر من خلية واحدة ، يجب عليك دائمًا قفل مرجع جدول البحث باستخدام علامة $ (مرجع الخلية المطلق) ، بحيث يتم نسخ الصيغة بشكل صحيح إلى الخلايا الأخرى.

البحث الأفقي في الصفوف

البحث الأفقي هو نسخة "منقولة" من البحث العمودي الذي يبحث في مجموعة بيانات مرتبة أفقيًا. بمعنى آخر ، يبحث عن قيمة البحث في صف واحد ، ويعيد قيمة في نفس الموضع من صف آخر.

بافتراض أن قيمة البحث في B9 ، وجدول البحث هو B1: F5 ، وإذا كنت تريد إرجاع قيمة مطابقة من الصف 5 ، فاستخدم إحدى الصيغ التالية:

وظيفة HLOOKUP

يمكن البحث فقط عبر الصف العلوي في مجموعة البيانات الخاصة بك .

=HLOOKUP(B8, $B$1:$F$5, 5, FALSE)

HLOOKUP MATCH

مثل Hlookup الخالص ، يمكن لهذه الصيغة البحث فقط في الصف العلوي ، ولكنها تتيح لك إدراج أو حذف الصفوف بأمان في جدول البحث.

=HLOOKUP(B8, $B$1:$F$5, MATCH($A$9, $A$1:$A$5, 0), FALSE)

حيث A1: A5 هي رؤوس الصفوف و A9 هو اسم الصف الذي تريد إرجاع التطابقات منه .

INDEX MATCH

يمكن البحث في أي صف ، وليس لديه أي من قيود الصيغ أعلاه.

=INDEX($B$5:$F$5,(MATCH(B8,$B$1:$F$1,0)))

بحث ثنائي الأبعاد (استنادًا إلى قيم الصفوف والأعمدة)

بحث ثنائي الأبعاد (المعروف أيضًا باسم بحث المصفوفة ، بحث مزدوج أو بحث ثنائي الاتجاه ) إرجاع قيمة تستند إلى التطابقات في كل من الصفوف والأعمدة. بمعنى آخر ، تبحث صيغة البحث ثنائية الأبعاد عن قيمة عند تقاطع صف وعمود محددين.

بافتراض أن جدول البحث الخاص بك هو A1: E6 ، تحتوي الخلية H2 على القيمة المراد مطابقتها في الصفوف و H3 تحتوي على القيمة لتتناسب مع الأعمدة ، وستعمل الصيغ التالية على علاج:

صيغة INDEX MATCH MATCH :

=INDEX($A$1:$E$6, MATCH(H2,$A$1:$A$6,0), MATCH(H3,$A$1:$E$1,0))

صيغة OFFSET MATCH MATCH :

=OFFSET($A$1,MATCH(H2,$A$2:$A$6,0),MATCH(H3,$B$1:$E$1,0))

بصرف النظر عن الصيغ أعلاه ، هناك عدد قليل من الطرق الأخرى لإجراء بحث المصفوفة في Excel ، ويمكنك العثور على التفاصيل الكاملة في كيفية إجراء بحث ثنائي الاتجاه