Mục lục
Hướng dẫn giải thích kiến thức cơ bản về Tra cứu trong Excel, chỉ ra điểm mạnh và điểm yếu của từng hàm Tra cứu trong Excel và cung cấp một số ví dụ để giúp bạn quyết định sử dụng công thức tra cứu nào là tốt nhất trong một tình huống cụ thể.
Tra cứu một giá trị cụ thể trong tập dữ liệu là một trong những nhiệm vụ phổ biến nhất trong Excel. Chưa hết, không tồn tại một công thức tra cứu “vạn năng” nào phù hợp với mọi trường hợp. Có lý do là thuật ngữ "tra cứu" có thể biểu thị nhiều thứ khác nhau: bạn có thể tìm kiếm theo chiều dọc trong một cột, theo chiều ngang trong một hàng hoặc tại giao điểm của một hàng và cột, tìm kiếm với một hoặc một số tiêu chí, trả về kết quả tìm thấy đầu tiên khớp hoặc nhiều khớp, thực hiện tra cứu phân biệt chữ hoa chữ thường hoặc không phân biệt chữ hoa chữ thường, v.v.
Trên trang này, bạn sẽ tìm thấy danh sách các hàm Tra cứu Excel cần thiết nhất với các ví dụ về công thức và hướng dẫn chuyên sâu được liên kết để bạn tham khảo.
Tra cứu Excel - kiến thức cơ bản
Trước khi chúng ta đi sâu vào các vòng xoắn phức tạp của các công thức Tra cứu Excel, hãy xác định các thuật ngữ chính để đảm bảo rằng chúng ta luôn ở trên cùng một trang.
Tra cứu - tìm kiếm một giá trị cụ thể trong bảng dữ liệu.
Giá trị tra cứu - một giá trị để tìm kiếm for.
Giá trị trả về (giá trị khớp hoặc khớp) - một giá trị ở cùng vị trí với giá trị tra cứu nhưng ở cột hoặc hàng khác (tùy thuộc vào việc bạn thực hiện dọc hay ngangtrong Excel.
Tra cứu ba chiều
Tra cứu ba chiều có nghĩa là tìm kiếm theo 3 giá trị tra cứu khác nhau. Trong tập dữ liệu bên dưới, giả sử bạn muốn tìm kiếm một năm cụ thể (H2), sau đó tìm tên cụ thể trong dữ liệu năm đó (H3), sau đó trả về giá trị cho một tháng cụ thể (H4).
Nhiệm vụ có thể được hoàn thành với công thức mảng sau (hãy nhớ nhấn Ctrl + Shift + Enter để hoàn thành chính xác):
=INDEX($A$1:$E$12,MIN(IF((ROW($A$1:$A$12)>MATCH(H2,$A$1:$A$12,0))*($A$1:$A$12=H3),ROW($A$1:$A$12),"")),MATCH(H4,$A$1:$E$1,0))
Tra cứu với nhiều tiêu chí
Để có thể đánh giá nhiều tiêu chí, chúng ta sẽ cần sửa đổi công thức Khớp chỉ mục cổ điển để nó biến thành một công thức mảng:
INDEX( lookup_table, MATCH (1, ( lookup_value1= lookup_column1) * ( lookup_value2= lookup_column2)*…, 0), return_column_number)Với bảng tra cứu nằm trong A1:C11, hãy tìm kết quả khớp theo 2 tiêu chí: tìm kiếm cột A cho một giá trị trong ô F1 và cột B cho một giá trị trong ô F2:
=INDEX($A$1:$C$11, MATCH(1, (F1=$A$1:$A$11) * (F2=$B$1:$B$11),0), 3)
Như thường lệ, bạn nhấn Ctrl + Shift + Enter để công thức được đánh giá dưới dạng công thức mảng.
Để biết giải thích chi tiết về logic của mula, vui lòng xem INDEX MATCH để tra cứu với nhiều tiêu chí.
Tra cứu để trả về nhiều giá trị
Cho dù bạn sử dụng hàm Tra cứu Excel nào (LOOKUP, VLOOKUP hoặc HLOOKUP), hàm đó chỉ có thể trả về một trận đấu duy nhất. Để có được tất cả các trận đấu được tìm thấy, bạn sẽ phải sử dụng 6các hàm khác nhau được kết hợp trong một công thức mảng:
IFERROR(INDEX( return_range, SMALL(IF( lookup_value= lookup_range, ROW( return_range)- m, ""), ROW() - n)),"")Ở đâu:
- m là số hàng của ô đầu tiên trong phạm vi trả về trừ đi 1.
- n là số hàng của ô chứa công thức đầu tiên trừ đi 1.
Với giá trị tra cứu nằm trong ô E2, phạm vi tra cứu trong A2:A11, phạm vi trả về trong B2:B11 và ô công thức đầu tiên trong hàng 2, công thức tra cứu của bạn có dạng sau:
=IFERROR(INDEX($B$2:$B$11, SMALL(IF($E$2 =$A$2:$A$11, ROW($B$2:$B$11 )- 1,""), ROW() - 1 )),"")
Để công thức trả về nhiều giá trị khớp, bạn nhập công thức đó vào ô đầu tiên (F2), nhấn Ctrl + Shift + Enter , sau đó sao chép công thức sang các ô khác trong cột.
Để biết giải thích chi tiết về công thức trên và các cách khác để trả về nhiều giá trị, vui lòng xem Cách Vlookup trả về nhiều kết quả.
Tra cứu lồng nhau (từ 2 bảng tra cứu)
Trong các tình huống khi bảng chính của bạn và bảng tra cứu từ wh Nếu bạn muốn lấy dữ liệu không có cột chung, bạn có thể sử dụng bảng tra cứu bổ sung để thiết lập kết quả khớp, như sau:
Để truy xuất giá trị từ Số tiền trong Lookup_table2 , bạn sử dụng công thức sau:
=VLOOKUP(VLOOKUP(A2, Lookup_table1!$A$1:$B$6, 2, FALSE), Lookup_table2!$A$1:$B$6, 2, FALSE)
Như minh họa trong ảnh chụp màn hình bên dưới, công thức tra cứu lồng nhau của chúng tôi hoạt động hoàn hảo:
Vlookup tuần tự từ nhiềusheet
Để thực hiện các Vlookup tuần tự dựa trên việc tra cứu trước đó thành công hay thất bại, hãy sử dụng các hàm IFERROR lồng nhau cùng với các VLOOKUP để đánh giá từng điều kiện một:
IFERROR(VLOOKUP( …), IFERROR(VLOOKUP( …), IFERROR(VLOOKUP( …),"Không tìm thấy")))Nếu Vlookup đầu tiên không thành công, IFERROR sẽ bẫy lỗi và chạy một Vlookup khác. Nếu Vlookup thứ hai cũng không tìm thấy gì, IFERROR thứ hai sẽ bắt lỗi và chạy Vlookup thứ ba, v.v. Nếu tất cả các Vlookup không thành công, IFERROR cuối cùng sẽ trả về "không tìm thấy" hoặc bất kỳ thông báo nào khác mà bạn cung cấp cho công thức.
Ví dụ: hãy thử lấy số tiền từ 3 trang tính khác nhau:
=IFERROR(VLOOKUP(B1,A6:B9,2,0), IFERROR(VLOOKUP(B1,D6:E9,2,0), IFERROR(VLOOKUP(B1,G6:H9,2,0), "Not found")))
Kết quả sẽ giống như sau:
Để biết thêm thông tin, vui lòng xem Cách sử dụng các hàm IFERROR lồng nhau trong Excel.
Tra cứu phân biệt chữ hoa chữ thường
Như bạn có thể biết, về bản chất, tất cả các hàm Tra cứu trong Excel đều không phân biệt chữ hoa chữ thường. Để buộc công thức tra cứu của bạn phân biệt giữa chữ thường và chữ hoa, hãy sử dụng LOOKUP hoặc INDEX MATCH kết hợp với hàm EXACT. Cá nhân tôi chọn INDEX MATCH vì nó không yêu cầu sắp xếp các giá trị trong cột tra cứu như hàm LOOKUP, có thể thực hiện cả tra cứu từ trái sang phải và từ phải sang trái và hoạt động hoàn hảo cho mọi loại dữ liệu.
INDEX( return_column, MATCH(TRUE,EXACT( lookup_column, lookup_value),0))Với G2 là giá trị tra cứu, A - cột để tra cứu và E - cột để trả về kết quả khớp, của chúng tôi công thức tra cứu phân biệt chữ hoa chữ thường diễn ra như sau:
=INDEX($E$2:$E$6, MATCH(TRUE, EXACT($A$2:$A$6,G2),0))
Vì đây là công thức mảng , hãy nhớ nhấn Ctrl + Shift + Enter để hoàn thành đúng cách.
Để biết thêm ví dụ về công thức, vui lòng xem Cách thực hiện tra cứu phân biệt chữ hoa chữ thường trong Excel.
Tra cứu chuỗi khớp một phần
Tra cứu theo từng phần đối sánh là một trong những nhiệm vụ khó khăn nhất trong Excel mà không tồn tại giải pháp chung nào. Việc sử dụng công thức nào tùy thuộc vào loại khác biệt giữa giá trị tra cứu của bạn và giá trị trong cột để tìm kiếm. Trong hầu hết các trường hợp, bạn sẽ sử dụng hàm LEFT, RIGHT hoặc MID để trích xuất phần chung của các giá trị và sau đó cung cấp phần đó cho đối số lookup_value của hàm Vlookup giống như được thực hiện theo công thức sau:
=VLOOKUP(RIGHT(D2,4), $A$2:$B$6, 2, FALSE)
Trong đó D2 là giá trị tra cứu, A2:B6 là bảng tra cứu và 2 trong số chỉ mục của cột để trả về kết quả khớp.
Để biết các cách khác để thực hiện tra cứu kết quả khớp một phần trong Excel, vui lòng xem Cách hợp nhất hai trang tính bằng cách khớp một phần.
Đây là cách bạn sử dụng các hàm Tra cứu trong Excel. Để xem kỹ hơn các công thức được thảo luận trong hướng dẫn này, bạn có thể tải xuống công thức Tra cứu Excel của chúng tôiví dụ.
Cách tra cứu không cần công thức trong Excel
Không cần phải nói rằng việc tra cứu trong Excel không phải là một nhiệm vụ tầm thường. Nếu bạn đang thực hiện những bước đầu tiên trong việc tìm hiểu lĩnh vực Excel, các công thức tra cứu có vẻ khá khó hiểu và khó hiểu. Nhưng xin đừng nản lòng, những kỹ năng này không tự nhiên đến với đa số người dùng!
Để giúp mọi thứ dễ dàng hơn cho người mới, chúng tôi đã tạo ra một công cụ đặc biệt, Merge Tables Wizard, có thể tra cứu, khớp và hợp nhất các bảng mà không cần một công thức nào. Ngoài ra, nó cung cấp một số tùy chọn thực sự độc đáo mà ngay cả những người dùng Excel nâng cao cũng có thể hưởng lợi từ:
- Tra cứu theo nhiều tiêu chí , tức là sử dụng một hoặc một số cột làm mã định danh duy nhất (s).
- Cập nhật giá trị trong các cột hiện có và thêm các cột mới từ bảng tra cứu.
- Trả về nhiều trận đấu trong các hàng riêng biệt. Khi được sử dụng kết hợp với Trình hướng dẫn kết hợp hàng, nó thậm chí có thể trả về nhiều kết quả trong một ô, bằng dấu phẩy hoặc được phân tách theo cách khác (bạn có thể tìm thấy ví dụ tại đây).
- Và hơn thế nữa.
Làm việc với Trình hướng dẫn Hợp nhất Bảng rất dễ dàng và trực quan. Tất cả những gì bạn phải làm là:
- Chọn bảng chính mà bạn muốn lấy các giá trị phù hợp.
- Chọn bảng tra cứu để lấy các giá trị phù hợp.
- Xác định một hoặc nhiều cột phổ biến.
- Chọn các cột sẽ được cập nhật hoặc/và thêm vào cuốibảng.
- Tùy chọn, chọn một hoặc nhiều tùy chọn hợp nhất bổ sung.
- Nhấp vào Hoàn tất và bạn sẽ có kết quả ngay lập tức!
Nếu bạn tò mò muốn dùng thử phần bổ trợ trên trang tính của riêng mình, bạn có thể tải xuống phiên bản dùng thử của Ultimate Suite bao gồm tất cả các công cụ tiết kiệm thời gian của chúng tôi dành cho Excel (trong tổng cộng, hơn 70 công cụ và hơn 300 tính năng!).
Có sẵn các bản tải xuống
Ví dụ về công thức Tra cứu Excel (tệp .xlsx)
Phiên bản Ultimate Suite 14 ngày đầy đủ chức năng (tệp .exe)
tra cứu).Bảng tra cứu . Trong khoa học máy tính, bảng tra cứu là một mảng dữ liệu, thường được sử dụng để ánh xạ giá trị đầu vào thành giá trị đầu ra. Theo hướng dẫn này, một bảng tra cứu trong Excel không phải là gì khác mà là một dải ô mà bạn tìm kiếm giá trị tra cứu.
Bảng chính (bảng chính) - một bảng mà bạn nhập vào đó. kéo các giá trị phù hợp.
Bảng tra cứu và bảng chính của bạn có thể có cấu trúc và kích thước khác nhau, tuy nhiên, chúng phải luôn chứa ít nhất một mã định danh duy nhất chung , tức là một cột hoặc hàng chứa dữ liệu giống hệt nhau , tùy thuộc vào việc bạn muốn thực hiện tra cứu theo chiều dọc hay chiều ngang.
Ảnh chụp màn hình sau đây hiển thị bảng tra cứu mẫu sẽ được sử dụng trong nhiều ví dụ bên dưới.
Hàm tra cứu Excel
Dưới đây là tổng quan nhanh về các công thức phổ biến nhất để thực hiện tra cứu trong Excel, ưu điểm và nhược điểm chính của chúng.
Hàm tra cứu
Hàm tra cứu Hàm LOOKUP trong Excel có thể thực hiện các kiểu tra cứu dọc và ngang đơn giản nhất.
Ưu điểm : Dễ sử dụng.
Nhược điểm : Hạn chế chức năng, không thể hoạt động với dữ liệu chưa được sắp xếp (yêu cầu sắp xếp t anh ấy tra cứu cột/hàng theo thứ tự tăng dần).
Để biết thêm thông tin, vui lòng xem Cách sử dụng hàm LOOKUP trong Excel.
Hàm VLOOKUP
Đây là phiên bản cải tiến của hàm LOOKUP chức năng được thiết kế đặc biệt để thực hiện tra cứu dọc trongcột.
Ưu điểm : Tương đối dễ sử dụng, có thể hoạt động với đối sánh chính xác và gần đúng.
Nhược điểm : Không thể nhìn sang trái, dừng lại hoạt động khi một cột được chèn vào hoặc xóa khỏi bảng tra cứu, giá trị tra cứu không được vượt quá 255 ký tự, yêu cầu nhiều sức mạnh xử lý trên tập dữ liệu lớn.
Để biết thêm thông tin, vui lòng xem hướng dẫn VLOOKUP trong Excel dành cho người mới bắt đầu.
Hàm HLOOKUP
Đây là hàm đối chiếu ngang của hàm VLOOKUP tìm kiếm giá trị ở hàng đầu tiên của bảng tra cứu và trả về giá trị ở cùng vị trí từ hàng khác.
Ưu điểm : Dễ sử dụng, có thể trả về kết quả khớp chính xác và gần đúng.
Nhược điểm : Chỉ có thể tìm kiếm ở hàng trên cùng của bảng tra cứu, bị ảnh hưởng bởi việc chèn hoặc xóa hàng, giá trị tra cứu phải dưới 255 ký tự.
Để biết thêm thông tin, vui lòng xem Cách sử dụng HLOOKUP trong Excel.
VLOOKUP MATCH / HLOOKUP MATCH
A tham chiếu cột hoặc hàng động được tạo bởi MATCH làm cho Excel này lo công thức okup miễn dịch với những thay đổi được thực hiện trong tập dữ liệu. Nói cách khác, với sự trợ giúp của MATCH, các hàm VLOOKUP và HLOOKUP có thể trả về giá trị chính xác cho dù có bao nhiêu cột/hàng đã được chèn vào hoặc bị xóa khỏi bảng tra cứu.
Công thức tra cứu theo chiều dọc
VLOOKUP( giá trị_tra cứu, bảng_tra cứu, MATCH( tên_cột_trả về, tiêu_đề_cột, 0), FALSE)Công thức tra cứu theo chiều ngang
HLOOKUP( lookup_value, lookup_table, MATCH( return_row_name, row_headers, 0), FALSE)Ưu điểm : Cải tiến so với các công thức Hlookup và Vlookup thông thường không bị chèn hoặc xóa dữ liệu.
Nhược điểm : Không linh hoạt lắm , yêu cầu cấu trúc dữ liệu cụ thể (giá trị tra cứu được cung cấp cho hàm MATCH phải chính xác bằng tên của cột trả về), không thể hoạt động với giá trị tra cứu vượt quá 255 ký tự.
Để biết thêm thông tin và ví dụ về công thức, vui lòng xem:
- Excel Vlookup and Match
- Excel Hlookup and Match
OFFSET MATCH
Phức tạp hơn nhưng mạnh mẽ hơn công thức tra cứu, không có nhiều giới hạn của Vlookup và Hlookup.
Công thức cho V-Lookup
OFFSET( lookup_table, MATCH( lookup_value, OFFSET( lookup_table, 0, n, ROWS( lookup_table), 1) ,0) -1, m, 1, 1)Trong đó:
- n - là phần bù của cột tra cứu, i. đ. số cột cần di chuyển từ điểm bắt đầu đến cột tra cứu.
- m - là phần bù cột trả về, i. đ. số lượng cột để di chuyển từ điểm bắt đầu đến cột trả về.
Công thức cho H-Lookup
OFFSET( lookup_table, m, MATCH( lookup_value, OFFSET( lookup_table, n, 0, 1, COLUMNS( lookup_table)), 0) -1, 1, 1)Ở đâu:
- n - là phần bù của hàng tra cứu, i. đ. số lượng hàng để di chuyển từ điểm bắt đầu đến hàng tra cứu.
- m - là độ lệch của hàng trả về, i. đ. số hàng để di chuyển từ điểm bắt đầu đến hàng trở lại.
Công thức tra cứu ma trận (theo hàng và cột)
{=OFFSET ( điểm_bắt đầu, MATCH ( giá trị_lookup_dọc, cột_tra cứu, 0), MATCH ( horizontal_lookup_value, lookup_row, 0))}Xin lưu ý rằng đây là công thức mảng, được nhập bằng cách nhấn Ctrl + Shift + Enter key cùng lúc.
Ưu điểm : Cho phép thực hiện Vlookup bên trái, Hlookup phía trên và tra cứu hai chiều (theo giá trị cột và hàng), không bị ảnh hưởng khi thay đổi dữ liệu set.
Nhược điểm : Cú pháp phức tạp và khó nhớ.
Để biết thêm thông tin và ví dụ về công thức, vui lòng xem: Sử dụng hàm OFFSET trong Excel
INDEX MATCH
Đó là cách tốt nhất để thực hiện tra cứu theo chiều dọc hoặc chiều ngang trong Excel, có thể thay thế hầu hết các công thức trên. Công thức Đối sánh chỉ mục là sở thích cá nhân của tôi và tôi sử dụng nó cho hầu hết tất cả các tra cứu Excel của mình.
Công thức cho V-Lookup
INDEX ( return_column, MATCH ( giá trị tra cứu, cột tra cứu, 0))Công thức tra cứu H
INDEX ( return_row, MATCH ( lookup_value, lookup_row, 0))Công thức tra cứu ma trận
Anphần mở rộng của công thức Khớp chỉ mục cổ điển để trả về một giá trị tại giao điểm của một cột và hàng cụ thể:
INDEX ( lookup_table, MATCH ( vertical_lookup_value, lookup_column, 0), MATCH ( horizontal_lookup_value, lookup_row, 0))Nhược điểm : Chỉ một - bạn cần nhớ cú pháp của công thức.
Ưu điểm : Công thức Tra cứu linh hoạt nhất trong Excel, vượt trội so với các hàm Vlookup, Hlookup và Lookup về nhiều mặt:
- Có thể thực hiện tra cứu bên trái và bên trên.
- Cho phép mở rộng hoặc thu gọn bảng tra cứu một cách an toàn bằng cách chèn hoặc xóa cột và hàng.
- Không giới hạn kích thước của giá trị tra cứu.
- Hoạt động nhanh hơn. Vì công thức Khớp chỉ mục tham chiếu đến các cột/hàng chứ không phải toàn bộ bảng, nên công thức này cần ít sức mạnh xử lý hơn và sẽ không làm chậm Excel của bạn.
Để biết thêm thông tin, vui lòng xem:
- INDEX MATCH là giải pháp thay thế tốt hơn cho VLOOKUP
- Công thức INDEX MATCH MATCH cho tra cứu hai chiều
Bảng so sánh Excel Lookup
Như bạn thấy , không phải tất cả các công thức Tra cứu trong Excel đều tương đương nhau, một số có thể xử lý một số tra cứu khác nhau trong khi những công thức khác chỉ có thể được sử dụng trong một tình huống cụ thể. Bảng dưới đây trình bày khả năng của từng công thức Tra cứu trong Excel.
| Công thức | Tra cứu theo chiều dọc | Tra cứu bên trái | Tra cứu theo chiều ngang | Tra cứu cấp trên | Ma trậntra cứu | Cho phép chèn/xóa dữ liệu |
| Tra cứu | ✓ | ✓ | ||||
| Vlookup | ✓ | |||||
| Hlookup | ✓ | |||||
| Vlookup Match | ✓ | ✓ | ||||
| Hlookup Match | ✓ | ✓ | ||||
| Trận bù | ✓ | ✓ | ✓ | ✓ | ✓ | |
| Trận đấu bù trừ | ✓ | ✓ | ||||
| Chỉ số phù hợp | ✓ | ✓ | ✓ | ✓ | ✓ | |
| Trận đấu chỉ số Trận đấu | ✓ | ✓ |
Ví dụ về công thức tra cứu Excel
Bước đầu tiên để quyết định sử dụng công thức nào trong một tình huống cụ thể là xác định loại tra cứu bạn muốn thực hiện. Dưới đây, bạn sẽ tìm thấy các ví dụ về công thức cho hầu hết các loại tra cứu phổ biến:
Tra cứu theo chiều dọc trong cột
Tra cứu theo chiều dọc hoặc Vlookup là quá trình tìm giá trị tra cứu trong một cột và trả về một giá trị trong cùng một hàng từ một cột khác. Có thể thực hiện Vlookup trong Excel theo nhiều cách khác nhau, bao gồm:
Hàm VLOOKUP
Nếu các giá trị tra cứu của bạn nằm ở cột bên trái của bảng và bạn không định thực hiện bất kỳ thay đổi cơ cấu đểtập dữ liệu của bạn (không thêm cũng không xóa cột), bạn có thể yên tâm sử dụng công thức Vlookup thông thường:
=VLOOKUP(G2, $A$2:$E$6, 5, FALSE)
Trong đó G2 là giá trị tra cứu, A2:E6 trong bảng tra cứu và E là cột trả về.
VLOOKUP MATCH
Nếu bạn đang làm việc với một bảng tra cứu Excel "biến", trong đó các cột có thể được chèn và xóa bất cứ lúc nào, làm cho công thức Vlookup của bạn miễn nhiễm với những thay đổi đó bằng cách nhúng hàm Match để tạo tham chiếu cột động thay vì số chỉ mục "được mã hóa cứng":
=VLOOKUP(F2,$A$1:$D$6, MATCH($G$1,$A$1:$D$1, 0), FALSE)
INDEX MATCH - Tra cứu bên trái
Đó là công thức yêu thích của tôi giúp xử lý việc tra cứu từ phải sang trái một cách dễ dàng và hoạt động hoàn hảo bất kể bạn thêm hoặc xóa bao nhiêu cột.
Ví dụ: để tìm kiếm cột B cho giá trị trong H2 và trả về giá trị khớp từ cột F, hãy sử dụng công thức sau:
=INDEX($F$2:$F$6,(MATCH(H2,$B$2:$B$6,0)))
Lưu ý. Khi bạn dự định sử dụng công thức Vlookup trong nhiều ô, bạn phải luôn khóa tham chiếu bảng tra cứu bằng cách sử dụng ký hiệu $ (tham chiếu ô tuyệt đối), để công thức được sao chép chính xác sang các ô khác.
Tra cứu theo chiều ngang theo hàng
Tra cứu theo chiều ngang là phiên bản "chuyển đổi" của tra cứu theo chiều dọc để tìm kiếm trong tập dữ liệu được sắp xếp theo chiều ngang. Nói cách khác, nó tìm kiếm giá trị tra cứu trong một hàng và trả về một giá trị ở cùng vị trí từ một hàng khác.
Giả sử giá trị tra cứu của bạn ở B9, bảng tra cứu là B1:F5 vàbạn muốn trả về giá trị khớp từ hàng 5, hãy sử dụng một trong các công thức sau:
Hàm HLOOKUP
Chỉ có thể tra cứu trên hàng trên cùng trong tập dữ liệu của bạn .
=HLOOKUP(B8, $B$1:$F$5, 5, FALSE)
MATCH HLOOKUP
Giống như Hlookup thuần túy, công thức này chỉ có thể tìm kiếm ở hàng trên cùng nhưng cho phép bạn chèn hoặc xóa các hàng trong bảng tra cứu một cách an toàn.
=HLOOKUP(B8, $B$1:$F$5, MATCH($A$9, $A$1:$A$5, 0), FALSE)
Trong đó A1:A5 là tiêu đề hàng và A9 là tên của hàng mà bạn muốn trả về kết quả khớp .
INDEX MATCH
Có thể tra cứu ở bất kỳ hàng nào và không có giới hạn nào của các công thức trên.
=INDEX($B$5:$F$5,(MATCH(B8,$B$1:$F$1,0)))
Tra cứu hai chiều (dựa trên giá trị hàng và cột)
Tra cứu hai chiều (còn gọi là tra cứu ma trận , tra cứu kép hoặc tra cứu 2 chiều ) trả về một giá trị dựa trên kết quả trùng khớp ở cả hàng và cột. Nói cách khác, công thức tra cứu 2 chiều tìm kiếm một giá trị tại giao điểm của một hàng và cột được chỉ định.
Giả sử bảng tra cứu của bạn là A1:E6, ô H2 chứa giá trị để khớp trên các hàng và H3 giữ giá trị để khớp trên các cột, các công thức sau sẽ hoạt động hiệu quả:
Công thức INDEX MATCH MATCH :
=INDEX($A$1:$E$6, MATCH(H2,$A$1:$A$6,0), MATCH(H3,$A$1:$E$1,0))
OFFSET MATCH Công thức MATCH :
=OFFSET($A$1,MATCH(H2,$A$2:$A$6,0),MATCH(H3,$B$1:$E$1,0))
Ngoài các công thức trên, còn có một số cách khác để thực hiện tra cứu ma trận trong Excel và bạn có thể tìm thấy đầy đủ chi tiết trong Cách thực hiện tra cứu 2 chiều
