A bemutató elmagyarázza az Excelben a keresés alapjait, bemutatja az egyes Excel keresési funkciók erősségeit és gyengeségeit, és számos példával segít eldönteni, hogy egy adott helyzetben melyik keresési képletet érdemes használni.

Egy adott érték keresése egy adathalmazon belül az egyik leggyakoribb feladat az Excelben. Mégsem létezik minden helyzetre alkalmas "univerzális" keresési formula. Ennek oka, hogy a "keresés" kifejezés számos különböző dolgot jelölhet: kereshet függőlegesen egy oszlopban, vízszintesen egy sorban vagy egy sor és oszlop metszéspontjában, kereshet egy vagy több kritériummal, visszaadhatja a "keresési" értéket, a "keresési" értéket.első találat vagy több találat, nagy- és kisbetű-érzékeny vagy kis- és nagybetű-érzéketlen keresés, és így tovább.

Ezen az oldalon a legfontosabb Excel Lookup funkciók listáját találja, képletpéldákkal és mélyreható oktatóanyagokkal, amelyekhez a hivatkozáshoz kapcsolódik.

Excel Lookup - az alapok

Mielőtt belemerülnénk az Excel Lookup képletek titkos fordulataiba, határozzuk meg a legfontosabb fogalmakat, hogy mindig ugyanazon az oldalon legyünk.

Keresés - egy megadott érték keresése egy adattáblában.

Keresési érték - a keresendő érték.

Visszatérési érték (matching value vagy match) - a keresési értékkel azonos pozícióban lévő, de egy másik oszlopban vagy sorban lévő érték (attól függően, hogy függőleges vagy vízszintes keresést végez).

Keresési táblázat A számítástechnikában a keresőtábla egy adattömb, amelyet általában arra használnak, hogy bemeneti értékeket kimeneti értékekhez rendeljenek. Az Excel keresőtáblája e bemutató szempontjából nem más, mint egy cellatartomány, amelyben egy keresési értéket keres.

Főasztal (master table) - egy olyan táblázat, amelybe az egyező értékeket húzza be.

A keresőtáblának és a fő táblának eltérő lehet a szerkezete és mérete, azonban mindig tartalmazniuk kell legalább egy közös egyedi azonosító , azaz egy olyan oszlop vagy sor, amely azonos adatokat tartalmaz, attól függően, hogy függőleges vagy vízszintes keresést akarunk-e végezni.

A következő képernyőkép egy mintatáblázatot mutat, amelyet az alábbi példák közül sokban használni fogunk.

Excel Lookup funkciók

Az alábbiakban gyors áttekintést nyújtunk az Excelben történő keresés elvégzéséhez használt legnépszerűbb képletekről, azok főbb előnyeiről és hátrányairól.

LOOKUP funkció

Az Excel LOOKUP funkciója a legegyszerűbb függőleges és vízszintes keresések végrehajtására alkalmas.

Előnyök : Könnyen használható.

Hátrányok : Korlátozott funkcionalitás, nem tud rendezetlen adatokkal dolgozni (a keresési oszlop/sor növekvő sorrendbe rendezése szükséges).

További információért lásd: Hogyan használjuk az Excel LOOKUP funkciót.

VLOOKUP funkció

Ez a LOOKUP funkció továbbfejlesztett változata, amelyet kifejezetten a következőkre terveztek. függőleges keresés oszlopokban.

Előnyök : Viszonylag könnyen használható, pontos és hozzávetőleges egyezéssel is tud dolgozni.

Hátrányok : Nem tud balra nézni, nem működik, ha egy oszlopot beillesztünk a keresési táblázatba vagy eltávolítunk belőle, a keresési érték nem haladhatja meg a 255 karaktert, nagy adathalmazok esetén nagy feldolgozási teljesítményt igényel.

További információért lásd az Excel VLOOKUP bemutatót kezdőknek.

HLOOKUP funkció

Ez a VLOOKUP vízszintes megfelelője, amely a keresőtábla első sorában keres egy értéket, és egy másik sorból adja vissza az azonos pozícióban lévő értéket.

Előnyök : Könnyen használható, pontos és hozzávetőleges egyezéseket ad vissza.

Hátrányok : Csak a keresési táblázat legfelső sorában tud keresni, a sorok beszúrása vagy törlése befolyásolja, a keresési értéknek 255 karakter alatt kell lennie.

További információért lásd: Hogyan használjuk a HLOOKUP-ot az Excelben.

VLOOKUP MÉRKŐZÉS / HLOOKUP MÉRKŐZÉS

A MATCH által létrehozott dinamikus oszlop- vagy sorhivatkozás immunissá teszi ezt az Excel keresési képletet az adatállományban végrehajtott változásokra. Más szóval, a MATCH segítségével a VLOOKUP és a HLOOKUP függvények helyes értékeket adnak vissza, függetlenül attól, hogy hány oszlopot/sorozatot illesztettek be vagy töröltek a keresési táblázatból.

Függőleges keresés képlete

Képlet a vízszintes kereséshez

Előnyök : A hagyományos Hlookup és Vlookup formulákhoz képest az adatok beszúrására vagy törlésére immunis javulás.

Hátrányok : Nem túl rugalmas, speciális adatszerkezetet igényel (a MATCH függvényhez megadott keresési értéknek pontosan meg kell egyeznie a visszatérő oszlop nevével), nem működik 255 karaktert meghaladó keresési értékekkel.

További információkért és képletpéldákért lásd:

• Excel Vlookup és Match
• Excel Hlookup és Match

OFFSET MATCH

Egy összetettebb, de erősebb keresési formula, amely mentes a Vlookup és Hlookup számos korlátozása alól.

A V-Lookup képlete

Hol:

• n - a keresési oszlop eltolása, azaz a kiindulási ponttól a keresési oszlopig áthelyezendő oszlopok száma.
• m - a visszatérő oszlop eltolása, azaz a kiindulási ponttól a visszatérő oszlopig áthelyezendő oszlopok száma.

H-Lookup képlet

Hol:

• n - a keresési sor eltolása, azaz a kiindulási ponttól a keresési sorig áthelyezendő sorok száma.
• m - a visszatérő sor eltolása, azaz a kiindulási ponttól a visszatérő sorig áthelyezendő sorok száma.

Mátrix keresési képlet (soronként és oszloponként)

Kérjük, figyeljen arra, hogy ez egy tömbképlet, amelyet a Ctrl + Shift + Enter billentyűk egyidejű lenyomásával kell beírni.

Előnyök : Lehetővé teszi a bal oldali Vlookup, a felső Hlookup és a kétirányú keresés (oszlop- és sorértékek szerint) végrehajtását, amelyet nem befolyásolnak az adathalmazban bekövetkezett változások.

Hátrányok : Összetett és nehezen megjegyezhető szintaxis.

További információkért és képletpéldákért lásd: Az OFFSET függvény használata az Excelben

INDEX MATCH

Ez a legjobb módja a függőleges vagy vízszintes keresésnek az Excelben, amely a fenti képletek többségét helyettesítheti. Az Index Match formula az én személyes preferenciám, és szinte minden Excel keresésemhez ezt használom.

A V-Lookup képlete

H-Lookup képlet

A mátrixkeresés képlete

A klasszikus Index Match formula kiterjesztése, amely egy adott oszlop és sor metszéspontjában lévő értéket ad vissza:

Hátrányok : Csak egy - emlékeznie kell a képlet szintaxisára.

Előnyök : Az Excel legsokoldalúbb keresési képlete, amely sok tekintetben felülmúlja a Vlookup, Hlookup és Lookup függvényeket:

• Képes bal és felső keresésre.
• Lehetővé teszi a keresőtábla biztonságos bővítését vagy összezsugorítását oszlopok és sorok beillesztésével vagy törlésével.
• Nincs korlát a keresési érték méretére.
• Gyorsabban működik. Mivel az Index Match formula nem egy teljes táblázatra, hanem oszlopokra/sorokra hivatkozik, kevesebb feldolgozási teljesítményt igényel, és nem lassítja az Excel használatát.

További információért kérjük, nézze meg:

• INDEX MATCH mint a VLOOKUP jobb alternatívája
• INDEX MATCH MATCH formula kétdimenziós kereséshez

Excel Lookup összehasonlító táblázat

Amint látja, nem minden Excel Lookup formula egyenértékű, egyesek számos különböző keresést tudnak kezelni, míg mások csak egy adott helyzetben használhatók. Az alábbi táblázat az egyes Lookup formulák képességeit vázolja fel az Excelben.

Excel keresési képlet példák

Az első lépés annak eldöntésében, hogy egy adott helyzetben melyik képletet használja, annak meghatározása, hogy milyen típusú keresést szeretne végrehajtani. Az alábbiakban képletpéldákat talál a legnépszerűbb keresési típusokra:

Függőleges keresés oszlopokban

A függőleges keresés vagy Vlookup az a folyamat, amelynek során egy keresési értéket találunk egy oszlopban, és ugyanabban a sorban egy másik oszlopban lévő értéket adunk vissza. A Vlookup az Excelben többféleképpen is elvégezhető, többek között:

VLOOKUP funkció

Ha a keresési értékek a táblázat bal oldali oszlopában találhatók, és nem tervez szerkezeti változtatásokat az adatállományon (sem oszlopok hozzáadása, sem törlése), akkor nyugodtan használhat egy hagyományos Vlookup-formulát:

=VLOOKUP(G2, $A$2:$E$6, 5, FALSE)

Ahol G2 a keresési érték, A2:E6 a keresési táblázatban, E pedig a visszatérési oszlop.

VLOOKUP MATCH

Ha egy "változó" Excel keresőtáblával dolgozik, ahol az oszlopok bármikor beilleszthetők és törölhetők, tegye a Vlookup-képletet immunissá ezekre a változásokra a Match funkció beágyazásával, amely egy dinamikus oszlophivatkozást hoz létre a "keményen kódolt" indexszám helyett:

=VLOOKUP(F2,$A$1:$D$6, MATCH($G$1,$A$1:$D$1, 0), FALSE)

INDEX MATCH - Bal oldali keresés

Ez a kedvenc képletem, amely könnyedén kezeli a jobbról balra történő kereséseket, és kifogástalanul működik, függetlenül attól, hogy hány oszlopot adsz hozzá vagy törölsz.

Ha például a B oszlopban a H2-ben lévő értéket szeretné keresni, és az F oszlopban lévő értéket szeretné visszaküldeni, használja ezt a képletet:

=INDEX($F$2:$F$6,(MATCH(H2,$B$2:$B$6,0)))

Megjegyzés: Ha egy Vlookup-képletet egynél több cellában tervez használni, akkor mindig a következő módon kell a keresőtábla hivatkozásának zárolása a $ jel (abszolút cellahivatkozás) használatával, hogy a képlet helyesen másolódjon át más cellákba.

Vízszintes keresés sorokban

A vízszintes keresés a függőleges keresés "áthelyezett" változata, amely egy vízszintesen elrendezett adathalmazban keres. Más szóval, a keresési értéket az egyik sorban keresi, és egy másik sorból ugyanabban a pozícióban lévő értéket adja vissza.

Feltételezve, hogy a keresési érték a B9-ben van, a keresési táblázat B1:F5, és az 5. sorban lévő megfelelő értéket szeretné visszaadni, használja a következő képletek egyikét:

HLOOKUP funkció

Csak az egész felső sor az adathalmazban.

=HLOOKUP(B8, $B$1:$F$5, 5, FALSE)

HLOOKUP MATCH

A tiszta Hlookuphoz hasonlóan ez a képlet is csak a legfelső sorban tud keresni, de lehetővé teszi, hogy sorok biztonságos beszúrása vagy törlése a keresési táblázatban.

=HLOOKUP(B8, $B$1:$F$5, MATCH($A$9, $A$1:$A$5, 0), FALSE)

Ahol A1:A5 a sorcímek, A9 pedig annak a sornak a neve, amelyből a találatokat vissza akarja adni.

INDEX MATCH

Can nézz fel bármelyik sorban , és nem rendelkezik a fenti képletek korlátai közül egyik sem.

=INDEX($B$5:$F$5,(MATCH(B8,$B$1:$F$1,0)))

Kétdimenziós keresés (sor- és oszlopértékek alapján)

Kétdimenziós keresés (más néven mátrix keresés , kettős keresés vagy 2-utas keresés ) a sorokban és oszlopokban található egyezések alapján ad vissza egy értéket. Más szóval, egy 2 dimenziós keresési formula egy megadott sor és oszlop metszéspontjában keres értéket.

Feltételezve, hogy a keresőtáblája A1:E6, a H2 cella tartalmazza a sorokban egyezni kívánt értéket, a H3 pedig az oszlopokban egyezni kívánt értéket, a következő képletek jól fognak működni:

INDEX MATCH MATCH formula :

=INDEX($A$1:$E$6, MATCH(H2,$A$1:$A$6,0), MATCH(H3,$A$1:$E$1,0))

OFFSET MATCH MATCH képlet :

=OFFSET($A$1,MATCH(H2,$A$2:$A$6,0),MATCH(H3,$B$1:$E$1,0))

A fenti képleteken kívül létezik még egy maroknyi más módszer is a mátrixkeresés elvégzésére az Excelben, és a teljes részleteket a Hogyan végezhetünk kétirányú keresést az Excelben című fejezetben találja meg.

Háromdimenziós keresés

A háromdimenziós keresés 3 különböző keresési érték alapján történő keresést jelent. Az alábbi adatkészletben, tegyük fel, hogy egy adott évet (H2), majd egy adott nevet szeretne keresni az év adatain belül (H3), majd egy adott hónap értékét (H4).

A feladatot a következő tömbképlettel lehet elvégezni (ne feledje, hogy a Ctrl + Shift + Enter billentyűkombinációt kell lenyomni a helyes befejezéshez):

=INDEX($A$1:$E$12,MIN(IF((ROW($A$1:$A$12)>MATCH(H2,$A$1:$A$12,0))*($A$1:$A$12=H3),ROW($A$1:$A$12),""))),MATCH(H4,$A$1:$E$1,0)))

Keresés több kritériummal

Ahhoz, hogy több kritériumot is ki tudjunk értékelni, a klasszikus Index Match képletet úgy kell módosítanunk, hogy az egy tömbképlet legyen:

Az A1:C11-ben található keresőtáblával keressünk egyezést 2 feltétel alapján: keressük meg az A oszlopban az F1 cellában lévő értéket, és a B oszlopban az F2 cellában lévő értéket:

=INDEX($A$1:$C$11, MATCH(1, (F1=$A$1:$A$11) * (F2=$B$1:$B$11),0), 3)

A szokásos módon a Ctrl + Shift + Enter billentyűkombinációt kell megnyomnia, hogy a képletet tömbképletként értékelje ki.

A képlet logikájának részletes magyarázatát lásd: INDEX MATCH a több kritériummal történő kereséshez.

Lookup több érték visszaadása

Bármelyik Excel Lookup funkciót is használja (LOOKUP, VLOOKUP vagy HLOOKUP), csak egyetlen egyezést adhat vissza. Ahhoz, hogy az összes talált egyezést megkapja, 6 különböző funkciót kell alkalmaznia egy tömbképletben kombinálva:

Hol:

• m a visszatérési tartomány első cellájának sorszáma mínusz 1.
• n az első képlet cellájának sorszáma mínusz 1.

Ha a keresési érték az E2 cellában, a keresési tartomány az A2:A11 cellában, a visszatérési tartomány a B2:B11 cellában, az első képletcellát pedig a 2. sorban találjuk, a keresési képlet a következő alakot veszi fel:

=IFERROR(INDEX($B$2:$B$11, SMALL(IF($E$2 =$A$2:$A$11, ROW($B$2:$B$11 )- 1,""), ROW() - 1 )),""),"")

Ahhoz, hogy a képlet több találatot adjon vissza, írja be az első cellába (F2), nyomja meg a Ctrl + Shift + Enter billentyűkombinációt, majd másolja a képletet az oszlopban lévő többi cellába.

A fenti képlet részletes magyarázatát és a több érték visszaadásának más módjait lásd a Hogyan adjon vissza több eredményt a Vlookup segítségével?

Beágyazott keresés (2 keresőtáblából)

Azokban az esetekben, amikor a fő táblának és a keresőtáblának, amelyből az adatokat szeretné kinyerni, nincs közös oszlopa, egy további keresőtáblát használhat az egyezések létrehozásához, például így:

Az értékek lekérdezése a Összeg oszlop a Lookup_table2 a következő képletet használja:

=VLOOKUP(VLOOKUP(A2, Lookup_table1!$A$1:$B$6, 2, FALSE), Lookup_table2!$A$1:$B$6, 2, FALSE)

Ahogy az alábbi képernyőképen látható, a beágyazott keresési képletünk tökéletesen működik:

Szekvenciális Vlookups több lapból

Ha egymás utáni Vlookupokat szeretne végrehajtani annak alapján, hogy egy korábbi keresés sikeres vagy sikertelen volt-e, használjon beágyazott IFERROR függvényeket a VLOOKUP-okkal együtt, hogy több feltételt egyenként kiértékeljen:

Ha az első Vlookup nem talál semmit, az IFERROR elkapja a hibát és lefuttat egy másik Vlookupot. Ha a második Vlookup sem talál semmit, a második IFERROR elkapja a hibát és lefuttatja a harmadik Vlookupot, és így tovább. Ha az összes Vlookup sikertelen, az utolsó IFERROR a "nem talált" vagy bármilyen más üzenetet ad a képlethez.

Példaként próbáljuk meg 3 különböző lapról lehívni az összeget:

=IFERROR(VLOOKUP(B1,A6:B9,2,0), IFERROR(VLOOKUP(B1,D6:E9,2,0), IFERROR(VLOOKUP(B1,G6:H9,2,0), "Nem található"))))

Az eredmény valahogy így fog kinézni:

További információért lásd: Hogyan használjuk a beágyazott IFERROR függvényeket az Excelben.

Nagy- és kisbetű-érzékeny keresés

Mint valószínűleg tudja, az Excel összes keresési függvénye természeténél fogva nem érzékeny a nagy- és kisbetűs szöveg megkülönböztetésére, használja a LOOKUP vagy az INDEX MATCH funkciót az EXACT funkcióval kombinálva. Én személy szerint az INDEX MATCH funkciót választom, mert nem szükséges az értékek rendezése a keresési oszlopban, mint a LOOKUP funkció esetében, és a balról jobbra történő keresést is képes elvégezni.és jobbról balra történő keresés, és tökéletesen működik minden adattípus esetében.

A G2 a keresési érték, az A - oszlop, amely alapján a keresést végezzük, és az E - oszlop, amelyből a találatokat visszaadjuk, az eset-érzékeny keresési képletünk a következőképpen néz ki:

=INDEX($E$2:$E$6, MATCH(TRUE, EXACT($A$2:$A$6,G2),0))

Mivel ez egy tömb képlet , a megfelelő befejezéshez nyomja le a Ctrl + Shift + Enter billentyűkombinációt.

További képletpéldákért lásd: Hogyan végezhetünk nagy- és kisbetűs keresést az Excelben.

Részleges string egyezés keresése

A részleges egyezés szerinti keresés az egyik legnagyobb kihívást jelentő feladat az Excelben, amelyre nem létezik univerzális megoldás. Az, hogy melyik képletet kell használni, attól függ, hogy milyen különbségek vannak a keresési értékek és a keresendő oszlop értékei között. A legtöbb esetben a LEFT, RIGHT vagy MID függvényt használjuk az értékek közös részének kinyerésére, majd ezt a részt megadjuk a(z) lookup_value argumentumát a Vlookup függvényben, ahogyan az a következő képletben is szerepel:

=VLOOKUP(RIGHT(D2,4), $A$2:$B$6, 2, FALSE)

Ahol D2 a keresési érték, A2:B6 a keresési táblázat, és 2 az indexszáma annak az oszlopnak, amelyből a találatokat vissza kell adni.

A részleges egyezés keresésének más módjairól az Excelben lásd: Hogyan egyesíthet két munkalapot részleges egyezéssel?

Így használja a Lookup függvényeket az Excelben. Ha közelebbről szeretné megnézni az ebben a bemutatóban tárgyalt képleteket, akkor szívesen letölti az Excel Lookup képlet példákat.

Képletmentes módja az Excel keresésnek az Excelben

Magától értetődik, hogy az Excel keresés nem triviális feladat. Ha Ön az első lépéseket teszi az Excel birodalmának megismerésében, a keresési képletek meglehetősen zavarosnak és nehezen érthetőnek tűnhetnek. De kérem, ne csüggedjen, ezek a készségek a felhasználók többsége számára nem természetesek!

Hogy megkönnyítsük a kezdők dolgát, létrehoztunk egy speciális eszközt, a Merge Tables Wizard-ot, amely egyetlen képlet nélkül képes megkeresni, összevetni és egyesíteni a táblázatokat. Emellett számos igazán egyedi lehetőséget biztosít, amelyekből még a haladó Excel-felhasználók is profitálhatnak:

• Keresés a következő szerint több kritérium , azaz egy vagy több oszlopot használjon egyedi azonosítóként.
• Frissítés a meglévő oszlopok értékei és hozzáadunk egy új oszlopok a keresőtáblából.
• Visszatérés több mérkőzés A sorok kombinálása varázslóval együtt használva akár több eredményt is visszaadhat egyetlen cellában, vesszővel vagy más módon elválasztva (egy példa itt található).
• És még több.

A táblázatok összevonása varázslóval való munka egyszerű és intuitív. Mindössze annyit kell tennie, hogy:

1. Válassza ki a fő táblázatot, ahonnan a megfelelő értékeket szeretné kihúzni.
2. Válassza ki a keresőtáblát, amelyből a találatokat ki szeretné húzni.
3. Egy vagy több közös oszlop meghatározása.
4. Válassza ki a frissítendő és/vagy a táblázat végéhez hozzáadandó oszlopokat.
5. Opcionálisan válasszon ki egy vagy több további egyesítési lehetőséget.
6. Kattintson a címre. Befejezés és egy pillanat alatt meglesz az eredmény!

Ha kíváncsi a bővítményt saját munkalapjain kipróbálni, akkor szívesen látjuk, ha letölti az Ultimate Suite próbaverzióját, amely tartalmazza az összes időtakarékos Excel-eszközünket (összesen több mint 70 eszköz és több mint 300 funkció!).

Elérhető letöltések

Excel keresési képlet példák (.xlsx fájl)

Ultimate Suite 14 napos, teljesen funkcionális verzió (.exe fájl)