V učbeniku so razložene osnove iskanja v Excelu, prikazane prednosti in slabosti posameznih funkcij iskanja v Excelu ter podani številni primeri, ki vam bodo pomagali pri odločitvi, katero formulo iskanja je najbolje uporabiti v določeni situaciji.

Iskanje določene vrednosti v naboru podatkov je eno najpogostejših opravil v Excelu. Kljub temu ne obstaja "univerzalna" formula za iskanje, ki bi bila primerna za vse primere. Razlog je v tem, da izraz "iskanje" lahko označuje več različnih stvari: iščete lahko navpično v stolpcu, vodoravno v vrstici ali na presečišču vrstice in stolpca, iščete z enim ali več merili, vrneteprvo najdeno ujemanje ali več ujemanj, iskanje po velikosti črk ali brez njih in tako naprej.

Na tej strani boste našli seznam najpomembnejših funkcij Excel Lookup s primeri formul in poglobljenimi učnimi gradivi, ki so vam na voljo.

Excelovo iskanje - osnove

Preden se poglobimo v skrivnostne zaplete formul Excel Lookup, definirajmo ključne izraze, da bomo vedno na isti strani.

Iskanje - iskanje določene vrednosti v tabeli s podatki.

Vrednost iskanja - vrednost za iskanje.

Vrnjena vrednost (ujemajoča se vrednost ali ujemanje) - vrednost na istem mestu kot vrednost iskanja, vendar v drugem stolpcu ali vrstici (odvisno od tega, ali gre za navpično ali vodoravno iskanje).

Preglednica za iskanje . V računalništvu je preglednica iskanja polje podatkov, ki se običajno uporablja za preslikavo vhodnih vrednosti v izhodne vrednosti. V tem učbeniku preglednica iskanja v Excelu ni nič drugega kot območje celic, v katerem iščete vrednost iskanja.

Glavna miza (glavna tabela) - tabela, v katero prenesete ustrezne vrednosti.

Preglednica za iskanje in glavna preglednica imata lahko različno strukturo in velikost, vendar morata vedno vsebovati vsaj eno skupni enolični identifikator , tj. stolpec ali vrstica z enakimi podatki, odvisno od tega, ali želite izvesti navpično ali vodoravno iskanje.

Naslednja zaslonska slika prikazuje vzorec preglednice za iskanje, ki bo uporabljena v številnih primerih v nadaljevanju.

Funkcije iskanja v Excelu

Spodaj je kratek pregled najbolj priljubljenih formul za iskanje v Excelu, njihovih glavnih prednosti in pomanjkljivosti.

Funkcija LOOKUP

Funkcija LOOKUP v Excelu lahko izvaja najpreprostejše vrste navpičnih in vodoravnih iskanj.

Prednosti : Enostaven za uporabo.

Proti : Omejena funkcionalnost, ne more delati z nesortiranimi podatki (zahteva razvrščanje stolpca/vrstice iskanja v naraščajočem vrstnem redu).

Za več informacij glejte Kako uporabljati Excelovo funkcijo LOOKUP.

Funkcija VLOOKUP

Gre za izboljšano različico funkcije LOOKUP, ki je posebej zasnovana za navpično iskanje v stolpcih.

Prednosti : Uporaba je razmeroma preprosta, lahko deluje z natančnim in približnim ujemanjem.

Proti : ne more pogledati na levo, preneha delovati, ko je stolpec vstavljen v preglednico iskanja ali odstranjen iz nje, vrednost iskanja ne sme presegati 255 znakov, zahteva veliko procesorske moči pri velikih zbirkah podatkov.

Za več informacij si oglejte Excelovo vadnico VLOOKUP za začetnike.

Funkcija HLOOKUP

Gre za vodoravni ekvivalent VLOOKUP, ki išče vrednost v prvi vrstici preglednice iskanja in vrne vrednost na istem mestu iz druge vrstice.

Prednosti : Enostavna uporaba, lahko vrne natančna in približna ujemanja.

Proti : Lahko išče samo v najvišji vrstici preglednice iskanja, vpliva na vstavljanje ali brisanje vrstic, vrednost iskanja mora biti manjša od 255 znakov.

Za več informacij glejte Kako uporabljati HLOOKUP v Excelu.

VLOOKUP MATCH / HLOOKUP MATCH

Dinamična referenca na stolpec ali vrstico, ki jo ustvari MATCH, naredi to Excelovo formulo za iskanje odporno na spremembe v podatkovnem nizu. Z drugimi besedami, s pomočjo MATCH lahko funkciji VLOOKUP in HLOOKUP vrneta pravilne vrednosti ne glede na to, koliko stolpcev/vrstic je bilo vstavljenih v preglednico za iskanje ali izbrisanih iz nje.

Formula za navpično iskanje

Formula za vodoravno iskanje

Prednosti : Izboljšava običajnih formul Hlookup in Vlookup, ki so odporne na vstavljanje ali brisanje podatkov.

Proti : Ni zelo prilagodljiv, zahteva posebno podatkovno strukturo (vrednost iskanja, posredovana funkciji MATCH, mora biti natančno enaka imenu vrnjenega stolpca), ne more delovati z vrednostmi iskanja, ki presegajo 255 znakov.

Za več informacij in primere formul glejte:

• Excel Vlookup in ujemanje
• Excel Hlookup in ujemanje

MATCH OFFSET

Bolj zapletena, vendar zmogljivejša formula za iskanje, brez številnih omejitev Vlookup in Hlookup.

Formula za iskanje V

Kje:

• n - je zamik stolpca iskanja, tj. število stolpcev, ki jih je treba premakniti od začetne točke do stolpca iskanja.
• m - je zamik vrnitvenega stolpca, tj. število stolpcev, ki jih je treba premakniti od začetne točke do vrnitvenega stolpca.

Formula za iskanje H

Kje:

• n - je zamik vrstice iskanja, tj. število vrstic, ki jih je treba premakniti od začetne točke do vrstice iskanja.
• m - je zamik vrnitvene vrstice, tj. število vrstic, ki jih je treba premakniti od začetne točke do vrnitvene vrstice.

Formula za iskanje po matrikah (po vrsticah in stolpcih)

Bodite pozorni, da gre za formulo v polju, ki jo vnesete tako, da hkrati pritisnete tipki Ctrl + Shift + Enter.

Prednosti : Omogoča izvajanje levostranskega iskanja Vlookup, zgornjega iskanja Hlookup in dvosmernega iskanja (po vrednostih stolpcev in vrstic), na kar ne vplivajo spremembe v podatkovnem nizu.

Proti : Zapletena in težko zapomnljiva sintaksa.

Za več informacij in primere formul glejte: Uporaba funkcije OFFSET v Excelu

INDEX MATCH

To je najboljši način za navpično ali vodoravno iskanje v Excelu, ki lahko nadomesti večino zgornjih formul. Formula Index Match je moja osebna prednost in jo uporabljam za skoraj vsa iskanja v Excelu.

Formula za iskanje V

Formula za iskanje H

Formula za iskanje po matriki

Razširitev klasične formule Index Match za vračanje vrednosti na presečišču določenega stolpca in vrstice:

Proti : Samo eno - zapomniti si morate sintakso formule.

Prednosti : Najbolj vsestranska formula Lookup v Excelu, ki je v mnogih pogledih boljša od funkcij Vlookup, Hlookup in Lookup:

• Izvede lahko levo in zgornje iskanje.
• Omogoča varno razširjanje ali krčenje preglednice z vstavljanjem ali brisanjem stolpcev in vrstic.
• Velikost vrednosti iskanja ni omejena.
• Deluje hitreje. Ker se formula Index Match sklicuje na stolpce/vrstice in ne na celotno tabelo, zahteva manj procesorske moči in ne upočasnjuje programa Excel.

Za več informacij si oglejte:

• INDEX MATCH kot boljša alternativa za VLOOKUP
• Formula INDEX MATCH MATCH za dvodimenzionalno iskanje

Primerjalna tabela Excel Lookup

Kot vidite, niso vse formule Excel Lookup enakovredne, nekatere lahko obdelujejo več različnih iskanj, druge pa lahko uporabite le v določenem primeru. V spodnji preglednici so opisane zmožnosti posameznih formul Lookup v Excelu.

Primeri Excelove formule za iskanje

Prvi korak pri odločanju, katero formulo uporabiti v določenem primeru, je določitev vrste iskanja, ki jo želite izvesti. V nadaljevanju so navedeni primeri formul za najbolj priljubljene vrste iskanja:

Navpično iskanje v stolpcih

Navpično iskanje ali Vlookup je postopek iskanja vrednosti iskanja v enem stolpcu in vračanja vrednosti v isti vrstici iz drugega stolpca. Vlookup v Excelu lahko izvedete na različne načine, med drugim:

Funkcija VLOOKUP

Če so vrednosti iskanja v levem stolpcu tabele in ne nameravate opraviti nobenih strukturnih sprememb nabora podatkov (ne dodajati ali brisati stolpcev), lahko mirno uporabite običajno formulo Vlookup:

=VLOOKUP(G2, $A$2:$E$6, 5, FALSE)

Pri čemer je G2 vrednost iskanja, A2:E6 v preglednici iskanja, E pa je stolpec vrnitve.

VLOOKUP MATCH

Če delate s "spremenljivo" Excelovo preglednico za iskanje, v katero lahko kadar koli vstavite in izbrišete stolpce, poskrbite, da bo vaša formula Vlookup odporna na te spremembe, tako da vgradite funkcijo Match, ki ustvari dinamično referenco na stolpec namesto "trdno zakodirane" številke indeksa:

=VLOOKUP(F2,$A$1:$D$6, MATCH($G$1,$A$1:$D$1, 0), FALSE)

INDEX MATCH - Levo iskanje

To je moja najljubša formula, ki z lahkoto opravlja iskanje od desne proti levi in deluje brezhibno ne glede na to, koliko stolpcev dodate ali izbrišete.

Če želite na primer v stolpcu B poiskati vrednost v H2 in vrniti ujemanje iz stolpca F, uporabite to formulo:

=INDEX($F$2:$F$6,(MATCH(H2,$B$2:$B$6,0))

Opomba: Če nameravate formulo Vlookup uporabiti v več kot eni celici, morate vedno zaklenite referenčno tabelo za iskanje z znakom $ (absolutni sklic na celico), da se formula pravilno kopira v druge celice.

Vodoravno iskanje v vrsticah

Vodoravno iskanje je "prenesena" različica navpičnega iskanja, ki išče v vodoravno urejenem naboru podatkov. Z drugimi besedami, v eni vrstici išče vrednost iskanja, v drugi vrstici pa vrne vrednost na istem mestu.

Če je vrednost iskanja v vrstici B9, tabela iskanja je B1:F5 in želite vrniti ustrezno vrednost iz vrstice 5, uporabite eno od naslednjih formul:

Funkcija HLOOKUP

Lahko se pogleda le čez zgornja vrstica v vašem naboru podatkov.

=HLOOKUP(B8, $B$1:$F$5, 5, FALSE)

HLOOKUP MATCH

Tako kot pri čistem iskanju Hlookup lahko ta formula išče samo v najvišji vrstici, vendar vam omogoča, da varno vstavljanje ali brisanje vrstic v preglednici iskanja.

=HLOOKUP(B8, $B$1:$F$5, MATCH($A$9, $A$1:$A$5, 0), FALSE)

Pri čemer so A1:A5 glave vrstic, A9 pa je ime vrstice, iz katere želite vrniti zadetke.

INDEX MATCH

Lahko iskanje v kateri koli vrstici in nima nobenih omejitev zgornjih formul.

=INDEX($B$5:$F$5,(MATCH(B8,$B$1:$F$1,0))

Dvodimenzionalno iskanje (na podlagi vrednosti vrstic in stolpcev)

Dvodimenzionalno iskanje (tudi iskanje matrike , dvojno iskanje ali dvosmerno iskanje ) vrne vrednost na podlagi ujemanj v obeh vrsticah in stolpcih. Z drugimi besedami, dvodimenzionalna formula za iskanje išče vrednost na presečišču določene vrstice in stolpca.

Če je vaša preglednica za iskanje A1:E6, celica H2 vsebuje vrednost za ujemanje v vrsticah, celica H3 pa vrednost za ujemanje v stolpcih, bodo naslednje formule delovale odlično:

Formula INDEX MATCH MATCH :

=INDEX($A$1:$E$6, MATCH(H2,$A$1:$A$6,0), MATCH(H3,$A$1:$E$1,0))

Formula OFFSET MATCH MATCH :

=OFFSET($A$1,MATCH(H2,$A$2:$A$6,0),MATCH(H3,$B$1:$E$1,0))

Poleg zgornjih formul obstaja še nekaj drugih načinov za izvajanje matričnega iskanja v Excelu, vse podrobnosti pa najdete v članku Kako izvajati dvosmerno iskanje v Excelu.

Tridimenzionalno iskanje

Tridimenzionalno iskanje pomeni iskanje po treh različnih vrednostih iskanja. V spodnjem naboru podatkov želite poiskati določeno leto (H2), nato določeno ime znotraj podatkov tega leta (H3) in nato vrniti vrednost za določen mesec (H4).

To nalogo lahko opravite z naslednjo formulo (ne pozabite pritisniti Ctrl + Shift + Enter, da jo pravilno dokončate):

=INDEX($A$1:$E$12,MIN(IF((ROW($A$1:$A$12)>MATCH(H2,$A$1:$A$12,0))*($A$1:$A$12=H3),ROW($A$1:$A$12),"")),MATCH(H4,$A$1:$E$1,0))

Iskanje z več merili

Da bi lahko ocenili več meril, bomo morali klasično formulo Index Match spremeniti tako, da bo postala formula za polje:

S preglednico iskanja, ki se nahaja v A1:C11, poiščimo ujemanje po dveh merilih: v stolpcu A poiščimo vrednost v celici F1, v stolpcu B pa vrednost v celici F2:

=INDEX($A$1:$C$11, MATCH(1, (F1=$A$1:$A$11) * (F2=$B$1:$B$11),0), 3)

Kot običajno pritisnite kombinacijo tipk Ctrl + Shift + Enter, da se formula ovrednoti kot formula polja.

Za podrobnejšo razlago logike formule glejte poglavje INDEX MATCH za iskanje z več merili.

Iskanje za vrnitev več vrednosti

Ne glede na to, katero funkcijo Excel Lookup uporabljate (LOOKUP, VLOOKUP ali HLOOKUP), lahko vrne le eno ujemanje. Če želite dobiti vsa najdena ujemanja, bi morali uporabiti 6 različnih funkcij, združenih v formuli polja:

Kje:

• m je številka vrstice prve celice v območju vrnitve minus 1.
• n je številka vrstice prve celice formule minus 1.

Če je vrednost iskanja v celici E2, območje iskanja v A2:A11, območje vračanja v B2:B11 in prva celica formule v vrstici 2, je vaša formula iskanja naslednja:

=IFERROR(INDEX($B$2:$B$11, SMALL(IF($E$2 =$A$2:$A$11, ROW($B$2:$B$11 )- 1,""), ROW() - 1 )),"")

Če želite, da formula vrne več zadetkov, jo vnesite v prvo celico (F2), pritisnite Ctrl + Shift + Enter in nato kopirajte formulo v druge celice v stolpcu.

Za podrobno razlago zgornje formule in drugih načinov vračanja več vrednosti glejte Kako z Vlookup vrniti več rezultatov.

Vgnezdeno iskanje (iz 2 preglednic iskanja)

Kadar glavna tabela in preglednica za iskanje, iz katere želite pridobiti podatke, nimata skupnega stolpca, lahko za ugotavljanje ujemanja uporabite dodatno preglednico za iskanje, kot je ta:

Če želite pridobiti vrednosti iz Znesek stolpec v Lookup_table2 , uporabite naslednjo formulo:

=VLOOKUP(VLOOKUP(A2, Lookup_table1!$A$1:$B$6, 2, FALSE), Lookup_table2!$A$1:$B$6, 2, FALSE)

Kot je prikazano na spodnji sliki zaslona, naša vgnezdena formula za iskanje deluje brezhibno:

Zaporedni pregledi iz več listov

Če želite izvajati zaporedna iskanja VLOOKUP glede na to, ali je prejšnje iskanje uspelo ali ne, uporabite vgnezdene funkcije IFERROR skupaj s funkcijami VLOOKUP, da zaporedoma ocenite več pogojev:

Če prvi Vlookup ne uspe, IFERROR ujame napako in izvede drugi Vlookup. Če tudi drugi Vlookup ne najde ničesar, drugi IFERROR ujame napako in izvede tretji Vlookup itd. Če vsi Vlookupi ne uspejo, zadnji IFERROR vrne "ni najden" ali katero koli drugo sporočilo, ki ste ga posredovali formuli.

Na primer, poskušajmo pridobiti znesek iz treh različnih listov:

=IFERROR(VLOOKUP(B1,A6:B9,2,0), IFERROR(VLOOKUP(B1,D6:E9,2,0), IFERROR(VLOOKUP(B1,G6:H9,2,0), "Ni najden")))

Rezultat bo videti približno takole:

Za več informacij glejte Kako uporabljati vgrajene funkcije IFERROR v Excelu.

Iskanje, občutljivo na velikost črk

Kot verjetno veste, so vse funkcije Excel Lookup po svoji naravi neobčutljive na velike in male črke. Če želite, da formula za iskanje razlikuje med besedilom z malimi in velikimi črkami, uporabite LOOKUP ali INDEX MATCH v kombinaciji s funkcijo EXACT. Osebno sem se odločil za INDEX MATCH, ker ne zahteva razvrščanja vrednosti v stolpcu iskanja, kot to počne funkcija LOOKUP, lahko izvaja tako levo-desnoin iskanja od desne proti levi ter odlično deluje za vse vrste podatkov.

Če je G2 vrednost iskanja, A - stolpec za iskanje in E - stolpec za vračanje zadetkov, je naša formula za iskanje, občutljiva na velikost črk, naslednja:

=INDEX($E$2:$E$6, MATCH(TRUE, EXACT($A$2:$A$6,G2),0))

Ker gre za formula polja , pritisnite kombinacijo tipk Ctrl + Shift + Enter, da jo pravilno dokončate.

Za več primerov formul glejte Kako v Excelu poiskati poizvedbo, ki upošteva velike in male črke.

Iskanje delnega ujemanja z nizom

Iskanje po delnem ujemanju je eno najzahtevnejših opravil v Excelu, za katerega ne obstaja univerzalna rešitev. Katero formulo boste uporabili, je odvisno od tega, kakšne razlike so med vrednostmi za iskanje in vrednostmi v stolpcu, v katerem iščete. V večini primerov uporabite funkcijo LEFT, RIGHT ali MID, da izluščite skupni del vrednosti in nato ta del posredujete funkciji lookup_value argumenta funkcije Vlookup, kot je to storjeno v naslednji formuli:

=VLOOKUP(RIGHT(D2,4), $A$2:$B$6, 2, FALSE)

Pri čemer je D2 vrednost iskanja, A2:B6 preglednica iskanja in 2 indeksna številka stolpca, iz katerega se vrnejo zadetki.

Za druge načine iskanja delnega ujemanja v Excelu glejte Kako združiti dva delovna lista z delnim ujemanjem.

Tako uporabljate funkcije Lookup v Excelu. Če si želite podrobneje ogledati formule, obravnavane v tem učbeniku, si lahko prenesete naše primere formul Excel Lookup.

Način iskanja brez formule v Excelu

Ni treba posebej poudarjati, da iskanje v Excelu ni trivialno opravilo. Če delate prve korake v učenju programa Excel, se vam bodo formule za iskanje morda zdele precej zmedene in težko razumljive. Vendar ne obupajte, te spretnosti za večino uporabnikov niso samoumevne!

Da bi olajšali delo začetnikom, smo ustvarili posebno orodje Čarovnik za združevanje tabel, s katerim lahko poiščete, ujemate in združite tabele brez ene same formule. Poleg tega ponuja številne res edinstvene možnosti, ki jih lahko izkoristijo tudi napredni uporabniki programa Excel:

• Iskanje po več meril , tj. uporabite enega ali več stolpcev kot edinstvene identifikatorje.
• Posodobitev vrednosti v obstoječih stolpcih in dodajte novo stolpci iz preglednice za iskanje.
• Vrnitev več zadetkov V kombinaciji s čarovnikom za združevanje vrstic lahko vrne celo več rezultatov v eni celici, ločenih z vejico ali kako drugače (primer je na voljo tukaj).
• In še več.

Delo s čarovnikom za združevanje tabel je preprosto in intuitivno:

1. Izberite glavno tabelo, iz katere želite povleči ujemajoče se vrednosti.
2. Izberite preglednico za iskanje, iz katere želite pridobiti zadetke.
3. Opredelite enega ali več skupnih stolpcev.
4. Izberite stolpce, ki jih želite posodobiti in/ali dodati na konec tabele.
5. Po želji lahko izberete eno ali več dodatnih možnosti združevanja.
6. Kliknite . Zaključek in v trenutku boste imeli rezultat!

Če želite dodatek preizkusiti na svojih delovnih listih, lahko prenesete preizkusno različico našega paketa Ultimate Suite, ki vključuje vsa naša orodja za prihranek časa za Excel (skupaj več kot 70 orodij in več kot 300 funkcij!).

Razpoložljivi prenosi

Primeri formule Excel Lookup (.xlsx datoteka)

Ultimate Suite 14-dnevna popolnoma funkcionalna različica (.exe datoteka)