Šajā pamācībā ir izskaidroti meklēšanas pamati programmā Excel, parādītas katras Excel meklēšanas funkcijas stiprās un vājās puses un sniegti vairāki piemēri, kas palīdzēs jums izlemt, kuru meklēšanas formulu vislabāk izmantot konkrētajā situācijā.

Konkrētas vērtības meklēšana datu kopā ir viens no visbiežāk sastopamajiem uzdevumiem programmā Excel. Tomēr nav "universālas" meklēšanas formulas, kas būtu piemērota visām situācijām. Tas ir tāpēc, ka termins "meklēšana" var apzīmēt dažādas lietas: jūs varat meklēt vertikāli slejā, horizontāli rindā vai rindas un slejas krustpunktā, meklēt pēc viena vai vairākiem kritērijiem, atgrieztpirmā atrastā atbilstība vai vairākas atbilstības, veikt uzrādīšanu pēc burtu un atbilžu izšķiroša vai neizšķiroša principa un tā tālāk.

Šajā lapā atradīsiet sarakstu ar svarīgākajām Excel meklēšanas funkcijām, kā arī formulu piemērus un padziļinātas pamācības, kas saistītas ar jūsu atsauci.

Excel meklēšana - pamati

Pirms iedziļināmies Excel meklētājformulu noslēpumainajos līkločos, definēsim galvenos terminus, lai vienmēr būtu vienisprātis.

Pārlūkošana - noteiktas vērtības meklēšana datu tabulā.

Pārlūkošanas vērtība - meklējamo vērtību.

Atgrieztā vērtība (atbilstošā vērtība vai sakritība) - vērtība tajā pašā pozīcijā, kurā atrodas meklēšanas vērtība, bet citā slejā vai rindā (atkarībā no tā, vai tiek veikta vertikāla vai horizontāla meklēšana).

Pārlūkošanas tabula . Datorzinātnē uzmeklēšanas tabula ir datu masīvs, ko parasti izmanto, lai ieejas vērtības attēlotu uz izejas vērtībām. Šajā pamācībā Excel uzmeklēšanas tabula nav nekas cits kā šūnu diapazons, kurā tiek meklēta uzmeklēšanas vērtība.

Galvenais galds (galvenā tabula) - tabula, kurā tiek ievilktas atbilstošās vērtības.

Jūsu uzmeklēšanas tabulai un galvenajai tabulai var būt atšķirīga struktūra un lielums, tomēr tajās vienmēr jābūt vismaz vienai kopējais unikālais identifikators t. i., kolonnu vai rindu, kurā ir identiski dati, atkarībā no tā, vai vēlaties veikt vertikālu vai horizontālu meklēšanu.

Nākamajā ekrānšāviņas attēlā ir parādīta meklēšanas tabulas paraugs, kas tiks izmantots daudzos turpmāk sniegtajos piemēros.

Excel meklēšanas funkcijas

Tālāk ir sniegts īss pārskats par populārākajām formulām, lai veiktu meklēšanu programmā Excel, to galvenajām priekšrocībām un trūkumiem.

LOOKUP funkcija

Ar funkciju LOOKUP programmā Excel var veikt visvienkāršākos vertikālo un horizontālo meklējumu veidus.

Plusi : Viegli lietojams.

Mīnusi : Ierobežota funkcionalitāte, nevar strādāt ar nešķirotiem datiem (nepieciešams šķirot meklēšanas kolonnu/rindu augošā secībā).

Lai uzzinātu vairāk, skatiet sadaļu Kā lietot Excel LOOKUP funkciju.

VLOOKUP funkcija

Tā ir LOOKUP funkcijas uzlabota versija, kas īpaši izstrādāta, lai veiktu vertikālā meklēšana slejās.

Plusi : Samērā viegli lietojams, var strādāt ar precīzu un aptuvenu atbilstību.

Mīnusi : Nevar skatīties pa kreisi, pārtrauc darboties, kad aile tiek ievietota vai izņemta no meklēšanas tabulas, meklēšanas vērtība nedrīkst pārsniegt 255 rakstzīmes, lielām datu kopām ir nepieciešama liela apstrādes jauda.

Lai iegūtu vairāk informācijas, skatiet Excel VLOOKUP pamācību iesācējiem.

HLOOKUP funkcija

Tas ir horizontāls VLOOKUP ekvivalents, kas meklē vērtību meklēšanas tabulas pirmajā rindā un atgriež vērtību tajā pašā pozīcijā no citas rindas.

Plusi : Viegli lietojams, var atrast precīzus un aptuvenus sakritības variantus.

Mīnusi : Var meklēt tikai meklētājtabulas augšējā rindā, to ietekmē rindu ievietošana vai dzēšana, meklēšanas vērtībai jābūt mazākai par 255 rakstzīmēm.

Lai iegūtu vairāk informācijas, skatiet sadaļu Kā lietot HLOOKUP programmā Excel.

VLOOKUP ATBILSTĪBA / HLOOKUP ATBILSTĪBA

MATCH izveidotā dinamiskā slejas vai rindas atsauce padara šo Excel uzmeklēšanas formulu imūnu pret datu kopas izmaiņām. Citiem vārdiem sakot, ar MATCH palīdzību VLOOKUP un HLOOKUP funkcijas var atgriezt pareizas vērtības neatkarīgi no tā, cik daudz slejas/rindu ir ievietotas vai dzēstas no uzmeklēšanas tabulas.

Vertikālās meklēšanas formula

Horizontālās meklēšanas formula

Plusi : Parasto Hlookup un Vlookup formulu uzlabojums, kas ir imūns pret datu ievietošanu vai dzēšanu.

Mīnusi : Nav ļoti elastīgs, nepieciešama īpaša datu struktūra (meklēšanas vērtībai, kas nodota MATCH funkcijai, jābūt precīzi vienādai ar atgrieztās kolonnas nosaukumu), nevar strādāt ar meklēšanas vērtībām, kas pārsniedz 255 rakstzīmes.

Lai iegūtu vairāk informācijas un formulu piemērus, skatiet:

• Excel Vlookup un saskaņošana
• Excel Hlookup un saskaņošana

OFFSET MATCH

Sarežģītāka, bet jaudīgāka meklēšanas formula, kurā nav daudzu Vlookup un Hlookup ierobežojumu.

V-izpētes formula

Kur:

• n - ir meklēšanas kolonnas nobīde, t. i., kolonnu skaits, kas jāpārvieto no sākuma punkta uz meklēšanas kolonnu.
• m - ir atgriešanās kolonnas nobīde, t. i., kolonnu skaits, kas jāpārvieto no sākuma punkta uz atgriešanās kolonnu.

H-izpētes formula

Kur:

• n - ir meklēšanas rindas nobīde, t. i., rindu skaits, kas jāpārvieto no sākuma punkta uz meklēšanas rindu.
• m - ir atgriešanās rindas nobīde, t. i., rindu skaits, kas jāpārvieto no sākuma punkta uz atgriešanās rindu.

Matricas meklēšanas formula (pēc rindas un kolonnas)

Lūdzu, pievērsiet uzmanību, ka šī ir masīva formula, kas tiek ievadīta, vienlaicīgi nospiežot taustiņus Ctrl + Shift + Enter.

Plusi : Ļauj veikt kreisās puses V-izskatu, augšējo H-izskatu un divvirzienu meklēšanu (pēc kolonnas un rindas vērtībām), ko neietekmē datu kopas izmaiņas.

Mīnusi : Sarežģīta un grūti iegaumējama sintakse.

Lai iegūtu plašāku informāciju un formulu piemērus, skatiet: Funkcijas OFFSET lietošana programmā Excel.

INDEX MATCH

Tas ir labākais veids, kā veikt vertikālu vai horizontālu meklēšanu programmā Excel, kas var aizstāt lielāko daļu iepriekš minēto formulu. Indeksu sakritības formula ir mana personīgā izvēle, un es to izmantoju gandrīz visām Excel meklēšanas formulām.

V-izpētes formula

H-izpētes formula

Matricas meklēšanas formula

Klasiskās indeksu sakritības formulas paplašinājums, lai atgrieztu vērtību konkrētas kolonnas un rindas krustpunktā:

Mīnusi : Tikai viens - jums jāatceras formulas sintakse.

Plusi : Visdaudzpusīgākā Lookkup formula programmā Excel, kas daudzējādā ziņā pārspēj Vlookup, Hlookup un Lookup funkcijas:

• Tā var veikt kreiso un augšējo meklēšanu.
• Ļauj droši paplašināt vai sašaurināt uzmeklēšanas tabulu, ievietojot vai dzēšot kolonnas un rindas.
• Pārlūkošanas vērtības lielums nav ierobežots.
• Tā kā indeksa sakritības formula atsaucas uz kolonnām/rindām, nevis uz visu tabulu, tai ir nepieciešama mazāka apstrādes jauda un tā nepalēnina Excel darbību.

Lai uzzinātu vairāk, lūdzu, skatiet:

• INDEX MATCH kā labāka alternatīva VLOOKUP
• INDEX MATCH MATCH formula divdimensiju meklēšanai

Excel uzmeklēšanas salīdzināšanas tabula

Kā redzat, ne visas Excel uzmeklēšanas formulas ir līdzvērtīgas, dažas var apstrādāt vairākas dažādas uzmeklēšanas formulas, bet citas var izmantot tikai konkrētā situācijā. Tālāk tabulā ir izklāstītas katras Excel uzmeklēšanas formulas iespējas.

Excel uzmeklēšanas formulas piemēri

Pirmais solis, lai izlemtu, kuru formulu izmantot konkrētā situācijā, ir noteikt, kāda veida meklēšanu vēlaties veikt. Tālāk ir sniegti formulu piemēri populārākajiem meklēšanas veidiem:

Vertikālā meklēšana kolonnās

Vertikālā meklēšana jeb Vlookup ir process, kurā vienā slejā tiek atrasta meklēšanas vērtība un no citas slejas tiek atgriezta vērtība tajā pašā rindā. Vlookup programmā Excel var veikt dažādos veidos, tostarp:

VLOOKUP funkcija

Ja jūsu meklēšanas vērtības atrodas tabulas kreisajā slejā un neplānojat veikt nekādas strukturālas izmaiņas datu kopā (ne pievienot, ne dzēst kolonnas), varat droši izmantot parasto Vlookup formulu:

=VLOOKUP(G2, $A$2:$E$6, 5, FALSE)

Kur G2 ir meklēšanas vērtība, A2:E6 meklēšanas tabulā, un E ir atgriešanas aile.

VLOOKUP MATCH

Ja strādājat ar "mainīgu" Excel uzmeklēšanas tabulu, kurā jebkurā laikā var ievietot un dzēst kolonnas, padariet savu Vlookup formulu imūnu pret šīm izmaiņām, iestrādājot funkciju Match, kas izveido dinamisku kolonnas atsauci, nevis "cietā kodētā" indeksa numuru:

=VLOOKUP(F2,$A$1:$D$6, MATCH($G$1,$A$1:$D$1, 0), FALSE)

INDEX MATCH - kreisā meklēšana

Tā ir mana iecienītākā formula, kas viegli veic meklēšanu no labās uz kreiso pusi un darbojas nevainojami neatkarīgi no tā, cik daudz kolonnu pievienojat vai dzēšat.

Piemēram, lai meklētu B slejā H2 vērtību un atrastu atbilstību F slejā, izmantojiet šo formulu:

=INDEX($F$2:$F$6,(MATCH(H2,$B$2:$B$6,0)))

Piezīme. Ja plānojat izmantot Vlookup formulu vairāk nekā vienā šūnā, jums vienmēr vajadzētu bloķēt meklēšanas tabulas atsauci izmantojot zīmi $ (absolūtā šūnas atsauce), lai formula tiktu pareizi kopēta uz citām šūnām.

Horizontālā meklēšana rindās

Horizontālā meklēšana ir vertikālās meklēšanas "transponēta" versija, kas meklē horizontāli sakārtotā datu kopā. Citiem vārdiem sakot, tā meklē meklē meklēšanas vērtību vienā rindā un atgriež vērtību tajā pašā pozīcijā no citas rindas.

Pieņemot, ka jūsu meklēšanas vērtība ir B9, meklēšanas tabula ir B1:F5 un jūs vēlaties atgriezt atbilstošo vērtību no 5. rindas, izmantojiet vienu no šādām formulām:

HLOOKUP funkcija

Var meklēt tikai pāri augšējā rindā jūsu datu kopā.

=HLOOKUP(B8, $B$1:$F$5, 5, FALSE)

HLOOKUP MATCH

Tāpat kā tīrā Hlookup, arī šī formula var meklēt tikai augšējā rindā, bet ļauj jums droši ievietot vai dzēst rindas meklēšanas tabulā.

=HLOOKUP(B8, $B$1:$F$5, MATCH($A$9, $A$1:$A$5, 0), FALSE)

kur A1:A5 ir rindu virsraksti un A9 ir tās rindas nosaukums, no kuras vēlaties atgriezt atbilstību.

INDEX MATCH

Var meklēt jebkurā rindā , un tai nav neviena no iepriekš minētajām formulām piemītošajiem ierobežojumiem.

=INDEX($B$5:$F$5,(MATCH(B8,$B$1:$F$1,0)))

Divdimensiju meklēšana (pamatojoties uz rindu un kolonnu vērtībām)

Divdimensiju meklēšana (arī matricas meklēšana , dubultā meklēšana vai Divvirzienu meklēšana ) atgriež vērtību, pamatojoties uz atbilstību gan rindās, gan kolonnās. Citiem vārdiem sakot, divdimensiju meklēšanas formula meklē vērtību norādītās rindas un kolonnas krustpunktā.

Pieņemot, ka jūsu uzmeklēšanas tabula ir A1:E6, šūnā H2 ir vērtība, kas jāatrod atbilstībai rindās, un šūnā H3 ir vērtība, kas jāatrod atbilstībai slejās, šādas formulas darbosies labi:

INDEX MATCH MATCH formula :

=INDEX($A$1:$E$6, MATCH(H2,$A$1:$A$6,0), MATCH(H3,$A$1:$E$1,0))

OFFSET MATCH MATCH formula :

=OFFSET($A$1,MATCH(H2,$A$2:$A$6,0),MATCH(H3,$B$1:$E$1,0))

Papildus iepriekš minētajām formulām ir arī vairāki citi veidi, kā Excel programmā Excel veikt matricas meklēšanu, un sīkāku informāciju par to var atrast sadaļā Kā veikt divvirzienu meklēšanu programmā Excel.

Trīsdimensiju meklēšana

Trīsdimensiju meklēšana nozīmē meklēšanu pēc 3 dažādām meklēšanas vērtībām. Pieņemsim, ka turpmāk dotajā datu kopā vēlaties meklēt konkrētu gadu (H2), pēc tam konkrētu nosaukumu šī gada datos (H3) un pēc tam atgriezt konkrēta mēneša vērtību (H4).

Uzdevumu var izpildīt, izmantojot šādu masīva formulu (lai to izpildītu pareizi, lūdzu, atcerieties nospiest Ctrl + Shift + Enter):

=INDEX($A$1:$E$12,MIN(IF((ROW($A$1:$A$12)>MATCH(H2,$A$1:$A$12,0))*($A$1:$A$12=H3),ROW($A$1:$A$12),"")),MATCH(H4,$A$1:$E$1,0)))

Meklēšana ar vairākiem kritērijiem

Lai varētu novērtēt vairākus kritērijus, mums būs jāmaina klasiskā indeksu sakritības formula, lai tā kļūtu par masīva formulu:

Izmantojot meklēšanas tabulu, kas atrodas A1:C11, meklēsim atbilstību pēc 2 kritērijiem: A slejā meklējiet vērtību šūnā F1, bet B slejā - vērtību šūnā F2:

=INDEX($A$1:$C$11, MATCH(1, (F1=$A$1:$A$11) * (F2=$B$1:$B$11),0), 3))

Kā parasti, nospiediet Ctrl + Shift + Enter, lai formula tiktu novērtēta kā masīva formula.

Sīkāku formulas loģikas skaidrojumu skatiet sadaļā INDEX MATCH, lai meklētu pēc vairākiem kritērijiem.

Meklēšana, lai atgrieztu vairākas vērtības

Neatkarīgi no tā, kādu Excel meklēšanas funkciju izmantojat (LOOKUP, VLOOKUP vai HLOOKUP), tā var atgriezt tikai vienu atbilstību. Lai iegūtu visas atrastās atbilstības, jums būtu jāizmanto 6 dažādas funkcijas, kas apvienotas masīva formulā:

Kur:

• m ir atgriešanas diapazona pirmās šūnas rindas numurs mīnus 1.
• n ir pirmās formulas šūnas rindas numurs mīnus 1.

Ja meklēšanas vērtība atrodas šūnā E2, meklēšanas diapazons - A2:A11, atgriešanas diapazons - B2:B11 un pirmā formulas šūna - 2. rindā, jūsu meklēšanas formula ir šāda:

=IFERROR(INDEX($B$2:$B$11, SMALL(IF($E$2 =$A$2:$A$11, ROW($B$2:$B$11 )- 1,""), ROW() - 1 )),"")

Lai formula dotu vairākus atbilžu variantus, ievadiet to pirmajā šūnā (F2), nospiediet Ctrl + Shift + Enter un pēc tam kopējiet formulu uz citām šūnām kolonnas lejasdaļā.

Sīkāku skaidrojumu par iepriekš minēto formulu un citiem veidiem, kā atgriezt vairākas vērtības, skatiet sadaļā Kā ar Vlookup atgriezt vairākus rezultātus.

Pārlūkošana (no 2 pārlūkošanas tabulām)

Situācijās, kad galvenajai tabulai un uzmeklēšanas tabulai, no kuras vēlaties iegūt datus, nav kopīgas kolonnas, varat izmantot papildu uzmeklēšanas tabulu, lai noteiktu atbilstību, piemēram, šādi:

Vērtību iegūšana no Summa slejā Lookup_table2 , izmantojiet šādu formulu:

=VLOOKUP(VLOOKUP(A2, Lookup_table1!$A$1:$B$6, 2, FALSE), Lookup_table2!$A$1:$B$6, 2, FALSE)

Kā redzams zemāk redzamajā ekrānšāviņas attēlā, mūsu iegultā meklēšanas formula darbojas nevainojami:

Secīga Vlookups no vairākām lapām

Lai veiktu secīgu VlookUP, pamatojoties uz to, vai iepriekšējā meklēšana ir bijusi veiksmīga vai neveiksmīga, kopā ar VLOOKUP izmantojiet ligzdotas IFERROR funkcijas, lai secīgi novērtētu vairākus nosacījumus:

Ja pirmais Vlookup neizdodas, IFERROR izsauc kļūdu un palaidīs vēl vienu Vlookup. Ja arī otrajā Vlookup nekas netiek atrasts, otrais IFERROR izsauc kļūdu un palaidīs trešo Vlookup, un tā tālāk. Ja visi Vlookup neizdodas, pēdējais IFERROR atdod "nav atrasts" vai jebkuru citu ziņojumu, ko jūs sniedzat formulai.

Piemēram, mēģināsim iegūt summu no 3 dažādām lapām:

=IFERROR(VLOOKUP(B1,A6:B9,2,0), IFERROR(VLOOKUP(B1,D6:E9,2,0), IFERROR(VLOOKUP(B1,G6:H9,2,0), "Nav atrasts"))))

Rezultāts būs līdzīgs šim:

Lai iegūtu vairāk informācijas, skatiet sadaļu Kā lietot ieliktās IFERROR funkcijas programmā Excel.

Uzrādes meklēšana pēc burtu un ciparu izteiksmēm

Kā jūs droši vien zināt, visas Excel meklēšanas funkcijas pēc savas būtības nespēj atšķirt mazos un lielos burtus. Lai liktu meklēšanas formulai atšķirt mazos un lielos burtus, izmantojiet LOOKUP vai INDEX MATCH kombinācijā ar funkciju EXACT. Es personīgi izvēlos INDEX MATCH, jo tā neprasa vērtību šķirošanu meklēšanas kolonnā, kā to dara LOOKUP funkcija, var veikt gan no kreisās puses uz labo, gan no kreisās puses uz labo.un meklēšanu no labās puses uz kreiso, un tas lieliski darbojas ar visiem datu tipiem.

Ja G2 ir meklēšanas vērtība, A - sleja, pret kuru meklēt, un E - sleja, no kuras jāatgriež atbilstības, mūsu uz mazajiem un lielajiem burtiem jutīgā meklēšanas formula ir šāda:

=INDEX($E$2:$E$6, MATCH(TRUE, EXACT($A$2:$A$6,G2),0))

Tā kā tas ir masīva formula , lai to pareizi pabeigtu, nospiediet taustiņus Ctrl + Shift + Enter.

Vairāk formulu piemēru skatiet sadaļā Kā veikt uz mazajiem un lielajiem burtiem atkarīgu meklēšanu programmā Excel.

Meklēšanas daļēja virknes atbilstība

Meklēšana pēc daļējas atbilstības ir viens no sarežģītākajiem uzdevumiem programmā Excel, kam nav universāla risinājuma. Kādu formulu izmantot, ir atkarīgs no tā, kādas atšķirības ir starp jūsu meklēšanas vērtībām un vērtībām meklētajā slejā. Vairumā gadījumu jūs izmantosiet funkciju LEFT, RIGHT vai MID, lai iegūtu vērtību kopīgo daļu, un pēc tam šo daļu sniegsiet funkcijai lookup_value Vlookup funkcijas argumentu, kā tas ir izdarīts šajā formulā:

=VLOOKUP(RIGHT(D2,4), $A$2:$B$6, 2, FALSE)

Kur D2 ir meklēšanas vērtība, A2:B6 ir meklēšanas tabula un 2 ir tās kolonnas indeksa numurs, no kuras jāatgriež atbilstības.

Lai uzzinātu citus veidus, kā veikt daļējas atbilstības meklēšanu programmā Excel, skatiet sadaļu Kā apvienot divas darblapas pēc daļējas atbilstības.

Tas ir veids, kā Excel programmā izmantot meklēšanas funkcijas. Lai sīkāk aplūkotu šajā pamācībā aplūkotās formulas, varat lejupielādēt mūsu Excel meklēšanas formulu piemērus.

Veids bez formulas, kā veikt meklēšanu programmā Excel

Pats par sevi saprotams, ka Excel uzmeklēšana nav triviāls uzdevums. Ja sperat pirmos soļus, apgūstot Excel jomu, uzmeklēšanas formulas var šķist diezgan mulsinošas un grūti saprotamas. Taču, lūdzu, nejūtieties apbēdināti, šīs prasmes lielākajai daļai lietotāju nav dabiskas!

Lai atvieglotu darbu iesācējiem, mēs izveidojām īpašu rīku - apvienošanas tabulas vedni, ar kuru var meklēt, salīdzināt un apvienot tabulas, neizmantojot nevienu formulu. Turklāt tas nodrošina vairākas patiešām unikālas opcijas, ko var izmantot pat pieredzējuši Excel lietotāji:

• Pārlūkošana pēc vairāki kritēriji t. i., izmantot vienu vai vairākas kolonnas kā unikālo(-os) identifikatoru(-us).
• Atjaunināt vērtības esošajās kolonnās un pievienot jaunu kolonnas no uzmeklēšanas tabulas.
• Atgriezties vairākas spēles Ja to izmanto kopā ar rindiņu apvienošanas vedni, tas var pat atgriezt vairākus rezultātus vienā šūnā, atdalītus ar komatu vai citādi (piemēru var atrast šeit).
• Un vēl.

Darbs ar tabulas apvienošanas vedni ir vienkāršs un intuitīvs. Viss, kas jums jādara, ir:

1. Izvēlieties galveno tabulu, no kuras vēlaties iegūt atbilstošās vērtības.
2. Atlasiet meklēšanas tabulu, no kuras tiks atlasītas atbilstības.
3. Definējiet vienu vai vairākas kopīgas kolonnas.
4. Izvēlieties kolonnas, kas tiks atjauninātas un/vai pievienotas tabulas beigās.
5. Pēc izvēles atlasiet vienu vai vairākas papildu apvienošanas opcijas.
6. Noklikšķiniet uz Apdare un pēc brīža būs rezultāts!

Ja vēlaties izmēģināt papildinājumu savās darblapās, varat lejupielādēt mūsu Ultimate Suite izmēģinājuma versiju, kurā iekļauti visi mūsu Excel rīki, kas ietaupa laiku (kopā vairāk nekā 70 rīki un vairāk nekā 300 funkcijas!).

Pieejamās lejupielādes

Excel meklētājformulas piemēri (.xlsx fails)

Ultimate Suite 14 dienu pilnībā funkcionāla versija (.exe fails)