Učebnica vysvetľuje základy vyhľadávania v programe Excel, ukazuje silné a slabé stránky jednotlivých funkcií vyhľadávania programu Excel a poskytuje množstvo príkladov, ktoré vám pomôžu rozhodnúť sa, ktorý vyhľadávací vzorec je najlepšie použiť v konkrétnej situácii.

Vyhľadávanie konkrétnej hodnoty v rámci súboru údajov je jednou z najčastejších úloh v programe Excel. Napriek tomu neexistuje žiadny "univerzálny" vyhľadávací vzorec vhodný pre všetky situácie. Dôvodom je, že pojem "vyhľadávanie" môže označovať rôzne veci: môžete vyhľadávať vertikálne v stĺpci, horizontálne v riadku alebo v priesečníku riadku a stĺpca, vyhľadávať pomocou jedného alebo viacerých kritérií, vrátiťprvá nájdená zhoda alebo viacero zhôd, vyhľadávanie s rozlišovaním veľkých a malých písmen atď.

Na tejto stránke nájdete zoznam najdôležitejších funkcií Excelu Lookup s príkladmi vzorcov a podrobnými návodmi, ktoré sú prepojené pre vašu potrebu.

Vyhľadávanie v programe Excel - základy

Skôr ako sa ponoríme do tajuplných zákutí vyhľadávacích vzorcov programu Excel, definujme si kľúčové pojmy, aby sme boli vždy na rovnakej strane.

Vyhľadávanie - hľadanie zadanej hodnoty v tabuľke údajov.

Vyhľadávacia hodnota - hodnotu, ktorú chcete vyhľadať.

Návratová hodnota (zodpovedajúca hodnota alebo zhoda) - hodnota na rovnakej pozícii ako hodnota vyhľadávania, ale v inom stĺpci alebo riadku (v závislosti od toho, či sa vykonáva vertikálne alebo horizontálne vyhľadávanie).

Vyhľadávacia tabuľka . V informatike je vyhľadávacia tabuľka pole údajov, ktoré sa vo všeobecnosti používa na mapovanie vstupných hodnôt na výstupné hodnoty. Z hľadiska tohto učebného materiálu nie je vyhľadávacia tabuľka programu Excel nič iné ako rozsah buniek, v ktorých sa hľadá vyhľadávaná hodnota.

Hlavný stôl (hlavná tabuľka) - tabuľka, do ktorej sa načítajú zodpovedajúce hodnoty.

Vaša vyhľadávacia tabuľka a hlavná tabuľka môžu mať rôznu štruktúru a veľkosť, vždy by však mali obsahovať aspoň jednu spoločný jedinečný identifikátor , t. j. stĺpec alebo riadok, ktorý obsahuje rovnaké údaje, v závislosti od toho, či chcete vykonať vertikálne alebo horizontálne vyhľadávanie.

Na nasledujúcom obrázku je zobrazená vzorová vyhľadávacia tabuľka, ktorá sa použije v mnohých z nasledujúcich príkladov.

Funkcie vyhľadávania programu Excel

Nižšie uvádzame stručný prehľad najobľúbenejších vzorcov na vyhľadávanie v programe Excel, ich hlavné výhody a nevýhody.

Funkcia LOOKUP

Funkcia LOOKUP v programe Excel dokáže vykonávať najjednoduchšie typy vertikálnych a horizontálnych vyhľadávaní.

Klady : Jednoduché používanie.

Nevýhody : Obmedzená funkčnosť, nedokáže pracovať s neusporiadanými údajmi (vyžaduje zoradenie stĺpca/riadku vyhľadávania vzostupne).

Ďalšie informácie nájdete v časti Ako používať funkciu LOOKUP aplikácie Excel.

Funkcia VLOOKUP

Je to vylepšená verzia funkcie LOOKUP špeciálne navrhnutá na vertikálne vyhľadávanie v stĺpcoch.

Klady : Pomerne jednoduché použitie, môže pracovať s presnou a približnou zhodou.

Nevýhody : Nemôže sa pozerať na svoju ľavú stranu, prestane fungovať, keď sa stĺpec vloží do vyhľadávacej tabuľky alebo sa z nej odstráni, hodnota vyhľadávania nemôže prekročiť 255 znakov, pri veľkých súboroch údajov vyžaduje veľký výpočtový výkon.

Viac informácií nájdete v časti Excel VLOOKUP tutoriál pre začiatočníkov.

Funkcia HLOOKUP

Je to horizontálna obdoba funkcie VLOOKUP, ktorá hľadá hodnotu v prvom riadku vyhľadávacej tabuľky a vracia hodnotu na rovnakej pozícii z iného riadku.

Klady : Jednoduché používanie, môže vrátiť presné a približné zhody.

Nevýhody : Môže vyhľadávať len v najvyššom riadku vyhľadávacej tabuľky, je ovplyvnený vkladaním alebo odstraňovaním riadkov, hodnota vyhľadávania by mala byť menšia ako 255 znakov.

Ďalšie informácie nájdete v časti Ako používať HLOOKUP v programe Excel.

VLOOKUP MATCH / HLOOKUP MATCH

Vďaka dynamickému odkazu na stĺpec alebo riadok vytvorenému funkciou MATCH je tento vyhľadávací vzorec programu Excel odolný voči zmenám vykonaným v súbore údajov. Inými slovami, s určitou pomocou funkcie MATCH môžu funkcie VLOOKUP a HLOOKUP vrátiť správne hodnoty bez ohľadu na to, koľko stĺpcov/riadkov bolo vložených do vyhľadávacej tabuľky alebo z nej odstránených.

Vzorec pre vertikálne vyhľadávanie

Vzorec pre horizontálne vyhľadávanie

Klady : Vylepšenie bežných vzorcov Hlookup a Vlookup, ktoré sú odolné voči vkladaniu alebo vymazávaniu údajov.

Nevýhody : Nie je veľmi flexibilný, vyžaduje špecifickú dátovú štruktúru (vyhľadávacia hodnota dodaná funkcii MATCH by sa mala presne rovnať názvu návratového stĺpca), nemôže pracovať s vyhľadávacími hodnotami presahujúcimi 255 znakov.

Ďalšie informácie a príklady vzorcov nájdete na:

• Excel Vlookup a zhoda
• Excel Hlookup a zhoda

OFFSET MATCH

Zložitejší, ale výkonnejší vzorec na vyhľadávanie, ktorý nemá mnohé obmedzenia Vlookup a Hlookup.

Vzorec pre vyhľadávanie V

Kde:

• n - je posunutie vyhľadávacieho stĺpca, t. j. počet stĺpcov, ktoré sa majú presunúť z počiatočného bodu do vyhľadávacieho stĺpca.
• m - je posunutie návratového stĺpca, t. j. počet stĺpcov, ktoré sa majú presunúť z počiatočného bodu do návratového stĺpca.

Vzorec pre H-Lokup

Kde:

• n - je posun vyhľadávacieho riadku, t. j. počet riadkov, ktoré sa majú presunúť z počiatočného bodu do vyhľadávacieho riadku.
• m - je posunutie návratového riadku, t. j. počet riadkov, ktoré sa majú presunúť z počiatočného bodu do návratového riadku.

Vzorec pre vyhľadávanie v matici (podľa riadkov a stĺpcov)

Upozorňujeme, že ide o vzorec poľa, ktorý sa zadáva súčasným stlačením klávesov Ctrl + Shift + Enter.

Klady : Umožňuje vykonať ľavostranný Vlookup, horný Hlookup a obojsmerné vyhľadávanie (podľa hodnôt stĺpcov a riadkov), ktoré nie je ovplyvnené zmenami v súbore údajov.

Nevýhody : Zložitá a ťažko zapamätateľná syntax.

Ďalšie informácie a príklady vzorcov nájdete na stránke: Používanie funkcie OFFSET v programe Excel

INDEX MATCH

Je to najlepší spôsob vertikálneho alebo horizontálneho vyhľadávania v programe Excel, ktorý môže nahradiť väčšinu vyššie uvedených vzorcov. Vzorec Index Match je mojou osobnou preferenciou a používam ho takmer na všetky vyhľadávania v programe Excel.

Vzorec pre vyhľadávanie V

Vzorec pre H-Lokup

Vzorec pre vyhľadávanie matíc

Rozšírenie klasického vzorca Index Match na vrátenie hodnoty v priesečníku konkrétneho stĺpca a riadku:

Nevýhody : Len jeden - musíte si zapamätať syntax vzorca.

Klady : Najuniverzálnejší vzorec na vyhľadávanie v programe Excel, ktorý je v mnohých ohľadoch lepší ako funkcie Vlookup, Hlookup a Lookup:

• Môže vykonávať ľavé a horné vyhľadávanie.
• Umožňuje bezpečné rozšírenie alebo zbalenie vyhľadávacej tabuľky vložením alebo odstránením stĺpcov a riadkov.
• Žiadne obmedzenie veľkosti hodnoty vyhľadávania.
• Funguje rýchlejšie. Keďže vzorec Index Match odkazuje na stĺpce/riadky, a nie na celú tabuľku, vyžaduje si menej výpočtového výkonu a nespomalí váš Excel.

Viac informácií nájdete na:

• INDEX MATCH ako lepšia alternatíva k VLOOKUP
• Vzorec INDEX MATCH MATCH pre dvojrozmerné vyhľadávanie

Porovnávacia tabuľka Excel Lookup

Ako vidíte, nie všetky vyhľadávacie vzorce programu Excel sú rovnocenné, niektoré dokážu spracovať viacero rôznych vyhľadávacích vzorcov, zatiaľ čo iné možno použiť len v konkrétnej situácii. V nasledujúcej tabuľke sú uvedené možnosti jednotlivých vyhľadávacích vzorcov v programe Excel.

Príklady vyhľadávacích vzorcov programu Excel

Prvým krokom pri rozhodovaní, ktorý vzorec použiť v konkrétnej situácii, je určiť, aký druh vyhľadávania chcete vykonať. Nižšie nájdete príklady vzorcov pre najobľúbenejšie typy vyhľadávania:

Vertikálne vyhľadávanie v stĺpcoch

Vertikálne vyhľadávanie alebo Vlookup je proces hľadania hodnoty v jednom stĺpci a vrátenia hodnoty v tom istom riadku z iného stĺpca. Vlookup v programe Excel možno vykonať rôznymi spôsobmi, vrátane:

Funkcia VLOOKUP

Ak sa hodnoty vyhľadávania nachádzajú v ľavom stĺpci tabuľky a neplánujete vykonávať žiadne štrukturálne zmeny v súbore údajov (ani pridávať, ani odstraňovať stĺpce), môžete pokojne použiť bežný vzorec Vlookup:

=VLOOKUP(G2, $A$2:$E$6, 5, FALSE)

Kde G2 je vyhľadávacia hodnota, A2:E6 vo vyhľadávacej tabuľke a E je návratový stĺpec.

VLOOKUP MATCH

Ak pracujete s "premenlivou" vyhľadávacou tabuľkou programu Excel, do ktorej možno kedykoľvek vkladať a odstraňovať stĺpce, zabezpečte, aby bol vzorec Vlookup voči týmto zmenám odolný, a to vložením funkcie Match, ktorá namiesto "natvrdo" zadaného indexového čísla vytvorí dynamický odkaz na stĺpec:

=VLOOKUP(F2,$A$1:$D$6, MATCH($G$1,$A$1:$D$1, 0), FALSE)

INDEX MATCH - ľavé vyhľadávanie

Je to môj obľúbený vzorec, ktorý si ľahko poradí s vyhľadávaním sprava doľava a funguje bezchybne bez ohľadu na to, koľko stĺpcov pridáte alebo odstránite.

Ak chcete napríklad vyhľadať hodnotu v stĺpci B a vrátiť zhodu zo stĺpca F, použite tento vzorec:

=INDEX($F$2:$F$6,(MATCH(H2,$B$2:$B$6,0))

Poznámka: Ak plánujete použiť vzorec Vlookup vo viac ako jednej bunke, mali by ste vždy uzamknúť odkaz na vyhľadávaciu tabuľku pomocou znaku $ (absolútny odkaz na bunku), aby sa vzorec správne skopíroval do iných buniek.

Horizontálne vyhľadávanie v riadkoch

Horizontálne vyhľadávanie je "transponovaná" verzia vertikálneho vyhľadávania, ktorá vyhľadáva v horizontálne usporiadanom súbore údajov. Inými slovami, vyhľadáva hodnotu vyhľadávania v jednom riadku a vracia hodnotu na rovnakej pozícii z iného riadku.

Za predpokladu, že hodnota vyhľadávania je v B9, tabuľka vyhľadávania je B1:F5 a chcete vrátiť zhodnú hodnotu z riadku 5, použite jeden z nasledujúcich vzorcov:

Funkcia HLOOKUP

Môže sa pozrieť len cez horný riadok vo vašom súbore údajov.

=HLOOKUP(B8, $B$1:$F$5, 5, FALSE)

HLOOKUP MATCH

Podobne ako čistý Hlookup, tento vzorec môže vyhľadávať len v najvyššom riadku, ale umožňuje vám bezpečne vkladať alebo odstraňovať riadky vo vyhľadávacej tabuľke.

=HLOOKUP(B8, $B$1:$F$5, MATCH($A$9, $A$1:$A$5, 0), FALSE)

Kde A1:A5 sú hlavičky riadkov a A9 je názov riadku, z ktorého chcete vrátiť zhody.

INDEX MATCH

Môže pozrieť sa do ľubovoľného riadku a nemá žiadne z obmedzení uvedených vzorcov.

=INDEX($B$5:$F$5,(MATCH(B8,$B$1:$F$1,0))

Dvojrozmerné vyhľadávanie (na základe hodnôt riadkov a stĺpcov)

Dvojrozmerné vyhľadávanie (tzv. vyhľadávanie matíc , dvojité vyhľadávanie alebo 2-cestné vyhľadávanie ) vráti hodnotu na základe zhody v riadkoch aj stĺpcoch. Inými slovami, dvojrozmerný vyhľadávací vzorec hľadá hodnotu v priesečníku zadaného riadku a stĺpca.

Za predpokladu, že vaša vyhľadávacia tabuľka je A1:E6, bunka H2 obsahuje hodnotu, ktorá sa má porovnať v riadkoch, a bunka H3 obsahuje hodnotu, ktorá sa má porovnať v stĺpcoch, budú fungovať nasledujúce vzorce:

Vzorec INDEX MATCH MATCH :

=INDEX($A$1:$E$6, MATCH(H2,$A$1:$A$6,0), MATCH(H3,$A$1:$E$1,0))

Vzorec OFFSET MATCH MATCH :

=OFFSET($A$1,MATCH(H2,$A$2:$A$6,0),MATCH(H3,$B$1:$E$1,0))

Okrem vyššie uvedených vzorcov existuje niekoľko ďalších spôsobov, ako v programe Excel vykonávať maticové vyhľadávanie, a všetky podrobnosti nájdete v článku Ako v programe Excel vykonávať dvojcestné vyhľadávanie.

Trojrozmerné vyhľadávanie

Trojrozmerné vyhľadávanie znamená vyhľadávanie podľa 3 rôznych hodnôt vyhľadávania. V nižšie uvedenom súbore údajov predpokladajme, že chcete vyhľadať konkrétny rok (H2), potom konkrétne meno v rámci údajov tohto roku (H3) a potom vrátiť hodnotu pre konkrétny mesiac (H4).

Úlohu možno vykonať pomocou nasledujúceho vzorca poľa (nezabudnite stlačiť klávesovú skratku Ctrl + Shift + Enter, aby ste ho správne dokončili):

=INDEX($A$1:$E$12,MIN(IF((ROW($A$1:$A$12)>MATCH(H2,$A$1:$A$12,0))*($A$1:$A$12=H3),ROW($A$1:$A$12),")),MATCH(H4,$A$1:$E$1,0))

Vyhľadávanie s viacerými kritériami

Aby sme mohli vyhodnotiť viacero kritérií, musíme upraviť klasický vzorec Index Match tak, aby sa zmenil na vzorec poľa:

S vyhľadávacou tabuľkou nachádzajúcou sa v A1:C11 nájdime zhodu podľa 2 kritérií: v stĺpci A vyhľadáme hodnotu v bunke F1 a v stĺpci B hodnotu v bunke F2:

=INDEX($A$1:$C$11, MATCH(1, (F1=$A$1:$A$11) * (F2=$B$1:$B$11),0), 3)

Ako zvyčajne, stlačte klávesovú skratku Ctrl + Shift + Enter, aby sa vzorec vyhodnotil ako vzorec poľa.

Podrobné vysvetlenie logiky vzorca nájdete v časti INDEX MATCH na vyhľadávanie pomocou viacerých kritérií.

Vyhľadávanie na vrátenie viacerých hodnôt

Bez ohľadu na to, akú funkciu Excel Lookup použijete (LOOKUP, VLOOKUP alebo HLOOKUP), môže vrátiť len jednu zhodu. Ak chcete získať všetky nájdené zhody, museli by ste použiť 6 rôznych funkcií skombinovaných do vzorca poľa:

Kde:

• m je číslo riadku prvej bunky v rozsahu vrátenia mínus 1.
• n je číslo riadku prvej bunky vzorca mínus 1.

Keď sa hodnota vyhľadávania nachádza v bunke E2, rozsah vyhľadávania v A2:A11, rozsah návratu v B2:B11 a prvá bunka vzorca v riadku 2, váš vyhľadávací vzorec má nasledujúci tvar:

=IFERROR(INDEX($B$2:$B$11, SMALL(IF($E$2 =$A$2:$A$11, ROW($B$2:$B$11 )- 1,""), ROW() - 1 )),"")

Ak chcete, aby vzorec vrátil viacnásobnú zhodu, zadajte ho do prvej bunky (F2), stlačte klávesovú skratku Ctrl + Shift + Enter a potom vzorec skopírujte do ďalších buniek v stĺpci.

Podrobné vysvetlenie uvedeného vzorca a ďalších spôsobov vrátenia viacerých hodnôt nájdete v časti Ako vrátiť viacero výsledkov pomocou Vlookup.

Vnorené vyhľadávanie (z 2 vyhľadávacích tabuliek)

V situáciách, keď hlavná tabuľka a vyhľadávacia tabuľka, z ktorej chcete čerpať údaje, nemajú spoločný stĺpec, môžete na zistenie zhody použiť ďalšiu vyhľadávaciu tabuľku, napríklad takto:

Získanie hodnôt z Suma stĺpec v Lookup_table2 , použijete tento vzorec:

=VLOOKUP(VLOOKUP(A2, Lookup_table1!$A$1:$B$6, 2, FALSE), Lookup_table2!$A$1:$B$6, 2, FALSE)

Ako je znázornené na nasledujúcom obrázku, náš vnorený vyhľadávací vzorec funguje dokonale:

Postupné vyhľadávanie z viacerých hárkov

Ak chcete vykonávať postupné vyhľadávanie na základe toho, či predchádzajúce vyhľadávanie bolo úspešné alebo neúspešné, použite vnorené funkcie IFERROR spolu s funkciami VLOOKUP na postupné vyhodnotenie viacerých podmienok:

Ak prvý Vlookup zlyhá, IFERROR zachytí chybu a spustí ďalší Vlookup. Ak ani druhý Vlookup nič nenájde, druhý IFERROR zachytí chybu a spustí tretí Vlookup atď. Ak všetky Vlookupy zlyhajú, posledný IFERROR vráti "not found" alebo akúkoľvek inú správu, ktorú zadáte do vzorca.

Ako príklad si skúsme vytiahnuť sumu z 3 rôznych hárkov:

=IFERROR(VLOOKUP(B1,A6:B9,2,0), IFERROR(VLOOKUP(B1,D6:E9,2,0), IFERROR(VLOOKUP(B1,G6:H9,2,0), "Nenašlo sa"))

Výsledok bude vyzerať podobne:

Ďalšie informácie nájdete v časti Ako používať vnorené funkcie IFERROR v programe Excel.

Vyhľadávanie citlivé na veľkosť písmen

Ako pravdepodobne viete, všetky vyhľadávacie funkcie programu Excel vo svojej podstate nerozlišujú veľké a malé písmená. Ak chcete prinútiť vyhľadávací vzorec, aby rozlišoval medzi malými a veľkými písmenami v texte, použite buď LOOKUP, alebo INDEX MATCH v kombinácii s funkciou EXACT. Osobne sa rozhodujem pre INDEX MATCH, pretože nevyžaduje triedenie hodnôt v stĺpci vyhľadávania ako funkcia LOOKUP, dokáže vykonať aj ľavý-pravýa vyhľadávania sprava doľava a funguje dokonale pre všetky typy údajov.

Keď je G2 hodnota vyhľadávania, A - stĺpec, podľa ktorého sa má vyhľadávať, a E - stĺpec, z ktorého sa majú vrátiť zhody, náš vzorec na vyhľadávanie s rozlišovaním veľkých a malých písmen vyzerá takto:

=INDEX($E$2:$E$6, MATCH(TRUE, EXACT($A$2:$A$6,G2),0))

Keďže ide o vzorec poľa , nezabudnite stlačiť klávesovú skratku Ctrl + Shift + Enter, aby ste ho správne dokončili.

Ďalšie príklady vzorcov nájdete v časti Ako v programe Excel vyhľadávať s ohľadom na veľkosť písmen.

Vyhľadávanie čiastočnej zhody reťazca

Vyhľadávanie podľa čiastočnej zhody je jednou z najnáročnejších úloh v programe Excel, pre ktorú neexistuje univerzálne riešenie. Ktorý vzorec použiť, závisí od toho, aké rozdiely sú medzi hodnotami vyhľadávania a hodnotami v stĺpci, v ktorom sa má vyhľadávať. Vo väčšine prípadov by ste mali použiť funkciu LEFT, RIGHT alebo MID na extrahovanie spoločnej časti hodnôt a potom túto časť dodať do funkcie lookup_value argument funkcie Vlookup, ako je to v nasledujúcom vzorci:

=VLOOKUP(RIGHT(D2,4), $A$2:$B$6, 2, FALSE)

Kde D2 je hodnota vyhľadávania, A2:B6 je vyhľadávacia tabuľka a 2 je číslo indexu stĺpca, z ktorého sa majú vrátiť zhody.

Ďalšie spôsoby vykonania čiastočnej zhody v programe Excel nájdete v časti Ako zlúčiť dva pracovné hárky pomocou čiastočnej zhody.

Takto sa používajú funkcie Lookup v programe Excel. Ak sa chcete bližšie zoznámiť so vzorcami, o ktorých sa hovorí v tomto návode, môžete si stiahnuť naše príklady vzorcov Excel Lookup.

Spôsob vyhľadávania bez vzorca v programe Excel

Je samozrejmé, že vyhľadávanie v aplikácii Excel nie je triviálna úloha. Ak podnikáte prvé kroky v učení sa sféry Excelu, vyhľadávacie vzorce sa vám môžu zdať dosť mätúce a náročné na pochopenie. Nenechajte sa však odradiť, tieto zručnosti nie sú pre väčšinu používateľov prirodzené!

Aby sme uľahčili prácu začiatočníkom, vytvorili sme špeciálny nástroj Sprievodca zlúčením tabuliek, ktorý dokáže vyhľadávať, porovnávať a spájať tabuľky bez jediného vzorca. Okrem toho poskytuje množstvo naozaj jedinečných možností, ktoré môžu využiť aj pokročilí používatelia aplikácie Excel:

• Vyhľadávanie podľa viaceré kritériá t. j. použiť jeden alebo viacero stĺpcov ako jedinečný identifikátor (identifikátory).
• Aktualizácia hodnoty v existujúcich stĺpcoch a pridať nový stĺpce z vyhľadávacej tabuľky.
• Návrat viacnásobné zhody v samostatných riadkoch. Pri použití v kombinácii so sprievodcom Kombinovať riadky môže dokonca vrátiť viacero výsledkov v jednej bunke, oddelených čiarkou alebo iným spôsobom (príklad nájdete tu).
• A ďalšie.

Práca so Sprievodcom spájaním tabuliek je jednoduchá a intuitívna. Stačí, ak:

1. Vyberte hlavnú tabuľku, do ktorej chcete vytiahnuť zodpovedajúce hodnoty.
2. Vyberte vyhľadávaciu tabuľku, z ktorej chcete vybrať zhody.
3. Definujte jeden alebo viac spoločných stĺpcov.
4. Vyberte stĺpce, ktoré sa majú aktualizovať a/alebo pridať na koniec tabuľky.
5. Voliteľne vyberte jednu alebo viacero ďalších možností zlúčenia.
6. Kliknite na . Dokončenie a za chvíľu budete mať výsledok!

Ak ste zvedaví, či si doplnok vyskúšate na vlastných hárkoch, môžete si stiahnuť skúšobnú verziu nášho balíka Ultimate Suite, ktorý obsahuje všetky naše nástroje na úsporu času pre Excel (spolu viac ako 70 nástrojov a viac ako 300 funkcií!).

Dostupné súbory na stiahnutie

Príklady vyhľadávacích vzorcov programu Excel (.xlsx súbor)

14-dňová plne funkčná verzia balíka Ultimate Suite (.exe súbor)