Tutorial menerangkan asas Carian dalam Excel, menunjukkan kekuatan dan kelemahan setiap fungsi Carian Excel dan menyediakan beberapa contoh untuk membantu anda memutuskan formula carian yang terbaik untuk digunakan dalam situasi tertentu.

Mencari nilai khusus dalam set data ialah salah satu tugas yang paling biasa dalam Excel. Namun begitu, tiada formula carian "universal" yang sesuai untuk semua situasi. Terdapat sebabnya ialah istilah "carian" mungkin menunjukkan pelbagai perkara yang berbeza: anda boleh melihat secara menegak dalam lajur, mendatar dalam satu baris atau di persimpangan baris dan lajur, cari dengan satu atau beberapa kriteria, kembalikan yang pertama ditemui padanan atau berbilang padanan, lakukan carian sensitif huruf besar atau huruf kecil, dan sebagainya.

Pada halaman ini, anda akan menemui senarai fungsi Carian Excel yang paling penting dengan contoh formula dan tutorial mendalam dipautkan untuk rujukan anda.

Excel Lookup - asas

Sebelum kita menyelami kelainan misteri formula Excel Lookup, mari kita tentukan istilah utama untuk memastikan bahawa kita sentiasa pada halaman yang sama.

Cari - mencari nilai yang ditentukan dalam jadual data.

Nilai carian - nilai untuk dicari untuk.

Nilai pulangan (nilai padanan atau padanan) - nilai pada kedudukan yang sama dengan nilai carian tetapi dalam lajur atau baris lain (bergantung pada sama ada anda melakukan menegak atau mendatardalam Excel.

Pencarian tiga dimensi

Pencarian tiga dimensi bermaksud mencari dengan 3 nilai carian berbeza. Dalam set data di bawah, andaikan anda ingin mencari tahun tertentu (H2), kemudian untuk nama tertentu dalam data tahun tersebut (H3), dan kemudian mengembalikan nilai untuk bulan tertentu (H4).

Tugas boleh dicapai dengan formula tatasusunan berikut (sila ingat untuk tekan Ctrl + Shift + Enter untuk menyelesaikannya dengan betul):

=INDEX($A$1:$E$12,MIN(IF((ROW($A$1:$A$12)>MATCH(H2,$A$1:$A$12,0))*($A$1:$A$12=H3),ROW($A$1:$A$12),"")),MATCH(H4,$A$1:$E$1,0))

Cari dengan berbilang kriteria

Untuk dapat menilai berbilang kriteria, kami perlu mengubah suai formula Padanan Indeks klasik supaya ia bertukar menjadi formula tatasusunan:

Dengan jadual carian yang berada dalam A1:C11, mari cari padanan mengikut 2 kriteria: cari lajur A untuk nilai dalam sel F1 dan lajur B untuk nilai dalam sel F2:

=INDEX($A$1:$C$11, MATCH(1, (F1=$A$1:$A$11) * (F2=$B$1:$B$11),0), 3)

Seperti biasa, anda tekan Ctrl + Shift + Enter untuk formula dinilai sebagai formula tatasusunan.

Untuk penjelasan terperinci tentang untuk logik mula, sila lihat INDEX MATCH untuk mencari dengan berbilang kriteria.

Cari untuk mengembalikan berbilang nilai

Mana-mana fungsi Carian Excel yang anda gunakan (LOOKUP, VLOOKUP atau HLOOKUP), ia hanya boleh mengembalikan satu perlawanan. Untuk mendapatkan semua padanan yang ditemui, anda perlu menggunakan 6fungsi berbeza digabungkan dalam formula tatasusunan:

Di mana:

• m ialah nombor baris sel pertama dalam julat pulangan tolak 1.
• n ialah nombor baris sel formula pertama tolak 1.

Dengan nilai carian terletak dalam sel E2, julat carian dalam A2:A11, julat kembali dalam B2:B11 dan sel formula pertama dalam baris 2, formula carian anda mempunyai bentuk berikut:

=IFERROR(INDEX($B$2:$B$11, SMALL(IF($E$2 =$A$2:$A$11, ROW($B$2:$B$11 )- 1,""), ROW() - 1 )),"")

Untuk formula mengembalikan berbilang padanan, anda masukkannya dalam sel pertama (F2), tekan Ctrl + Shift + Enter , dan kemudian salin formula ke sel lain di bawah lajur.

Untuk mendapatkan penjelasan terperinci tentang formula di atas dan cara lain untuk mengembalikan berbilang nilai, sila lihat Cara Vlookup untuk mengembalikan berbilang hasil.

Pencarian bersarang (daripada 2 jadual carian)

Dalam situasi apabila jadual utama anda dan jadual carian daripada wh jika anda ingin menarik data tidak mempunyai lajur biasa, anda boleh menggunakan jadual carian tambahan untuk mewujudkan padanan, seperti ini:

Untuk mendapatkan semula nilai daripada Jumlah lajur dalam Lookup_table2 , anda menggunakan formula berikut:

=VLOOKUP(VLOOKUP(A2, Lookup_table1!$A$1:$B$6, 2, FALSE), Lookup_table2!$A$1:$B$6, 2, FALSE)

Seperti yang ditunjukkan dalam tangkapan skrin di bawah, formula carian bersarang kami berfungsi dengan sempurna:

Vlookup Berjujukan daripada berbilanghelaian

Untuk melakukan Vlookup berjujukan berdasarkan sama ada carian sebelumnya berjaya atau gagal, gunakan fungsi IFERROR bersarang bersama-sama dengan VLOOKUP untuk menilai berbilang keadaan satu demi satu:

Jika Vlookup pertama gagal, IFERROR memerangkap ralat dan menjalankan satu lagi Vlookup. Jika Vlookup kedua juga tidak menemui apa-apa, IFERROR kedua menangkap ralat dan menjalankan Vlookup ketiga, dan seterusnya. Jika semua Vlookup gagal, IFERROR terakhir mengembalikan "tidak dijumpai" atau sebarang mesej lain yang anda berikan kepada formula.

Sebagai contoh, mari cuba tarik jumlah daripada 3 helaian berbeza:

=IFERROR(VLOOKUP(B1,A6:B9,2,0), IFERROR(VLOOKUP(B1,D6:E9,2,0), IFERROR(VLOOKUP(B1,G6:H9,2,0), "Not found")))

Hasilnya akan kelihatan seperti ini:

Untuk mendapatkan maklumat lanjut, sila lihat Cara menggunakan fungsi IFERROR bersarang dalam Excel.

Pencarian sensitif huruf besar/kecil

Seperti yang mungkin anda ketahui, semua fungsi Carian Excel tidak peka huruf besar/kecil mengikut sifatnya. Untuk memaksa formula carian anda membezakan antara teks huruf kecil dan huruf besar, gunakan sama ada LOOKUP atau INDEX MATCH dalam kombinasi dengan fungsi EXACT. Saya sendiri memilih untuk INDEX MATCH kerana ia tidak memerlukan pengisihan nilai dalam lajur carian seperti yang dilakukan oleh fungsi LOOKUP, boleh melakukan kedua-dua carian kiri-ke-kanan dan kanan-ke-kiri dan berfungsi dengan sempurna untuk semua jenis data.

Dengan G2 sebagai nilai carian, A - lajur untuk mencari lawan dan E - lajur untuk mengembalikan padanan daripada, kami formula carian sensitif huruf besar-besaran adalah seperti berikut:

=INDEX($E$2:$E$6, MATCH(TRUE, EXACT($A$2:$A$6,G2),0))

Memandangkan ia merupakan formula tatasusunan , pastikan anda menekan Ctrl + Shift + Enter untuk melengkapkannya dengan betul.

Untuk lebih banyak contoh formula, sila lihat Cara melakukan carian sensitif huruf besar dalam Excel.

Cari padanan rentetan separa

Mencari mengikut separa padanan ialah salah satu tugas yang paling mencabar dalam Excel yang tiada penyelesaian universal. Formula yang hendak digunakan bergantung pada jenis perbezaan yang terdapat antara nilai carian anda dan nilai dalam lajur untuk dicari. Dalam kebanyakan kes, anda akan menggunakan fungsi KIRI, KANAN atau TENGAH untuk mengekstrak bahagian biasa nilai dan kemudian berikan bahagian itu kepada argumen lookup_value bagi fungsi Vlookup seperti yang dilakukan dalam formula berikut:

=VLOOKUP(RIGHT(D2,4), $A$2:$B$6, 2, FALSE)

Di mana D2 ialah nilai carian, A2:B6 ialah jadual carian dan 2 dalam nombor indeks lajur untuk mengembalikan padanan.

Untuk cara lain untuk melakukan carian padanan separa dalam Excel, sila lihat Cara menggabungkan dua lembaran kerja mengikut padanan separa.

Beginilah cara anda menggunakan fungsi Carian dalam Excel. Untuk melihat dengan lebih dekat formula yang dibincangkan dalam tutorial ini, anda dialu-alukan untuk memuat turun formula Carian Excel kamicontoh.

Cara bebas formula untuk melakukan carian dalam Excel

Sudah semestinya carian Excel bukanlah tugas yang remeh. Jika anda mengambil langkah pertama anda dalam mempelajari bidang Excel, formula carian mungkin kelihatan agak mengelirukan dan sukar untuk difahami. Tetapi tolong, jangan berasa kecil hati, kemahiran ini tidak datang secara semula jadi kepada majoriti pengguna!

Untuk memudahkan urusan orang baru, kami mencipta alat khas, Merge Tables Wizard, yang boleh mencari, memadankan dan gabungkan jadual tanpa formula tunggal. Selain itu, ia menyediakan beberapa pilihan yang benar-benar unik yang bahkan pengguna Excel lanjutan boleh mendapat manfaat daripada:

• Cari mengikut berbilang kriteria , iaitu menggunakan satu atau beberapa lajur sebagai pengecam unik (s).
• Kemas kini nilai dalam lajur sedia ada dan tambahkan lajur baharu daripada jadual carian.
• Kembalikan berbilang padanan dalam baris yang berasingan. Apabila digunakan dalam kombinasi dengan Wizard Gabungan Baris, ia juga boleh mengembalikan berbilang hasil dalam sel tunggal, koma atau sebaliknya (contoh boleh didapati di sini).
• Dan banyak lagi.

Bekerja dengan Wizard Merge Tables adalah mudah dan intuitif. Apa yang anda perlu lakukan ialah:

1. Pilih jadual utama anda tempat anda ingin menarik nilai yang sepadan.
2. Pilih jadual carian untuk mengeluarkan padanan.
3. Tentukan satu atau lebih lajur biasa.
4. Pilih lajur untuk dikemas kini atau/dan ditambahkan pada penghujungjadual.
5. Secara pilihan, pilih satu atau lebih pilihan gabungan tambahan.
6. Klik Selesai dan anda akan mendapat keputusan dalam seketika!

Jika anda ingin mencuba tambahan pada lembaran kerja anda sendiri, anda dialu-alukan untuk memuat turun versi percubaan Suite Ultimate kami yang merangkumi semua alatan penjimatan masa kami untuk Excel (dalam jumlah, 70+ alatan dan 300+ ciri!).

Muat turun yang tersedia

Contoh formula Carian Excel (fail .xlsx)

Versi fungsi penuh Ultimate Suite 14 hari (fail .exe)

Jadual carian . Dalam sains komputer, jadual carian ialah susunan data, yang biasanya digunakan untuk memetakan nilai input kepada nilai output. Dari segi tutorial ini, jadual carian Excel tidak lain hanyalah julat sel tempat anda mencari nilai carian.

Jadual utama (jadual induk) - jadual di mana anda tarik nilai padanan.

Jadual carian dan jadual utama anda mungkin mempunyai struktur dan saiz yang berbeza, namun ia harus sentiasa mengandungi sekurang-kurangnya satu pengecam unik biasa , iaitu lajur atau baris yang menyimpan data yang sama , bergantung pada sama ada anda mahu melakukan carian menegak atau mendatar.

Tangkapan skrin berikut menunjukkan jadual carian sampel yang akan digunakan dalam kebanyakan contoh di bawah.

Fungsi Carian Excel

Di bawah ialah ikhtisar ringkas formula paling popular untuk melakukan carian dalam Excel, kelebihan dan kelemahan utamanya.

Fungsi LOOKUP

Fungsi LOOKUP dalam Excel boleh melakukan jenis carian menegak dan mendatar yang paling mudah.

Kebaikan : Mudah digunakan.

Keburukan : Terhad kefungsian, tidak boleh berfungsi dengan data yang tidak diisih (memerlukan pengisihan t la mencari lajur/baris dalam tertib menaik).

Untuk mendapatkan maklumat lanjut, sila lihat Cara menggunakan fungsi Excel LOOKUP.

Fungsi VLOOKUP

Ia adalah versi LOOKUP yang dipertingkatkan. fungsi yang direka khas untuk melakukan carian menegak dalamlajur.

Kebaikan : Agak mudah digunakan, boleh berfungsi dengan padanan tepat dan anggaran.

Keburukan : Tidak boleh melihat ke kiri, berhenti berfungsi apabila lajur dimasukkan ke dalam atau dialih keluar daripada jadual carian, nilai carian tidak boleh melebihi 255 aksara, memerlukan banyak kuasa pemprosesan pada set data yang besar.

Untuk mendapatkan maklumat lanjut, sila lihat tutorial Excel VLOOKUP untuk pemula.

Fungsi HLOOKUP

Ia ialah rakan sejawatan mendatar VLOOKUP yang mencari nilai dalam baris pertama jadual carian dan mengembalikan nilai dalam kedudukan yang sama dari baris lain.

Kebaikan : Mudah digunakan, boleh mengembalikan padanan tepat dan anggaran.

Keburukan : Hanya boleh mencari di baris paling atas jadual carian, dipengaruhi oleh sisipan atau pemadaman baris, nilai carian hendaklah di bawah 255 aksara.

Untuk mendapatkan maklumat lanjut, sila lihat Cara menggunakan HLOOKUP dalam Excel.

VLOOKUP MATCH / HLOOKUP MATCH

A rujukan lajur atau baris dinamik yang dicipta oleh MATCH menjadikan Excel ini lo formula okup kebal terhadap perubahan yang dibuat dalam set data. Dalam erti kata lain, dengan sedikit bantuan daripada MATCH, fungsi VLOOKUP dan HLOOKUP boleh mengembalikan nilai yang betul tidak kira berapa banyak lajur/baris telah dimasukkan atau dipadamkan daripada jadual carian.

Formula untuk carian Menegak

Formula untuk carian Mendatar

Kebaikan : Penambahbaikan berbanding formula Hlookup dan Vlookup biasa yang kebal terhadap sisipan atau pemadaman data.

Keburukan : Tidak begitu fleksibel , memerlukan struktur data tertentu (nilai carian yang dibekalkan kepada fungsi MATCH hendaklah betul-betul sama dengan nama lajur pulangan), tidak boleh berfungsi dengan nilai carian melebihi 255 aksara.

Untuk maklumat lanjut dan contoh formula, sila lihat:

• Excel Vlookup and Match
• Excel Hlookup and Match

OFFSET MATCH

Lebih kompleks tetapi lebih berkuasa formula carian, bebas daripada banyak had Vlookup dan Hlookup.

Formula untuk V-Lookup

Di mana:

• n - ialah lajur carian mengimbangi, i. e. bilangan lajur untuk bergerak dari titik permulaan ke lajur carian.
• m - ialah lajur pulangan mengimbangi, i. e. bilangan lajur untuk bergerak dari titik permulaan ke lajur kembali.

Formula untuk H-Lookup

Di mana:

• n - ialah baris carian diimbangi, i. e. bilangan baris untuk dialihkan dari titik permulaan ke baris carian.
• m - ialah mengimbangi baris kembali, i. e. bilangan baris untuk bergerak dari titik permulaan ke baris balik.

Formula untuk carian matriks (mengikut baris dan lajur)

Sila ambil perhatian bahawa ini ialah formula tatasusunan, yang dimasukkan dengan menekan Ctrl + Shift + Enter kekunci pada masa yang sama.

Kebaikan : Membolehkan melakukan Vlookup sebelah kiri, Hlookup atas dan carian dua hala (mengikut nilai lajur dan baris), tidak terjejas oleh perubahan dalam data set.

Keburukan : Sintaks yang rumit dan sukar diingati.

Untuk mendapatkan maklumat lanjut dan contoh formula, sila lihat: Menggunakan fungsi OFFSET dalam Excel

INDEX MATCH

Ini adalah cara terbaik untuk melakukan carian menegak atau mendatar dalam Excel yang boleh menggantikan kebanyakan formula di atas. Formula Padanan Indeks ialah pilihan peribadi saya dan saya menggunakannya untuk hampir semua carian Excel saya.

Formula untuk Carian V

Formula untuk H-Lookup

Formula untuk carian matriks

Satulanjutan formula Padanan Indeks klasik untuk mengembalikan nilai pada persilangan lajur dan baris tertentu:

Keburukan : Hanya satu - anda perlu mengingati sintaks formula.

Kebaikan : Formula Carian paling serba boleh dalam Excel, lebih baik daripada fungsi Vlookup, Hlookup dan Lookup dalam banyak aspek:

• Ia boleh melakukan carian kiri dan atas.
• Membenarkan memanjangkan atau meruntuhkan jadual carian dengan selamat dengan memasukkan atau memadamkan lajur dan baris.
• Tiada had pada saiz nilai carian.
• Berfungsi dengan lebih pantas. Oleh kerana formula Padanan Indeks merujuk lajur/baris dan bukannya keseluruhan jadual, ia memerlukan kuasa pemprosesan yang kurang dan tidak akan melambatkan Excel anda.

Untuk mendapatkan maklumat lanjut, sila lihat:

• INDEX MATCH sebagai alternatif yang lebih baik kepada VLOOKUP
• INDEX MATCH MATCH formula untuk carian dua dimensi

Jadual perbandingan Excel Lookup

Seperti yang anda lihat , bukan semua formula Carian Excel adalah setara, sesetengahnya boleh mengendalikan beberapa carian berbeza manakala yang lain hanya boleh digunakan dalam situasi tertentu. Jadual di bawah menggariskan keupayaan setiap formula Carian dalam Excel.

Contoh formula carian Excel

Langkah pertama dalam menentukan formula yang hendak digunakan dalam situasi tertentu ialah menentukan jenis carian yang ingin anda lakukan. Di bawah anda akan menemui contoh formula untuk jenis carian yang paling popular:

Pencarian menegak dalam lajur

Pencarian menegak atau Vlookup ialah proses mencari nilai carian dalam satu lajur dan mengembalikan nilai dalam baris yang sama dari lajur lain. Vlookup dalam Excel boleh dilakukan dalam pelbagai cara, termasuk:

Fungsi VLOOKUP

Jika nilai carian anda berada dalam lajur sebelah kiri jadual dan anda tidak bercadang untuk melakukan apa-apa perubahan struktur kepadaset data anda (tidak menambah atau memadam lajur), anda boleh menggunakan formula Vlookup biasa dengan selamat:

=VLOOKUP(G2, $A$2:$E$6, 5, FALSE)

Di mana G2 ialah nilai carian, A2:E6 dalam jadual carian dan E ialah lajur pulangan.

VLOOKUP MATCH

Jika anda menggunakan jadual carian Excel "pembolehubah" di mana lajur boleh disisipkan dan dipadamkan pada bila-bila masa, jadikan formula Vlookup anda kebal terhadap perubahan tersebut dengan membenamkan fungsi Padanan yang mencipta rujukan lajur dinamik dan bukannya nombor indeks "berkod keras":

=VLOOKUP(F2,$A$1:$D$6, MATCH($G$1,$A$1:$D$1, 0), FALSE)

PADAN INDEKS - Carian kiri

Ia adalah formula kegemaran saya yang mengendalikan carian kanan ke kiri dengan mudah dan berfungsi dengan sempurna tidak kira berapa banyak lajur yang anda tambah atau padamkan.

Sebagai contoh, untuk mencari lajur B untuk nilai dalam H2 dan kembalikan padanan dari lajur F, gunakan formula ini:

=INDEX($F$2:$F$6,(MATCH(H2,$B$2:$B$6,0)))

Nota. Apabila anda merancang untuk menggunakan formula Vlookup dalam lebih daripada satu sel, anda hendaklah sentiasa mengunci rujukan jadual carian dengan menggunakan tanda $ (rujukan sel mutlak), supaya formula disalin dengan betul ke sel lain.

Pencarian mendatar dalam baris

Pencarian mendatar ialah versi carian menegak yang "tertukar" yang mencari dalam set data yang disusun secara mendatar. Dalam erti kata lain, ia mencari nilai carian dalam satu baris dan mengembalikan nilai dalam kedudukan yang sama daripada baris lain.

Dengan mengandaikan nilai carian anda dalam B9, jadual carian ialah B1:F5 dananda ingin mengembalikan nilai yang sepadan daripada baris 5, gunakan salah satu daripada formula berikut:

Fungsi HLOOKUP

Boleh mencari hanya merentas baris atas dalam set data anda .

=HLOOKUP(B8, $B$1:$F$5, 5, FALSE)

HLOOKUP MATCH

Seperti Hlookup tulen, formula ini boleh mencari hanya di baris paling atas, tetapi membenarkan anda sisipkan atau padamkan baris dengan selamat dalam jadual carian.

=HLOOKUP(B8, $B$1:$F$5, MATCH($A$9, $A$1:$A$5, 0), FALSE)

Di mana A1:A5 ialah pengepala baris dan A9 ialah nama baris yang anda mahu kembalikan padanan .

PADAN INDEKS

Boleh mencari dalam mana-mana baris dan tidak mempunyai pengehadan formula di atas.

=INDEX($B$5:$F$5,(MATCH(B8,$B$1:$F$1,0)))

Pencarian dua dimensi (berdasarkan nilai baris dan lajur)

Pencarian dua dimensi (aka pencarian matriks , pencarian berganda atau pencarian 2 hala ) mengembalikan nilai berdasarkan padanan dalam kedua-dua baris dan lajur. Dalam erti kata lain, formula carian 2 dimensi mencari nilai di persimpangan baris dan lajur yang ditentukan.

Dengan mengandaikan jadual carian anda ialah A1:E6, sel H2 mengandungi nilai untuk dipadankan pada baris dan H3 memegang nilai untuk dipadankan pada lajur, formula berikut akan berfungsi:

formula PADANAN INDEKS :

=INDEX($A$1:$E$6, MATCH(H2,$A$1:$A$6,0), MATCH(H3,$A$1:$E$1,0))

Formula PADANAN OFFSET MATCH :

=OFFSET($A$1,MATCH(H2,$A$2:$A$6,0),MATCH(H3,$B$1:$E$1,0))

Selain daripada formula di atas, terdapat beberapa cara lain untuk melakukan carian matriks dalam Excel , dan anda boleh mendapatkan butiran penuh dalam Cara melakukan carian 2 hala