Taula de continguts
El tutorial explica els conceptes bàsics de la cerca a Excel, mostra els punts forts i febles de cada funció de cerca d'Excel i ofereix una sèrie d'exemples per ajudar-vos a decidir quina fórmula de cerca s'utilitza millor en una situació concreta.
Buscar un valor específic dins d'un conjunt de dades és una de les tasques més habituals a Excel. No obstant això, no existeix cap fórmula de cerca "universal" adequada per a totes les situacions. La raó és que el terme "cerca" pot indicar una varietat de coses diferents: podeu mirar verticalment en una columna, horitzontalment en una fila o a la intersecció d'una fila i una columna, cercar amb un o diversos criteris, tornar el primer trobat. coincideix o coincideix múltiples, feu una cerca que distingeix entre majúscules i minúscules o no, etc.
En aquesta pàgina, trobareu una llista de les funcions de cerca d'Excel més essencials amb exemples de fórmules i tutorials detallats enllaçat per a la vostra referència.
Excel Lookup: conceptes bàsics
Abans de submergir-nos en els girs arcanics de les fórmules de Excel Lookup, anem a definir els termes clau per assegurar-nos que som sempre a la mateixa pàgina.
Cerca : cerca un valor especificat en una taula de dades.
Valor de cerca : un valor per cercar for.
Valor de retorn (valor coincident o coincidència): un valor a la mateixa posició que el valor de cerca però en una altra columna o fila (segons si ho feu vertical o horitzontal).a Excel.
Cerca tridimensional
La cerca tridimensional significa cercar per 3 valors de cerca diferents. En un conjunt de dades a continuació, suposant que voleu cercar un any específic (H2), després un nom específic dins de les dades d'aquest any (H3) i després retornar un valor per a un mes específic (H4).
La tasca es pot realitzar amb la fórmula de matriu següent (si us plau, recordeu prémer Ctrl + Maj + Retorn per completar-la correctament):
=INDEX($A$1:$E$12,MIN(IF((ROW($A$1:$A$12)>MATCH(H2,$A$1:$A$12,0))*($A$1:$A$12=H3),ROW($A$1:$A$12),"")),MATCH(H4,$A$1:$E$1,0))
Cerca amb diversos criteris
Per poder avaluar diversos criteris, haurem de modificar la fórmula clàssica de concordança d'índexs perquè es converteixi en una fórmula matricial:
INDEX( taula_de_cerca, MATCH (1, ( valor_de_cerca1= columna_de_cerca1) * ( valor_de_cerca2= columna_de_cerca2)*…, 0), número_de_columna_retorn)Amb la taula de cerca que resideix a A1:C11, busquem una coincidència amb 2 criteris: cerqueu a la columna A un valor a la cel·la F1 i la columna B a un valor a la cel·la F2:
=INDEX($A$1:$C$11, MATCH(1, (F1=$A$1:$A$11) * (F2=$B$1:$B$11),0), 3)
Com de costum, premeu Ctrl + Maj + Retorn perquè la fórmula s'avaluï com a fórmula de matriu.
Per obtenir l'explicació detallada de la la lògica de mula, vegeu INDEX MATCH per cercar amb diversos criteris.
Buscar per retornar diversos valors
Sigui quina sigui la funció de cerca d'Excel que utilitzeu (LOOKUP, VLOOKUP o HLOOKUP), només pot tornar un sol partit. Per obtenir totes les coincidències trobades, n'haurieu d'emprar 6diferents funcions combinades en una fórmula de matriu:
IFERROR(INDEX( interval_retorn, SMALL(IF( valor_cerca= interval_cerca, FILA( interval_retorn)- m,""), ROW() - n)),"")On:
- m és el número de fila de la primera cel·la de l'interval de retorn menys 1.
- n és el número de fila de la primera cel·la de la fórmula menys 1.
Amb el valor de cerca situat a la cel·la E2, l'interval de cerca a A2:A11, l'interval de retorn a B2:B11 i la primera cel·la de la fórmula de la fila 2, la fórmula de cerca pren la forma següent:
=IFERROR(INDEX($B$2:$B$11, SMALL(IF($E$2 =$A$2:$A$11, ROW($B$2:$B$11 )- 1,""), ROW() - 1 )),"")
Perquè la fórmula torni diverses coincidències, introduïu-la a la primera cel·la (F2), premeu Ctrl + Maj + Retorn i després copieu la fórmula a altres cel·les de la columna.
Per obtenir una explicació detallada de la fórmula anterior i altres maneres de retornar diversos valors, vegeu Com fer una cerca V per retornar diversos resultats.
Cerca imbricada (a partir de 2 taules de cerca)
En situacions en què la vostra taula principal i la taula de cerca de wh Si voleu extreure dades no teniu una columna comuna, podeu utilitzar una taula de cerca addicional per establir coincidències, com aquesta:
Per recuperar els valors del Amount a la columna Lookup_table2 , feu servir la fórmula següent:
=VLOOKUP(VLOOKUP(A2, Lookup_table1!$A$1:$B$6, 2, FALSE), Lookup_table2!$A$1:$B$6, 2, FALSE)
Com es mostra a la captura de pantalla següent, la nostra fórmula de cerca imbricada funciona perfectament:
Recerca virtual seqüencial de múltiplesfulls
Per realitzar cerques virtuals seqüencials en funció de si una cerca anterior ha estat correcta o fallada, utilitzeu funcions IFERROR imbricades juntament amb BUSCAR V per avaluar diverses condicions una per una:
IFERROR(BUSCARV( …), IFERROR(VLOOKUP( …), IFERROR(VLOOKUP( …),"Not found"))))Si la primera Vlookup falla, IFERROR atrapa l'error i s'executa un altre Vlookup. Si el segon Vlookup tampoc no troba res, el segon IFERROR detecta l'error i executa el tercer Vlookup, i així successivament. Si fallen totes les cerques virtuals, l'últim IFERROR retorna "no trobat" o qualsevol altre missatge que proporcioneu a la fórmula.
Per exemple, intentem extreure la quantitat de 3 fulls diferents:
=IFERROR(VLOOKUP(B1,A6:B9,2,0), IFERROR(VLOOKUP(B1,D6:E9,2,0), IFERROR(VLOOKUP(B1,G6:H9,2,0), "Not found")))
El resultat serà semblant a això:
Per obtenir més informació, vegeu Com utilitzar les funcions IFERROR imbricades a Excel.
Cerca que distingeix entre majúscules i minúscules
Com probablement sabeu, totes les funcions de cerca d'Excel no distingeixen entre majúscules i minúscules per la seva naturalesa. Per forçar la fórmula de cerca a distingir entre el text en minúscula i en majúscula, utilitzeu CERCA o COINCORDACIÓ ÍNDICE en combinació amb la funció EXACTA. Personalment, opto per INDEX MATCH perquè no requereix ordenar valors a la columna de cerca com ho fa la funció LOOKUP, pot fer cerques tant d'esquerra a dreta com de dreta a esquerra i funciona perfectament per a tots els tipus de dades.
ÍNDEX( columna_retorn, COINCIDENT(CERTADER,EXACTE( columna_de_cerca, valor_de_cerca),0))Amb G2 com el valor de cerca, columna A - per cercar i columna E - per retornar les coincidències, la nostra La fórmula de cerca que distingeix entre majúscules i minúscules és la següent:
=INDEX($E$2:$E$6, MATCH(TRUE, EXACT($A$2:$A$6,G2),0))
Com que és una fórmula de matriu , assegureu-vos de prémer Ctrl + Maj + Retorn per completar-la correctament.
Per obtenir més exemples de fórmules, vegeu Com fer una cerca que distingeix entre majúscules i minúscules a Excel.
Cerca la coincidència de la cadena parcial
Cerca per un parcial La coincidència és una de les tasques més difícils d'Excel per a la qual no existeix una solució universal. La fórmula que s'ha d'utilitzar depèn del tipus de diferències que hi hagi entre els valors de cerca i els valors de la columna per cercar. En la majoria dels casos, utilitzareu la funció ESQUERRA, DRET o MITJÀ per extreure la part comuna dels valors i a continuació, proporcioneu aquesta part a l'argument lookup_value de la funció Vlookup tal com es fa amb la fórmula següent:
=VLOOKUP(RIGHT(D2,4), $A$2:$B$6, 2, FALSE)
On D2 és el valor de cerca, A2:B6 és la taula de cerca i 2 al número d'índex de la columna per retornar les coincidències.
Per a altres maneres de realitzar una cerca de coincidència parcial a Excel, vegeu Com fusionar dos fulls de treball per coincidència parcial.
Així és com s'utilitzen les funcions de cerca a Excel. Per veure amb més detall les fórmules que es discuteixen en aquest tutorial, us convidem a descarregar la nostra fórmula de cerca d'Excelexemples.
Manera sense fórmules de fer cerca a Excel
No cal dir que la cerca d'Excel no és una tasca trivial. Si esteu fent els vostres primers passos per aprendre l'àmbit d'Excel, les fórmules de cerca poden semblar bastant confuses i difícils d'entendre. Però, si us plau, no us sentiu desanimat, aquestes habilitats no són naturals per a la majoria dels usuaris!
Per facilitar les coses als novells, hem creat una eina especial, l'Assistent de combinació de taules, que pot buscar, fer coincidir i fusionar taules sense una sola fórmula. A més, ofereix una sèrie d'opcions realment úniques de les quals fins i tot els usuaris avançats d'Excel poden beneficiar-se:
- Recerca per criteris múltiples , és a dir, utilitzar una o diverses columnes com a identificador únic. (s).
- Actualitzeu els valors de les columnes existents i afegiu noves columnes des de la taula de cerca.
- Retorna coincidències múltiples en files separades. Quan s'utilitza en combinació amb l'assistent de combinació de files, fins i tot pot retornar diversos resultats en una sola cel·la, per comes o separats d'una altra manera (aquí es pot trobar un exemple).
- I més.
Treballar amb l'assistent de combinació de taules és fàcil i intuïtiu. Tot el que heu de fer és:
- Seleccioneu la vostra taula principal d'on voleu treure els valors coincidents.
- Seleccioneu la taula de cerca des d'on extreure les coincidències.
- Definiu una o més columnes comunes.
- Trieu les columnes que voleu actualitzar o afegir al final dela taula.
- Opcionalment, seleccioneu una o més opcions de combinació addicionals.
- Feu clic a Finalitza i tindreu un resultat en un moment!
Si teniu curiositat per provar el complement als vostres propis fulls de treball, podeu descarregar una versió de prova de la nostra Suite Ultimate que inclou totes les nostres eines per estalviar temps per a Excel (en total, més de 70 eines i més de 300 funcions!).
Descàrregues disponibles
Excels de fórmules de cerca d'Excel (fitxer .xlsx)
Versió totalment funcional de 14 dies d'Ultimate Suite (fitxer .exe)
cerca).Taula de cerca . En informàtica, una taula de cerca és una matriu de dades, que s'utilitza generalment per mapejar els valors d'entrada als valors de sortida. Pel que fa a aquest tutorial, una taula de cerca d'Excel no és altra cosa que un rang de cel·les on cerqueu un valor de cerca.
Taula principal (taula mestra): una taula a la qual extreu valors coincidents.
La vostra taula de cerca i la vostra taula principal poden tenir una estructura i una mida diferents, però sempre haurien de contenir almenys un identificador únic comú , és a dir, una columna o una fila que contingui dades idèntiques. , depenent de si voleu fer una cerca vertical o horitzontal.
La captura de pantalla següent mostra una taula de cerca de mostra que s'utilitzarà en molts dels exemples següents.
Funcions de cerca d'Excel
A continuació es mostra una visió general ràpida de les fórmules més populars per fer cerques a Excel, els seus principals avantatges i inconvenients.
Funció de cerca
La La funció LOOKUP a Excel pot realitzar els tipus més senzills de cerques verticals i horitzontals.
Pros : Fàcil d'utilitzar.
Contres : Limitat funcionalitat, no pot funcionar amb dades no ordenades (requereix l'ordenació t la columna/fila de cerca en ordre ascendent).
Per obtenir més informació, vegeu Com utilitzar la funció CERCA d'Excel.
Funció CERCA V
És una versió millorada de la CERCA. funció especialment dissenyada per fer cerca vertical acolumnes.
Pros : relativament fàcil d'utilitzar, pot funcionar amb coincidència exacta i aproximada.
Contres : no es pot mirar a l'esquerra, s'atura treballant quan s'insereix o s'elimina una columna a la taula de cerca, un valor de cerca no pot superar els 255 caràcters, requereix molta potència de processament en grans conjunts de dades.
Per obtenir més informació, consulteu el tutorial de BUSCAR V d'Excel per a principiants.
Funció HLOOKUP
És una contrapartida horitzontal de VLOOKUP que cerca un valor a la primera fila de la taula de cerca i retorna el valor a la mateixa posició des d'una altra fila.
Pros : fàcil d'utilitzar, pot tornar coincidències exactes i aproximades.
Contres : només es pot cercar a la fila superior de la taula de cerca, es veu afectada per la inserció o si elimineu files, un valor de cerca hauria de tenir menys de 255 caràcters.
Per obtenir més informació, vegeu Com utilitzar HLOOKUP a Excel.
VLOOKUP MATCH / HLOOKUP MATCH
A La referència dinàmica de columna o fila creada per MATCH fa que aquest Excel sigui baix fórmula okup immune als canvis fets al conjunt de dades. Dit d'una altra manera, amb l'ajuda de MATCH, les funcions BUSCARV i BUSCAR HL poden retornar els valors correctes sense importar quantes columnes/files s'hagin inserit o suprimit d'una taula de cerca.
Fórmula per a la cerca vertical.
CERCA V( valor_de_cerca, taula_de_cerca, COINCORDA( nom_de_columna_retorn, capçaleres_de_columna, 0), FALSE)Fórmula per a la cerca horitzontal
HLOOKUP( lookup_value, lookup_table, MATCH( return_row_name, row_headers, 0), FALSE)Pros : una millora respecte a les fórmules normals de Hlookup i Vlookup immunes a la inserció o supressió de dades.
Contres : Poc flexible , requereix una estructura de dades específica (el valor de cerca subministrat a la funció MATCH hauria de ser exactament igual al nom de la columna de retorn), no pot funcionar amb valors de cerca que superin els 255 caràcters.
Per obtenir més informació i exemples de fórmules, si us plau, vegeu:
- Excel Vlookup and Match
- Excel Hlookup and Match
OFFSET MATCH
Una més complexa però més potent fórmula de cerca, lliure de moltes limitacions de Vlookup i Hlookup.
Fórmula per a V-Lookup
OFFSET( taula_de_cerca, MATCH( valor_de_cerca, OFFSET( taula_de_cerca, 0, n, FILES( taula_de_cerca), 1) ,0) -1, m, 1, 1)On:
- n - és el desplaçament de la columna de cerca, és a dir. e. el nombre de columnes que cal moure des del punt inicial a la columna de cerca.
- m - és el desplaçament de la columna de retorn, és a dir. e. el nombre de columnes que cal moure des del punt inicial a la columna de retorn.
Fórmula per a la cerca H
OFFSET( taula_cerca, m, MATCH( valor_cerca, OFFSET( taula_de_cerca, n, 0, 1, COLUMNS( taula_de_cerca)), 0) -1, 1, 1)On:
- n - és el desplaçament de la fila de cerca, és a dir. e. el nombre de files que cal moure des del punt inicial a la fila de cerca.
- m - és el desplaçament de la fila de retorn, és a dir. e. el nombre de files que cal moure des del punt inicial fins a la fila de retorn.
Fórmula per a la cerca de matrius (per fila i columna)
{=OFFSET ( punt_inici, COINCORDA ( valor_de_cerca_vertical, columna_de_cerca<2)>, 0), MATCH ( valor_de_cerca_horitzontal , fila_de_cerca , 0))}Preneu atenció que es tracta d'una fórmula de matriu, que s'introdueix prement Ctrl + Maj + Retorn tecles al mateix temps.
Pros : permet realitzar una cerca V a l'esquerra, una cerca superior i una cerca bidireccional (per valors de columna i fila), no afectat pels canvis en les dades. conjunt.
Contres : sintaxi complexa i difícil de recordar.
Per obtenir més informació i exemples de fórmules, vegeu: Ús de la funció OFFSET a Excel
INDEX MATCH
És la millor manera de fer una cerca vertical o horitzontal a Excel que pot substituir la majoria de les fórmules anteriors. La fórmula de concordança d'índex és la meva preferència personal i la faig servir per a gairebé totes les meves cerques d'Excel.
Fórmula per a V-Lookup
INDEX ( return_column , COINCORD ( valor_de_cerca , columna_de_cerca , 0))Fórmula per a la cerca H
ÍNDEX ( fila_retorn , COINCIDENT ( valor_de_cerca , fila_de_cerca , 0))Fórmula per a la cerca de matriu
Anextensió de la fórmula clàssica de concordança d'índex per retornar un valor a la intersecció d'una columna i una fila específiques:
INDEX ( taula_de_cerca , COINCORDA ( valor_de_cerca_vertical , columna_de_cerca >, 0), MATCH ( valor_de_cerca_horitzontal , fila_de_cerca , 0))Contres : només un: cal recordar la sintaxi de la fórmula.
Pros : la fórmula de cerca més versàtil d'Excel, superior a les funcions Vlookup, Hlookup i Lookup en molts aspectes:
- Pot fer cerques a l'esquerra i a la part superior.
- Permet ampliar o reduir de manera segura la taula de cerca inserint o suprimint columnes i files.
- Sense límits a la mida del valor de cerca.
- Funciona més ràpidament. Com que una fórmula de concordança d'índex fa referència a columnes/files en lloc d'una taula sencera, requereix menys potència de processament i no alentirà l'Excel.
Per obtenir més informació, consulteu:
- INDEX MATCH com a millor alternativa a VLOOKUP
- INDEX MATCH Fórmula MATCH per a la cerca bidimensional
Taula de comparació de la cerca d'Excel
Com veieu , no totes les fórmules de cerca d'Excel són equivalents, algunes poden gestionar una sèrie de cerques diferents, mentre que altres només es poden utilitzar en una situació específica. La taula següent descriu les capacitats de cada fórmula de cerca a Excel.
| Fórmula | Cerca vertical | Cerca esquerra | Cerca horitzontal | Cerca superior | Matriucerca | Permet la inserció/supressió de dades |
| Cerca | ✓ | ✓ | ||||
| Vlookup | ✓ | |||||
| Busca | ✓ | |||||
| Vlookup Match | ✓ | ✓ | ||||
| Concordança de cerca | ✓ | ✓ | ||||
| Concordança de compensació | ✓ | ✓ | ✓ | ✓ | ✓ | |
| Concordança desplaçada | ✓ | ✓ | ||||
| Coincidència d'índex | ✓ | ✓ | ✓ | ✓ | ✓ | |
| Coincidència d'índex | ✓ | ✓ |
Exemples de fórmules de cerca d'Excel
El primer pas per decidir quina fórmula utilitzar en una situació específica és determinar quin tipus de cerca voleu realitzar. A continuació trobareu exemples de fórmules per als tipus de cerca més populars:
Cerca vertical en columnes
Una cerca vertical o Vlookup és el procés per trobar un valor de cerca en una columna i retornant un valor a la mateixa fila des d'una altra columna. La cerca virtual a Excel es pot fer de diverses maneres, com ara:
Funció BUSCAR V
Si els vostres valors de cerca es troben a la columna de l'esquerra de la taula i no teniu previst fer cap canvis estructurals ael vostre conjunt de dades (ni afegir ni suprimir columnes), podeu utilitzar amb seguretat una fórmula de Vlookup normal:
=VLOOKUP(G2, $A$2:$E$6, 5, FALSE)
On G2 és el valor de cerca, A2:E6 a la taula de cerca i E és la columna de retorn.
COINCIDENT DE CERCA V
Si esteu treballant amb una taula de cerca "variable" d'Excel on es poden inserir i suprimir columnes en qualsevol moment, fes que la teva fórmula Vlookup sigui immune a aquests canvis incrussant la funció Match que crea una referència de columna dinàmica en lloc d'un número d'índex "codificat dur":
=VLOOKUP(F2,$A$1:$D$6, MATCH($G$1,$A$1:$D$1, 0), FALSE)
CONcordança amb l'índex: cerca a l'esquerra
És la meva fórmula preferida que gestiona les cerques de dreta a esquerra amb facilitat i funciona de manera impecable, independentment de quantes columnes afegiu o suprimiu.
Per exemple, per a la columna de cerca B per al valor de H2 i retornar una coincidència de la columna F, utilitzeu aquesta fórmula:
=INDEX($F$2:$F$6,(MATCH(H2,$B$2:$B$6,0)))
Nota. Quan penseu utilitzar una fórmula Vlookup en més d'una cel·la, sempre hauríeu de bloquejar la referència de la taula de cerca utilitzant el signe $ (referència de cel·la absoluta), de manera que la fórmula es copie correctament a altres cel·les.
Cerca horitzontal en files
Una cerca horitzontal és una versió "transposada" de la cerca vertical que cerca en un conjunt de dades disposat horitzontalment. En altres paraules, cerca el valor de cerca en una fila i retorna un valor a la mateixa posició des d'una altra fila.
Suposant que el vostre valor de cerca és a B9, la taula de cerca és B1:F5 iSi voleu retornar un valor coincident de la fila 5, utilitzeu una de les fórmules següents:
Funció HLOOKUP
Pots cercar només a la fila superior del vostre conjunt de dades .
=HLOOKUP(B8, $B$1:$F$5, 5, FALSE)
HLOOKUP MATCH
Com la Hlookup pura, aquesta fórmula només pot cercar a la fila superior, però us permet insereix o suprimeix files de manera segura a la taula de cerca.
=HLOOKUP(B8, $B$1:$F$5, MATCH($A$9, $A$1:$A$5, 0), FALSE)
On A1:A5 són les capçaleres de fila i A9 és el nom de la fila des de la qual voleu tornar coincidències .
INDEX MATCH
Pot buscar cap amunt en qualsevol fila i no té cap de les limitacions de les fórmules anteriors.
=INDEX($B$5:$F$5,(MATCH(B8,$B$1:$F$1,0)))
Cerca bidimensional (basada en valors de files i columnes)
Cerca bidimensional (també coneguda com cerca de matrius , cerca doble o cerca bidireccional ) retorna un valor basat en les coincidències tant a les files com a les columnes. En altres paraules, una fórmula de cerca bidimensional cerca un valor a la intersecció d'una fila i una columna especificades.
Suposant que la vostra taula de cerca és A1:E6, la cel·la H2 conté el valor que ha de coincidir a les files i H3 conté el valor que s'ha de fer coincidir a les columnes, les fórmules següents seran un plaer:
Fórmula de coincidència d'índex :
=INDEX($A$1:$E$6, MATCH(H2,$A$1:$A$6,0), MATCH(H3,$A$1:$E$1,0))
Fórmula de COINCIDENCIA DE COINCIDENT OFFSET :
=OFFSET($A$1,MATCH(H2,$A$2:$A$6,0),MATCH(H3,$B$1:$E$1,0))
A part de les fórmules anteriors, hi ha un grapat d'altres maneres de realitzar una cerca de matriu a Excel , i podeu trobar tots els detalls a Com fer una cerca bidireccional
