Тепер, коли ми дізналися як вводити дати і час в електронну таблицю Настав час поговорити про способи обчислення часу в Google Таблицях. Ми детально розглянемо способи знаходження різниці в часі, побачимо, як підсумовувати дати і час, а також навчимося відображати тільки одиниці дати або часу і повністю відокремлювати їх.

Як розрахувати різницю в часі в Google Sheets

Коли ви працюєте над деякими проектами, зазвичай важливо контролювати, скільки часу ви витрачаєте. Це називається минулим часом. Таблиці Google можуть допомогти вам розрахувати різницю в часі багатьма різними способами.

Приклад 1. Віднімаємо час для отримання тривалості часу в Google Таблицях

Якщо у вас є час початку та закінчення роботи, то дізнатися витрачений час не є проблемою:

Припустимо, в колонці А вказано час початку, а в колонці В - час закінчення. За допомогою простої формули віднімання в колонці С2 ви дізнаєтесь, скільки часу зайняло те чи інше завдання:

=B2-A2

За замовчуванням час форматується у вигляді "чч:мм".

Для отримання результатів тільки в годинах або в годинах, хвилинах і секундах необхідно застосувати спеціальний формат з відповідними часовими кодами: h і hh:mm:ss Для таких випадків Google навіть пропонує спеціальний формат номера - Google. Тривалість :

Порада. Щоб застосувати користувацький формат часу, перейдіть до розділу Формат> Номер> Більше форматів> Нестандартний формат номера в меню вашої електронної таблиці.

Приклад 2. Обчислення тривалості часу в таблицях Google за допомогою функції TEXT

Ще одна хитрість підрахунку тривалості часу в Google Таблицях полягає у використанні функції ТЕКСТ:

=TEXT(B2-A2, "h") - годинами

=TEXT(B2-A2, "h:mm") - по годинах і хвилинах

=TEXT(B2-A2, "h:mm:ss") - години, хвилини та секунди

Зверніть увагу, що записи вирівняні по лівому краю, тому що функція ТЕКСТ завжди повертає результати у текстовому форматі. Це означає, що ці значення не можуть бути використані для подальших обчислень.

Приклад 3. різниця в часі в годинах, хвилинах і секундах

Ви можете відстежувати витрачений час і отримувати результат в одній одиниці часу, не враховуючи інші одиниці. Наприклад, порахувати кількість тільки годин, тільки хвилин або тільки секунд.

Примітка: для отримання коректних результатів клітинки повинні бути відформатовані або як числа, або автоматично: Формат> Номер> Номер або Формат> Номер> Автоматичний .

• Щоб отримати кількість витрачених годин, відніміть час початку роботи від часу закінчення і помножте результат на 24 (оскільки в добі 24 години):

  Дивіться також: Функція Excel IMAGE для вставки зображення в комірку
  =(Час закінчення - Час початку) * 24

  Ви отримаєте різницю в часі у вигляді десяткового дробу:

  

  Якщо час початку більше, ніж час закінчення, формула поверне від'ємне число, як у комірці C5 в моєму прикладі.

  Порада. Функція INT дозволить вам побачити кількість повних відпрацьованих годин, оскільки вона округляє числа до найближчого цілого числа:

  

• Щоб порахувати хвилини, відніміть час початку від часу закінчення і помножте отриманий результат на 1,440 (оскільки в одній добі 1,440 хвилин):

  =(Час закінчення - Час початку) * 1440

  

• Щоб дізнатися, скільки секунд пройшло між двома моментами, діємо так само: підставляємо час початку від часу закінчення і множимо результат на 86 400 (кількість секунд у добі):

  =(Час закінчення - Час початку) * 86400

  

Порада. У всіх цих випадках можна уникнути множення. Просто спочатку відніміть час, а потім застосуйте формат часу, що минув, від Формат> Число> Більше форматів> Більше форматів дати та часу Якщо ви натиснете стрілку вниз праворуч від текстового поля, ви зможете вибрати додаткові одиниці виміру дати та часу:

Приклад 4. Функції для отримання різниці в часі в електронній таблиці Google

Як завжди, Google Таблиці надають для цього три особливо корисні функції.

Примітка. Ці функції працюють тільки в межах 24 годин і 60 хвилин і секунд. Якщо різниця в часі перевищує ці межі, формули повертатимуть помилки.

• =HOUR(B2-A2) - повернутися години тільки (без хвилин і секунд)
• =MINUTE(B2-A2) - повернутися хвилини тільки (без годин і секунд)
• = SECOND(B2-A2) - повернутися секунди тільки (без годин і хвилин)

Як додавати і віднімати час в Google Таблицях: години, хвилини або секунди

Ці операції також можуть бути досягнуті двома методами: один передбачає базові математичні розрахунки, інший - функції. Якщо перший спосіб працює завжди, то другий, з функціями, працює тільки тоді, коли ви додаєте або віднімаєте одиниці менше, ніж 24 години, або 60 хвилин, або 60 секунд.

Додавання або віднімання годин в Google Таблицях

• Додати менше 24 годин:

  = Час початку + TIME(N годин, 0, 0)

  Ось як виглядає формула на реальних даних:

  =A2+TIME(3,0,0)

  

• Додайте більше 24 годин:

  =Час початку + (N годин / 24)

  Щоб додати 27 годин до часу в А2, я використовую цю формулу:

  =A2+(27/24)

  

• Щоб відняти 24 і більше годин, візьміть за основу формули, наведені вище, але змініть знак плюс (+) на знак мінус (-). Ось що у мене вийшло:

  =A2-TIME(3,0,0) - відняти 3 години

  =A2-(27/24) - відняти 27 годин

Додавання або віднімання хвилин в Google Таблицях

Принцип маніпуляцій з хвилинами такий самий, як і з годинами.

• Є функція TIME, яка додає і віднімає до 60 хвилин:

  = Час початку + TIME(0, N хвилин, 0)

  Якщо ви хочете додати 40 хвилин, ви можете зробити це таким чином:

  =A2+TIME(0,40,0)

  Якщо вам потрібно відняти 20 хвилин, то ось формула, яку слід використовувати:

  =A2-TIME(0,40,0)

  

• І є формула, заснована на простій арифметиці, щоб додавати і віднімати за 60 хвилин:

  =Час початку + (N хвилин / 1440)

  Таким чином, ось як ви додаєте 120 хвилин:

  =A2+(120/1440)

  Поставте мінус замість плюса, щоб відняти 120 хвилин:

  =A2-(120/1440)

  

Додавання або віднімання секунд в Google Таблицях

Секунди в таблицях Google розраховуються так само, як і години та хвилини.

• Ви можете використовувати функцію ЧАС для додавання або віднімання до 60 секунд:

  = Час початку + TIME(0, 0, N секунд)

  Наприклад, додати 30 секунд:

  =A2+TIME(0,0,30)

  Або підставити 30 секунд:

  =A2-TIME(0,0,30)

• Щоб порахувати більше 60 секунд, скористайтеся простою математикою:

  =Час старту + (N секунд / 86400)

  Додайте 700 секунд:

  =A2+(700/86400)

  Або підставити 700 секунд:

  =A2-(700/86400)

Як підсумувати час в Google Таблицях

Щоб знайти загальний час у вашій таблиці в Google Sheets, ви можете скористатися функцією SUM. Хитрість тут полягає в тому, щоб вибрати правильний формат для відображення результату.

За замовчуванням результат буде відформатовано як Тривалість - hh:mm:ss

Але найчастіше стандартного формату часу або тривалості буде недостатньо, і вам потрібно буде придумати свій власний.

Комірки A7:A9 містять одне і те ж значення часу, просто відображаються по-різному. І з ними дійсно можна виконувати обчислення: віднімати, сумувати, переводити в десятковий дріб тощо.

Витягнути дату і час з повного запису "дата-час"

Уявімо, що в одній комірці Google Таблиці є і дата, і час. Ви хочете їх розділити: в одну комірку витягти тільки дату, а в іншу - тільки час.

Розділити час дати з використанням формату Число

Для того, щоб відобразити дату або час в одній комірці на екрані або роздрукувати її, достатньо виділити вихідну комірку, перейти на Формат> Номер та обирайте Дата або Час .

Однак, якщо ви хочете використовувати ці значення для подальших обчислень (віднімання, додавання тощо), цього буде недостатньо. Якщо ви не бачите одиницю часу в комірці, це не обов'язково означає, що вона відсутня, і навпаки.

Що ж робити?

Розділити час дати за допомогою формул

Google зберігає дати і час у вигляді чисел. Наприклад, він бачить дату 8/24/2017 11:40:03 у вигляді числа 42971,4861458 Ціла частина - це дата, дробова - час. Отже, ваше завдання зводиться до того, щоб відокремити цілу частину від дробової.

1. Для вилучення дати (цілої частини) використовуйте функцію ROUNDDOWN у комірці B2:

   =ROUNDDOWN(A2,0)

   

   Формула округлює значення в меншу сторону і відкидає дробову частину.

2. Щоб витягти час, помістіть наступну формулу віднімання в C2:

=A2-B2

Використовуйте надбудову Split Date & Time

Можливо, ви здивуєтеся, але для цієї роботи є одне спеціальне доповнення. Воно дуже маленьке і просте, але його внесок у роботу з Google Таблицями важко переоцінити.

Функція Split Date & Time розділяє всі записи з датою і часом у всьому стовпчику відразу. Ви контролюєте бажаний результат за допомогою всього 4 простих налаштувань:

Ви скажіть доповнення:

1. Чи є рядок заголовка.
2. Якщо ви хочете отримати одиницю виміру Дата.
3. Якщо ви хочете отримати одиницю часу.
4. І якщо ви хочете замінити початкову колонку новими даними.

Він буквально знімає з ваших плечей тягар розділення одиниць дати та часу:

Доповнення є частиною колекції Power Tools, тому у вас під рукою буде більше 30 інших корисних доповнень. Встановіть його з магазину Google Таблиць, щоб випробувати все на практиці.

Це способи не просто відобразити дату чи час, а рознести їх по різних комірках. І з цими записами тепер можна виконувати різні обчислення.

Сподіваюся, ці приклади допоможуть вам вирішити ваші завдання при роботі з датами і часом в Google Таблицях.