Isi kandungan
Tutorial ini menyelami pelbagai cara menggunakan fungsi ISNA dalam Excel untuk mengendalikan ralat #N/A.
Apabila Excel tidak dapat mencari perkara yang diminta, #N/ Ralat muncul dalam sel. Untuk memintas dan mengendalikan ralat sedemikian, anda boleh menggunakan fungsi ISNA. Apakah kegunaan praktikal itu? Pada asasnya, ia membantu menjadikan formula anda lebih mesra pengguna dan lembaran kerja anda kelihatan lebih baik.
Fungsi ISNA dalam Excel
Fungsi ISNA Excel digunakan untuk menyemak sel atau formula untuk ralat #N/A. Hasilnya ialah nilai logik: TRUE jika ralat #N/A dikesan, FALSE sebaliknya.
Fungsi ini tersedia dalam semua versi Excel 2000 hingga 2021 dan Excel 365.
The sintaks fungsi ISNA adalah semudah yang mungkin:
ISNA(nilai)Di mana nilai ialah nilai sel atau formula yang anda ingin semak untuk ralat #N/A.
Untuk mencipta formula ISNA dalam bentuk asasnya, sediakan rujukan sel sebagai satu-satunya hujahnya:
=ISNA(A2)
Sekiranya sel yang dirujuk mengandungi ralat #N/A, anda akan mendapat BENAR. Sekiranya terdapat sebarang ralat, nilai atau sel kosong lain, anda akan mendapat FALSE:
Cara menggunakan ISNA dalam Excel
Menggunakan fungsi ISNA dalam bentuk tulen mempunyai sedikit pengertian praktikal. Lebih kerap, ia digunakan bersama dengan fungsi lain untuk menilai hasil formula tertentu. Untuk ini, letak sahaja formula lain itu dalam hujah nilai ISNA:
ISNA( formula_anda())Dalam set data di bawah, katakan anda ingin membandingkan dua senarai (lajur A dan D) dan mengenal pasti nama yang terdapat dalam kedua-dua senarai dan nama yang muncul hanya dalam senarai 1.
Untuk membandingkan nama dalam A3 dengan setiap nama dalam lajur D, formulanya ialah:
=MATCH(A3, $D$2:$D$9, 0)
Jika nilai carian ditemui, fungsi MATCH mengembalikannya kedudukan relatif dalam tatasusunan carian, jika tidak ralat #N/A berlaku. Untuk menguji keputusan MATCH, kami menyarangkannya dalam ISNA:
=ISNA(MATCH(A3, $D$2:$D$9, 0))
Formula ini pergi ke B3, dan kemudian disalin melalui B14.
Kini, anda boleh dengan jelas lihat pelajar mana yang telah lulus semua ujian (nama tidak tersedia dalam lajur D > MATCH mengembalikan #N/A > ISNA mengembalikan BENAR) dan yang mempunyai sekurang-kurangnya satu ujian gagal (nama muncul dalam lajur D > tiada ralat > ISNA mengembalikan FALSE).
Petua. Dalam Excel 365 dan Excel 2021, anda boleh menggunakan fungsi XMATCH yang lebih moden. bukannya MATCH.
JIKA formula ISNA dalam Excel
Dengan reka bentuk, fungsi ISNA hanya boleh mengembalikan dua nilai Boolean. Untuk memaparkan mesej tersuai anda, gunakannya dalam kombinasi dengan fungsi IF:
IF(ISNA(…), " text_if_error", " text_if_no_error")Memperhalusi kami contoh lebih jauh, mari kita ketahui pelajar dari kumpulan A yang tidak gagal sebarang ujian dan kembalikan "Tiada ujian yang gagal" untuk mereka. Untuk pelajar yang tinggal, kami akan mengembalikan "Gagal". Untuk melakukan ini, benamkan formula ISNA MATCH dalamujian logik IF, supaya IF menjadi fungsi paling luar:
=IF(ISNA(MATCH(A3,$D$2:$D$9,0)), "No failed tests", "Failed")
Hasilnya kelihatan jauh lebih baik dan lebih intuitif sekarang, setuju?
Cara menggunakan ISNA dalam Excel dengan VLOOKUP
Gabungan IF ISNA ialah penyelesaian universal yang boleh digunakan dengan mana-mana fungsi yang mencari sesuatu dalam set data dan mengembalikan ralat #N/A apabila nilai carian tidak ditemui.
Sintaks fungsi ISNA dengan VLOOKUP adalah seperti berikut:
IF(ISNA(VLOOKUP(…), " custom_text", VLOOKUP( …))Diterjemahkan ke dalam bahasa manusia, ia berkata: jika VLOOKUP menghasilkan ralat #N/A, kembalikan teks tersuai, sebaliknya kembalikan hasil VLOOKUP.
Dalam jadual sampel kami, anggap anda ingin kembalikan subjek yang pelajar gagal dalam ujian. Bagi mereka yang telah berjaya lulus semua ujian, "Tiada ujian gagal" akan dipaparkan.
Untuk mencari subjek, kami membina formula VLOOKUP klasik ini:
=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)
Dan kemudian sarangkannya dalam formula generik IF ISNA yang dibincangkan di atas:
48 51
Dalam Excel 2013 dan versi yang lebih baru, anda boleh menggunakan fungsi IFNA untuk menangkap dan mengendalikan ralat #N/A. Ini menjadikan formula anda lebih pendek dan lebih mudah dibaca.
Sebagai contoh, kami menggantikan ralat #N/A dengan sempang ("-") dan mendapatkan penyelesaian yang elegan ini:
=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "-")
Pengguna Excel 365 dan 2021 tidak memerlukan sebarang fungsi pembungkus sama sekali sebagai pengganti moden VLOOKUP,Fungsi XLOOKUP, boleh mengendalikan ralat #N/A secara asli:
=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "-")
Hasilnya akan sama seperti yang ditunjukkan dalam tangkapan skrin di atas.
Formula SUMPRODUCT ISNA untuk dikira #N/A ralat
Untuk mengira #N/A ralat dalam julat tertentu, gunakan fungsi ISNA bersama-sama dengan SUMPRODUCT dengan cara ini:
SUMPRODUCT(--ISNA( julat))Di sini, ISNA mengembalikan tatasusunan nilai TRUE dan FALSE, penolakan berganda (--) memaksa nilai logik menjadi 1 dan 0, dan SUMPRODUCT menambah hasilnya.
Sebagai contoh, untuk ketahui bilangan pelajar yang berjaya dalam semua ujian, ubah suai formula MATCH untuk julat nilai carian (A3:A14) dan sarangkannya dalam ISNA:
=SUMPRODUCT(--ISNA(MATCH(A3:A14, D2:D9, 0)))
Formula menentukan bahawa 9 pelajar tidak mempunyai ujian yang gagal, iaitu fungsi MATCH mengembalikan 9 #N/A ralat:
Begitulah cara mencipta dan menggunakan formula ISNA dalam Excel. Saya mengucapkan terima kasih kerana membaca dan berharap dapat berjumpa anda di blog kami minggu hadapan!
Muat turun yang tersedia
Contoh formula ISNA (fail.xlsx)
