Αυτό το σεμινάριο εξετάζει διάφορους τρόπους χρήσης της συνάρτησης ISNA στο Excel για τον χειρισμό σφαλμάτων #N/A.

Όταν το Excel δεν μπορεί να βρει αυτό που του ζητείται, εμφανίζεται ένα σφάλμα #N/A σε ένα κελί. Για να αναχαιτίσετε και να χειριστείτε τέτοια σφάλματα, μπορείτε να χρησιμοποιήσετε τη συνάρτηση ISNA. Ποια είναι η πρακτική χρησιμότητα αυτού; Ουσιαστικά, βοηθάει να κάνετε τους τύπους σας πιο εύχρηστους και τα φύλλα εργασίας σας πιο όμορφα.

Συνάρτηση ISNA στο Excel

Η συνάρτηση ISNA του Excel χρησιμοποιείται για τον έλεγχο κελιών ή τύπων για σφάλματα #N/A. Το αποτέλεσμα είναι μια λογική τιμή: TRUE εάν ανιχνεύεται σφάλμα #N/A, FALSE διαφορετικά.

Η λειτουργία είναι διαθέσιμη σε όλες τις εκδόσεις του Excel 2000 έως 2021 και του Excel 365.

Η σύνταξη της συνάρτησης ISNA είναι όσο πιο απλή γίνεται:

Πού αξία είναι η τιμή του κελιού ή ο τύπος που θέλετε να ελέγξετε για σφάλματα #N/A.

Για να δημιουργήσετε έναν τύπο ISNA στη βασική του μορφή, δώστε μια αναφορά κελιού ως μοναδικό όρισμα:

=ISNA(A2)

Σε περίπτωση που το αναφερόμενο κελί περιέχει σφάλμα #N/A, θα λάβετε TRUE. Σε περίπτωση οποιουδήποτε άλλου σφάλματος, τιμής ή κενού κελιού, θα λάβετε FALSE:

Πώς να χρησιμοποιήσετε το ISNA στο Excel

Η χρήση της συνάρτησης ISNA στην καθαρή της μορφή έχει ελάχιστο πρακτικό νόημα. Συχνότερα, χρησιμοποιείται μαζί με άλλες συναρτήσεις για να αξιολογήσει το αποτέλεσμα ενός συγκεκριμένου τύπου. Για το σκοπό αυτό, απλά βάλτε αυτόν τον άλλο τύπο στην εντολή αξία επιχείρημα του ISNA:

Στο παρακάτω σύνολο δεδομένων, υποθέστε ότι θέλετε να συγκρίνετε δύο λίστες (στήλες Α και Δ) και να εντοπίσετε τα ονόματα που υπάρχουν και στις δύο λίστες και εκείνα που εμφανίζονται μόνο στη λίστα 1.

Για να συγκρίνετε το όνομα στο Α3 με κάθε όνομα στη στήλη Δ, ο τύπος είναι ο εξής:

=MATCH(A3, $D$2:$D$9, 0)

Εάν βρεθεί μια τιμή αναζήτησης, η συνάρτηση MATCH επιστρέφει τη σχετική της θέση στον πίνακα αναζήτησης, διαφορετικά εμφανίζεται ένα σφάλμα #N/A. Για να ελέγξουμε το αποτέλεσμα της MATCH, την ενθέτουμε στην ISNA:

=ISNA(MATCH(A3, $D$2:$D$9, 0))

Αυτός ο τύπος πηγαίνει στο Β3 και στη συνέχεια αντιγράφεται μέσω του Β14.

Τώρα, μπορείτε να δείτε καθαρά ποιοι μαθητές έχουν περάσει όλες τις εξετάσεις (ένα όνομα δεν υπάρχει στη στήλη D>- η MATCH επιστρέφει #N/A>- η ISNA επιστρέφει TRUE) και ποιοι έχουν τουλάχιστον μία αποτυχημένη εξέταση (ένα όνομα εμφανίζεται στη στήλη D>- κανένα σφάλμα>- η ISNA επιστρέφει FALSE).

Συμβουλή. Στο Excel 365 και στο Excel 2021, μπορείτε να χρησιμοποιήσετε μια πιο σύγχρονη συνάρτηση XMATCH. αντί της MATCH.

Τύπος IF ISNA στο Excel

Από το σχεδιασμό της, η συνάρτηση ISNA μπορεί να επιστρέψει μόνο δύο τιμές Boolean. Για να εμφανίσετε τα προσαρμοσμένα μηνύματά σας, χρησιμοποιήστε την σε συνδυασμό με τη συνάρτηση IF:

Εξειδικεύοντας λίγο περισσότερο το παράδειγμά μας, ας βρούμε ποιοι μαθητές από την ομάδα Α δεν απέτυχαν σε κανένα τεστ και ας επιστρέψουμε γι' αυτούς την ένδειξη "Δεν απέτυχαν σε κανένα τεστ". Για τους υπόλοιπους μαθητές, θα επιστρέψουμε την ένδειξη "Απέτυχαν". Για να το κάνουμε αυτό, ενσωματώστε τον τύπο ISNA MATCH στο λογικό τεστ της IF, έτσι ώστε η IF να γίνει η πιο εξωτερική συνάρτηση:

=IF(ISNA(MATCH(A3,$D$2:$D$9,0)), "Δεν υπάρχουν αποτυχημένες δοκιμές", "Αποτυχημένες")

Τα αποτελέσματα φαίνονται πολύ καλύτερα και πιο διαισθητικά τώρα, συμφωνείτε;

Πώς να χρησιμοποιήσετε το ISNA στο Excel με το VLOOKUP

Ο συνδυασμός IF ISNA είναι μια καθολική λύση που μπορεί να χρησιμοποιηθεί με οποιαδήποτε συνάρτηση που αναζητά κάτι σε ένα σύνολο δεδομένων και επιστρέφει ένα σφάλμα #N/A όταν δεν βρίσκεται μια τιμή αναζήτησης.

Η σύνταξη της συνάρτησης ISNA με VLOOKUP έχει ως εξής:

Μεταφρασμένο σε ανθρώπινη γλώσσα, λέει: αν το VLOOKUP καταλήξει σε σφάλμα #N/A, επιστρέψτε προσαρμοσμένο κείμενο, διαφορετικά επιστρέψτε το αποτέλεσμα του VLOOKUP.

Στον πίνακα του παραδείγματός μας, υποθέστε ότι θέλετε να επιστρέψετε τα θέματα στα οποία οι μαθητές απέτυχαν στις εξετάσεις. Για όσους έχουν περάσει όλες τις εξετάσεις με επιτυχία, θα εμφανιστεί η ένδειξη "Καμία αποτυχημένη εξέταση".

Για να αναζητήσουμε τα θέματα, κατασκευάζουμε αυτόν τον κλασικό τύπο VLOOKUP:

=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)

Και στη συνέχεια να το ενσωματώσετε στον γενικό τύπο IF ISNA που συζητήθηκε παραπάνω:

=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "Δεν υπάρχουν αποτυχημένες δοκιμές", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))

Στο Excel 2013 και μεταγενέστερες εκδόσεις, μπορείτε να χρησιμοποιήσετε τη συνάρτηση IFNA για να πιάσετε και να χειριστείτε τα σφάλματα #N/A. Αυτό κάνει τον τύπο σας πιο σύντομο και πιο ευανάγνωστο.

Για παράδειγμα, αντικαθιστούμε τα σφάλματα #N/A με παύλες ("-") και παίρνουμε αυτή την κομψή λύση:

=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "-")

Οι χρήστες του Excel 365 και 2021 δεν χρειάζονται καθόλου καμία συνάρτηση περιτύλιξης, καθώς ο σύγχρονος διάδοχος του VLOOKUP, η συνάρτηση XLOOKUP, μπορεί να χειριστεί εγγενώς τα σφάλματα #N/A:

=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "-")

Το αποτέλεσμα θα είναι ακριβώς το ίδιο όπως φαίνεται στο παραπάνω στιγμιότυπο.

Τύπος SUMPRODUCT ISNA για την καταμέτρηση σφαλμάτων #N/A

Για να μετρήσετε #N/A σφάλματα σε ένα συγκεκριμένο εύρος, χρησιμοποιήστε τη συνάρτηση ISNA μαζί με τη SUMPRODUCT με αυτόν τον τρόπο:

Εδώ, η ISNA επιστρέφει έναν πίνακα τιμών TRUE και FALSE, η διπλή άρνηση (--) εξαναγκάζει τις λογικές τιμές σε 1 και 0 και η SUMPRODUCT προσθέτει το αποτέλεσμα.

Για παράδειγμα, για να μάθετε πόσοι μαθητές πέτυχαν σε όλες τις εξετάσεις, τροποποιήστε τον τύπο MATCH για ένα εύρος τιμών αναζήτησης (A3:A14) και φωλιάστε τον στην ISNA:

=SUMPRODUCT(--ISNA(MATCH(A3:A14, D2:D9, 0))

Ο τύπος προσδιορίζει ότι 9 μαθητές δεν έχουν αποτύχει στις εξετάσεις, δηλαδή η συνάρτηση MATCH επιστρέφει 9 σφάλματα #N/A:

Αυτός είναι ο τρόπος δημιουργίας και χρήσης τύπων ISNA στο Excel. Σας ευχαριστώ για την ανάγνωση και ανυπομονώ να σας δω στο blog μας την επόμενη εβδομάδα!

Διαθέσιμες λήψεις

Παραδείγματα τύπων ISNA (.xlsx αρχείο)