Sommario
Questa esercitazione analizza vari modi di utilizzare la funzione ISNA in Excel per gestire gli errori #N/A.
Quando Excel non riesce a trovare ciò che gli viene richiesto, in una cella appare un errore #N/A. Per intercettare e gestire tali errori, è possibile utilizzare la funzione ISNA. Qual è l'utilità pratica di questa funzione? Essenzialmente, aiuta a rendere le formule più facili da usare e i fogli di lavoro più belli.
Funzione ISNA in Excel
La funzione ISNA di Excel viene utilizzata per verificare la presenza di errori #N/A nelle celle o nelle formule. Il risultato è un valore logico: VERO se viene rilevato un errore #N/A, FALSO altrimenti.
La funzione è disponibile in tutte le versioni di Excel dalla 2000 alla 2021 e in Excel 365.
La sintassi della funzione ISNA è la più semplice possibile:
ISNA(valore)Dove valore è il valore della cella o della formula che si desidera controllare per verificare la presenza di errori #N/A.
Per creare una formula ISNA nella sua forma di base, occorre fornire come unico argomento un riferimento di cella:
=ISNA(A2)
Se la cella di riferimento contiene un errore #N/A, si otterrà VERO. In caso di qualsiasi altro errore, valore o cella vuota, si otterrà FALSO:
Come utilizzare ISNA in Excel
L'uso della funzione ISNA nella sua forma pura ha poco senso pratico. Più spesso, viene utilizzata insieme ad altre funzioni per valutare il risultato di una certa formula. A tal fine, è sufficiente inserire l'altra formula nel campo valore argomento dell'ISNA:
ISNA( la tua_formula ())Nel set di dati sottostante, supponiamo di voler confrontare due elenchi (colonne A e D) e di identificare i nomi che sono presenti in entrambi gli elenchi e quelli che appaiono solo nell'elenco 1.
Per confrontare il nome in A3 con ogni nome della colonna D, la formula è:
=MATCH(A3, $D$2:$D$9, 0)
Se viene trovato un valore di ricerca, la funzione MATCH restituisce la sua posizione relativa nell'array di ricerca, altrimenti si verifica un errore #N/A. Per verificare il risultato di MATCH, lo annidiamo in ISNA:
=ISNA(MATCH(A3, $D$2:$D$9, 0))
Questa formula va in B3 e poi viene copiata in B14.
Ora è possibile vedere chiaramente quali studenti hanno superato tutti i test (un nome non è disponibile nella colonna D> MATCH restituisce #N/A> ISNA restituisce TRUE) e quali hanno almeno un test fallito (un nome appare nella colonna D> nessun errore> ISNA restituisce FALSE).
Suggerimento: in Excel 365 e Excel 2021, al posto di MATCH è possibile utilizzare la più moderna funzione XMATCH.
Formula IF ISNA in Excel
La funzione ISNA, per sua natura, può restituire solo due valori booleani. Per visualizzare i vostri messaggi personalizzati, usatela in combinazione con la funzione IF:
IF(ISNA(...), " testo_se_errore ", " text_if_no_error ")Affinando ulteriormente il nostro esempio, scopriamo quali studenti del gruppo A non hanno fallito alcun test e restituiamo per loro "Nessun test fallito". Per i restanti studenti, restituiremo "Fallito". Per fare ciò, incorporiamo la formula ISNA MATCH nel test logico di IF, in modo che IF diventi la funzione più esterna:
=IF(ISNA(MATCH(A3,$D$2:$D$9,0)), "Nessun test fallito", "Fallito")
I risultati appaiono ora molto migliori e più intuitivi, siete d'accordo?
Come utilizzare ISNA in Excel con VLOOKUP
La combinazione IF ISNA è una soluzione universale che può essere utilizzata con qualsiasi funzione che cerchi qualcosa in un insieme di dati e che restituisca un errore #N/A quando non viene trovato un valore di ricerca.
La sintassi della funzione ISNA con VLOOKUP è la seguente:
IF(ISNA(VLOOKUP(...), " testo personalizzato ", VLOOKUP(...))Tradotto in linguaggio umano, dice: se VLOOKUP produce un errore #N/A, restituire il testo personalizzato, altrimenti restituire il risultato di VLOOKUP.
Nella nostra tabella di esempio, supponiamo di voler restituire le materie in cui gli studenti non hanno superato i test. Per coloro che hanno superato tutti i test con successo, verrà visualizzato "Nessun test non superato".
Per cercare i soggetti, costruiamo la classica formula VLOOKUP:
=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)
E poi annidarlo nella formula generica IF ISNA discussa sopra:
=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "Nessun test fallito", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
In Excel 2013 e versioni successive, è possibile utilizzare la funzione IFNA per catturare e gestire gli errori #N/A. Questo rende la formula più breve e più facile da leggere.
Come esempio, sostituiamo gli errori #N/A con dei trattini ("-") e otteniamo questa elegante soluzione:
=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "-")
Gli utenti di Excel 365 e 2021 non hanno bisogno di alcuna funzione wrapper, poiché il successore moderno di VLOOKUP, la funzione XLOOKUP, è in grado di gestire gli errori #N/A in modo nativo:
=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "-")
Il risultato sarà esattamente quello mostrato nella schermata precedente.
Formula SUMPRODUCT ISNA per contare gli errori #N/A
Per contare gli errori #N/A in un determinato intervallo, utilizzare la funzione ISNA insieme a SUMPRODUCT in questo modo:
SUMPRODUCT(--ISNA( gamma ))In questo caso, ISNA restituisce un array di valori VERO e FALSO, la doppia negazione (--) costringe i valori logici in 1 e 0 e SUMPRODUCT somma il risultato.
Ad esempio, per sapere quanti studenti hanno superato tutti i test, modificare la formula MATCH per un intervallo di valori di ricerca (A3:A14) e annidarla in ISNA:
=SUMPRODOTTO(--ISNA [MATCH(A3:A14, D2:D9, 0)])
La formula determina che 9 studenti non hanno fallito i test, cioè la funzione MATCH restituisce 9 errori #N/A:
Ecco come creare e utilizzare le formule ISNA in Excel. Vi ringrazio per la lettura e vi aspetto sul nostro blog la prossima settimana!
Download disponibili
Esempi di formule ISNA (file .xlsx)
