В този урок ще разгледаме различни начини за използване на функцията ISNA в Excel за обработка на грешки #N/A.

Когато Excel не може да открие това, което е поискано, в клетката се появява грешка #N/A. За да прихващате и обработвате такива грешки, можете да използвате функцията ISNA. Каква е практическата полза от това? По същество тя помага да направите формулите си по-удобни за използване, а работните листове - по-красиви.

Функция ISNA в Excel

Функцията ISNA на Excel се използва за проверка на клетки или формули за грешки #N/A. Резултатът е логическа стойност: TRUE, ако е открита грешка #N/A, FALSE в противен случай.

Функцията е налична във всички версии на Excel от 2000 до 2021 и Excel 365.

Синтаксисът на функцията ISNA е възможно най-прост:

Къде: стойност е стойността на клетката или формулата, която искате да проверите за грешки #N/A.

За да създадете формула ISNA в нейната основна форма, въведете референция към клетка като единствен аргумент:

=ISNA(A2)

В случай че посочената клетка съдържа грешка #N/A, ще получите TRUE. В случай на друга грешка, стойност или празна клетка, ще получите FALSE:

Как да използвате ISNA в Excel

Използването на функцията ISNA в чист вид няма голям практически смисъл. По-често тя се използва заедно с други функции, за да се оцени резултатът от определена формула. За тази цел просто поставете тази друга формула в стойност аргумент на ISNA:

Предположете, че искате да сравните два списъка (колони A и D) и да определите имената, които присъстват и в двата списъка, и тези, които се появяват само в списък 1.

За да се сравни името в A3 с всяко име в колона D, формулата е:

=MATCH(A3, $D$2:$D$9, 0)

Ако е намерена стойност за търсене, функцията MATCH връща относителната ѝ позиция в масива за търсене, в противен случай се появява грешка #N/A. За да проверим резултата от MATCH, го вмъкваме в ISNA:

=ISNA(MATCH(A3, $D$2:$D$9, 0))

Тази формула отива в B3 и след това се копира в B14.

Сега можете ясно да видите кои ученици са преминали успешно всички тестове (в колона D няма име> MATCH връща #N/A> ISNA връща TRUE) и кои имат поне един неуспешен тест (в колона D се появява име> няма грешка> ISNA връща FALSE).

Съвет. В Excel 365 и Excel 2021 можете да използвате по-модерната функция XMATCH вместо MATCH.

Формула IF ISNA в Excel

По замисъл функцията ISNA може да връща само две булеви стойности. За да показвате персонализирани съобщения, използвайте я в комбинация с функцията IF:

Като усъвършенстваме примера си още малко, нека да открием кои ученици от група А не са се провалили на нито един тест и да върнем за тях "Няма провалени тестове". За останалите ученици ще върнем "Не е издържал". За да направите това, вградете формулата ISNA MATCH в логическия тест на IF, така че IF да стане най-външната функция:

=IF(ISNA(MATCH(A3,$D$2:$D$9,0)), "Няма неуспешни тестове", "Неуспешни")

Сега резултатите изглеждат много по-добре и по-интуитивно, съгласни ли сте?

Как да използвате ISNA в Excel с VLOOKUP

Комбинацията IF ISNA е универсално решение, което може да се използва с всяка функция, която търси нещо в набор от данни и връща грешка #N/A, когато стойността за търсене не е намерена.

Синтаксисът на функцията ISNA с VLOOKUP е следният:

Преведена на човешки език, тя гласи: ако VLOOKUP доведе до грешка #N/A, върнете потребителски текст, в противен случай върнете резултата от VLOOKUP.

Предполагаме, че в нашата примерна таблица желаете да върнете предметите, по които учениците не са издържали тестовете. За тези, които са издържали успешно всички тестове, ще се покаже "Няма неиздържани тестове".

За да потърсим предметите, съставяме тази класическа формула VLOOKUP:

=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)

И след това го вложете в общата формула IF ISNA, разгледана по-горе:

=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "Няма неуспешни тестове", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))

В Excel 2013 и по-късните версии можете да използвате функцията IFNA, за да улавяте и обработвате грешки #N/A. Това прави формулата ви по-кратка и по-лесна за четене.

Като пример, заменяме грешките #N/A с тирета ("-") и получаваме това елегантно решение:

=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "-")

Потребителите на Excel 365 и 2021 изобщо не се нуждаят от обвиваща функция, тъй като съвременният наследник на VLOOKUP, функцията XLOOKUP, може да обработва грешки #N/A по естествен път:

=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "-")

Резултатът ще бъде точно същият, както е показано на снимката по-горе.

Формула SUMPRODUCT ISNA за преброяване на грешките #N/A

За да преброите грешките #N/A в определен диапазон, използвайте функцията ISNA заедно със SUMPRODUCT по този начин:

Тук ISNA връща масив от стойности TRUE и FALSE, двойното отрицание (--) превръща логическите стойности в 1 и 0, а SUMPRODUCT събира резултата.

Например, за да разберете колко ученици са издържали всички тестове, модифицирайте формулата MATCH за диапазон от стойности за търсене (A3:A14) и я вложете в ISNA:

=SUMPRODUCT(--ISNA(MATCH(A3:A14, D2:D9, 0)))

Формулата определя, че 9 ученици нямат неуспешни тестове, т.е. функцията MATCH връща 9 грешки #N/A:

Това е начинът за създаване и използване на формулите ISNA в Excel. Благодаря ви, че прочетохте, и с нетърпение очаквам да ви видя в нашия блог следващата седмица!

Налични изтегляния

Примери за формули на ISNA (.xlsx файл)